ediff.el 57.7 KB
Newer Older
1
;;; ediff.el --- a comprehensive visual interface to diff & patch
Erik Naggum's avatar
Erik Naggum committed
2

3
;; Copyright (C) 1994-2014 Free Software Foundation, Inc.
Richard M. Stallman's avatar
Richard M. Stallman committed
4

5
;; Author: Michael Kifer <kifer@cs.stonybrook.edu>
Richard M. Stallman's avatar
Richard M. Stallman committed
6
;; Created: February 2, 1994
7
;; Keywords: comparing, merging, patching, vc, tools, unix
8
;; Version: 2.81.4
Richard M. Stallman's avatar
Richard M. Stallman committed
9

10 11 12 13 14
;; Yoni Rabkin <yoni@rabkins.net> contacted the maintainer of this
;; file on 20/3/2008, and the maintainer agreed that when a bug is
;; filed in the Emacs bug reporting system against this file, a copy
;; of the bug report be sent to the maintainer's email address.

15 16
(defconst ediff-version "2.81.5" "The current version of Ediff")
(defconst ediff-date "July 4, 2013" "Date of last update")
Michael Kifer's avatar
Michael Kifer committed
17

18

Richard M. Stallman's avatar
Richard M. Stallman committed
19 20
;; This file is part of GNU Emacs.

21
;; GNU Emacs is free software: you can redistribute it and/or modify
Richard M. Stallman's avatar
Richard M. Stallman committed
22
;; it under the terms of the GNU General Public License as published by
23 24
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Richard M. Stallman's avatar
Richard M. Stallman committed
25 26 27 28 29 30 31

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
32
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
Richard M. Stallman's avatar
Richard M. Stallman committed
33 34 35

;;; Commentary:

36
;; Never read that diff output again!
Michael Kifer's avatar
Michael Kifer committed
37
;; Apply patch interactively!
38
;; Merge with ease!
Richard M. Stallman's avatar
Richard M. Stallman committed
39

40
;; This package provides a convenient way of simultaneous browsing through
Karl Heuer's avatar
Karl Heuer committed
41
;; the differences between a pair (or a triple) of files or buffers.  The
42 43 44 45 46
;; files being compared, file-A, file-B, and file-C (if applicable) are
;; shown in separate windows (side by side, one above the another, or in
;; separate frames), and the differences are highlighted as you step
;; through them.  You can also copy difference regions from one buffer to
;; another (and recover old differences if you change your mind).
Richard M. Stallman's avatar
Richard M. Stallman committed
47

48
;; Ediff also supports merging operations on files and buffers, including
Michael Kifer's avatar
Michael Kifer committed
49
;; merging using ancestor versions.  Both comparison and merging operations can
50 51 52
;; be performed on directories, i.e., by pairwise comparison of files in those
;; directories.

Richard M. Stallman's avatar
Richard M. Stallman committed
53
;; In addition, Ediff can apply a patch to a file and then let you step
54
;; though both files, the patched and the original one, simultaneously,
Richard M. Stallman's avatar
Richard M. Stallman committed
55 56 57 58
;; difference-by-difference.  You can even apply a patch right out of a
;; mail buffer, i.e., patches received by mail don't even have to be saved.
;; Since Ediff lets you copy differences between buffers, you can, in
;; effect, apply patches selectively (i.e., you can copy a difference
59
;; region from file_orig to file, thereby undoing any particular patch that
Richard M. Stallman's avatar
Richard M. Stallman committed
60 61
;; you don't like).

Karl Heuer's avatar
Karl Heuer committed
62
;; Ediff is aware of version control, which lets the user compare
Michael Kifer's avatar
Michael Kifer committed
63 64
;; files with their older versions.  Ediff can also work with remote and
;; compressed files.  Details are given below.
Karl Heuer's avatar
Karl Heuer committed
65

Michael Kifer's avatar
Michael Kifer committed
66
;; Finally, Ediff supports directory-level comparison, merging and patching.
67
;; See the on-line manual for details.
Richard M. Stallman's avatar
Richard M. Stallman committed
68

69
;; This package builds upon the ideas borrowed from emerge.el and several
Michael Kifer's avatar
Michael Kifer committed
70
;; Ediff's functions are adaptations from emerge.el.  Much of the functionality
71 72
;; Ediff provides is also influenced by emerge.el.

Michael Kifer's avatar
Michael Kifer committed
73 74
;; The present version of Ediff supersedes Emerge.  It provides a superior user
;; interface and has numerous major features not found in Emerge.  In
75 76
;; particular, it can do patching, and 2-way and 3-way file comparison,
;; merging, and directory operations.
77

Michael Kifer's avatar
Michael Kifer committed
78 79


Richard M. Stallman's avatar
Richard M. Stallman committed
80 81
;;; Bugs:

Michael Kifer's avatar
Michael Kifer committed
82
;;  1. The undo command doesn't restore deleted regions well.  That is, if
Richard M. Stallman's avatar
Richard M. Stallman committed
83
;;  you delete all characters in a difference region and then invoke
84
;;  `undo', the reinstated text will most likely be inserted outside of
Richard M. Stallman's avatar
Richard M. Stallman committed
85
;;  what Ediff thinks is the current difference region. (This problem
86
;;  doesn't seem to exist with XEmacs.)
Richard M. Stallman's avatar
Richard M. Stallman committed
87 88 89 90
;;
;;  If at any point you feel that difference regions are no longer correct,
;;  you can hit '!' to recompute the differences.

Karl Heuer's avatar
Karl Heuer committed
91
;;  2. On a monochrome display, the repertoire of faces with which to
Michael Kifer's avatar
Michael Kifer committed
92 93
;;  highlight fine differences is limited.  By default, Ediff is using
;;  underlining.  However, if the region is already underlined by some other
Richard M. Stallman's avatar
Richard M. Stallman committed
94
;;  overlays, there is no simple way to temporarily remove that residual
Michael Kifer's avatar
Michael Kifer committed
95 96 97 98
;;  underlining.  This problem occurs when a buffer is highlighted with
;;  hilit19.el or font-lock.el packages.  If this residual highlighting gets
;;  in the way, you can do the following.  Both font-lock.el and hilit19.el
;;  provide commands for unhighlighting buffers.  You can either place these
99
;;  commands in `ediff-prepare-buffer-hook' (which will unhighlight every
Richard M. Stallman's avatar
Richard M. Stallman committed
100 101
;;  buffer used by Ediff) or you can execute them interactively, at any time
;;  and on any buffer.
102

