desktop.el 60.7 KB
Newer Older
1
;;; desktop.el --- save partial status of Emacs when killed -*- lexical-binding: t -*-
Richard M. Stallman's avatar
Richard M. Stallman committed
2

Paul Eggert's avatar
Paul Eggert committed
3
;; Copyright (C) 1993-1995, 1997, 2000-2016 Free Software Foundation,
Paul Eggert's avatar
Paul Eggert committed
4
;; Inc.
Richard M. Stallman's avatar
Richard M. Stallman committed
5 6

;; Author: Morten Welinder <terra@diku.dk>
Dave Love's avatar
Dave Love committed
7
;; Keywords: convenience
Paul Eggert's avatar
Paul Eggert committed
8
;; Favorite-brand-of-beer: None, I hate beer.
Richard M. Stallman's avatar
Richard M. Stallman committed
9 10 11

;; This file is part of GNU Emacs.

12
;; GNU Emacs is free software: you can redistribute it and/or modify
Richard M. Stallman's avatar
Richard M. Stallman committed
13
;; it under the terms of the GNU General Public License as published by
14 15
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Richard M. Stallman's avatar
Richard M. Stallman committed
16 17 18 19 20 21 22

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
23
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
Richard M. Stallman's avatar
Richard M. Stallman committed
24 25 26

;;; Commentary:

27 28 29 30 31 32 33 34
;; Save the Desktop, i.e.,
;;	- some global variables
;; 	- the list of buffers with associated files.  For each buffer also
;;		- the major mode
;;		- the default directory
;;		- the point
;;		- the mark & mark-active
;;		- buffer-read-only
35
;;		- some local variables
36
;;	- frame and window configuration
Richard M. Stallman's avatar
Richard M. Stallman committed
37

Kenichi Handa's avatar
Kenichi Handa committed
38
;; To use this, use customize to turn on desktop-save-mode or add the
39
;; following line somewhere in your init file:
40
;;
Kenichi Handa's avatar
Kenichi Handa committed
41
;;	(desktop-save-mode 1)
42
;;
Kenichi Handa's avatar
Kenichi Handa committed
43
;; For further usage information, look at the section
Glenn Morris's avatar
Glenn Morris committed
44
;; (info "(emacs)Saving Emacs Sessions") in the GNU Emacs Manual.
Kenichi Handa's avatar
Kenichi Handa committed
45 46

;; When the desktop module is loaded, the function `desktop-kill' is
47
;; added to the `kill-emacs-hook'.  This function is responsible for
Kenichi Handa's avatar
Kenichi Handa committed
48
;; saving the desktop when Emacs is killed.  Furthermore an anonymous
49
;; function is added to the `after-init-hook'.  This function is
Kenichi Handa's avatar
Kenichi Handa committed
50
;; responsible for loading the desktop when Emacs is started.
51

52 53 54 55 56
;; Special handling.
;; -----------------
;; Variables `desktop-buffer-mode-handlers' and `desktop-minor-mode-handlers'
;; are supplied to handle special major and minor modes respectively.
;; `desktop-buffer-mode-handlers' is an alist of major mode specific functions
57
;; to restore a desktop buffer.  Elements must have the form
58
;;
59
;;    (MAJOR-MODE . RESTORE-BUFFER-FUNCTION).
60
;;
61
;; Functions listed are called by `desktop-create-buffer' when `desktop-read'
62
;; evaluates the desktop file.  Buffers with a major mode not specified here,
63 64 65
;; are restored by the default handler `desktop-restore-file-buffer'.
;; `desktop-minor-mode-handlers' is an alist of functions to restore
;; non-standard minor modes.  Elements must have the form
66
;;
67
;;    (MINOR-MODE . RESTORE-FUNCTION).
68
;;
69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85
;; Functions are called by `desktop-create-buffer' to restore minor modes.
;; Minor modes not specified here, are restored by the standard minor mode
;; function.  If you write a module that defines a major or minor mode that
;; needs a special handler, then place code like

;;    (defun foo-restore-desktop-buffer
;;    ...
;;    (add-to-list 'desktop-buffer-mode-handlers
;;                 '(foo-mode . foo-restore-desktop-buffer))

;; or

;;    (defun bar-desktop-restore
;;    ...
;;    (add-to-list 'desktop-minor-mode-handlers
;;                 '(bar-mode . bar-desktop-restore))

86 87 88 89
;; in the module itself.  The mode function must either be autoloaded,
;; or of the form "foobar-mode" and defined in library "foobar", so that
;; desktop can guess how to load its definition.
;; See the docstrings of `desktop-buffer-mode-handlers' and
90 91 92 93 94 95 96 97 98 99 100 101 102 103
;; `desktop-minor-mode-handlers' for more info.

;; Minor modes.
;; ------------
;; Conventional minor modes (see node "Minor Mode Conventions" in the elisp
;; manual) are handled in the following way:
;; When `desktop-save' saves the state of a buffer to the desktop file, it
;; saves as `desktop-minor-modes' the list of names of those variables in
;; `minor-mode-alist' that have a non-nil value.
;; When `desktop-create' restores the buffer, each of the symbols in
;; `desktop-minor-modes' is called as function with parameter 1.
;; The variables `desktop-minor-mode-table' and `desktop-minor-mode-handlers'
;; are used to handle non-conventional minor modes.  `desktop-save' uses
;; `desktop-minor-mode-table' to map minor mode variables to minor mode
104
;; functions before writing `desktop-minor-modes'.  If a minor mode has a
105 106 107 108 109 110 111 112 113
;; variable name that is different form its function name, an entry

;;    (NAME RESTORE-FUNCTION)

;; should be added to `desktop-minor-mode-table'.  If a minor mode should not
;; be restored, RESTORE-FUNCTION should be set to nil.  `desktop-create' uses
;; `desktop-minor-mode-handlers' to lookup minor modes that needs a restore
;; function different from the usual minor mode function.
;; ---------------------------------------------------------------------------
114

