cl-extra.el 29.6 KB
Newer Older
1
;;; cl-extra.el --- Common Lisp features, part 2  -*- lexical-binding: t -*-
Richard M. Stallman's avatar
Richard M. Stallman committed
2

Paul Eggert's avatar
Paul Eggert committed
3
;; Copyright (C) 1993, 2000-2015 Free Software Foundation, Inc.
Richard M. Stallman's avatar
Richard M. Stallman committed
4 5 6

;; Author: Dave Gillespie <daveg@synaptics.com>
;; Keywords: extensions
7
;; Package: emacs
Richard M. Stallman's avatar
Richard M. Stallman committed
8 9 10

;; This file is part of GNU Emacs.

11
;; GNU Emacs is free software: you can redistribute it and/or modify
Richard M. Stallman's avatar
Richard M. Stallman committed
12
;; it under the terms of the GNU General Public License as published by
13 14
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Richard M. Stallman's avatar
Richard M. Stallman committed
15 16 17 18 19 20 21

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
Richard M. Stallman's avatar
Richard M. Stallman committed
23

Richard M. Stallman's avatar
Richard M. Stallman committed
24
;;; Commentary:
Richard M. Stallman's avatar
Richard M. Stallman committed
25 26 27 28 29 30 31 32 33 34 35 36 37

;; These are extensions to Emacs Lisp that provide a degree of
;; Common Lisp compatibility, beyond what is already built-in
;; in Emacs Lisp.
;;
;; This package was written by Dave Gillespie; it is a complete
;; rewrite of Cesar Quiroz's original cl.el package of December 1986.
;;
;; Bug reports, comments, and suggestions are welcome!

;; This file contains portions of the Common Lisp extensions
;; package which are autoloaded since they are relatively obscure.

Richard M. Stallman's avatar
Richard M. Stallman committed
38
;;; Code:
Richard M. Stallman's avatar
Richard M. Stallman committed
39