Michael Kifer's avatar
Michael Kifer committed
103

104
;;; Acknowledgments:
105

106 107
;; Ediff was inspired by Dale R. Worley's <drw@math.mit.edu> emerge.el.
;; Ediff would not have been possible without the help and encouragement of
Michael Kifer's avatar
Michael Kifer committed
108 109
;; its many users.  See Ediff on-line Info for the full list of those who
;; helped.  Improved defaults in Ediff file-name reading commands.
110 111 112

;;; Code:

113
(provide 'ediff)
114

Michael Kifer's avatar
Michael Kifer committed
115
;; Compiler pacifier
116
(eval-and-compile
Daniel Hackney's avatar
Daniel Hackney committed
117
  (unless (fboundp 'declare-function) (defmacro declare-function (&rest  _r))))
118

Glenn Morris's avatar
Glenn Morris committed
119
(require 'ediff-util)
Michael Kifer's avatar
Michael Kifer committed
120 121 122 123 124 125
;; end pacifier

(require 'ediff-init)
(require 'ediff-mult)  ; required because of the registry stuff

(defgroup ediff nil
126
  "Comprehensive visual interface to `diff' and `patch'."
Michael Kifer's avatar
Michael Kifer committed
127
  :tag "Ediff"
Michael Kifer's avatar
Michael Kifer committed
128 129 130 131
  :group 'tools)


(defcustom ediff-use-last-dir nil
Lute Kamstra's avatar
Lute Kamstra committed
132
  "If t, Ediff will use previous directory as default when reading file name."
Michael Kifer's avatar
Michael Kifer committed
133 134
  :type 'boolean
  :group 'ediff)
Michael Kifer's avatar
Michael Kifer committed
135

Michael Kifer's avatar
Michael Kifer committed
136 137 138 139 140 141 142 143 144
;; Last directory used by an Ediff command for file-A.
(defvar ediff-last-dir-A nil)
;; Last directory used by an Ediff command for file-B.
(defvar ediff-last-dir-B nil)
;; Last directory used by an Ediff command for file-C.
(defvar ediff-last-dir-C nil)
;; Last directory used by an Ediff command for the ancestor file.
(defvar ediff-last-dir-ancestor nil)
;; Last directory used by an Ediff command as the output directory for merge.
Michael Kifer's avatar
Michael Kifer committed
145
(defvar ediff-last-merge-autostore-dir nil)
Richard M. Stallman's avatar
Richard M. Stallman committed
146

147

Michael Kifer's avatar
Michael Kifer committed
148
;; Used as a startup hook to set `_orig' patch file read-only.
Karl Heuer's avatar
Karl Heuer committed
149
(defun ediff-set-read-only-in-buf-A ()
Michael Kifer's avatar
Michael Kifer committed
150
  (ediff-with-current-buffer ediff-buffer-A
151
    (setq buffer-read-only t)))
Richard M. Stallman's avatar
Richard M. Stallman committed
152

Glenn Morris's avatar
Glenn Morris committed
153 154 155 156 157
(declare-function dired-get-filename "dired"
                  (&optional localp no-error-if-not-filep))
(declare-function dired-get-marked-files "dired"
                  (&optional localp arg filter distinguish-one-marked))

158
;; Return a plausible default for ediff's first file:
159 160 161 162 163
;; In dired, return the file number FILENO (or 0) in the list
;; (all-selected-files, filename under the cursor), where directories are
;; ignored. Otherwise, return DEFAULT file name, if non-nil. Else,
;; if the buffer is visiting a file, return that file name.
(defun ediff-get-default-file-name (&optional default fileno)
164
  (cond ((eq major-mode 'dired-mode)
165 166 167
	 (let ((current (dired-get-filename nil 'no-error))
	       (marked (condition-case nil
			   (dired-get-marked-files 'no-dir)
168
			 (error nil)))
169 170 171 172 173 174 175 176 177 178 179
	       aux-list choices result)
	   (or (integerp fileno) (setq fileno 0))
	   (if (stringp default)
	       (setq aux-list (cons default aux-list)))
	   (if (and (stringp current) (not (file-directory-p current)))
	       (setq aux-list (cons current aux-list)))
	   (setq choices (nconc  marked aux-list))
	   (setq result (elt choices fileno))
	   (or result
	       default)))
	((stringp default) default)
180 181 182 183
	((buffer-file-name (current-buffer))
	 (file-name-nondirectory (buffer-file-name (current-buffer))))
	))

184
;;; Compare files/buffers
Richard M. Stallman's avatar
Richard M. Stallman committed
185 186 187

;;;###autoload
(defun ediff-files (file-A file-B &optional startup-hooks)
188
  "Run Ediff on a pair of files, FILE-A and FILE-B."
Richard M. Stallman's avatar
Richard M. Stallman committed
189
  (interactive
190 191 192 193
   (let ((dir-A (if ediff-use-last-dir
		    ediff-last-dir-A
		  default-directory))
	 dir-B f)
194
     (list (setq f (ediff-read-file-name
195
		    "File A to compare"
196
		    dir-A
197 198
		    (ediff-get-default-file-name)
		    'no-dirs))
199
	   (ediff-read-file-name "File B to compare"
200 201
				 (setq dir-B
				       (if ediff-use-last-dir
202
					   ediff-last-dir-B
203 204
					 (file-name-directory f)))
				 (progn
205 206 207 208 209 210
				   (ediff-add-to-history
				    'file-name-history
				    (ediff-abbreviate-file-name
				     (expand-file-name
				      (file-name-nondirectory f)
				      dir-B)))
211
				   (ediff-get-default-file-name f 1)))
212
	   )))
213
  (ediff-files-internal file-A
214 215 216 217 218 219 220
			(if (file-directory-p file-B)
			    (expand-file-name
			     (file-name-nondirectory file-A) file-B)
			  file-B)
			nil ; file-C
			startup-hooks
			'ediff-files))
221

222 223 224 225 226 227 228 229
;;;###autoload
(defun ediff-files3 (file-A file-B file-C &optional startup-hooks)
  "Run Ediff on three files, FILE-A, FILE-B, and FILE-C."
  (interactive
   (let ((dir-A (if ediff-use-last-dir
		    ediff-last-dir-A
		  default-directory))
	 dir-B dir-C f ff)
230
     (list (setq f (ediff-read-file-name
231 232 233 234
		    "File A to compare"
		    dir-A
		    (ediff-get-default-file-name)
		    'no-dirs))
235
	   (setq ff (ediff-read-file-name "File B to compare"
236 237 238 239 240
					  (setq dir-B
						(if ediff-use-last-dir
						    ediff-last-dir-B
						  (file-name-directory f)))
					  (progn
241 242 243 244 245 246
					    (ediff-add-to-history
					     'file-name-history
					     (ediff-abbreviate-file-name
					      (expand-file-name
					       (file-name-nondirectory f)
					       dir-B)))
247
					    (ediff-get-default-file-name f 1))))
248
	   (ediff-read-file-name "File C to compare"
249 250 251 252
				 (setq dir-C (if ediff-use-last-dir
						 ediff-last-dir-C
					       (file-name-directory ff)))
				 (progn
253 254 255 256 257 258
				   (ediff-add-to-history
				    'file-name-history
				    (ediff-abbreviate-file-name
				     (expand-file-name
				      (file-name-nondirectory ff)
				      dir-C)))
259
				   (ediff-get-default-file-name ff 2)))
Richard M. Stallman's avatar
Richard M. Stallman committed
260
	   )))
261
  (ediff-files-internal file-A
Richard M. Stallman's avatar
Richard M. Stallman committed
262 263 264 265
			(if (file-directory-p file-B)
			    (expand-file-name
			     (file-name-nondirectory file-A) file-B)
			  file-B)
266 267 268 269 270 271
			(if (file-directory-p file-C)
			    (expand-file-name
			     (file-name-nondirectory file-A) file-C)
			  file-C)
			startup-hooks
			'ediff-files3))
Richard M. Stallman's avatar
Richard M. Stallman committed
272

273 274
;;;###autoload
(defalias 'ediff3 'ediff-files3)
Richard M. Stallman's avatar
Richard M. Stallman committed
275 276


277
(defun ediff-find-file (file-var buffer-name &optional last-dir hooks-var)
278 279 280 281 282 283 284 285 286 287
  "Visit FILE and arrange its buffer to Ediff's liking.
FILE-VAR is actually a variable symbol whose value must contain a true
file name.
BUFFER-NAME is a variable symbol, which will get the buffer object into
which FILE is read.
LAST-DIR is the directory variable symbol where FILE's
directory name should be returned.  HOOKS-VAR is a variable symbol that will
be assigned the hook to be executed after `ediff-startup' is finished.
`ediff-find-file' arranges that the temp files it might create will be
deleted."
288
  (let* ((file (symbol-value file-var))
Michael Kifer's avatar
Michael Kifer committed
289
	 (file-magic (ediff-filename-magic-p file))
290
	 (temp-file-name-prefix (file-name-nondirectory file)))
291 292 293 294
    (cond ((not (file-readable-p file))
	   (error "File `%s' does not exist or is not readable" file))
	  ((file-directory-p file)
	   (error "File `%s' is a directory" file)))
295

Michael Kifer's avatar
Michael Kifer committed
296
    ;; some of the commands, below, require full file name
297
    (setq file (expand-file-name file))
298

299 300 301
    ;; Record the directory of the file
    (if last-dir
	(set last-dir (expand-file-name (file-name-directory file))))
302

303 304
    ;; Setup the buffer
    (set buffer-name (find-file-noselect file))
305

Michael Kifer's avatar
Michael Kifer committed
306
    (ediff-with-current-buffer (symbol-value buffer-name)
307
      (widen) ; Make sure the entire file is seen
Michael Kifer's avatar
Michael Kifer committed
308 309
      (cond (file-magic  ;   file has a handler, such as jka-compr-handler or
	     		 ;;; ange-ftp-hook-function--arrange for temp file
310
	     (ediff-verify-file-buffer 'magic)
311 312 313
	     (setq file
		   (ediff-make-temp-file
		    (current-buffer) temp-file-name-prefix))
Michael Kifer's avatar
Michael Kifer committed
314
	     (set hooks-var (cons `(lambda () (delete-file ,file))
315 316 317 318
				  (symbol-value hooks-var))))
	    ;; file processed via auto-mode-alist, a la uncompress.el
	    ((not (equal (file-truename file)
			 (file-truename (buffer-file-name))))
319 320 321
	     (setq file
		   (ediff-make-temp-file
		    (current-buffer) temp-file-name-prefix))
Michael Kifer's avatar
Michael Kifer committed
322
	     (set hooks-var (cons `(lambda () (delete-file ,file))
323 324 325 326 327
				  (symbol-value hooks-var))))
	    (t ;; plain file---just check that the file matches the buffer
	     (ediff-verify-file-buffer))))
    (set file-var file)))

Michael Kifer's avatar
Michael Kifer committed
328 329 330
;; MERGE-BUFFER-FILE is the file to be associated with the merge buffer
(defun ediff-files-internal (file-A file-B file-C startup-hooks job-name
				    &optional merge-buffer-file)
331
  (let (buf-A buf-B buf-C)
332 333 334 335 336
    (if (string= file-A file-B)
	(error "Files A and B are the same"))
    (if (stringp file-C)
	(or (and (string= file-A file-C) (error "Files A and C are the same"))
	    (and (string= file-B file-C) (error "Files B and C are the same"))))
337 338
    (message "Reading file %s ... " file-A)
    ;;(sit-for 0)
339
    (ediff-find-file 'file-A 'buf-A 'ediff-last-dir-A 'startup-hooks)
340 341
    (message "Reading file %s ... " file-B)
    ;;(sit-for 0)
342
    (ediff-find-file 'file-B 'buf-B 'ediff-last-dir-B 'startup-hooks)
343
    (if (stringp file-C)
344
	(progn
345 346
	  (message "Reading file %s ... " file-C)
	  ;;(sit-for 0)
347 348 349 350 351 352 353 354 355
	  (ediff-find-file
	   'file-C 'buf-C
	   (if (eq job-name 'ediff-merge-files-with-ancestor)
	       'ediff-last-dir-ancestor 'ediff-last-dir-C)
	   'startup-hooks)))
    (ediff-setup buf-A file-A
		 buf-B file-B
		 buf-C file-C
		 startup-hooks
Michael Kifer's avatar
Michael Kifer committed
356 357
		 (list (cons 'ediff-job-name job-name))
		 merge-buffer-file)))
358

359
(declare-function diff-latest-backup-file "diff" (fn))
360 361 362

;;;###autoload
(defalias 'ediff 'ediff-files)
Richard M. Stallman's avatar
Richard M. Stallman committed
363

364 365 366 367 368 369
;;;###autoload
(defun ediff-current-file ()
  "Start ediff between current buffer and its file on disk.
This command can be used instead of `revert-buffer'.  If there is
nothing to revert then this command fails."
  (interactive)
370 371 372 373
  ;; This duplicates code from menu-bar.el.
  (unless (or (not (eq revert-buffer-function 'revert-buffer--default))
              (not (eq revert-buffer-insert-file-contents-function
		       'revert-buffer-insert-file-contents--default-function))
374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402
              (and buffer-file-number
                   (or (buffer-modified-p)
                       (not (verify-visited-file-modtime
                             (current-buffer))))))
    (error "Nothing to revert"))
  (let* ((auto-save-p (and (recent-auto-save-p)
                           buffer-auto-save-file-name
                           (file-readable-p buffer-auto-save-file-name)
                           (y-or-n-p
                            "Buffer has been auto-saved recently.  Compare with auto-save file? ")))
         (file-name (if auto-save-p
                        buffer-auto-save-file-name
                      buffer-file-name))
         (revert-buf-name (concat "FILE=" file-name))
         (revert-buf (get-buffer revert-buf-name))
         (current-major major-mode))
    (unless file-name
      (error "Buffer does not seem to be associated with any file"))
    (when revert-buf
      (kill-buffer revert-buf)
      (setq revert-buf nil))
    (setq revert-buf (get-buffer-create revert-buf-name))
    (with-current-buffer revert-buf
      (insert-file-contents file-name)
      ;; Assume same modes:
      (funcall current-major))
    (ediff-buffers revert-buf (current-buffer))))


403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418
;;;###autoload
(defun ediff-backup (file)
  "Run Ediff on FILE and its backup file.
Uses the latest backup, if there are several numerical backups.
If this file is a backup, `ediff' it with its original."
  (interactive (list (read-file-name "Ediff (file with backup): ")))
  ;; The code is taken from `diff-backup'.
  (require 'diff)
  (let (bak ori)
    (if (backup-file-name-p file)
	(setq bak file
	      ori (file-name-sans-versions file))
      (setq bak (or (diff-latest-backup-file file)
		    (error "No backup found for %s" file))
	    ori file))
    (ediff-files bak ori)))
Richard M. Stallman's avatar
Richard M. Stallman committed
419 420

;;;###autoload
421
(defun ediff-buffers (buffer-A buffer-B &optional startup-hooks job-name)
Richard M. Stallman's avatar
Richard M. Stallman committed
422
  "Run Ediff on a pair of buffers, BUFFER-A and BUFFER-B."
423
  (interactive
424 425 426 427 428 429 430 431 432 433 434 435
   (let (bf)
     (list (setq bf (read-buffer "Buffer A to compare: "
				 (ediff-other-buffer "") t))
	   (read-buffer "Buffer B to compare: "
			(progn
			  ;; realign buffers so that two visible bufs will be
			  ;; at the top
			  (save-window-excursion (other-window 1))
			  (ediff-other-buffer bf))
			t))))
  (or job-name (setq job-name 'ediff-buffers))
  (ediff-buffers-internal buffer-A buffer-B nil startup-hooks job-name))
Michael Kifer's avatar
Michael Kifer committed
436 437 438 439

;;;###autoload
(defalias 'ebuffers 'ediff-buffers)

440

441 442 443 444
;;;###autoload
(defun ediff-buffers3 (buffer-A buffer-B buffer-C
				 &optional startup-hooks job-name)
  "Run Ediff on three buffers, BUFFER-A, BUFFER-B, and BUFFER-C."
445
  (interactive
446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465
   (let (bf bff)
     (list (setq bf (read-buffer "Buffer A to compare: "
				 (ediff-other-buffer "") t))
	   (setq bff (read-buffer "Buffer B to compare: "
				  (progn
				    ;; realign buffers so that two visible
				    ;; bufs will be at the top
				    (save-window-excursion (other-window 1))
				    (ediff-other-buffer bf))
				  t))
	   (read-buffer "Buffer C to compare: "
				  (progn
				    ;; realign buffers so that three visible
				    ;; bufs will be at the top
				    (save-window-excursion (other-window 1))
				    (ediff-other-buffer (list bf bff)))
				  t)
	   )))
  (or job-name (setq job-name 'ediff-buffers3))
  (ediff-buffers-internal buffer-A buffer-B buffer-C startup-hooks job-name))
Michael Kifer's avatar
Michael Kifer committed
466 467 468

;;;###autoload
(defalias 'ebuffers3 'ediff-buffers3)
469

470 471


Michael Kifer's avatar
Michael Kifer committed
472 473 474
;; MERGE-BUFFER-FILE is the file to be associated with the merge buffer
(defun ediff-buffers-internal (buf-A buf-B buf-C startup-hooks job-name
				     &optional merge-buffer-file)
475 476 477 478 479 480
  (let* ((buf-A-file-name (buffer-file-name (get-buffer buf-A)))
	 (buf-B-file-name (buffer-file-name (get-buffer buf-B)))
	 (buf-C-is-alive (ediff-buffer-live-p buf-C))
	 (buf-C-file-name (if buf-C-is-alive
			      (buffer-file-name (get-buffer buf-B))))
	 file-A file-B file-C)
481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496
    (unwind-protect
	(progn
	  (if (not (ediff-buffer-live-p buf-A))
	      (error "Buffer %S doesn't exist" buf-A))
	  (if (not (ediff-buffer-live-p buf-B))
	      (error "Buffer %S doesn't exist" buf-B))
	  (let ((ediff-job-name job-name))
	    (if (and ediff-3way-comparison-job
		     (not buf-C-is-alive))
		(error "Buffer %S doesn't exist" buf-C)))
	  (if (stringp buf-A-file-name)
	      (setq buf-A-file-name (file-name-nondirectory buf-A-file-name)))
	  (if (stringp buf-B-file-name)
	      (setq buf-B-file-name (file-name-nondirectory buf-B-file-name)))
	  (if (stringp buf-C-file-name)
	      (setq buf-C-file-name (file-name-nondirectory buf-C-file-name)))
497

498 499 500 501
	  (setq file-A (ediff-make-temp-file buf-A buf-A-file-name)
		file-B (ediff-make-temp-file buf-B buf-B-file-name))
	  (if buf-C-is-alive
	      (setq file-C (ediff-make-temp-file buf-C buf-C-file-name)))
502

503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519
	  (ediff-setup (get-buffer buf-A) file-A
		       (get-buffer buf-B) file-B
		       (if buf-C-is-alive (get-buffer buf-C))
		       file-C
		       (cons `(lambda ()
				(delete-file ,file-A)
				(delete-file ,file-B)
				(if (stringp ,file-C) (delete-file ,file-C)))
			     startup-hooks)
		       (list (cons 'ediff-job-name job-name))
		       merge-buffer-file))
      (if (and (stringp file-A) (file-exists-p file-A))
	  (delete-file file-A))
      (if (and (stringp file-B) (file-exists-p file-B))
	  (delete-file file-B))
      (if (and (stringp file-C) (file-exists-p file-C))
	  (delete-file file-C)))))
520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540


;;; Directory and file group operations

;; Get appropriate default name for directory:
;; If ediff-use-last-dir, use ediff-last-dir-A.
;; In dired mode, use the directory that is under the point (if any);
;; otherwise, use default-directory
(defun ediff-get-default-directory-name ()
  (cond (ediff-use-last-dir ediff-last-dir-A)
	((eq major-mode 'dired-mode)
	 (let ((f (dired-get-filename nil 'noerror)))
	   (if (and (stringp f) (file-directory-p f))
	       f
	     default-directory)))
	(t default-directory)))


;;;###autoload
(defun ediff-directories (dir1 dir2 regexp)
  "Run Ediff on a pair of directories, DIR1 and DIR2, comparing files that have
541 542
the same name in both.  The third argument, REGEXP, is nil or a regular
expression; only file names that match the regexp are considered."
543 544
  (interactive
   (let ((dir-A (ediff-get-default-directory-name))
545
	 (default-regexp (eval ediff-default-filtering-regexp))
546
	 f)
547
     (list (setq f (read-directory-name
548 549
		    "Directory A to compare: " dir-A nil 'must-match))
	   (read-directory-name "Directory B to compare: "
550 551 552 553
			   (if ediff-use-last-dir
			       ediff-last-dir-B
			     (ediff-strip-last-dir f))
			   nil 'must-match)
554 555 556 557 558 559 560 561
	   (read-string
	    (if (stringp default-regexp)
		(format "Filter through regular expression (default %s): "
			 default-regexp)
	      "Filter through regular expression: ")
	    nil
	    'ediff-filtering-regexp-history
	    (eval ediff-default-filtering-regexp))
562 563 564 565 566 567 568 569 570 571 572 573 574
	   )))
  (ediff-directories-internal
   dir1 dir2 nil regexp 'ediff-files 'ediff-directories
   ))

;;;###autoload
(defalias 'edirs 'ediff-directories)


;;;###autoload
(defun ediff-directory-revisions (dir1 regexp)
  "Run Ediff on a directory, DIR1, comparing its files with their revisions.
The second argument, REGEXP, is a regular expression that filters the file
Michael Kifer's avatar
Michael Kifer committed
575
names.  Only the files that are under revision control are taken into account."
576
  (interactive
577 578 579
   (let ((dir-A (ediff-get-default-directory-name))
	 (default-regexp (eval ediff-default-filtering-regexp))
	 )
580 581
     (list (read-directory-name
	    "Directory to compare with revision:" dir-A nil 'must-match)
582 583 584 585 586 587 588 589
	   (read-string
	    (if (stringp default-regexp)
		(format "Filter through regular expression (default %s): "
			 default-regexp)
	      "Filter through regular expression: ")
	    nil
	    'ediff-filtering-regexp-history
	    (eval ediff-default-filtering-regexp))
590 591 592 593 594 595 596 597 598 599 600 601
	   )))
  (ediff-directory-revisions-internal
   dir1 regexp 'ediff-revision 'ediff-directory-revisions
   ))

;;;###autoload
(defalias 'edir-revisions 'ediff-directory-revisions)


;;;###autoload
(defun ediff-directories3 (dir1 dir2 dir3 regexp)
  "Run Ediff on three directories, DIR1, DIR2, and DIR3, comparing files that
602 603 604
have the same name in all three.  The last argument, REGEXP, is nil or a
regular expression; only file names that match the regexp are considered."

605 606
  (interactive
   (let ((dir-A (ediff-get-default-directory-name))
607
	 (default-regexp (eval ediff-default-filtering-regexp))
608
	 f)
609 610 611 612 613 614 615 616 617 618 619
     (list (setq f (read-directory-name "Directory A to compare:" dir-A nil))
	   (setq f (read-directory-name "Directory B to compare:"
				   (if ediff-use-last-dir
				       ediff-last-dir-B
				     (ediff-strip-last-dir f))
				   nil 'must-match))
	   (read-directory-name "Directory C to compare:"
			   (if ediff-use-last-dir
			       ediff-last-dir-C
			     (ediff-strip-last-dir f))
			   nil 'must-match)
620 621 622 623 624 625 626 627
	   (read-string
	    (if (stringp default-regexp)
		(format "Filter through regular expression (default %s): "
			 default-regexp)
	      "Filter through regular expression: ")
	    nil
	    'ediff-filtering-regexp-history
	    (eval ediff-default-filtering-regexp))
628 629 630 631 632 633 634 635 636
	   )))
  (ediff-directories-internal
   dir1 dir2 dir3 regexp 'ediff-files3 'ediff-directories3
   ))

;;;###autoload
(defalias 'edirs3 'ediff-directories3)

;;;###autoload
Michael Kifer's avatar
Michael Kifer committed
637
(defun ediff-merge-directories (dir1 dir2 regexp &optional merge-autostore-dir)
638
  "Run Ediff on a pair of directories, DIR1 and DIR2, merging files that have
639 640
the same name in both.  The third argument, REGEXP, is nil or a regular
expression; only file names that match the regexp are considered."
641 642
  (interactive
   (let ((dir-A (ediff-get-default-directory-name))
643
	 (default-regexp (eval ediff-default-filtering-regexp))
644
	 f)
645 646 647 648 649 650 651
     (list (setq f (read-directory-name "Directory A to merge:"
					dir-A nil 'must-match))
	   (read-directory-name "Directory B to merge:"
			   (if ediff-use-last-dir
			       ediff-last-dir-B
			     (ediff-strip-last-dir f))
			   nil 'must-match)
652 653 654 655 656 657 658 659
	   (read-string
	    (if (stringp default-regexp)
		(format "Filter through regular expression (default %s): "
			 default-regexp)
	      "Filter through regular expression: ")
	    nil
	    'ediff-filtering-regexp-history
	    (eval ediff-default-filtering-regexp))
660 661 662
	   )))
  (ediff-directories-internal
   dir1 dir2 nil regexp 'ediff-merge-files 'ediff-merge-directories
Michael Kifer's avatar
Michael Kifer committed
663
   nil merge-autostore-dir
664 665 666 667 668 669
   ))

;;;###autoload
(defalias 'edirs-merge 'ediff-merge-directories)

;;;###autoload
Michael Kifer's avatar
Michael Kifer committed
670 671 672
(defun ediff-merge-directories-with-ancestor (dir1 dir2 ancestor-dir regexp
						   &optional
						   merge-autostore-dir)
Michael Kifer's avatar
Michael Kifer committed
673
  "Merge files in directories DIR1 and DIR2 using files in ANCESTOR-DIR as ancestors.
Michael Kifer's avatar
Michael Kifer committed
674
Ediff merges files that have identical names in DIR1, DIR2.  If a pair of files
Michael Kifer's avatar
Michael Kifer committed
675
in DIR1 and DIR2 doesn't have an ancestor in ANCESTOR-DIR, Ediff will merge
676 677
without ancestor.  The fourth argument, REGEXP, is nil or a regular expression;
only file names that match the regexp are considered."
678 679
  (interactive
   (let ((dir-A (ediff-get-default-directory-name))
680
	 (default-regexp (eval ediff-default-filtering-regexp))
681
	 f)
682 683
     (list (setq f (read-directory-name "Directory A to merge:" dir-A nil))
	   (setq f (read-directory-name "Directory B to merge:"
684
				 (if ediff-use-last-dir
685
				     ediff-last-dir-B
686
				   (ediff-strip-last-dir f))
687 688
				 nil 'must-match))
	   (read-directory-name "Ancestor directory:"
689
				 (if ediff-use-last-dir
690
				     ediff-last-dir-C
691
				   (ediff-strip-last-dir f))
692
				 nil 'must-match)
693 694 695 696 697 698 699 700
	   (read-string
	    (if (stringp default-regexp)
		(format "Filter through regular expression (default %s): "
			 default-regexp)
	      "Filter through regular expression: ")
	    nil
	    'ediff-filtering-regexp-history
	    (eval ediff-default-filtering-regexp))
701 702
	   )))
  (ediff-directories-internal
Michael Kifer's avatar
Michael Kifer committed
703
   dir1 dir2 ancestor-dir regexp
704
   'ediff-merge-files-with-ancestor 'ediff-merge-directories-with-ancestor
Michael Kifer's avatar
Michael Kifer committed
705
   nil merge-autostore-dir
706 707 708
   ))

;;;###autoload
Michael Kifer's avatar
Michael Kifer committed
709 710
(defun ediff-merge-directory-revisions (dir1 regexp
					     &optional merge-autostore-dir)
711 712
  "Run Ediff on a directory, DIR1, merging its files with their revisions.
The second argument, REGEXP, is a regular expression that filters the file
Michael Kifer's avatar
Michael Kifer committed
713
names.  Only the files that are under revision control are taken into account."
714
  (interactive
715 716 717
   (let ((dir-A (ediff-get-default-directory-name))
	 (default-regexp (eval ediff-default-filtering-regexp))
	 )
718 719
     (list (read-directory-name
	    "Directory to merge with revisions:" dir-A nil 'must-match)
720 721 722 723 724 725 726 727
	   (read-string
	    (if (stringp default-regexp)
		(format "Filter through regular expression (default %s): "
			 default-regexp)
	      "Filter through regular expression: ")
	    nil
	    'ediff-filtering-regexp-history
	    (eval ediff-default-filtering-regexp))
728 729 730
	   )))
  (ediff-directory-revisions-internal
   dir1 regexp 'ediff-merge-revisions 'ediff-merge-directory-revisions
Michael Kifer's avatar
Michael Kifer committed
731
   nil merge-autostore-dir
732 733 734 735 736 737
   ))

;;;###autoload
(defalias 'edir-merge-revisions 'ediff-merge-directory-revisions)

;;;###autoload
Michael Kifer's avatar
Michael Kifer committed
738 739 740
(defun ediff-merge-directory-revisions-with-ancestor (dir1 regexp
							   &optional
							   merge-autostore-dir)
741 742
  "Run Ediff on a directory, DIR1, merging its files with their revisions and ancestors.
The second argument, REGEXP, is a regular expression that filters the file
Michael Kifer's avatar
Michael Kifer committed
743
names.  Only the files that are under revision control are taken into account."
744
  (interactive
745 746 747
   (let ((dir-A (ediff-get-default-directory-name))
	 (default-regexp (eval ediff-default-filtering-regexp))
	 )
748 749 750
     (list (read-directory-name
	    "Directory to merge with revisions and ancestors:"
	    dir-A nil 'must-match)
751 752 753 754 755 756 757 758
	   (read-string
	    (if (stringp default-regexp)
		(format "Filter through regular expression (default %s): "
			 default-regexp)
	      "Filter through regular expression: ")
	    nil
	    'ediff-filtering-regexp-history
	    (eval ediff-default-filtering-regexp))
759 760 761 762
	   )))
  (ediff-directory-revisions-internal
   dir1 regexp 'ediff-merge-revisions-with-ancestor
   'ediff-merge-directory-revisions-with-ancestor
Michael Kifer's avatar
Michael Kifer committed
763
   nil merge-autostore-dir
764 765 766 767 768
   ))

;;;###autoload
(defalias
  'edir-merge-revisions-with-ancestor
769
  'ediff-merge-directory-revisions-with-ancestor)
770 771 772 773 774 775

;;;###autoload
(defalias 'edirs-merge-with-ancestor 'ediff-merge-directories-with-ancestor)

;; Run ediff-action (ediff-files, ediff-merge, ediff-merge-with-ancestors)
;; on a pair of directories (three directories, in case of ancestor).
776 777
;; The third argument, REGEXP, is nil or a regular expression;
;; only file names that match the regexp are considered.
778
;; JOBNAME is the symbol indicating the meta-job to be performed.
Michael Kifer's avatar
Michael Kifer committed
779
;; MERGE-AUTOSTORE-DIR is the directory in which to store merged files.
780
(defun ediff-directories-internal (dir1 dir2 dir3 regexp action jobname
Michael Kifer's avatar
Michael Kifer committed
781 782
					&optional startup-hooks
					merge-autostore-dir)
783 784 785 786 787 788 789 790 791 792 793 794
  (if (stringp dir3)
      (setq dir3 (if (file-directory-p dir3) dir3 (file-name-directory dir3))))

  (cond ((string= dir1 dir2)
	 (error "Directories A and B are the same: %s" dir1))
	((and (eq jobname 'ediff-directories3)
	      (string= dir1 dir3))
	 (error "Directories A and C are the same: %s" dir1))
	((and (eq jobname 'ediff-directories3)
	      (string= dir2 dir3))
	 (error "Directories B and C are the same: %s" dir1)))

Michael Kifer's avatar
Michael Kifer committed
795 796 797 798
  (if merge-autostore-dir
      (or (stringp merge-autostore-dir)
	  (error "%s: Directory for storing merged files must be a string"
		 jobname)))
799
  (let (;; dir-diff-struct is of the form (common-list diff-list)
Michael Kifer's avatar
Michael Kifer committed
800 801 802 803
	;; It is a structure where ediff-intersect-directories returns
	;; commonalities and differences among directories
	dir-diff-struct
	meta-buf)
Michael Kifer's avatar
Michael Kifer committed
804 805 806
    (if (and ediff-autostore-merges
	     (ediff-merge-metajob jobname)
	     (not merge-autostore-dir))
807
	(setq merge-autostore-dir
808
	      (read-directory-name "Save merged files in directory: "
Michael Kifer's avatar
Michael Kifer committed
809
			      (if ediff-use-last-dir
Michael Kifer's avatar
Michael Kifer committed
810 811
					ediff-last-merge-autostore-dir
				      (ediff-strip-last-dir dir1))
Michael Kifer's avatar
Michael Kifer committed
812 813
			      nil
			      'must-match)))
Michael Kifer's avatar
Michael Kifer committed
814
    ;; verify we are not merging into an orig directory
Michael Kifer's avatar
Michael Kifer committed
815
    (if merge-autostore-dir
Michael Kifer's avatar
Michael Kifer committed
816
	(cond ((and (stringp dir1) (string= merge-autostore-dir dir1))
Michael Kifer's avatar
Michael Kifer committed
817 818
	       (or (y-or-n-p
		    "Directory for saving merged files = Directory A.  Sure? ")
Michael Kifer's avatar
Michael Kifer committed
819 820
		   (error "Directory merge aborted")))
	      ((and (stringp dir2) (string= merge-autostore-dir dir2))
Michael Kifer's avatar
Michael Kifer committed
821 822
	       (or (y-or-n-p
		    "Directory for saving merged files = Directory B.  Sure? ")
Michael Kifer's avatar
Michael Kifer committed
823 824 825
		   (error "Directory merge aborted")))
	      ((and (stringp dir3) (string= merge-autostore-dir dir3))
	       (or (y-or-n-p
Michael Kifer's avatar
Michael Kifer committed
826
		    "Directory for saving merged files = Ancestor Directory.  Sure? ")
Michael Kifer's avatar
Michael Kifer committed
827
		   (error "Directory merge aborted")))))
828 829

    (setq dir-diff-struct (ediff-intersect-directories
Michael Kifer's avatar
Michael Kifer committed
830 831
			   jobname
			   regexp dir1 dir2 dir3 merge-autostore-dir))
832 833 834
    (setq startup-hooks
	  ;; this sets various vars in the meta buffer inside
	  ;; ediff-prepare-meta-buffer
Michael Kifer's avatar
Michael Kifer committed
835 836 837
	  (cons `(lambda ()
		   ;; tell what to do if the user clicks on a session record
		   (setq ediff-session-action-function (quote ,action))
838
		   ;; set ediff-dir-difference-list
Michael Kifer's avatar
Michael Kifer committed
839 840
		   (setq ediff-dir-difference-list
			 (cdr (quote ,dir-diff-struct))))
841
		startup-hooks))
842
    (setq meta-buf (ediff-prepare-meta-buffer
Michael Kifer's avatar
Michael Kifer committed
843
		    'ediff-filegroup-action
Michael Kifer's avatar
Michael Kifer committed
844
		    (car dir-diff-struct)
845 846 847 848 849 850 851
		    "*Ediff Session Group Panel"
		    'ediff-redraw-directory-group-buffer
		    jobname
		    startup-hooks))
    (ediff-show-meta-buffer meta-buf)
    ))

Michael Kifer's avatar
Michael Kifer committed
852 853
;; MERGE-AUTOSTORE-DIR can be given to tell ediff where to store the merged
;; files
854
(defun ediff-directory-revisions-internal (dir1 regexp action jobname
Michael Kifer's avatar
Michael Kifer committed
855 856
						&optional startup-hooks
						merge-autostore-dir)
857
  (setq dir1 (if (file-directory-p dir1) dir1 (file-name-directory dir1)))
Michael Kifer's avatar
Michael Kifer committed
858

Michael Kifer's avatar
Michael Kifer committed
859 860 861 862 863
  (if merge-autostore-dir
      (or (stringp merge-autostore-dir)
	  (error "%S: Directory for storing merged files must be a string"
		 jobname)))
  (let (file-list meta-buf)
864
    (if (and ediff-autostore-merges
Michael Kifer's avatar
Michael Kifer committed
865 866
	     (ediff-merge-metajob jobname)
	     (not merge-autostore-dir))
867
	(setq merge-autostore-dir
868
	      (read-directory-name "Save merged files in directory: "
Michael Kifer's avatar
Michael Kifer committed
869 870 871 872 873
			      (if ediff-use-last-dir
				  ediff-last-merge-autostore-dir
				(ediff-strip-last-dir dir1))
			      nil
			      'must-match)))
Michael Kifer's avatar
Michael Kifer committed
874
    ;; verify merge-autostore-dir != dir1
Michael Kifer's avatar
Michael Kifer committed
875
    (if (and merge-autostore-dir
Michael Kifer's avatar
Michael Kifer committed
876 877 878
	     (stringp dir1)
	     (string= merge-autostore-dir dir1))
	(or (y-or-n-p
Michael Kifer's avatar
Michael Kifer committed
879
	     "Directory for saving merged file = directory A.  Sure? ")
Michael Kifer's avatar
Michael Kifer committed
880
	    (error "Merge of directory revisions aborted")))
881

882
    (setq file-list
Michael Kifer's avatar
Michael Kifer committed
883 884
	  (ediff-get-directory-files-under-revision
	   jobname regexp dir1 merge-autostore-dir))
885 886 887
    (setq startup-hooks
	  ;; this sets various vars in the meta buffer inside
	  ;; ediff-prepare-meta-buffer
Michael Kifer's avatar
Michael Kifer committed
888 889 890
	  (cons `(lambda ()
		   ;; tell what to do if the user clicks on a session record
		   (setq ediff-session-action-function (quote ,action)))
891
		startup-hooks))
892
    (setq meta-buf (ediff-prepare-meta-buffer
Michael Kifer's avatar
Michael Kifer committed
893
		    'ediff-filegroup-action
894 895 896 897 898 899 900
		    file-list
		    "*Ediff Session Group Panel"
		    'ediff-redraw-directory-group-buffer
		    jobname
		    startup-hooks))
    (ediff-show-meta-buffer meta-buf)
    ))
901 902 903 904 905


;;; Compare regions and windows

;;;###autoload
Karl Heuer's avatar
Karl Heuer committed
906 907
(defun ediff-windows-wordwise (dumb-mode &optional wind-A wind-B startup-hooks)
  "Compare WIND-A and WIND-B, which are selected by clicking, wordwise.
908 909 910 911 912
With prefix argument, DUMB-MODE, or on a non-windowing display, works as
follows:
If WIND-A is nil, use selected window.
If WIND-B is nil, use window next to WIND-A."
  (interactive "P")
Karl Heuer's avatar
Karl Heuer committed
913 914
  (ediff-windows dumb-mode wind-A wind-B
		 startup-hooks 'ediff-windows-wordwise 'word-mode))
915

Karl Heuer's avatar
Karl Heuer committed
916 917 918 919 920 921 922 923 924 925
;;;###autoload
(defun ediff-windows-linewise (dumb-mode &optional wind-A wind-B startup-hooks)
  "Compare WIND-A and WIND-B, which are selected by clicking, linewise.
With prefix argument, DUMB-MODE, or on a non-windowing display, works as
follows:
If WIND-A is nil, use selected window.
If WIND-B is nil, use window next to WIND-A."
  (interactive "P")
  (ediff-windows dumb-mode wind-A wind-B
		 startup-hooks 'ediff-windows-linewise nil))
926

Karl Heuer's avatar
Karl Heuer committed
927 928 929 930 931 932 933
;; Compare WIND-A and WIND-B, which are selected by clicking.
;; With prefix argument, DUMB-MODE, or on a non-windowing display,
;; works as follows:
;; If WIND-A is nil, use selected window.
;; If WIND-B is nil, use window next to WIND-A.
(defun ediff-windows (dumb-mode wind-A wind-B startup-hooks job-name word-mode)
  (if (or dumb-mode (not (ediff-window-display-p)))
934 935 936 937
      (setq wind-A (ediff-get-next-window wind-A nil)
	    wind-B (ediff-get-next-window wind-B wind-A))
    (setq wind-A (ediff-get-window-by-clicking wind-A nil 1)
	  wind-B (ediff-get-window-by-clicking wind-B wind-A 2)))
938

939 940 941
  (let ((buffer-A (window-buffer wind-A))
	(buffer-B (window-buffer wind-B))
	beg-A end-A beg-B end-B)
942

943 944
    (save-excursion
      (save-window-excursion
Karl Heuer's avatar
Karl Heuer committed
945
	(sit-for 0) ; sync before using window-start/end -- a precaution
946 947 948 949 950 951
	(select-window wind-A)
	(setq beg-A (window-start)
	      end-A (window-end))
	(select-window wind-B)
	(setq beg-B (window-start)
	      end-B (window-end))))
952 953
    (setq buffer-A
	  (ediff-clone-buffer-for-window-comparison
Michael Kifer's avatar
Michael Kifer committed
954
	   buffer-A wind-A "-Window.A-")
955 956
	  buffer-B
	  (ediff-clone-buffer-for-window-comparison
Michael Kifer's avatar
Michael Kifer committed
957
	   buffer-B wind-B "-Window.B-"))
958 959
    (ediff-regions-internal
     buffer-A beg-A end-A buffer-B beg-B end-B
Michael Kifer's avatar
Michael Kifer committed
960
     startup-hooks job-name word-mode nil)))
961

962

963
;;;###autoload
Karl Heuer's avatar
Karl Heuer committed
964
(defun ediff-regions-wordwise (buffer-A buffer-B &optional startup-hooks)
965
  "Run Ediff on a pair of regions in specified buffers.
966
Regions \(i.e., point and mark\) can be set in advance or marked interactively.
967
This function is effective only for relatively small regions, up to 200
Michael Kifer's avatar
Michael Kifer committed
968
lines.  For large regions, use `ediff-regions-linewise'."
969
  (interactive
970 971 972 973 974 975 976 977