115 116 117 118
;; By the way: don't use desktop.el to customize Emacs -- the file .emacs
;; in your home directory is used for that.  Saving global default values
;; for buffers is an example of misuse.

119 120 121
;; PLEASE NOTE: The kill ring can be saved as specified by the variable
;; `desktop-globals-to-save' (by default it isn't).  This may result in saving
;; things you did not mean to keep.  Use M-x desktop-clear RET.
122

123 124 125 126 127
;; Thanks to  hetrick@phys.uva.nl (Jim Hetrick)      for useful ideas.
;;            avk@rtsg.mot.com (Andrew V. Klein)     for a dired tip.
;;            chris@tecc.co.uk (Chris Boucher)       for a mark tip.
;;            f89-kam@nada.kth.se (Klas Mellbourn)   for a mh-e tip.
;;            kifer@sbkifer.cs.sunysb.edu (M. Kifer) for a bug hunt.
128
;;            treese@lcs.mit.edu (Win Treese)        for ange-ftp tips.
Glenn Morris's avatar
Glenn Morris committed
129
;;            pot@cnuce.cnr.it (Francesco Potortì)  for misc. tips.
130 131 132 133 134
;; ---------------------------------------------------------------------------
;; TODO:
;;
;; Recognize more minor modes.
;; Save mark rings.
Richard M. Stallman's avatar
Richard M. Stallman committed
135 136 137

;;; Code:

138
(require 'cl-lib)
139
(require 'frameset)
140

141
(defvar desktop-file-version "208"
Kenichi Handa's avatar
Kenichi Handa committed
142
  "Version number of desktop file format.
143 144 145
Written into the desktop file and used at desktop read to provide
backward compatibility.")

146
;; ----------------------------------------------------------------------------
147 148
;; USER OPTIONS -- settings you might want to play with.
;; ----------------------------------------------------------------------------
149 150 151 152 153

(defgroup desktop nil
  "Save status of Emacs when you exit."
  :group 'frames)

154 155
;; Maintained for backward compatibility
(define-obsolete-variable-alias 'desktop-enable 'desktop-save-mode "22.1")
Kenichi Handa's avatar
Kenichi Handa committed
156 157
;;;###autoload
(define-minor-mode desktop-save-mode
158
  "Toggle desktop saving (Desktop Save mode).
Glenn Morris's avatar
Glenn Morris committed
159 160 161
With a prefix argument ARG, enable Desktop Save mode if ARG is positive,
and disable it otherwise.  If called from Lisp, enable the mode if ARG
is omitted or nil.
162

Glenn Morris's avatar
Glenn Morris committed
163 164 165 166 167
When Desktop Save mode is enabled, the state of Emacs is saved from
one session to another.  In particular, Emacs will save the desktop when
it exits (this may prompt you; see the option `desktop-save').  The next
time Emacs starts, if this mode is active it will restore the desktop.

168 169
To manually save the desktop at any time, use the command `\\[desktop-save]'.
To load it, use `\\[desktop-read]'.
Glenn Morris's avatar
Glenn Morris committed
170 171 172 173 174 175 176

Once a desktop file exists, Emacs will auto-save it according to the
option `desktop-auto-save-timeout'.

To see all the options you can set, browse the `desktop' customization group.

For further details, see info node `(emacs)Saving Emacs Sessions'."
Kenichi Handa's avatar
Kenichi Handa committed
177
  :global t
178 179
  :group 'desktop
  (if desktop-save-mode
180 181
      (desktop-auto-save-enable)
    (desktop-auto-save-disable)))
Kenichi Handa's avatar
Kenichi Handa committed
182

183 184 185 186
(defun desktop-save-mode-off ()
  "Disable `desktop-save-mode'.  Provided for use in hooks."
  (desktop-save-mode 0))

187
(defcustom desktop-save 'ask-if-new
Lute Kamstra's avatar
Lute Kamstra committed
188
  "Specifies whether the desktop should be saved when it is killed.
Kenichi Handa's avatar
Kenichi Handa committed
189 190
A desktop is killed when the user changes desktop or quits Emacs.
Possible values are:
191 192 193 194 195 196
   t             -- always save.
   ask           -- always ask.
   ask-if-new    -- ask if no desktop file exists, otherwise just save.
   ask-if-exists -- ask if desktop file exists, otherwise don't save.
   if-exists     -- save if desktop file exists, otherwise don't save.
   nil           -- never save.
Kenichi Handa's avatar
Kenichi Handa committed
197
The desktop is never saved when `desktop-save-mode' is nil.
198
The variables `desktop-dirname' and `desktop-base-file-name'
Kenichi Handa's avatar
Kenichi Handa committed
199
determine where the desktop is saved."
200 201
  :type
  '(choice
202 203 204 205 206 207
    (const :tag "Always save" t)
    (const :tag "Always ask" ask)
    (const :tag "Ask if desktop file is new, else do save" ask-if-new)
    (const :tag "Ask if desktop file exists, else don't save" ask-if-exists)
    (const :tag "Save if desktop file exists, else don't" if-exists)
    (const :tag "Never save" nil))
208
  :group 'desktop
209
  :version "22.1")
210