40
(require 'cl-lib)
41
(require 'seq)
Richard M. Stallman's avatar
Richard M. Stallman committed
42 43 44

;;; Type coercion.

45
;;;###autoload
46
(defun cl-coerce (x type)
Richard M. Stallman's avatar
Richard M. Stallman committed
47
  "Coerce OBJECT to type TYPE.
48 49
TYPE is a Common Lisp type specifier.
\n(fn OBJECT TYPE)"
Richard M. Stallman's avatar
Richard M. Stallman committed
50 51 52 53 54
  (cond ((eq type 'list) (if (listp x) x (append x nil)))
	((eq type 'vector) (if (vectorp x) x (vconcat x)))
	((eq type 'string) (if (stringp x) x (concat x)))
	((eq type 'array) (if (arrayp x) x (vconcat x)))
	((and (eq type 'character) (stringp x) (= (length x) 1)) (aref x 0))
55 56
	((and (eq type 'character) (symbolp x))
         (cl-coerce (symbol-name x) type))
Richard M. Stallman's avatar
Richard M. Stallman committed
57
	((eq type 'float) (float x))
58
	((cl-typep x type) x)
Richard M. Stallman's avatar
Richard M. Stallman committed
59 60 61 62 63
	(t (error "Can't coerce %s to type %s" x type))))


;;; Predicates.

64
;;;###autoload
65
(defun cl-equalp (x y)
Juanma Barranquero's avatar
Juanma Barranquero committed
66
  "Return t if two Lisp objects have similar structures and contents.
Richard M. Stallman's avatar
Richard M. Stallman committed
67 68 69 70 71 72
This is like `equal', except that it accepts numerically equal
numbers of different types (float vs. integer), and also compares
strings case-insensitively."
  (cond ((eq x y) t)
	((stringp x)
	 (and (stringp y) (= (length x) (length y))
73
	      (or (string-equal x y)
74
		  (string-equal (downcase x) (downcase y))))) ;Lazy but simple!
Richard M. Stallman's avatar
Richard M. Stallman committed
75 76 77
	((numberp x)
	 (and (numberp y) (= x y)))
	((consp x)
78
	 (while (and (consp x) (consp y) (cl-equalp (car x) (car y)))
79
	   (setq x (cdr x) y (cdr y)))
80
	 (and (not (consp x)) (cl-equalp x y)))
Richard M. Stallman's avatar
Richard M. Stallman committed
81 82 83 84
	((vectorp x)
	 (and (vectorp y) (= (length x) (length y))
	      (let ((i (length x)))
		(while (and (>= (setq i (1- i)) 0)
85
			    (cl-equalp (aref x i) (aref y i))))
Richard M. Stallman's avatar
Richard M. Stallman committed
86 87 88 89 90 91
		(< i 0))))
	(t (equal x y))))


;;; Control structures.

92
;;;###autoload
93
(defun cl--mapcar-many (cl-func cl-seqs)
Richard M. Stallman's avatar
Richard M. Stallman committed
94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109
  (if (cdr (cdr cl-seqs))
      (let* ((cl-res nil)
	     (cl-n (apply 'min (mapcar 'length cl-seqs)))
	     (cl-i 0)
	     (cl-args (copy-sequence cl-seqs))
	     cl-p1 cl-p2)
	(setq cl-seqs (copy-sequence cl-seqs))
	(while (< cl-i cl-n)
	  (setq cl-p1 cl-seqs cl-p2 cl-args)
	  (while cl-p1
	    (setcar cl-p2
		    (if (consp (car cl-p1))
			(prog1 (car (car cl-p1))
			  (setcar cl-p1 (cdr (car cl-p1))))
		      (aref (car cl-p1) cl-i)))
	    (setq cl-p1 (cdr cl-p1) cl-p2 (cdr cl-p2)))
110
	  (push (apply cl-func cl-args) cl-res)
Richard M. Stallman's avatar
Richard M. Stallman committed
111 112 113 114 115 116 117 118
	  (setq cl-i (1+ cl-i)))
	(nreverse cl-res))
    (let ((cl-res nil)
	  (cl-x (car cl-seqs))
	  (cl-y (nth 1 cl-seqs)))
      (let ((cl-n (min (length cl-x) (length cl-y)))
	    (cl-i -1))
	(while (< (setq cl-i (1+ cl-i)) cl-n)
119
	  (push (funcall cl-func
120 121 122
                         (if (consp cl-x) (pop cl-x) (aref cl-x cl-i))
                         (if (consp cl-y) (pop cl-y) (aref cl-y cl-i)))
                cl-res)))
Richard M. Stallman's avatar
Richard M. Stallman committed
123 124
      (nreverse cl-res))))

125
;;;###autoload
126
(defun cl-map (cl-type cl-func cl-seq &rest cl-rest)
127 128 129
  "Map a FUNCTION across one or more SEQUENCEs, returning a sequence.
TYPE is the sequence type to return.
\n(fn TYPE FUNCTION SEQUENCE...)"
130 131
  (let ((cl-res (apply 'cl-mapcar cl-func cl-seq cl-rest)))
    (and cl-type (cl-coerce cl-res cl-type))))
Richard M. Stallman's avatar
Richard M. Stallman committed
132

133
;;;###autoload
134
(defun cl-maplist (cl-func cl-list &rest cl-rest)
135
  "Map FUNCTION to each sublist of LIST or LISTs.
Glenn Morris's avatar
Glenn Morris committed
136
Like `cl-mapcar', except applies to lists and their cdr's rather than to
137 138
the elements themselves.
\n(fn FUNCTION LIST...)"
Richard M. Stallman's avatar
Richard M. Stallman committed
139 140 141 142 143
  (if cl-rest
      (let ((cl-res nil)
	    (cl-args (cons cl-list (copy-sequence cl-rest)))
	    cl-p)
	(while (not (memq nil cl-args))
144
	  (push (apply cl-func cl-args) cl-res)
Richard M. Stallman's avatar
Richard M. Stallman committed
145
	  (setq cl-p cl-args)
146
	  (while cl-p (setcar cl-p (cdr (pop cl-p)) )))
Richard M. Stallman's avatar
Richard M. Stallman committed
147 148 149
	(nreverse cl-res))
    (let ((cl-res nil))
      (while cl-list
150
	(push (funcall cl-func cl-list) cl-res)
Richard M. Stallman's avatar
Richard M. Stallman committed
151 152 153
	(setq cl-list (cdr cl-list)))
      (nreverse cl-res))))

Glenn Morris's avatar
Glenn Morris committed
154
;;;###autoload
Dave Love's avatar
Dave Love committed
155
(defun cl-mapc (cl-func cl-seq &rest cl-rest)
Glenn Morris's avatar
Glenn Morris committed
156
  "Like `cl-mapcar', but does not accumulate values returned by the function.
157
\n(fn FUNCTION SEQUENCE...)"
Richard M. Stallman's avatar
Richard M. Stallman committed
158
  (if cl-rest
159
      (progn (apply 'cl-map nil cl-func cl-seq cl-rest)
Dave Love's avatar
Dave Love committed
160
	     cl-seq)
161
    (mapc cl-func cl-seq)))
Richard M. Stallman's avatar
Richard M. Stallman committed
162

163
;;;###autoload
164 165
(defun cl-mapl (cl-func cl-list &rest cl-rest)
  "Like `cl-maplist', but does not accumulate values returned by the function.
166
\n(fn FUNCTION LIST...)"
Richard M. Stallman's avatar
Richard M. Stallman committed
167
  (if cl-rest
168
      (apply 'cl-maplist cl-func cl-list cl-rest)
Richard M. Stallman's avatar
Richard M. Stallman committed
169 170 171 172
    (let ((cl-p cl-list))
      (while cl-p (funcall cl-func cl-p) (setq cl-p (cdr cl-p)))))
  cl-list)

173
;;;###autoload
174
(defun cl-mapcan (cl-func cl-seq &rest cl-rest)
Glenn Morris's avatar
Glenn Morris committed
175
  "Like `cl-mapcar', but nconc's together the values returned by the function.
176
\n(fn FUNCTION SEQUENCE...)"
177
  (apply 'nconc (apply 'cl-mapcar cl-func cl-seq cl-rest)))
Richard M. Stallman's avatar
Richard M. Stallman committed
178

179
;;;###autoload
180 181
(defun cl-mapcon (cl-func cl-list &rest cl-rest)
  "Like `cl-maplist', but nconc's together the values returned by the function.
182
\n(fn FUNCTION LIST...)"
183
  (apply 'nconc (apply 'cl-maplist cl-func cl-list cl-rest)))
Richard M. Stallman's avatar
Richard M. Stallman committed
184

185
;;;###autoload
186
(defun cl-some (cl-pred cl-seq &rest cl-rest)
Richard M. Stallman's avatar
Richard M. Stallman committed
187
  "Return true if PREDICATE is true of any element of SEQ or SEQs.
188 189
If so, return the true (non-nil) value returned by PREDICATE.
\n(fn PREDICATE SEQ...)"
Richard M. Stallman's avatar
Richard M. Stallman committed
190 191
  (if (or cl-rest (nlistp cl-seq))
      (catch 'cl-some
192
	(apply 'cl-map nil
Richard M. Stallman's avatar
Richard M. Stallman committed
193 194 195 196 197
	       (function (lambda (&rest cl-x)
			   (let ((cl-res (apply cl-pred cl-x)))
			     (if cl-res (throw 'cl-some cl-res)))))
	       cl-seq cl-rest) nil)
    (let ((cl-x nil))
198
      (while (and cl-seq (not (setq cl-x (funcall cl-pred (pop cl-seq))))))
Richard M. Stallman's avatar
Richard M. Stallman committed
199 200
      cl-x)))

201
;;;###autoload
202
(defun cl-every (cl-pred cl-seq &rest cl-rest)
203 204
  "Return true if PREDICATE is true of every element of SEQ or SEQs.
\n(fn PREDICATE SEQ...)"
Richard M. Stallman's avatar
Richard M. Stallman committed
205 206
  (if (or cl-rest (nlistp cl-seq))
      (catch 'cl-every
207
	(apply 'cl-map nil
Richard M. Stallman's avatar
Richard M. Stallman committed
208 209 210 211 212 213 214
	       (function (lambda (&rest cl-x)
			   (or (apply cl-pred cl-x) (throw 'cl-every nil))))
	       cl-seq cl-rest) t)
    (while (and cl-seq (funcall cl-pred (car cl-seq)))
      (setq cl-seq (cdr cl-seq)))
    (null cl-seq)))

215
;;;###autoload
216
(defun cl-notany (cl-pred cl-seq &rest cl-rest)
217 218
  "Return true if PREDICATE is false of every element of SEQ or SEQs.
\n(fn PREDICATE SEQ...)"
219
  (not (apply 'cl-some cl-pred cl-seq cl-rest)))
Richard M. Stallman's avatar
Richard M. Stallman committed
220

221
;;;###autoload
222
(defun cl-notevery (cl-pred cl-seq &rest cl-rest)
223 224
  "Return true if PREDICATE is false of some element of SEQ or SEQs.
\n(fn PREDICATE SEQ...)"
225
  (not (apply 'cl-every cl-pred cl-seq cl-rest)))
Richard M. Stallman's avatar
Richard M. Stallman committed
226

227
;;;###autoload
228
(defun cl--map-keymap-recursively (cl-func-rec cl-map &optional cl-base)
Richard M. Stallman's avatar
Richard M. Stallman committed
229
  (or cl-base
Dave Love's avatar
Dave Love committed
230
      (setq cl-base (copy-sequence [0])))
231
  (map-keymap
Richard M. Stallman's avatar
Richard M. Stallman committed
232 233 234 235
   (function
    (lambda (cl-key cl-bind)
      (aset cl-base (1- (length cl-base)) cl-key)
      (if (keymapp cl-bind)
236
	  (cl--map-keymap-recursively
Richard M. Stallman's avatar
Richard M. Stallman committed
237
	   cl-func-rec cl-bind
Dave Love's avatar
Dave Love committed
238
	   (vconcat cl-base (list 0)))
Richard M. Stallman's avatar
Richard M. Stallman committed
239 240 241
	(funcall cl-func-rec cl-base cl-bind))))
   cl-map))

242
;;;###autoload
243
(defun cl--map-intervals (cl-func &optional cl-what cl-prop cl-start cl-end)
Richard M. Stallman's avatar
Richard M. Stallman committed
244 245 246
  (or cl-what (setq cl-what (current-buffer)))
  (if (bufferp cl-what)
      (let (cl-mark cl-mark2 (cl-next t) cl-next2)
Dave Love's avatar
Dave Love committed
247
	(with-current-buffer cl-what
Richard M. Stallman's avatar
Richard M. Stallman committed
248 249 250
	  (setq cl-mark (copy-marker (or cl-start (point-min))))
	  (setq cl-mark2 (and cl-end (copy-marker cl-end))))
	(while (and cl-next (or (not cl-mark2) (< cl-mark cl-mark2)))
Dave Love's avatar
Dave Love committed
251 252 253 254 255
	  (setq cl-next (if cl-prop (next-single-property-change
				     cl-mark cl-prop cl-what)
			  (next-property-change cl-mark cl-what))
		cl-next2 (or cl-next (with-current-buffer cl-what
				       (point-max))))
Richard M. Stallman's avatar
Richard M. Stallman committed
256 257 258 259 260 261 262
	  (funcall cl-func (prog1 (marker-position cl-mark)
			     (set-marker cl-mark cl-next2))
		   (if cl-mark2 (min cl-next2 cl-mark2) cl-next2)))
	(set-marker cl-mark nil) (if cl-mark2 (set-marker cl-mark2 nil)))
    (or cl-start (setq cl-start 0))
    (or cl-end (setq cl-end (length cl-what)))
    (while (< cl-start cl-end)
Dave Love's avatar
Dave Love committed
263 264 265
      (let ((cl-next (or (if cl-prop (next-single-property-change
				      cl-start cl-prop cl-what)
			   (next-property-change cl-start cl-what))
Richard M. Stallman's avatar
Richard M. Stallman committed
266 267 268 269
			 cl-end)))
	(funcall cl-func cl-start (min cl-next cl-end))
	(setq cl-start cl-next)))))

270
;;;###autoload
271
(defun cl--map-overlays (cl-func &optional cl-buffer cl-start cl-end cl-arg)
Richard M. Stallman's avatar
Richard M. Stallman committed
272
  (or cl-buffer (setq cl-buffer (current-buffer)))
273 274 275 276 277 278 279 280 281 282 283 284 285 286
  (let (cl-ovl)
    (with-current-buffer cl-buffer
      (setq cl-ovl (overlay-lists))
      (if cl-start (setq cl-start (copy-marker cl-start)))
      (if cl-end (setq cl-end (copy-marker cl-end))))
    (setq cl-ovl (nconc (car cl-ovl) (cdr cl-ovl)))
    (while (and cl-ovl
		(or (not (overlay-start (car cl-ovl)))
		    (and cl-end (>= (overlay-start (car cl-ovl)) cl-end))
		    (and cl-start (<= (overlay-end (car cl-ovl)) cl-start))
		    (not (funcall cl-func (car cl-ovl) cl-arg))))
      (setq cl-ovl (cdr cl-ovl)))
    (if cl-start (set-marker cl-start nil))
    (if cl-end (set-marker cl-end nil))))
Richard M. Stallman's avatar
Richard M. Stallman committed
287

288
;;; Support for `setf'.
289
;;;###autoload
290
(defun cl--set-frame-visible-p (frame val)
Richard M. Stallman's avatar
Richard M. Stallman committed
291 292 293 294 295 296 297 298
  (cond ((null val) (make-frame-invisible frame))
	((eq val 'icon) (iconify-frame frame))
	(t (make-frame-visible frame)))
  val)


;;; Numbers.

299
;;;###autoload
300
(defun cl-gcd (&rest args)
Richard M. Stallman's avatar
Richard M. Stallman committed
301
  "Return the greatest common divisor of the arguments."
302 303 304 305 306
  (let ((a (or (pop args) 0)))
    (dolist (b args)
      (while (/= b 0)
        (setq b (% a (setq a b)))))
    (abs a)))
Richard M. Stallman's avatar
Richard M. Stallman committed
307

308
;;;###autoload
309
(defun cl-lcm (&rest args)
Richard M. Stallman's avatar
Richard M. Stallman committed
310 311 312
  "Return the least common multiple of the arguments."
  (if (memq 0 args)
      0
313 314 315 316
    (let ((a (or (pop args) 1)))
      (dolist (b args)
        (setq a (* (/ a (cl-gcd a b)) b)))
      (abs a))))
Richard M. Stallman's avatar
Richard M. Stallman committed
317

318
;;;###autoload
319
(defun cl-isqrt (x)
Richard M. Stallman's avatar
Richard M. Stallman committed
320
  "Return the integer square root of the argument."
321 322 323
  (if (and (integerp x) (> x 0))
      (let ((g (cond ((<= x 100) 10) ((<= x 10000) 100)
		     ((<= x 1000000) 1000) (t x)))
Richard M. Stallman's avatar
Richard M. Stallman committed
324
	    g2)
325
	(while (< (setq g2 (/ (+ g (/ x g)) 2)) g)
Richard M. Stallman's avatar
Richard M. Stallman committed
326 327
	  (setq g g2))
	g)
328
    (if (eq x 0) 0 (signal 'arith-error nil))))
Richard M. Stallman's avatar
Richard M. Stallman committed
329

330
;;;###autoload
331
(defun cl-floor (x &optional y)
Richard M. Stallman's avatar
Richard M. Stallman committed
332 333
  "Return a list of the floor of X and the fractional part of X.
With two arguments, return floor and remainder of their quotient."
334 335
  (let ((q (floor x y)))
    (list q (- x (if y (* y q) q)))))
Richard M. Stallman's avatar
Richard M. Stallman committed
336

337
;;;###autoload
338
(defun cl-ceiling (x &optional y)
Richard M. Stallman's avatar
Richard M. Stallman committed
339 340
  "Return a list of the ceiling of X and the fractional part of X.
With two arguments, return ceiling and remainder of their quotient."
341
  (let ((res (cl-floor x y)))
Richard M. Stallman's avatar
Richard M. Stallman committed
342 343 344
    (if (= (car (cdr res)) 0) res
      (list (1+ (car res)) (- (car (cdr res)) (or y 1))))))

345
;;;###autoload
346
(defun cl-truncate (x &optional y)
Richard M. Stallman's avatar
Richard M. Stallman committed
347 348 349
  "Return a list of the integer part of X and the fractional part of X.
With two arguments, return truncation and remainder of their quotient."
  (if (eq (>= x 0) (or (null y) (>= y 0)))
350
      (cl-floor x y) (cl-ceiling x y)))
Richard M. Stallman's avatar
Richard M. Stallman committed
351

352
;;;###autoload
353
(defun cl-round (x &optional y)
Richard M. Stallman's avatar
Richard M. Stallman committed
354 355 356 357 358
  "Return a list of X rounded to the nearest integer and the remainder.
With two arguments, return rounding and remainder of their quotient."
  (if y
      (if (and (integerp x) (integerp y))
	  (let* ((hy (/ y 2))
359
		 (res (cl-floor (+ x hy) y)))
Richard M. Stallman's avatar
Richard M. Stallman committed
360 361 362 363 364 365 366 367 368 369 370
	    (if (and (= (car (cdr res)) 0)
		     (= (+ hy hy) y)
		     (/= (% (car res) 2) 0))
		(list (1- (car res)) hy)
	      (list (car res) (- (car (cdr res)) hy))))
	(let ((q (round (/ x y))))
	  (list q (- x (* q y)))))
    (if (integerp x) (list x 0)
      (let ((q (round x)))
	(list q (- x q))))))

371
;;;###autoload
372
(defun cl-mod (x y)
Richard M. Stallman's avatar
Richard M. Stallman committed
373
  "The remainder of X divided by Y, with the same sign as Y."
374
  (nth 1 (cl-floor x y)))
Richard M. Stallman's avatar
Richard M. Stallman committed
375

376
;;;###autoload
377
(defun cl-rem (x y)
Richard M. Stallman's avatar
Richard M. Stallman committed
378
  "The remainder of X divided by Y, with the same sign as X."
379
  (nth 1 (cl-truncate x y)))
Richard M. Stallman's avatar
Richard M. Stallman committed
380

381
;;;###autoload
382
(defun cl-signum (x)
383 384
  "Return 1 if X is positive, -1 if negative, 0 if zero."
  (cond ((> x 0) 1) ((< x 0) -1) (t 0)))
Richard M. Stallman's avatar
Richard M. Stallman committed
385

386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417
;;;###autoload
(cl-defun cl-parse-integer (string &key start end radix junk-allowed)
  "Parse integer from the substring of STRING from START to END.
STRING may be surrounded by whitespace chars (chars with syntax ` ').
Other non-digit chars are considered junk.
RADIX is an integer between 2 and 36, the default is 10.  Signal
an error if the substring between START and END cannot be parsed
as an integer unless JUNK-ALLOWED is non-nil."
  (cl-check-type string string)
  (let* ((start (or start 0))
	 (len	(length string))
	 (end   (or end len))
	 (radix (or radix 10)))
    (or (<= start end len)
	(error "Bad interval: [%d, %d)" start end))
    (cl-flet ((skip-whitespace ()
		(while (and (< start end)
			    (= 32 (char-syntax (aref string start))))
		  (setq start (1+ start)))))
      (skip-whitespace)
      (let ((sign (cl-case (and (< start end) (aref string start))
		    (?+ (cl-incf start) +1)
		    (?- (cl-incf start) -1)
		    (t  +1)))
	    digit sum)
	(while (and (< start end)
		    (setq digit (cl-digit-char-p (aref string start) radix)))
	  (setq sum (+ (* (or sum 0) radix) digit)
		start (1+ start)))
	(skip-whitespace)
	(cond ((and junk-allowed (null sum)) sum)
	      (junk-allowed (* sign sum))
418
	      ((or (/= start end) (null sum))
419
	       (error "Not an integer string: ‘%s’" string))
420 421
	      (t (* sign sum)))))))

Richard M. Stallman's avatar
Richard M. Stallman committed
422 423 424

;; Random numbers.

425
;;;###autoload
426
(defun cl-random (lim &optional state)
Richard M. Stallman's avatar
Richard M. Stallman committed
427 428
  "Return a random nonnegative number less than LIM, an integer or float.
Optional second arg STATE is a random-state object."
429
  (or state (setq state cl--random-state))
Richard M. Stallman's avatar
Richard M. Stallman committed
430 431 432
  ;; Inspired by "ran3" from Numerical Recipes.  Additive congruential method.
  (let ((vec (aref state 3)))
    (if (integerp vec)
433
	(let ((i 0) (j (- 1357335 (abs (% vec 1357333)))) (k 1))
Richard M. Stallman's avatar
Richard M. Stallman committed
434 435 436 437
	  (aset state 3 (setq vec (make-vector 55 nil)))
	  (aset vec 0 j)
	  (while (> (setq i (% (+ i 21) 55)) 0)
	    (aset vec i (setq j (prog1 k (setq k (- j k))))))
438
	  (while (< (setq i (1+ i)) 200) (cl-random 2 state))))
Richard M. Stallman's avatar
Richard M. Stallman committed
439 440 441 442 443
    (let* ((i (aset state 1 (% (1+ (aref state 1)) 55)))
	   (j (aset state 2 (% (1+ (aref state 2)) 55)))
	   (n (logand 8388607 (aset vec i (- (aref vec i) (aref vec j))))))
      (if (integerp lim)
	  (if (<= lim 512) (% n lim)
444
	    (if (> lim 8388607) (setq n (+ (lsh n 9) (cl-random 512 state))))
Richard M. Stallman's avatar
Richard M. Stallman committed
445 446
	    (let ((mask 1023))
	      (while (< mask (1- lim)) (setq mask (1+ (+ mask mask))))
447
	      (if (< (setq n (logand n mask)) lim) n (cl-random lim state))))
Richard M. Stallman's avatar
Richard M. Stallman committed
448 449
	(* (/ n '8388608e0) lim)))))

450
;;;###autoload
451
(defun cl-make-random-state (&optional state)
452
  "Return a copy of random-state STATE, or of the internal state if omitted.
Richard M. Stallman's avatar
Richard M. Stallman committed
453
If STATE is t, return a new state object seeded from the time of day."
454
  (cond ((null state) (cl-make-random-state cl--random-state))
455
	((vectorp state) (copy-tree state t))
456
	((integerp state) (vector 'cl--random-state-tag -1 30 state))
457
	(t (cl-make-random-state (cl--random-time)))))
Richard M. Stallman's avatar
Richard M. Stallman committed
458

459
;;;###autoload
460
(defun cl-random-state-p (object)
Richard M. Stallman's avatar
Richard M. Stallman committed
461 462
  "Return t if OBJECT is a random-state object."
  (and (vectorp object) (= (length object) 4)
463
       (eq (aref object 0) 'cl--random-state-tag)))
Richard M. Stallman's avatar
Richard M. Stallman committed
464 465 466 467


;; Implementation limits.

468 469
(defun cl--finite-do (func a b)
  (condition-case _
Richard M. Stallman's avatar
Richard M. Stallman committed
470 471 472 473
      (let ((res (funcall func a b)))   ; check for IEEE infinity
	(and (numberp res) (/= res (/ res 2)) res))
    (arith-error nil)))

474
;;;###autoload
Richard M. Stallman's avatar
Richard M. Stallman committed
475
(defun cl-float-limits ()
476
  "Initialize the Common Lisp floating-point parameters.
477 478 479 480 481
This sets the values of: `cl-most-positive-float', `cl-most-negative-float',
`cl-least-positive-float', `cl-least-negative-float', `cl-float-epsilon',
`cl-float-negative-epsilon', `cl-least-positive-normalized-float', and
`cl-least-negative-normalized-float'."
  (or cl-most-positive-float (not (numberp '2e1))
Richard M. Stallman's avatar
Richard M. Stallman committed
482 483
      (let ((x '2e0) y z)
	;; Find maximum exponent (first two loops are optimizations)
484 485 486
	(while (cl--finite-do '* x x) (setq x (* x x)))
	(while (cl--finite-do '* x (/ x 2)) (setq x (* x (/ x 2))))
	(while (cl--finite-do '+ x x) (setq x (+ x x)))
Richard M. Stallman's avatar
Richard M. Stallman committed
487
	(setq z x y (/ x 2))
488
	;; Now cl-fill in 1's in the mantissa.
489
	(while (and (cl--finite-do '+ x y) (/= (+ x y) x))
Richard M. Stallman's avatar
Richard M. Stallman committed
490
	  (setq x (+ x y) y (/ y 2)))
491 492
	(setq cl-most-positive-float x
	      cl-most-negative-float (- x))
Richard M. Stallman's avatar
Richard M. Stallman committed
493 494
	;; Divide down until mantissa starts rounding.
	(setq x (/ x z) y (/ 16 z) x (* x y))
495
	(while (condition-case _ (and (= x (* (/ x 2) 2)) (> (/ y 2) 0))
Richard M. Stallman's avatar
Richard M. Stallman committed
496 497
		 (arith-error nil))
	  (setq x (/ x 2) y (/ y 2)))
498 499
	(setq cl-least-positive-normalized-float y
	      cl-least-negative-normalized-float (- y))
Richard M. Stallman's avatar
Richard M. Stallman committed
500 501
	;; Divide down until value underflows to zero.
	(setq x (/ 1 z) y x)
502
	(while (condition-case _ (> (/ x 2) 0) (arith-error nil))
Richard M. Stallman's avatar
Richard M. Stallman committed
503
	  (setq x (/ x 2)))
504 505
	(setq cl-least-positive-float x
	      cl-least-negative-float (- x))
Richard M. Stallman's avatar
Richard M. Stallman committed
506 507
	(setq x '1e0)
	(while (/= (+ '1e0 x) '1e0) (setq x (/ x 2)))
508
	(setq cl-float-epsilon (* x 2))
Richard M. Stallman's avatar
Richard M. Stallman committed
509 510
	(setq x '1e0)
	(while (/= (- '1e0 x) '1e0) (setq x (/ x 2)))
511
	(setq cl-float-negative-epsilon (* x 2))))
Richard M. Stallman's avatar
Richard M. Stallman committed
512 513 514 515 516
  nil)


;;; Sequence functions.

517
;;;###autoload
518
(defun cl-subseq (seq start &optional end)
Richard M. Stallman's avatar
Richard M. Stallman committed
519 520
  "Return the subsequence of SEQ from START to END.
If END is omitted, it defaults to the length of the sequence.
521 522 523
If START or END is negative, it counts from the end.
Signal an error if START or END are outside of the sequence (i.e
too large if positive or too small if negative)"
Stefan Monnier's avatar
Stefan Monnier committed
524 525
  (declare (gv-setter
            (lambda (new)
526 527 528 529
              (macroexp-let2 nil new new
		`(progn (cl-replace ,seq ,new :start1 ,start :end1 ,end)
			,new)))))
  (seq-subseq seq start end))
Richard M. Stallman's avatar
Richard M. Stallman committed
530

531
;;;###autoload
532
(defalias 'cl-concatenate #'seq-concatenate
533
  "Concatenate, into a sequence of type TYPE, the argument SEQUENCEs.
534
\n(fn TYPE SEQUENCE...)")
Richard M. Stallman's avatar
Richard M. Stallman committed
535 536 537 538


;;; List functions.

539
;;;###autoload
540
(defun cl-revappend (x y)
Richard M. Stallman's avatar
Richard M. Stallman committed
541 542 543
  "Equivalent to (append (reverse X) Y)."
  (nconc (reverse x) y))

544
;;;###autoload
545
(defun cl-nreconc (x y)
Richard M. Stallman's avatar
Richard M. Stallman committed
546 547 548
  "Equivalent to (nconc (nreverse X) Y)."
  (nconc (nreverse x) y))

549
;;;###autoload
550
(defun cl-list-length (x)
551
  "Return the length of list X.  Return nil if list is circular."
Richard M. Stallman's avatar
Richard M. Stallman committed
552 553 554 555 556
  (let ((n 0) (fast x) (slow x))
    (while (and (cdr fast) (not (and (eq fast slow) (> n 0))))
      (setq n (+ n 2) fast (cdr (cdr fast)) slow (cdr slow)))
    (if fast (if (cdr fast) nil (1+ n)) n)))

557
;;;###autoload
558
(defun cl-tailp (sublist list)
Richard M. Stallman's avatar
Richard M. Stallman committed
559 560 561 562 563 564 565
  "Return true if SUBLIST is a tail of LIST."
  (while (and (consp list) (not (eq sublist list)))
    (setq list (cdr list)))
  (if (numberp sublist) (equal sublist list) (eq sublist list)))

;;; Property lists.

566
;;;###autoload
567
(defun cl-get (sym tag &optional def)
568 569
  "Return the value of SYMBOL's PROPNAME property, or DEFAULT if none.
\n(fn SYMBOL PROPNAME &optional DEFAULT)"
Stefan Monnier's avatar
Stefan Monnier committed
570
  (declare (compiler-macro cl--compiler-macro-get)
571
           (gv-setter (lambda (store) (ignore def) `(put ,sym ,tag ,store))))
Richard M. Stallman's avatar
Richard M. Stallman committed
572 573
  (or (get sym tag)
      (and def
574
           ;; Make sure `def' is really absent as opposed to set to nil.
Richard M. Stallman's avatar
Richard M. Stallman committed
575 576 577 578
	   (let ((plist (symbol-plist sym)))
	     (while (and plist (not (eq (car plist) tag)))
	       (setq plist (cdr (cdr plist))))
	     (if plist (car (cdr plist)) def)))))
579
(autoload 'cl--compiler-macro-get "cl-macs")
Richard M. Stallman's avatar
Richard M. Stallman committed
580

581
;;;###autoload
582
(defun cl-getf (plist tag &optional def)
Richard M. Stallman's avatar
Richard M. Stallman committed
583
  "Search PROPLIST for property PROPNAME; return its value or DEFAULT.
584 585
PROPLIST is a list of the sort returned by `symbol-plist'.
\n(fn PROPLIST PROPNAME &optional DEFAULT)"
Stefan Monnier's avatar
Stefan Monnier committed
586 587 588
  (declare (gv-expander
            (lambda (do)
              (gv-letplace (getter setter) plist
Leo Liu's avatar
Leo Liu committed
589 590 591 592 593 594 595 596
                (macroexp-let2* nil ((k tag) (d def))
                  (funcall do `(cl-getf ,getter ,k ,d)
			   (lambda (v)
			     (macroexp-let2 nil val v
			       `(progn
				  ,(funcall setter
					    `(cl--set-getf ,getter ,k ,val))
				  ,val)))))))))
Richard M. Stallman's avatar
Richard M. Stallman committed
597 598
  (setplist '--cl-getf-symbol-- plist)
  (or (get '--cl-getf-symbol-- tag)
599 600
      ;; Originally we called cl-get here,
      ;; but that fails, because cl-get has a compiler macro
Karl Heuer's avatar
Karl Heuer committed
601 602
      ;; definition that uses getf!
      (when def
603
        ;; Make sure `def' is really absent as opposed to set to nil.
Karl Heuer's avatar
Karl Heuer committed
604 605 606
	(while (and plist (not (eq (car plist) tag)))
	  (setq plist (cdr (cdr plist))))
	(if plist (car (cdr plist)) def))))
Richard M. Stallman's avatar
Richard M. Stallman committed
607

608
;;;###autoload
609
(defun cl--set-getf (plist tag val)
Richard M. Stallman's avatar
Richard M. Stallman committed
610 611
  (let ((p plist))
    (while (and p (not (eq (car p) tag))) (setq p (cdr (cdr p))))
612
    (if p (progn (setcar (cdr p) val) plist) (cl-list* tag val plist))))
Richard M. Stallman's avatar
Richard M. Stallman committed
613

614
;;;###autoload
615
(defun cl--do-remf (plist tag)
Richard M. Stallman's avatar
Richard M. Stallman committed
616 617 618 619
  (let ((p (cdr plist)))
    (while (and (cdr p) (not (eq (car (cdr p)) tag))) (setq p (cdr (cdr p))))
    (and (cdr p) (progn (setcdr p (cdr (cdr (cdr p)))) t))))

620
;;;###autoload
Richard M. Stallman's avatar
Richard M. Stallman committed
621
(defun cl-remprop (sym tag)
622 623
  "Remove from SYMBOL's plist the property PROPNAME and its value.
\n(fn SYMBOL PROPNAME)"
Richard M. Stallman's avatar
Richard M. Stallman committed
624 625 626
  (let ((plist (symbol-plist sym)))
    (if (and plist (eq tag (car plist)))
	(progn (setplist sym (cdr (cdr plist))) t)
627
      (cl--do-remf plist tag))))
Richard M. Stallman's avatar
Richard M. Stallman committed
628

629 630 631 632 633 634 635
;;; Streams.

;;;###autoload
(defun cl-fresh-line (&optional stream)
  "Output a newline unless already at the beginning of a line."
  (terpri stream 'ensure))

Richard M. Stallman's avatar
Richard M. Stallman committed
636 637 638 639 640 641 642 643 644
;;; Some debugging aids.

(defun cl-prettyprint (form)
  "Insert a pretty-printed rendition of a Lisp FORM in current buffer."
  (let ((pt (point)) last)
    (insert "\n" (prin1-to-string form) "\n")
    (setq last (point))
    (goto-char (1+ pt))
    (while (search-forward "(quote " last t)
645
      (delete-char -7)
Richard M. Stallman's avatar
Richard M. Stallman committed
646 647 648 649
      (insert "'")
      (forward-sexp)
      (delete-char 1))
    (goto-char (1+ pt))
650
    (cl--do-prettyprint)))
Richard M. Stallman's avatar
Richard M. Stallman committed
651

652
(defun cl--do-prettyprint ()
Richard M. Stallman's avatar
Richard M. Stallman committed
653 654 655 656 657
  (skip-chars-forward " ")
  (if (looking-at "(")
      (let ((skip (or (looking-at "((") (looking-at "(prog")
		      (looking-at "(unwind-protect ")
		      (looking-at "(function (")
658
		      (looking-at "(cl--block-wrapper ")))
Richard M. Stallman's avatar
Richard M. Stallman committed
659 660 661 662 663 664 665 666 667
	    (two (or (looking-at "(defun ") (looking-at "(defmacro ")))
	    (let (or (looking-at "(let\\*? ") (looking-at "(while ")))
	    (set (looking-at "(p?set[qf] ")))
	(if (or skip let
		(progn
		  (forward-sexp)
		  (and (>= (current-column) 78) (progn (backward-sexp) t))))
	    (let ((nl t))
	      (forward-char 1)
668 669 670
	      (cl--do-prettyprint)
	      (or skip (looking-at ")") (cl--do-prettyprint))
	      (or (not two) (looking-at ")") (cl--do-prettyprint))
Richard M. Stallman's avatar
Richard M. Stallman committed
671 672 673 674
	      (while (not (looking-at ")"))
		(if set (setq nl (not nl)))
		(if nl (insert "\n"))
		(lisp-indent-line)
675
		(cl--do-prettyprint))
Richard M. Stallman's avatar
Richard M. Stallman committed
676 677 678
	      (forward-char 1))))
    (forward-sexp)))

679
;;;###autoload
Richard M. Stallman's avatar
Richard M. Stallman committed
680
(defun cl-prettyexpand (form &optional full)
Glenn Morris's avatar
Glenn Morris committed
681 682 683
  "Expand macros in FORM and insert the pretty-printed result.
Optional argument FULL non-nil means to expand all macros,
including `cl-block' and `cl-eval-when'."
Richard M. Stallman's avatar
Richard M. Stallman committed
684
  (message "Expanding...")
685
  (let ((cl--compiling-file full)
Richard M. Stallman's avatar
Richard M. Stallman committed
686
	(byte-compile-macro-environment nil))
687 688
    (setq form (macroexpand-all form
                                (and (not full) '((cl-block) (cl-eval-when)))))
Richard M. Stallman's avatar
Richard M. Stallman committed
689 690 691 692
    (message "Formatting...")
    (prog1 (cl-prettyprint form)
      (message ""))))

693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751 752 753 754
;;; Integration into the online help system.

(eval-when-compile (require 'cl-macs))  ;Explicitly, for cl--find-class.
(require 'help-mode)

;; FIXME: We could go crazy and add another entry so describe-symbol can be
;; used with the slot names of CL structs (and/or EIEIO objects).
(add-to-list 'describe-symbol-backends
             `(nil ,#'cl-find-class ,(lambda (s _b _f) (cl-describe-type s))))

(defconst cl--typedef-regexp
  (concat "(" (regexp-opt '("defclass" "defstruct" "cl-defstruct"
                            "cl-deftype" "deftype"))
          "[ \t\r\n]+%s[ \t\r\n]+"))
(with-eval-after-load 'find-func
  (defvar find-function-regexp-alist)
  (add-to-list 'find-function-regexp-alist
               `(define-type . cl--typedef-regexp)))

(define-button-type 'cl-help-type
  :supertype 'help-function-def
  'help-function #'cl-describe-type
  'help-echo (purecopy "mouse-2, RET: describe this type"))

(define-button-type 'cl-type-definition
  :supertype 'help-function-def
  'help-echo (purecopy "mouse-2, RET: find type definition"))

(declare-function help-fns-short-filename "help-fns" (filename))

;;;###autoload
(defun cl-find-class (type) (cl--find-class type))

;;;###autoload
(defun cl-describe-type (type)
  "Display the documentation for type TYPE (a symbol)."
  (interactive
   (let ((str (completing-read "Describe type: " obarray #'cl-find-class t)))
     (if (<= (length str) 0)
         (user-error "Abort!")
       (list (intern str)))))
  (help-setup-xref (list #'cl-describe-type type)
                   (called-interactively-p 'interactive))
  (save-excursion
    (with-help-window (help-buffer)
      (with-current-buffer standard-output
        (let ((class (cl-find-class type)))
          (if class
              (cl--describe-class type class)
            ;; FIXME: Describe other types (the built-in ones, or those from
            ;; cl-deftype).
            (user-error "Unknown type %S" type))))
      (with-current-buffer standard-output
        ;; Return the text we displayed.
        (buffer-string)))))

(defun cl--describe-class (type &optional class)
  (unless class (setq class (cl--find-class type)))
  (let ((location (find-lisp-object-file-name type 'define-type))
        ;; FIXME: Add a `cl-class-of' or `cl-typeof' or somesuch.
        (metatype (cl--class-name (symbol-value (aref class 0)))))
    (insert (symbol-name type)
755
            (substitute-command-keys " is a type (of kind ‘"))
756 757
    (help-insert-xref-button (symbol-name metatype)
                             'cl-help-type metatype)
758
    (insert (substitute-command-keys "’)"))
759
    (when location
760
      (insert (substitute-command-keys " in ‘"))
761 762 763
      (help-insert-xref-button
       (help-fns-short-filename location)
       'cl-type-definition type location 'define-type)
764
      (insert (substitute-command-keys "’")))
765 766 767 768 769 770 771 772 773
    (insert ".\n")

    ;; Parents.
    (let ((pl (cl--class-parents class))
          cur)
      (when pl
        (insert " Inherits from ")
        (while (setq cur (pop pl))
          (setq cur (cl--class-name cur))
774
          (insert (substitute-command-keys "‘"))
775 776
          (help-insert-xref-button (symbol-name cur)
                                   'cl-help-type cur)
777
          (insert (substitute-command-keys (if pl "’, " "’"))))
778 779 780 781 782 783 784 785 786 787
        (insert ".\n")))

    ;; Children, if available.  ¡For EIEIO!
    (let ((ch (condition-case nil
                  (cl-struct-slot-value metatype 'children class)
                (cl-struct-unknown-slot nil)))
          cur)
      (when ch
        (insert " Children ")
        (while (setq cur (pop ch))
788
          (insert (substitute-command-keys "‘"))
789 790
          (help-insert-xref-button (symbol-name cur)
                                   'cl-help-type cur)
791
          (insert (substitute-command-keys (if ch "’, " "’"))))
792 793 794 795 796 797 798 799 800 801 802 803 804 805 806
        (insert ".\n")))

    ;; Type's documentation.
    (let ((doc (cl--class-docstring class)))
      (when doc
        (insert "\n" doc "\n\n")))

    ;; Describe all the slots in this class.
    (cl--describe-class-slots class)

    ;; Describe all the methods specific to this class.
    (let ((generics (cl--generic-all-functions type)))
      (when generics
        (insert (propertize "Specialized Methods:\n\n" 'face 'bold))
        (dolist (generic generics)
807
          (insert (substitute-command-keys "‘"))
808 809
          (help-insert-xref-button (symbol-name generic)
                                   'help-function generic)
810
          (insert (substitute-command-keys "’"))
811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835
          (pcase-dolist (`(,qualifiers ,args ,doc)
                         (cl--generic-method-documentation generic type))
            (insert (format " %s%S\n" qualifiers args)
                    (or doc "")))
          (insert "\n\n"))))))

(defun cl--describe-class-slot (slot)
  (insert
   (concat
    (propertize "Slot: " 'face 'bold)
    (prin1-to-string (cl--slot-descriptor-name slot))
    (unless (eq (cl--slot-descriptor-type slot) t)
      (concat "    type = "
              (prin1-to-string (cl--slot-descriptor-type slot))))
    ;; FIXME: The default init form is treated differently for structs and for
    ;; eieio objects: for structs, the default is nil, for eieio-objects
    ;; it's a special "unbound" value.
    (unless nil ;; (eq (cl--slot-descriptor-initform slot) eieio-unbound)
      (concat "    default = "
              (prin1-to-string (cl--slot-descriptor-initform slot))))
    (when (alist-get :printer (cl--slot-descriptor-props slot))
      (concat "    printer = "
              (prin1-to-string
               (alist-get :printer (cl--slot-descriptor-props slot)))))
    (when (alist-get :documentation (cl--slot-descriptor-props slot))
836 837 838
      (concat "\n  "
              (substitute-command-keys
               (alist-get :documentation (cl--slot-descriptor-props slot)))
839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857
              "\n")))
   "\n"))

(defun cl--describe-class-slots (class)
  "Print help description for the slots in CLASS.
Outputs to the current buffer."
  (let* ((slots (cl--class-slots class))
         ;; FIXME: Add a `cl-class-of' or `cl-typeof' or somesuch.
         (metatype (cl--class-name (symbol-value (aref class 0))))
         ;; ¡For EIEIO!
         (cslots (condition-case nil
                     (cl-struct-slot-value metatype 'class-slots class)
                   (cl-struct-unknown-slot nil))))
    (insert (propertize "Instance Allocated Slots:\n\n"
			'face 'bold))
    (mapc #'cl--describe-class-slot slots)
    (when (> (length cslots) 0)
      (insert (propertize "\nClass Allocated Slots:\n\n" 'face 'bold))
      (mapc #'cl--describe-class-slot cslots))))
Richard M. Stallman's avatar
Richard M. Stallman committed
858 859 860 861


(run-hooks 'cl-extra-load-hook)

862
;; Local variables:
Glenn Morris's avatar
Glenn Morris committed
863
;; byte-compile-dynamic: t
864 865 866
;; generated-autoload-file: "cl-loaddefs.el"
;; End: