eldoc.el 17.8 KB
Newer Older
Noah Friedman's avatar
Noah Friedman committed
1 2
;;; eldoc.el --- show function arglist or variable docstring in echo area

Lute Kamstra's avatar
Lute Kamstra committed
3 4
;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2003, 2005
;;   Free Software Foundation, Inc.
Noah Friedman's avatar
Noah Friedman committed
5

6 7
;; Author: Noah Friedman <friedman@splode.com>
;; Maintainer: friedman@splode.com
Noah Friedman's avatar
Noah Friedman committed
8 9 10
;; Keywords: extensions
;; Created: 1995-10-06

11
;; This file is part of GNU Emacs.
Noah Friedman's avatar
Noah Friedman committed
12

13
;; GNU Emacs is free software; you can redistribute it and/or modify
Noah Friedman's avatar
Noah Friedman committed
14 15 16
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.
17 18

;; GNU Emacs is distributed in the hope that it will be useful,
Noah Friedman's avatar
Noah Friedman committed
19 20 21
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.
22

Noah Friedman's avatar
Noah Friedman committed
23
;; You should have received a copy of the GNU General Public License
24 25 26
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.
Noah Friedman's avatar
Noah Friedman committed
27 28 29

;;; Commentary:

30 31 32 33 34 35 36 37
;; This program was inspired by the behavior of the "mouse documentation
;; window" on many Lisp Machine systems; as you type a function's symbol
;; name as part of a sexp, it will print the argument list for that
;; function.  Behavior is not identical; for example, you need not actually
;; type the function name, you need only move point around in a sexp that
;; calls it.  Also, if point is over a documented variable, it will print
;; the one-line documentation for that variable instead, to remind you of
;; that variable's meaning.
Noah Friedman's avatar
Noah Friedman committed
38 39 40 41 42 43

;; One useful way to enable this minor mode is to put the following in your
;; .emacs:
;;
;;      (add-hook 'emacs-lisp-mode-hook 'turn-on-eldoc-mode)
;;      (add-hook 'lisp-interaction-mode-hook 'turn-on-eldoc-mode)
44
;;      (add-hook 'ielm-mode-hook 'turn-on-eldoc-mode)
Noah Friedman's avatar
Noah Friedman committed
45

46 47 48 49
;; Major modes for other languages may use Eldoc by defining an
;; appropriate function as the buffer-local value of
;; `eldoc-print-current-symbol-info-function'.

Noah Friedman's avatar
Noah Friedman committed
50 51
;;; Code:

52 53
(require 'help-fns)		       ;For fundoc-usage handling functions.

54 55
(defgroup eldoc nil
  "Show function arglist or variable docstring in echo area."
56
  :group 'lisp
57 58 59
  :group 'extensions)

(defcustom eldoc-idle-delay 0.50
Noah Friedman's avatar
Noah Friedman committed
60 61 62 63
  "*Number of seconds of idle time to wait before printing.
If user input arrives before this interval of time has elapsed after the
last input, no documentation will be printed.

64 65 66
If this variable is set to 0, no idle time is required."
  :type 'number
  :group 'eldoc)
Noah Friedman's avatar
Noah Friedman committed
67

68
;;;###autoload
69
(defcustom eldoc-minor-mode-string " ElDoc"
70 71
  "*String to display in mode line when Eldoc Mode is enabled; nil for none."
  :type '(choice string (const :tag "None" nil))
72
  :group 'eldoc)
73

74
(defcustom eldoc-argument-case 'upcase
Noah Friedman's avatar
Noah Friedman committed
75 76 77
  "Case to display argument names of functions, as a symbol.
This has two preferred values: `upcase' or `downcase'.
Actually, any name of a function which takes a string as an argument and
78
returns another string is acceptable."
79 80 81
  :type '(radio (function-item upcase)
		(function-item downcase)
                function)
82
  :group 'eldoc)
Noah Friedman's avatar
Noah Friedman committed
83

84 85
(defcustom eldoc-echo-area-use-multiline-p 'truncate-sym-name-if-fit
  "*Allow long eldoc messages to resize echo area display.
86
If value is t, never attempt to truncate messages; complete symbol name
87 88 89
and function arglist or 1-line variable documentation will be displayed
even if echo area must be resized to fit.

90
If value is any non-nil value other than t, symbol name may be truncated
91 92 93 94 95 96
if it will enable the function arglist or documentation string to fit on a
single line without resizing window.  Otherwise, behavior is just like
former case.

If value is nil, messages are always truncated to fit in a single line of
display in the echo area.  Function or variable symbol name may be
97
truncated to make more of the arglist or documentation string visible."
98 99 100 101 102 103 104 105
  :type '(radio (const :tag "Always" t)
                (const :tag "Never" nil)
                (const :tag "Yes, but truncate symbol names if it will\
 enable argument list to fit on one line" truncate-sym-name-if-fit))
  :group 'eldoc)

;;; No user options below here.

106 107 108 109 110 111 112 113
;; Commands after which it is appropriate to print in the echo area.
;; Eldoc does not try to print function arglists, etc. after just any command,
;; because some commands print their own messages in the echo area and these
;; functions would instantly overwrite them.  But self-insert-command as well
;; as most motion commands are good candidates.
;; This variable contains an obarray of symbols; do not manipulate it
;; directly.  Instead, use `eldoc-add-command' and `eldoc-remove-command'.
(defvar eldoc-message-commands nil)
Noah Friedman's avatar
Noah Friedman committed
114

115 116
;; This is used by eldoc-add-command to initialize eldoc-message-commands
;; as an obarray.
117 118 119 120 121
;; It should probably never be necessary to do so, but if you
;; choose to increase the number of buckets, you must do so before loading
;; this file since the obarray is initialized at load time.
;; Remember to keep it a prime number to improve hash performance.
(defvar eldoc-message-commands-table-size 31)
Noah Friedman's avatar
Noah Friedman committed
122

123 124 125 126 127 128
;; Bookkeeping; elements are as follows:
;;   0 - contains the last symbol read from the buffer.
;;   1 - contains the string last displayed in the echo area for that
;;       symbol, so it can be printed again if necessary without reconsing.
;;   2 - 'function if function args, 'variable if variable documentation.
(defvar eldoc-last-data (make-vector 3 nil))
129
(defvar eldoc-last-message nil)
Noah Friedman's avatar
Noah Friedman committed
130

131
;; eldoc's timer object.
132 133 134 135 136
(defvar eldoc-timer nil)

;; idle time delay currently in use by timer.
;; This is used to determine if eldoc-idle-delay is changed by the user.
(defvar eldoc-current-idle-delay eldoc-idle-delay)
Noah Friedman's avatar
Noah Friedman committed
137 138 139


;;;###autoload
140 141
(define-minor-mode eldoc-mode
  "Toggle ElDoc mode on or off.
Richard M. Stallman's avatar
Richard M. Stallman committed
142 143 144 145 146
In ElDoc mode, the echo area displays information about a
function or variable in the text where point is.  If point is
on a documented variable, it displays that variable's doc string.
Otherwise it displays the argument list of the function called
in the expression point is on.
147 148

With prefix ARG, turn ElDoc mode on if and only if ARG is positive."
Lute Kamstra's avatar
Lute Kamstra committed
149
  :group 'eldoc :lighter eldoc-minor-mode-string
150
  (setq eldoc-last-message nil)
151 152 153 154 155 156
  (if eldoc-mode
      (progn
	(add-hook 'post-command-hook 'eldoc-schedule-timer nil t)
	(add-hook 'pre-command-hook 'eldoc-pre-command-refresh-echo-area t))
   (remove-hook 'post-command-hook 'eldoc-schedule-timer)
   (remove-hook 'pre-command-hook 'eldoc-pre-command-refresh-echo-area)))
Noah Friedman's avatar
Noah Friedman committed
157 158 159 160 161 162 163

;;;###autoload
(defun turn-on-eldoc-mode ()
  "Unequivocally turn on eldoc-mode (see variable documentation)."
  (interactive)
  (eldoc-mode 1))

164