211 212
(defcustom desktop-auto-save-timeout auto-save-timeout
  "Number of seconds idle time before auto-save of the desktop.
213
The idle timer activates auto-saving only when window configuration changes.
Glenn Morris's avatar
Glenn Morris committed
214
This applies to an existing desktop file when `desktop-save-mode' is enabled.
215
Zero or nil means disable auto-saving due to idleness."
216 217 218 219
  :type '(choice (const :tag "Off" nil)
                 (integer :tag "Seconds"))
  :set (lambda (symbol value)
         (set-default symbol value)
220 221
         (ignore-errors
	   (if (and (integerp value) (> value 0))
222 223
	       (desktop-auto-save-enable value)
	     (desktop-auto-save-disable))))
224 225 226
  :group 'desktop
  :version "24.4")

227 228 229 230 231 232 233 234 235 236 237 238 239 240
(defcustom desktop-load-locked-desktop 'ask
  "Specifies whether the desktop should be loaded if locked.
Possible values are:
   t    -- load anyway.
   nil  -- don't load.
   ask  -- ask the user.
If the value is nil, or `ask' and the user chooses not to load the desktop,
the normal hook `desktop-not-loaded-hook' is run."
  :type
  '(choice
    (const :tag "Load anyway" t)
    (const :tag "Don't load" nil)
    (const :tag "Ask the user" ask))
  :group 'desktop
241
  :version "22.2")
242

243 244 245
(define-obsolete-variable-alias 'desktop-basefilename
                                'desktop-base-file-name "22.1")

246
(defcustom desktop-base-file-name
247
  (convert-standard-filename ".emacs.desktop")
Kenichi Handa's avatar
Kenichi Handa committed
248
  "Name of file for Emacs desktop, excluding the directory part."
249 250
  :type 'file
  :group 'desktop)
Richard M. Stallman's avatar
Richard M. Stallman committed
251

252 253 254 255 256
(defcustom desktop-base-lock-name
  (convert-standard-filename ".emacs.desktop.lock")
  "Name of lock file for Emacs desktop, excluding the directory part."
  :type 'file
  :group 'desktop
257
  :version "22.2")
258

Chong Yidong's avatar
Chong Yidong committed
259
(defcustom desktop-path (list user-emacs-directory "~")
260 261 262
  "List of directories to search for the desktop file.
The base name of the file is specified in `desktop-base-file-name'."
  :type '(repeat directory)
263
  :group 'desktop
264
  :version "23.2")                      ; user-emacs-directory added
265

266
(defcustom desktop-missing-file-warning nil
267
  "If non-nil, offer to recreate the buffer of a deleted file.
268 269 270 271
Also pause for a moment to display message about errors signaled in
`desktop-buffer-mode-handlers'.

If nil, just print error messages in the message buffer."
272
  :type 'boolean
273
  :group 'desktop
274
  :version "22.1")
Richard M. Stallman's avatar
Richard M. Stallman committed
275

276
(defcustom desktop-no-desktop-file-hook nil
Kenichi Handa's avatar
Kenichi Handa committed
277
  "Normal hook run when `desktop-read' can't find a desktop file.
278
Run in the directory in which the desktop file was sought.
279
May be used to show a dired buffer."
280
  :type 'hook
281
  :group 'desktop
282
  :version "22.1")
283

284 285 286 287 288 289 290
(defcustom desktop-not-loaded-hook nil
  "Normal hook run when the user declines to re-use a desktop file.
Run in the directory in which the desktop file was found.
May be used to deal with accidental multiple Emacs jobs."
  :type 'hook
  :group 'desktop
  :options '(desktop-save-mode-off save-buffers-kill-emacs)
291
  :version "22.2")
292

293
(defcustom desktop-after-read-hook nil
Kenichi Handa's avatar
Kenichi Handa committed
294
  "Normal hook run after a successful `desktop-read'.
295
May be used to show a buffer list."
296
  :type 'hook
297
  :group 'desktop
298
  :options '(list-buffers)
299
  :version "22.1")
300 301

(defcustom desktop-save-hook nil
Kenichi Handa's avatar
Kenichi Handa committed
302
  "Normal hook run before the desktop is saved in a desktop file.
303 304 305
Run with the desktop buffer current with only the header present.
May be used to add to the desktop code or to truncate history lists,
for example."
306 307 308
  :type 'hook
  :group 'desktop)

309 310 311 312 313 314
(defcustom desktop-globals-to-save
  '(desktop-missing-file-warning
    tags-file-name
    tags-table-list
    search-ring
    regexp-search-ring
315 316
    register-alist
    file-name-history)
Kenichi Handa's avatar
Kenichi Handa committed
317 318 319 320
  "List of global variables saved by `desktop-save'.
An element may be variable name (a symbol) or a cons cell of the form
\(VAR . MAX-SIZE), which means to truncate VAR's value to at most
MAX-SIZE elements (if the value is a list) before saving the value.
321 322 323 324
Feature: Saving `kill-ring' implies saving `kill-ring-yank-pointer'."
  :type '(repeat (restricted-sexp :match-alternatives (symbolp consp)))
  :group 'desktop)

325 326 327 328 329 330 331
(defcustom desktop-globals-to-clear
  '(kill-ring
    kill-ring-yank-pointer
    search-ring
    search-ring-yank-pointer
    regexp-search-ring
    regexp-search-ring-yank-pointer)
332
  "List of global variables that `desktop-clear' will clear.
333
An element may be variable name (a symbol) or a cons cell of the form
334 335
\(VAR . FORM).  Symbols are set to nil and for cons cells VAR is set
to the value obtained by evaluating FORM."
336
  :type '(repeat (restricted-sexp :match-alternatives (symbolp consp)))
337
  :group 'desktop
338
  :version "22.1")
339

340
(defcustom desktop-clear-preserve-buffers
Glenn Morris's avatar
Glenn Morris committed
341 342
  '("\\*scratch\\*" "\\*Messages\\*" "\\*server\\*" "\\*tramp/.+\\*"
    "\\*Warnings\\*")
Lute Kamstra's avatar
Lute Kamstra committed
343
  "List of buffers that `desktop-clear' should not delete.
344 345
Each element is a regular expression.  Buffers with a name matched by any of
these won't be deleted."
Glenn Morris's avatar
Glenn Morris committed
346
  :version "23.3"                       ; added Warnings - bug#6336
347 348
  :type '(repeat string)
  :group 'desktop)
349

350
;;;###autoload
351 352 353 354 355 356 357 358 359
(defcustom desktop-locals-to-save
  '(desktop-locals-to-save  ; Itself!  Think it over.
    truncate-lines
    case-fold-search
    case-replace
    fill-column
    overwrite-mode
    change-log-default-name
    line-number-mode
360 361 362 363
    column-number-mode
    size-indication-mode
    buffer-file-coding-system
    indent-tabs-mode
364
    tab-width
365 366 367
    indicate-buffer-boundaries
    indicate-empty-lines
    show-trailing-whitespace)
Richard M. Stallman's avatar
Richard M. Stallman committed
368
  "List of local variables to save for each buffer.
369 370
The variables are saved only when they really are local.  Conventional minor
modes are restored automatically; they should not be listed here."
Kenichi Handa's avatar
Kenichi Handa committed
371 372
  :type '(repeat symbol)
  :group 'desktop)
373

374
(defcustom desktop-buffers-not-to-save "\\` "
375
  "Regexp identifying buffers that are to be excluded from saving."
376 377
  :type '(choice (const :tag "None" nil)
		 regexp)
378
  :version "24.4"		    ; skip invisible temporary buffers
379
  :group 'desktop)
Richard M. Stallman's avatar
Richard M. Stallman committed
380

Kenichi Handa's avatar
Kenichi Handa committed
381
;; Skip tramp and ange-ftp files
382
(defcustom desktop-files-not-to-save
383
  "\\(^/[^/:]*:\\|(ftp)$\\)"
384
  "Regexp identifying files whose buffers are to be excluded from saving."
385 386
  :type '(choice (const :tag "None" nil)
		 regexp)
387
  :group 'desktop)
388

389 390 391
;; We skip TAGS files to save time (tags-file-name is saved instead).
(defcustom desktop-modes-not-to-save
  '(tags-table-mode)
392 393 394 395
  "List of major modes whose buffers should not be saved."
  :type '(repeat symbol)
  :group 'desktop)

396
(defcustom desktop-restore-frames t
397 398 399
  "When non-nil, save and restore the frame and window configuration.
See related options `desktop-restore-reuses-frames',
`desktop-restore-in-current-display', and `desktop-restore-forces-onscreen'."
400 401 402 403
  :type 'boolean
  :group 'desktop
  :version "24.4")

404
(defcustom desktop-restore-in-current-display nil
405 406 407 408
  "Controls how restoring of frames treats displays.
If t, restores frames into the current display.
If nil, restores frames into their original displays (if possible).
If `delete', deletes frames on other displays instead of restoring them."
409 410
  :type '(choice (const :tag "Restore in current display" t)
		 (const :tag "Restore in original display" nil)
Glenn Morris's avatar
Glenn Morris committed
411
		 (const :tag "Delete frames in other displays" delete))
412 413 414
  :group 'desktop
  :version "24.4")

415
(defcustom desktop-restore-forces-onscreen t
416 417 418 419 420 421 422
  "If t, restores frames that are fully offscreen onscreen instead.
If `all', also restores frames that are partially offscreen onscreen.

Note that checking of frame boundaries is only approximate.
It can fail to reliably detect frames whose onscreen/offscreen state
depends on a few pixels, especially near the right / bottom borders
of the screen."
423
  :type '(choice (const :tag "Only fully offscreen frames" t)
424
		 (const :tag "Also partially offscreen frames" all)
425 426 427 428
		 (const :tag "Do not force frames onscreen" nil))
  :group 'desktop
  :version "24.4")

429
(defcustom desktop-restore-reuses-frames t
430
  "If t, restoring frames reuses existing frames.
431 432
If nil, deletes existing frames.
If `keep', keeps existing frames and does not reuse them."
433 434
  :type '(choice (const :tag "Reuse existing frames" t)
		 (const :tag "Delete existing frames" nil)
435
		 (const :tag "Keep existing frames" :keep))
436 437 438
  :group 'desktop
  :version "24.4")

439
(defcustom desktop-file-name-format 'absolute
Lute Kamstra's avatar
Lute Kamstra committed
440
  "Format in which desktop file names should be saved.
441 442 443 444 445
Possible values are:
   absolute -- Absolute file name.
   tilde    -- Relative to ~.
   local    -- Relative to directory of desktop file."
  :type '(choice (const absolute) (const tilde) (const local))
446
  :group 'desktop
447
  :version "22.1")
448

449 450 451 452
(defcustom desktop-restore-eager t
  "Number of buffers to restore immediately.
Remaining buffers are restored lazily (when Emacs is idle).
If value is t, all buffers are restored immediately."
453
  :type '(choice (const t) integer)
454
  :group 'desktop
455
  :version "22.1")
456 457 458 459 460

(defcustom desktop-lazy-verbose t
  "Verbose reporting of lazily created buffers."
  :type 'boolean
  :group 'desktop
461
  :version "22.1")
462 463 464 465 466 467

(defcustom desktop-lazy-idle-delay 5
  "Idle delay before starting to create buffers.
See `desktop-restore-eager'."
  :type 'integer
  :group 'desktop
468
  :version "22.1")