165 166 167 168 169 170 171 172 173 174 175 176
(defun eldoc-schedule-timer ()
  (or (and eldoc-timer
           (memq eldoc-timer timer-idle-list))
      (setq eldoc-timer
            (run-with-idle-timer eldoc-idle-delay t
                                 'eldoc-print-current-symbol-info)))

  ;; If user has changed the idle delay, update the timer.
  (cond ((not (= eldoc-idle-delay eldoc-current-idle-delay))
         (setq eldoc-current-idle-delay eldoc-idle-delay)
         (timer-set-idle-time eldoc-timer eldoc-idle-delay t))))

177 178
(defun eldoc-message (&rest args)
  (let ((omessage eldoc-last-message))
179
    (setq eldoc-last-message
180 181 182 183 184 185 186
	  (cond ((eq (car args) eldoc-last-message) eldoc-last-message)
		((null (car args)) nil)
		;; If only one arg, no formatting to do, so put it in
		;; eldoc-last-message so eq test above might succeed on
		;; subsequent calls.
		((null (cdr args)) (car args))
		(t (apply 'format args))))
187 188 189
    ;; In emacs 19.29 and later, and XEmacs 19.13 and later, all messages
    ;; are recorded in a log.  Do not put eldoc messages in that log since
    ;; they are Legion.
190 191 192 193
    ;; Emacs way of preventing log messages.
    (let ((message-log-max nil))
      (cond (eldoc-last-message (message "%s" eldoc-last-message))
	    (omessage (message nil)))))
194 195
  eldoc-last-message)

196 197 198 199 200 201 202 203 204 205 206
;; This function goes on pre-command-hook for XEmacs or when using idle
;; timers in Emacs.  Motion commands clear the echo area for some reason,
;; which make eldoc messages flicker or disappear just before motion
;; begins.  This function reprints the last eldoc message immediately
;; before the next command executes, which does away with the flicker.
;; This doesn't seem to be required for Emacs 19.28 and earlier.
(defun eldoc-pre-command-refresh-echo-area ()
  (and eldoc-last-message
       (if (eldoc-display-message-no-interference-p)
           (eldoc-message eldoc-last-message)
         (setq eldoc-last-message nil))))
207 208 209

;; Decide whether now is a good time to display a message.
(defun eldoc-display-message-p ()
210
  (and (eldoc-display-message-no-interference-p)
211 212 213 214 215 216 217 218
       ;; If this-command is non-nil while running via an idle
       ;; timer, we're still in the middle of executing a command,
       ;; e.g. a query-replace where it would be annoying to
       ;; overwrite the echo area.
       (and (not this-command)
	    (symbolp last-command)
	    (intern-soft (symbol-name last-command)
			 eldoc-message-commands))))
Noah Friedman's avatar
Noah Friedman committed
219

220 221
;; Check various conditions about the current environment that might make
;; it undesirable to print eldoc messages right this instant.
222 223 224
(defun eldoc-display-message-no-interference-p ()
  (and eldoc-mode
       (not executing-kbd-macro)
225
       (not (and (boundp 'edebug-active) edebug-active))
226 227 228 229 230
       ;; Having this mode operate in an active minibuffer/echo area causes
       ;; interference with what's going on there.
       (not cursor-in-echo-area)
       (not (eq (selected-window) (minibuffer-window)))))

231

Richard M. Stallman's avatar
Richard M. Stallman committed
232
(defvar eldoc-documentation-function nil
233 234 235 236 237 238 239 240 241 242
  "If non-nil, function to call to return doc string.
The function of no args should return a one-line string for displaying
doc about a function etc. appropriate to the context around point.
It should return nil if there's no doc appropriate for the context.
Typically doc is returned if point is on a function-like name or in its
arg list.

This variable is expected to be made buffer-local by modes (other than
Emacs Lisp mode) that support Eldoc.")

243
(defun eldoc-print-current-symbol-info ()
244 245
  (condition-case err
      (and (eldoc-display-message-p)
Richard M. Stallman's avatar
Richard M. Stallman committed
246 247
	   (if eldoc-documentation-function
	       (eldoc-message (funcall eldoc-documentation-function))
248 249 250 251 252 253 254 255 256 257
	     (let* ((current-symbol (eldoc-current-symbol))
		    (current-fnsym  (eldoc-fnsym-in-current-sexp))
		    (doc (cond
			  ((eq current-symbol current-fnsym)
			   (or (eldoc-get-fnsym-args-string current-fnsym)
			       (eldoc-get-var-docstring current-symbol)))
			  (t
			   (or (eldoc-get-var-docstring current-symbol)
			       (eldoc-get-fnsym-args-string current-fnsym))))))
	       (eldoc-message doc))))
258 259 260
    ;; This is run from post-command-hook or some idle timer thing,
    ;; so we need to be careful that errors aren't ignored.
    (error (message "eldoc error: %s" err))))
261 262 263 264 265 266 267

;; Return a string containing the function parameter list, or 1-line
;; docstring if function is a subr and no arglist is obtainable from the
;; docstring or elsewhere.
(defun eldoc-get-fnsym-args-string (sym)
  (let ((args nil)
        (doc nil))
268
    (cond ((not (and sym (symbolp sym) (fboundp sym))))
269 270 271
          ((and (eq sym (aref eldoc-last-data 0))
                (eq 'function (aref eldoc-last-data 2)))
           (setq doc (aref eldoc-last-data 1)))
272 273 274 275
	  ((setq doc (help-split-fundoc (documentation sym t) sym))
	   (setq args (car doc))
	   (string-match "\\`[^ )]* ?" args)
	   (setq args (concat "(" (substring args (match-end 0)))))
Noah Friedman's avatar
Noah Friedman committed
276
          (t
277 278 279 280 281 282 283 284 285
           (setq args (eldoc-function-argstring sym))))
    (cond (args
           (setq doc (eldoc-docstring-format-sym-doc sym args))
           (eldoc-last-data-store sym doc 'function)))
    doc))

;; Return a string containing a brief (one-line) documentation string for
;; the variable.
(defun eldoc-get-var-docstring (sym)
286 287 288 289 290 291 292 293 294 295 296
  (when sym
    (cond ((and (eq sym (aref eldoc-last-data 0))
		(eq 'variable (aref eldoc-last-data 2)))
	   (aref eldoc-last-data 1))
	  (t
	   (let ((doc (documentation-property sym 'variable-documentation t)))
	     (cond (doc
		    (setq doc (eldoc-docstring-format-sym-doc
			       sym (eldoc-docstring-first-line doc)))
		    (eldoc-last-data-store sym doc 'variable)))
	     doc)))))
297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320

(defun eldoc-last-data-store (symbol doc type)
  (aset eldoc-last-data 0 symbol)
  (aset eldoc-last-data 1 doc)
  (aset eldoc-last-data 2 type))

;; Note that any leading `*' in the docstring (which indicates the variable
;; is a user option) is removed.
(defun eldoc-docstring-first-line (doc)
  (and (stringp doc)
       (substitute-command-keys
        (save-match-data
          (let ((start (if (string-match "^\\*" doc) (match-end 0) 0)))
            (cond ((string-match "\n" doc)
                   (substring doc start (match-beginning 0)))
                  ((zerop start) doc)
                  (t (substring doc start))))))))

;; If the entire line cannot fit in the echo area, the symbol name may be
;; truncated or eliminated entirely from the output to make room for the
;; description.
(defun eldoc-docstring-format-sym-doc (sym doc)
  (save-match-data
    (let* ((name (symbol-name sym))
321
           (ea-multi eldoc-echo-area-use-multiline-p)
322 323 324 325 326 327 328 329 330 331 332 333 334
           ;; Subtract 1 from window width since emacs will not write
           ;; any chars to the last column, or in later versions, will
           ;; cause a wraparound and resize of the echo area.
           (ea-width (1- (window-width (minibuffer-window))))
           (strip (- (+ (length name) (length ": ") (length doc)) ea-width)))
      (cond ((or (<= strip 0)
                 (eq ea-multi t)
                 (and ea-multi (> (length doc) ea-width)))
             (format "%s: %s" sym doc))
            ((> (length doc) ea-width)
             (substring (format "%s" doc) 0 ea-width))
            ((>= strip (length name))
             (format "%s" doc))
335
            (t
336 337 338 339 340
             ;; Show the end of the partial symbol name, rather
             ;; than the beginning, since the former is more likely
             ;; to be unique given package namespace conventions.
             (setq name (substring name strip))
             (format "%s: %s" name doc))))))
Noah Friedman's avatar
Noah Friedman committed
341

342

Noah Friedman's avatar
Noah Friedman committed
343
(defun eldoc-fnsym-in-current-sexp ()
344 345 346 347 348 349 350 351 352 353 354 355 356 357
  (let ((p (point)))
    (eldoc-beginning-of-sexp)
    (prog1
        ;; Don't do anything if current word is inside a string.
        (if (= (or (char-after (1- (point))) 0) ?\")
            nil
          (eldoc-current-symbol))
      (goto-char p))))

(defun eldoc-beginning-of-sexp ()
  (let ((parse-sexp-ignore-comments t))
    (condition-case err
        (while (progn
                 (forward-sexp -1)
358
                 (or (= (char-before) ?\")
359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377
                     (> (point) (point-min)))))
      (error nil))))

;; returns nil unless current word is an interned symbol.
(defun eldoc-current-symbol ()
  (let ((c (char-after (point))))
    (and c
         (memq (char-syntax c) '(?w ?_))
         (intern-soft (current-word)))))

;; Do indirect function resolution if possible.
(defun eldoc-symbol-function (fsym)
  (let ((defn (and (fboundp fsym)
                   (symbol-function fsym))))
    (and (symbolp defn)
         (condition-case err
             (setq defn (indirect-function fsym))
           (error (setq defn nil))))
    defn))
Noah Friedman's avatar
Noah Friedman committed
378

379
(defun eldoc-function-argstring (fn)
380
  (eldoc-function-argstring-format (help-function-arglist fn)))
Noah Friedman's avatar
Noah Friedman committed
381

382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401
(defun eldoc-function-argstring-format (arglist)
  (cond ((not (listp arglist))
         (setq arglist nil))
        ((symbolp (car arglist))
         (setq arglist
               (mapcar (function (lambda (s)
                                   (if (memq s '(&optional &rest))
                                       (symbol-name s)
                                     (funcall eldoc-argument-case
                                              (symbol-name s)))))
                       arglist)))
        ((stringp (car arglist))
         (setq arglist
               (mapcar (function (lambda (s)
                                   (if (member s '("&optional" "&rest"))
                                       s
                                     (funcall eldoc-argument-case s))))
                       arglist))))
  (concat "(" (mapconcat 'identity arglist " ") ")"))

Noah Friedman's avatar
Noah Friedman committed
402

403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430
;; When point is in a sexp, the function args are not reprinted in the echo
;; area after every possible interactive command because some of them print
;; their own messages in the echo area; the eldoc functions would instantly
;; overwrite them unless it is more restrained.
;; These functions do display-command table management.

(defun eldoc-add-command (&rest cmds)
  (or eldoc-message-commands
      (setq eldoc-message-commands
            (make-vector eldoc-message-commands-table-size 0)))

  (let (name sym)
    (while cmds
      (setq name (car cmds))
      (setq cmds (cdr cmds))

      (cond ((symbolp name)
             (setq sym name)
             (setq name (symbol-name sym)))
            ((stringp name)
             (setq sym (intern-soft name))))

      (and (symbolp sym)
           (fboundp sym)
           (set (intern name eldoc-message-commands) t)))))

(defun eldoc-add-command-completions (&rest names)
  (while names
431 432 433
    (apply 'eldoc-add-command
	   (all-completions (car names) obarray 'fboundp))
    (setq names (cdr names))))
434 435 436 437 438 439 440 441 442 443

(defun eldoc-remove-command (&rest cmds)
  (let (name)
    (while cmds
      (setq name (car cmds))
      (setq cmds (cdr cmds))

      (and (symbolp name)
           (setq name (symbol-name name)))

444
      (unintern name eldoc-message-commands))))
445 446 447 448 449 450 451

(defun eldoc-remove-command-completions (&rest names)
  (while names
    (apply 'eldoc-remove-command
           (all-completions (car names) eldoc-message-commands))
    (setq names (cdr names))))

452

453 454 455
;; Prime the command list.
(eldoc-add-command-completions
 "backward-" "beginning-of-" "delete-other-windows" "delete-window"
456 457
 "end-of-" "forward-" "indent-for-tab-command" "goto-" "mouse-set-point"
 "next-" "other-window" "previous-" "recenter" "scroll-"
458 459
 "self-insert-command" "split-window-"
 "up-list" "down-list")
Noah Friedman's avatar
Noah Friedman committed
460 461 462

(provide 'eldoc)

Miles Bader's avatar
Miles Bader committed
463
;;; arch-tag: c9a58f9d-2055-46c1-9b82-7248b71a8375
Noah Friedman's avatar
Noah Friedman committed
464
;;; eldoc.el ends here