469

470
;;;###autoload
471
(defvar-local desktop-save-buffer nil
472 473
  "When non-nil, save buffer status in desktop file.

474 475
If the value is a function, it is called by `desktop-save' with argument
DESKTOP-DIRNAME to obtain auxiliary information to save in the desktop
476
file along with the state of the buffer for which it was called.
477

Kenichi Handa's avatar
Kenichi Handa committed
478
When file names are returned, they should be formatted using the call
479
\"(desktop-file-name FILE-NAME DESKTOP-DIRNAME)\".
480

481 482 483
Later, when `desktop-read' evaluates the desktop file, auxiliary information
is passed as the argument DESKTOP-BUFFER-MISC to functions in
`desktop-buffer-mode-handlers'.")
484
(make-obsolete-variable 'desktop-buffer-modes-to-save
485
                        'desktop-save-buffer "22.1")
486
(make-obsolete-variable 'desktop-buffer-misc-functions
487
                        'desktop-save-buffer "22.1")
488

489
;;;###autoload
Chong Yidong's avatar
Chong Yidong committed
490
(defvar desktop-buffer-mode-handlers nil
491
  "Alist of major mode specific functions to restore a desktop buffer.
492 493 494 495
Functions listed are called by `desktop-create-buffer' when `desktop-read'
evaluates the desktop file.  List elements must have the form

   (MAJOR-MODE . RESTORE-BUFFER-FUNCTION).
496 497 498 499

Buffers with a major mode not specified here, are restored by the default
handler `desktop-restore-file-buffer'.

500
Handlers are called with argument list
501

502
   (DESKTOP-BUFFER-FILE-NAME DESKTOP-BUFFER-NAME DESKTOP-BUFFER-MISC)
503 504

Furthermore, they may use the following variables:
505

506 507 508 509 510 511 512
   `desktop-file-version'
   `desktop-buffer-major-mode'
   `desktop-buffer-minor-modes'
   `desktop-buffer-point'
   `desktop-buffer-mark'
   `desktop-buffer-read-only'
   `desktop-buffer-locals'
513

514
If a handler returns a buffer, then the saved mode settings
515 516 517 518
and variable values for that buffer are copied into it.

Modules that define a major mode that needs a special handler should contain
code like
519

520 521
   (defun foo-restore-desktop-buffer
   ...
522 523
   (add-to-list \\='desktop-buffer-mode-handlers
                \\='(foo-mode . foo-restore-desktop-buffer))
524

525 526 527
The major mode function must either be autoloaded, or of the form
\"foobar-mode\" and defined in library \"foobar\", so that desktop
can guess how to load the mode's definition.")
528

529
;;;###autoload
530 531
(put 'desktop-buffer-mode-handlers 'risky-local-variable t)
(make-obsolete-variable 'desktop-buffer-handlers
532
                        'desktop-buffer-mode-handlers "22.1")
533

534 535
(defcustom desktop-minor-mode-table
  '((auto-fill-function auto-fill-mode)
536 537
    (defining-kbd-macro nil)
    (isearch-mode nil)
538
    (vc-mode nil)
539
    (vc-dired-mode nil)
540 541
    (erc-track-minor-mode nil)
    (savehist-mode nil))
542 543 544 545
  "Table mapping minor mode variables to minor mode functions.
Each entry has the form (NAME RESTORE-FUNCTION).
NAME is the name of the buffer-local variable indicating that the minor
mode is active.  RESTORE-FUNCTION is the function to activate the minor mode.
546
RESTORE-FUNCTION nil means don't try to restore the minor mode.
547
Only minor modes for which the name of the buffer-local variable
548
and the name of the minor mode function are different have to be added to
549
this table.  See also `desktop-minor-mode-handlers'."
550 551 552
  :type 'sexp
  :group 'desktop)

553
;;;###autoload
Chong Yidong's avatar
Chong Yidong committed
554
(defvar desktop-minor-mode-handlers nil
555 556 557 558 559 560 561 562 563 564 565 566 567 568 569
  "Alist of functions to restore non-standard minor modes.
Functions are called by `desktop-create-buffer' to restore minor modes.
List elements must have the form

   (MINOR-MODE . RESTORE-FUNCTION).

Minor modes not specified here, are restored by the standard minor mode
function.

Handlers are called with argument list

   (DESKTOP-BUFFER-LOCALS)

Furthermore, they may use the following variables:

570 571 572 573 574 575 576 577 578
   `desktop-file-version'
   `desktop-buffer-file-name'
   `desktop-buffer-name'
   `desktop-buffer-major-mode'
   `desktop-buffer-minor-modes'
   `desktop-buffer-point'
   `desktop-buffer-mark'
   `desktop-buffer-read-only'
   `desktop-buffer-misc'
579 580 581 582 583 584 585 586 587 588

When a handler is called, the buffer has been created and the major mode has
been set, but local variables listed in desktop-buffer-locals has not yet been
created and set.

Modules that define a minor mode that needs a special handler should contain
code like

   (defun foo-desktop-restore
   ...
589 590
   (add-to-list \\='desktop-minor-mode-handlers
                \\='(foo-mode . foo-desktop-restore))
591

592 593 594
The minor mode function must either be autoloaded, or of the form
\"foobar-mode\" and defined in library \"foobar\", so that desktop
can guess how to load the mode's definition.
595 596 597

See also `desktop-minor-mode-table'.")

598
;;;###autoload
599 600
(put 'desktop-minor-mode-handlers 'risky-local-variable t)

601 602
;; ----------------------------------------------------------------------------
(defvar desktop-dirname nil
Kenichi Handa's avatar
Kenichi Handa committed
603
  "The directory in which the desktop file should be saved.")
Richard M. Stallman's avatar
Richard M. Stallman committed
604

605 606 607 608 609
(defun desktop-full-file-name (&optional dirname)
  "Return the full name of the desktop file in DIRNAME.
DIRNAME omitted or nil means use `desktop-dirname'."
  (expand-file-name desktop-base-file-name (or dirname desktop-dirname)))

610 611 612 613 614
(defun desktop-full-lock-name (&optional dirname)
  "Return the full name of the desktop lock file in DIRNAME.
DIRNAME omitted or nil means use `desktop-dirname'."
  (expand-file-name desktop-base-lock-name (or dirname desktop-dirname)))

Richard M. Stallman's avatar
Richard M. Stallman committed
615
(defconst desktop-header
616 617 618
";; --------------------------------------------------------------------------
;; Desktop File for Emacs
;; --------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
619
" "*Header to place in Desktop file.")
620 621 622

(defvar desktop-delay-hook nil
  "Hooks run after all buffers are loaded; intended for internal use.")
623

624 625 626 627
(defvar desktop-file-checksum nil
  "Checksum of the last auto-saved contents of the desktop file.
Used to avoid writing contents unchanged between auto-saves.")

628
(defvar desktop-saved-frameset nil
629 630
  "Saved state of all frames.
Only valid during frame saving & restoring; intended for internal use.")
631

632 633 634 635 636 637
;; ----------------------------------------------------------------------------
;; Desktop file conflict detection
(defvar desktop-file-modtime nil
  "When the desktop file was last modified to the knowledge of this Emacs.
Used to detect desktop file conflicts.")

638 639 640 641 642 643 644 645 646 647 648 649
(defvar desktop-var-serdes-funs
  (list (list
	 'mark-ring
	 (lambda (mr)
	   (mapcar #'marker-position mr))
	 (lambda (mr)
	   (mapcar #'copy-marker mr))))
  "Table of serialization/deserialization functions for variables.
Each record is a list of form: (var serializer deserializer).
These records can be freely reordered, deleted, or new ones added.
However, for compatibility, don't modify the functions for existing records.")

650 651 652 653
(defun desktop-owner (&optional dirname)
  "Return the PID of the Emacs process that owns the desktop file in DIRNAME.
Return nil if no desktop file found or no Emacs process is using it.
DIRNAME omitted or nil means use `desktop-dirname'."
654 655 656 657 658 659 660 661 662
  (let (owner
	(file (desktop-full-lock-name dirname)))
    (and (file-exists-p file)
	 (ignore-errors
	   (with-temp-buffer
	     (insert-file-contents-literally file)
	     (goto-char (point-min))
	     (setq owner (read (current-buffer)))
	     (integerp owner)))
663 664 665 666 667 668 669 670 671 672 673 674 675 676
	 owner)))

(defun desktop-claim-lock (&optional dirname)
  "Record this Emacs process as the owner of the desktop file in DIRNAME.
DIRNAME omitted or nil means use `desktop-dirname'."
  (write-region (number-to-string (emacs-pid)) nil
		(desktop-full-lock-name dirname)))

(defun desktop-release-lock (&optional dirname)
  "Remove the lock file for the desktop in DIRNAME.
DIRNAME omitted or nil means use `desktop-dirname'."
  (let ((file (desktop-full-lock-name dirname)))
    (when (file-exists-p file) (delete-file file))))

677
;; ----------------------------------------------------------------------------
Kenichi Handa's avatar
Kenichi Handa committed
678
(defun desktop-truncate (list n)
679
  "Truncate LIST to at most N elements destructively."
Kenichi Handa's avatar
Kenichi Handa committed
680
  (let ((here (nthcdr (1- n) list)))
681 682
    (when (consp here)
      (setcdr here nil))))
683

684
;; ----------------------------------------------------------------------------
685
;;;###autoload
686 687
(defun desktop-clear ()
  "Empty the Desktop.
688 689
This kills all buffers except for internal ones and those with names matched by
a regular expression in the list `desktop-clear-preserve-buffers'.
690 691 692 693
Furthermore, it clears the variables listed in `desktop-globals-to-clear'.
When called interactively and `desktop-restore-frames' is non-nil, it also
deletes all frames except the selected one (and its minibuffer frame,
if different)."
Richard M. Stallman's avatar
Richard M. Stallman committed
694
  (interactive)
695
  (desktop-lazy-abort)
696 697
  (dolist (var desktop-globals-to-clear)
    (if (symbolp var)
698
	(eval `(setq-default ,var nil))
699
      (eval `(setq-default ,(car var) ,(cdr var)))))
700
  (let ((preserve-regexp (concat "^\\("
701 702 703 704 705
                                 (mapconcat (lambda (regexp)
                                              (concat "\\(" regexp "\\)"))
                                            desktop-clear-preserve-buffers
                                            "\\|")
                                 "\\)$")))
706 707
    (dolist (buffer (buffer-list))
      (let ((bufname (buffer-name buffer)))
708
	(unless (or (eq (aref bufname 0) ?\s) ;; Don't kill internal buffers
709 710
		    (string-match-p preserve-regexp bufname))
	  (kill-buffer buffer)))))
711
  (delete-other-windows)
712 713 714 715 716
  (when (and desktop-restore-frames
	     ;; Non-interactive calls to desktop-clear happen before desktop-read
	     ;; which already takes care of frame restoration and deletion.
	     (called-interactively-p 'any))
    (let* ((this (selected-frame))
Paul Eggert's avatar
Paul Eggert committed
717
	   (mini (window-frame (minibuffer-window this)))) ; in case they differ
718
      (dolist (frame (sort (frame-list) #'frameset-minibufferless-first-p))
719 720 721 722 723 724
	(condition-case err
	    (unless (or (eq frame this)
			(eq frame mini)
			(frame-parameter frame 'desktop-dont-clear))
	      (delete-frame frame))
	  (error
725
	   (delay-warning 'desktop (error-message-string err))))))))
726

727
;; ----------------------------------------------------------------------------
Juanma Barranquero's avatar
Juanma Barranquero committed
728 729
(unless noninteractive
  (add-hook 'kill-emacs-hook 'desktop-kill))
730

Richard M. Stallman's avatar
Richard M. Stallman committed
731
(defun desktop-kill ()
Kenichi Handa's avatar
Kenichi Handa committed
732
  "If `desktop-save-mode' is non-nil, do what `desktop-save' says to do.
733 734
If the desktop should be saved and `desktop-dirname'
is nil, ask the user where to save the desktop."
735 736 737
  (when (and desktop-save-mode
             (let ((exists (file-exists-p (desktop-full-file-name))))
               (or (eq desktop-save t)
738 739 740 741
                   (and exists (eq desktop-save 'if-exists))
		   ;; If it exists, but we aren't using it, we are going
		   ;; to ask for a new directory below.
                   (and exists desktop-dirname (eq desktop-save 'ask-if-new))
742 743 744 745
                   (and
                    (or (memq desktop-save '(ask ask-if-new))
                        (and exists (eq desktop-save 'ask-if-exists)))
                    (y-or-n-p "Save desktop? ")))))
746 747
    (unless desktop-dirname
      (setq desktop-dirname
748 749
            (file-name-as-directory
             (expand-file-name
750
	      (read-directory-name "Directory for desktop file: " nil nil t)))))
751
    (condition-case err
752
	(desktop-save desktop-dirname t)
753
      (file-error
754
       (unless (yes-or-no-p "Error while saving the desktop.  Ignore? ")
755 756 757
	 (signal (car err) (cdr err))))))
  ;; If we own it, we don't anymore.
  (when (eq (emacs-pid) (desktop-owner)) (desktop-release-lock)))
758

759
;; ----------------------------------------------------------------------------
760
(defun desktop-list* (&rest args)
761
  (and args (apply #'cl-list* args)))
762

763 764
;; ----------------------------------------------------------------------------
(defun desktop-buffer-info (buffer)
765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782
  "Return information describing BUFFER.
This function is not pure, as BUFFER is made current with
`set-buffer'.

Returns a list of all the necessary information to recreate the
buffer, which is (in order):

    `uniquify-buffer-base-name';
    `buffer-file-name';
    `buffer-name';
    `major-mode';
    list of minor-modes,;
    `point';
    `mark';
    `buffer-read-only';
    auxiliary information given by `desktop-save-buffer';
    local variables;
    auxiliary information given by `desktop-var-serdes-funs'."
783 784
  (set-buffer buffer)
  (list
785 786
   ;; base name of the buffer; replaces the buffer name if managed by uniquify
   (and (fboundp 'uniquify-buffer-base-name) (uniquify-buffer-base-name))
787
   ;; basic information
788
   (desktop-file-name (buffer-file-name) desktop-dirname)
789
   (buffer-name)
790 791 792
   major-mode
   ;; minor modes
   (let (ret)
793 794 795 796 797 798 799
     (dolist (minor-mode (mapcar #'car minor-mode-alist) ret)
       (and (boundp minor-mode)
            (symbol-value minor-mode)
            (let* ((special (assq minor-mode desktop-minor-mode-table))
                   (value (cond (special (cadr special))
                                ((functionp minor-mode) minor-mode))))
              (when value (cl-pushnew value ret))))))
800 801 802 803 804 805
   ;; point and mark, and read-only status
   (point)
   (list (mark t) mark-active)
   buffer-read-only
   ;; auxiliary information
   (when (functionp desktop-save-buffer)
806
     (funcall desktop-save-buffer desktop-dirname))
807
   ;; local variables
808 809 810 811 812 813 814 815
   (let ((loclist (buffer-local-variables))
	 (ll nil))
     (dolist (local desktop-locals-to-save)
       (let ((here (assq local loclist)))
	 (cond (here
		(push here ll))
	       ((member local loclist)
		(push local ll)))))
816 817 818 819 820 821
     ll)
   (mapcar (lambda (record)
	     (let ((var (car record)))
	       (list var
		     (funcall (cadr record) (symbol-value var)))))
	   desktop-var-serdes-funs)))
822

823
;; ----------------------------------------------------------------------------
824 825 826
(defun desktop--v2s (value)
  "Convert VALUE to a pair (QUOTE . SEXP); (eval SEXP) gives VALUE.
SEXP is an sexp that when evaluated yields VALUE.
Richard M. Stallman's avatar
Richard M. Stallman committed
827
QUOTE may be `may' (value may be quoted),
828
`must' (value must be quoted), or nil (value must not be quoted)."
829
  (cond
830
    ((or (numberp value) (null value) (eq t value) (keywordp value))
831
     (cons 'may value))
832 833 834
    ((stringp value)
     (let ((copy (copy-sequence value)))
       (set-text-properties 0 (length copy) nil copy)
835 836
       ;; Get rid of text properties because we cannot read them.
       (cons 'may copy)))
837
    ((symbolp value)
838
     (cons 'must value))
839
    ((vectorp value)
840 841
     (let* ((pass1 (mapcar #'desktop--v2s value))
	    (special (assq nil pass1)))
842
       (if special
843 844 845 846 847 848
	   (cons nil `(vector
                       ,@(mapcar (lambda (el)
                                   (if (eq (car el) 'must)
                                       `',(cdr el) (cdr el)))
                                 pass1)))
	 (cons 'may `[,@(mapcar #'cdr pass1)]))))
849 850 851
    ((consp value)
     (let ((p value)
	   newlist
852
	   use-list*)
853
       (while (consp p)
854 855
	 (let ((q.sexp (desktop--v2s (car p))))
           (push q.sexp newlist))
856
	 (setq p (cdr p)))
857 858 859 860 861
       (when p
         (let ((last (desktop--v2s p)))
           (setq use-list* t)
           (push last newlist)))
       (if (assq nil newlist)
862
	   (cons nil
863 864 865 866 867
		 `(,(if use-list* 'desktop-list* 'list)
                   ,@(mapcar (lambda (el)
                               (if (eq (car el) 'must)
                                   `',(cdr el) (cdr el)))
                             (nreverse newlist))))
868
	 (cons 'must
869 870 871
	       `(,@(mapcar #'cdr
                           (nreverse (if use-list* (cdr newlist) newlist)))
                 ,@(if use-list* (cdar newlist)))))))
872
    ((subrp value)
873 874
     (cons nil `(symbol-function
                 ',(intern-soft (substring (prin1-to-string value) 7 -1)))))
875
    ((markerp value)
876 877 878 879 880 881 882 883 884 885
     (let ((pos (marker-position value))
	   (buf (buffer-name (marker-buffer value))))
       (cons nil
             `(let ((mk (make-marker)))
                (add-hook 'desktop-delay-hook
                          `(lambda ()
                             (set-marker ,mk ,,pos (get-buffer ,,buf))))
                mk))))
    (t                                  ; Save as text.
     (cons 'may "Unprintable entity"))))
886

887
;; ----------------------------------------------------------------------------
Kenichi Handa's avatar
Kenichi Handa committed
888
(defun desktop-value-to-string (value)
Richard M. Stallman's avatar
Richard M. Stallman committed
889 890
  "Convert VALUE to a string that when read evaluates to the same value.
Not all types of values are supported."
891
  (let* ((print-escape-newlines t)
892 893
	 (print-length nil)
	 (print-level nil)
894
	 (float-output-format nil)
895 896
	 (quote.sexp (desktop--v2s value))
	 (quote (car quote.sexp))
897 898
	 (print-quoted t)
	 (txt (prin1-to-string (cdr quote.sexp))))
899 900 901
    (if (eq quote 'must)
	(concat "'" txt)
      txt)))
902

903
;; ----------------------------------------------------------------------------
904 905 906
(defun desktop-outvar (varspec)
  "Output a setq statement for variable VAR to the desktop file.
The argument VARSPEC may be the variable name VAR (a symbol),
907
or a cons cell of the form (VAR . MAX-SIZE),
908 909 910 911 912 913
which means to truncate VAR's value to at most MAX-SIZE elements
\(if the value is a list) before saving the value."
  (let (var size)
    (if (consp varspec)
	(setq var (car varspec) size (cdr varspec))
      (setq var varspec))
914 915 916 917 918 919 920 921 922 923
    (when (boundp var)
      (when (and (integerp size)
		 (> size 0)
		 (listp (eval var)))
	(desktop-truncate (eval var) size))
      (insert "(setq "
	      (symbol-name var)
	      " "
	      (desktop-value-to-string (symbol-value var))
	      ")\n"))))
924

925
;; ----------------------------------------------------------------------------
926
(defun desktop-save-buffer-p (filename bufname mode &rest _dummy)
927
  "Return t if buffer should have its state saved in the desktop file.
928
FILENAME is the visited file name, BUFNAME is the buffer name, and
929 930
MODE is the major mode.
\n\(fn FILENAME BUFNAME MODE)"
Glenn Morris's avatar
Glenn Morris committed
931
  (let ((case-fold-search nil)
932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950
	(no-regexp-to-check (not (stringp desktop-files-not-to-save)))
	dired-skip)
    (and (or filename
	     (not (stringp desktop-buffers-not-to-save))
	     (not (string-match-p desktop-buffers-not-to-save bufname)))
	 (not (memq mode desktop-modes-not-to-save))
	 (or (and filename
		  (or no-regexp-to-check
		      (not (string-match-p desktop-files-not-to-save filename))))
	     (and (memq mode '(dired-mode vc-dir-mode))
		  (or no-regexp-to-check
		      (not (setq dired-skip
				 (with-current-buffer bufname
				   (string-match-p desktop-files-not-to-save
						   default-directory))))))
	     (and (null filename)
		  (null dired-skip)  ; bug#5755
		  (with-current-buffer bufname desktop-save-buffer)))
	 t)))
951

952
;; ----------------------------------------------------------------------------
953 954 955 956 957 958 959 960 961 962 963 964 965 966
(defun desktop-file-name (filename dirname)
  "Convert FILENAME to format specified in `desktop-file-name-format'.
DIRNAME must be the directory in which the desktop file will be saved."
  (cond
    ((not filename) nil)
    ((eq desktop-file-name-format 'tilde)
     (let ((relative-name (file-relative-name (expand-file-name filename) "~")))
       (cond
         ((file-name-absolute-p relative-name) relative-name)
         ((string= "./" relative-name) "~/")
         ((string= "." relative-name) "~")
         (t (concat "~/" relative-name)))))
    ((eq desktop-file-name-format 'local) (file-relative-name filename dirname))
    (t (expand-file-name filename))))
967

Miles Bader's avatar
Miles Bader committed
968

969
;; ----------------------------------------------------------------------------