tramp-smb.el 50.8 KB
Newer Older
Michael Albinus's avatar
Michael Albinus committed
1
;;; tramp-smb.el --- Tramp access functions for SMB servers
2

3
;; Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008,
Glenn Morris's avatar
Glenn Morris committed
4
;;   2009, 2010 Free Software Foundation, Inc.
5

Michael Albinus's avatar
Michael Albinus committed
6
;; Author: Michael Albinus <michael.albinus@gmx.de>
7 8 9 10
;; Keywords: comm, processes

;; This file is part of GNU Emacs.

11
;; GNU Emacs is free software: you can redistribute it and/or modify
12
;; it under the terms of the GNU General Public License as published by
13 14
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
15 16 17 18 19 20 21

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
23 24 25 26 27 28 29

;;; Commentary:

;; Access functions for SMB servers like SAMBA or M$ Windows from Tramp.

;;; Code:

Glenn Morris's avatar
Glenn Morris committed
30
(eval-when-compile (require 'cl))	; block, return
31
(require 'tramp)
32
(require 'tramp-cache)
33
(require 'tramp-compat)
34 35 36 37 38 39 40 41 42 43 44 45 46

;; Define SMB method ...
(defcustom tramp-smb-method "smb"
  "*Method to connect SAMBA and M$ SMB servers."
  :group 'tramp
  :type 'string)

;; ... and add it to the method list.
(add-to-list 'tramp-methods (cons tramp-smb-method nil))

;; Add a default for `tramp-default-method-alist'. Rule: If there is
;; a domain in USER, it must be the SMB method.
(add-to-list 'tramp-default-method-alist
47
	     `(nil ,tramp-prefix-domain-regexp ,tramp-smb-method))
48 49 50 51 52

;; Add a default for `tramp-default-user-alist'. Rule: For the SMB method,
;; the anonymous user is chosen.
(add-to-list 'tramp-default-user-alist
	     `(,tramp-smb-method nil ""))
53 54 55 56 57 58 59 60 61 62 63

;; Add completion function for SMB method.
(tramp-set-completion-function
 tramp-smb-method
 '((tramp-parse-netrc "~/.netrc")))

(defcustom tramp-smb-program "smbclient"
  "*Name of SMB client to run."
  :group 'tramp
  :type 'string)

64 65 66 67 68 69 70
(defcustom tramp-smb-conf "/dev/null"
  "*Path of the smb.conf file.
If it is nil, no smb.conf will be added to the `tramp-smb-program'
call, letting the SMB client use the default one."
  :group 'tramp
  :type '(choice (const nil) (file :must-match t)))

71 72 73
(defvar tramp-smb-version nil
  "*Version string of the SMB client.")

Michael Albinus's avatar
Michael Albinus committed
74
(defconst tramp-smb-prompt "^smb: .+> \\|^\\s-+Server\\s-+Comment$"
75 76 77
  "Regexp used as prompt in smbclient.")

(defconst tramp-smb-errors
78
  ;; `regexp-opt' not possible because of first string.
79 80
  (mapconcat
   'identity
81
   '(;; Connection error / timeout / unknown command.
82
     "Connection to \\S-+ failed"
83
     "Read from server failed, maybe it closed the connection"
84
     "Call timed out: server did not respond"
85 86 87
     "\\S-+: command not found"
     "Server doesn't support UNIX CIFS calls"
     ;; Samba.
88
     "ERRDOS"
89
     "ERRHRD"
90
     "ERRSRV"
91 92 93 94 95 96
     "ERRbadfile"
     "ERRbadpw"
     "ERRfilexists"
     "ERRnoaccess"
     "ERRnomem"
     "ERRnosuchshare"
97
     ;; Windows 4.0 (Windows NT), Windows 5.0 (Windows 2000),
98
     ;; Windows 5.1 (Windows XP), Windows 5.2 (Windows Server 2003).
99
     "NT_STATUS_ACCESS_DENIED"
100
     "NT_STATUS_ACCOUNT_LOCKED_OUT"
101 102
     "NT_STATUS_BAD_NETWORK_NAME"
     "NT_STATUS_CANNOT_DELETE"
103
     "NT_STATUS_CONNECTION_REFUSED"
104 105 106
     "NT_STATUS_DIRECTORY_NOT_EMPTY"
     "NT_STATUS_DUPLICATE_NAME"
     "NT_STATUS_FILE_IS_A_DIRECTORY"
107
     "NT_STATUS_LOGON_FAILURE"
108
     "NT_STATUS_NETWORK_ACCESS_DENIED"
109
     "NT_STATUS_NOT_IMPLEMENTED"
110
     "NT_STATUS_NO_SUCH_FILE"
111
     "NT_STATUS_OBJECT_NAME_COLLISION"
112 113
     "NT_STATUS_OBJECT_NAME_INVALID"
     "NT_STATUS_OBJECT_NAME_NOT_FOUND"
114
     "NT_STATUS_SHARING_VIOLATION"
115
     "NT_STATUS_TRUSTED_RELATIONSHIP_FAILURE"
116
     "NT_STATUS_WRONG_PASSWORD")
117 118 119 120
   "\\|")
  "Regexp for possible error strings of SMB servers.
Used instead of analyzing error codes of commands.")

121 122 123 124 125 126 127 128 129 130
(defconst tramp-smb-actions-with-share
  '((tramp-smb-prompt tramp-action-succeed)
    (tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-process-alive))
  "List of pattern/action pairs.
This list is used for login to SMB servers.

See `tramp-actions-before-shell' for more info.")
131

132 133 134 135 136 137 138
(defconst tramp-smb-actions-without-share
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-out-of-band))
  "List of pattern/action pairs.
This list is used for login to SMB servers.
139

140
See `tramp-actions-before-shell' for more info.")
141

142 143 144
;; New handlers should be added here.
(defconst tramp-smb-file-name-handler-alist
  '(
145
    ;; `access-file' performed by default handler.
146
    (add-name-to-file . tramp-smb-handle-add-name-to-file)
147 148
    ;; `byte-compiler-base-file-name' performed by default handler.
    (copy-directory . tramp-smb-handle-copy-directory)
149 150 151
    (copy-file . tramp-smb-handle-copy-file)
    (delete-directory . tramp-smb-handle-delete-directory)
    (delete-file . tramp-smb-handle-delete-file)
152
    ;; `diff-latest-backup-file' performed by default handler.
153
    (directory-file-name . tramp-handle-directory-file-name)
154
    (directory-files . tramp-smb-handle-directory-files)
155 156
    (directory-files-and-attributes
     . tramp-smb-handle-directory-files-and-attributes)
157 158
    (dired-call-process . ignore)
    (dired-compress-file . ignore)
159
    (dired-uncache . tramp-handle-dired-uncache)
160
    (expand-file-name . tramp-smb-handle-expand-file-name)
161 162 163 164 165 166 167 168
    (file-accessible-directory-p . tramp-smb-handle-file-directory-p)
    (file-attributes . tramp-smb-handle-file-attributes)
    (file-directory-p .  tramp-smb-handle-file-directory-p)
    (file-executable-p . tramp-smb-handle-file-exists-p)
    (file-exists-p . tramp-smb-handle-file-exists-p)
    (file-local-copy . tramp-smb-handle-file-local-copy)
    (file-modes . tramp-handle-file-modes)
    (file-name-all-completions . tramp-smb-handle-file-name-all-completions)
169
    (file-name-as-directory . tramp-handle-file-name-as-directory)
170 171 172
    (file-name-completion . tramp-handle-file-name-completion)
    (file-name-directory . tramp-handle-file-name-directory)
    (file-name-nondirectory . tramp-handle-file-name-nondirectory)
173
    ;; `file-name-sans-versions' performed by default handler.
174
    (file-newer-than-file-p . tramp-smb-handle-file-newer-than-file-p)
175
    (file-ownership-preserved-p . ignore)
176 177
    (file-readable-p . tramp-smb-handle-file-exists-p)
    (file-regular-p . tramp-handle-file-regular-p)
Michael Albinus's avatar
Michael Albinus committed
178 179
    (file-remote-p . tramp-handle-file-remote-p)
    ;; `file-selinux-context' performed by default handler.
180
    (file-symlink-p . tramp-handle-file-symlink-p)
181
    ;; `file-truename' performed by default handler.
182
    (file-writable-p . tramp-smb-handle-file-writable-p)
183
    (find-backup-file-name . tramp-handle-find-backup-file-name)
184 185
    ;; `find-file-noselect' performed by default handler.
    ;; `get-file-buffer' performed by default handler.
186 187 188 189 190
    (insert-directory . tramp-smb-handle-insert-directory)
    (insert-file-contents . tramp-handle-insert-file-contents)
    (load . tramp-handle-load)
    (make-directory . tramp-smb-handle-make-directory)
    (make-directory-internal . tramp-smb-handle-make-directory-internal)
191
    (make-symbolic-link . tramp-smb-handle-make-symbolic-link)
192
    (rename-file . tramp-smb-handle-rename-file)
193
    (set-file-modes . tramp-smb-handle-set-file-modes)
Michael Albinus's avatar
Michael Albinus committed
194
    ;; `set-file-selinux-context' performed by default handler.
195
    (set-file-times . ignore)
196 197
    (set-visited-file-modtime . ignore)
    (shell-command . ignore)
Michael Albinus's avatar
Michael Albinus committed
198
    (substitute-in-file-name . tramp-smb-handle-substitute-in-file-name)
199
    (unhandled-file-name-directory . tramp-handle-unhandled-file-name-directory)
200 201
    (vc-registered . ignore)
    (verify-visited-file-modtime . ignore)
202 203 204 205 206 207 208 209
    (write-region . tramp-smb-handle-write-region)
)
  "Alist of handler functions for Tramp SMB method.
Operations not mentioned here will be handled by the default Emacs primitives.")

(defun tramp-smb-file-name-p (filename)
  "Check if it's a filename for SMB servers."
  (let ((v (tramp-dissect-file-name filename)))
210
    (string= (tramp-file-name-method v) tramp-smb-method)))
211 212 213 214 215 216 217

(defun tramp-smb-file-name-handler (operation &rest args)
  "Invoke the SMB related OPERATION.
First arg specifies the OPERATION, second arg is a list of arguments to
pass to the OPERATION."
  (let ((fn (assoc operation tramp-smb-file-name-handler-alist)))
    (if fn
218
	(save-match-data (apply (cdr fn) args))
219 220 221 222 223 224
      (tramp-run-real-handler operation args))))

(add-to-list 'tramp-foreign-file-name-handler-alist
	     (cons 'tramp-smb-file-name-p 'tramp-smb-file-name-handler))


225 226
;; File name primitives.

227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256
(defun tramp-smb-handle-add-name-to-file
  (filename newname &optional ok-if-already-exists)
  "Like `add-name-to-file' for Tramp files."
  (unless (tramp-equal-remote filename newname)
    (with-parsed-tramp-file-name
	(if (tramp-tramp-file-p filename) filename newname) nil
      (tramp-error
       v 'file-error
       "add-name-to-file: %s"
       "only implemented for same method, same user, same host")))
  (with-parsed-tramp-file-name filename v1
    (with-parsed-tramp-file-name newname v2
      (when (file-directory-p filename)
	(tramp-error
	 v2 'file-error
	 "add-name-to-file: %s must not be a directory" filename))
      (when (and (not ok-if-already-exists)
		 (file-exists-p newname)
		 (not (numberp ok-if-already-exists))
		 (y-or-n-p
		  (format
		   "File %s already exists; make it a new name anyway? "
		   newname)))
	(tramp-error
	 v2 'file-error
	 "add-name-to-file: file %s already exists" newname))
      ;; We must also flush the cache of the directory, because
      ;; `file-attributes' reads the values from there.
      (tramp-flush-file-property v2 (file-name-directory v2-localname))
      (tramp-flush-file-property v2 v2-localname)
257 258 259 260 261 262 263 264 265 266 267 268
      (unless
	  (tramp-smb-send-command
	   v1
	   (format
	    "%s \"%s\" \"%s\""
	    (if (tramp-smb-get-cifs-capabilities v1) "link" "hardlink")
	    (tramp-smb-get-localname v1)
	    (tramp-smb-get-localname v2)))
	(tramp-error
	 v2 'file-error
	 "error with add-name-to-file, see buffer `%s' for details"
	 (buffer-name))))))
269

270 271
(defun tramp-smb-handle-copy-directory
  (dirname newname &optional keep-date parents)
272
  "Like `copy-directory' for Tramp files.  KEEP-DATE is not handled."
273 274 275 276 277
  (setq dirname (expand-file-name dirname)
	newname (expand-file-name newname))
  (let ((t1 (tramp-tramp-file-p dirname))
	(t2 (tramp-tramp-file-p newname)))
    (with-parsed-tramp-file-name (if t1 dirname newname) nil
278
      (cond
279
       ;; We must use a local temporary directory.
280 281 282 283 284 285 286 287
       ((and t1 t2)
	(let ((tmpdir
	       (make-temp-name
		(expand-file-name
		 tramp-temp-name-prefix
		 (tramp-compat-temporary-file-directory)))))
	  (unwind-protect
	      (progn
288 289 290
		(tramp-compat-copy-directory dirname tmpdir keep-date parents)
		(tramp-compat-copy-directory tmpdir newname keep-date parents))
	    (tramp-compat-delete-directory tmpdir 'recursive))))
291 292

       ;; We can copy recursively.
293 294
       ((or t1 t2)
	(let ((prompt (tramp-smb-send-command v "prompt"))
295
	      (recurse (tramp-smb-send-command v "recurse")))
296 297 298 299 300 301 302
	  (unless (file-directory-p newname)
	    (make-directory newname parents))
	  (unwind-protect
	      (unless
		  (and
		   prompt recurse
		   (tramp-smb-send-command
303
		    v (format "cd \"%s\"" (tramp-smb-get-localname v)))
304 305 306 307 308 309 310 311 312 313 314 315
		   (tramp-smb-send-command
		    v (format "lcd \"%s\"" (if t1 newname dirname)))
		   (if t1
		       (tramp-smb-send-command v "mget *")
		     (tramp-smb-send-command v "mput *")))
		;; Error.
		(with-current-buffer (tramp-get-connection-buffer v)
		  (goto-char (point-min))
		  (search-forward-regexp tramp-smb-errors nil t)
		  (tramp-error
		   v 'file-error
		   "%s `%s'" (match-string 0) (if t1 dirname newname))))
316
	    ;; Go home.
317 318 319
	    (tramp-smb-send-command
	     v (format
		"cd %s" (if (tramp-smb-get-cifs-capabilities v) "/" "\\")))
320 321 322
	    ;; Toggle prompt and recurse OFF.
	    (if prompt (tramp-smb-send-command v "prompt"))
	    (if recurse (tramp-smb-send-command v "recurse")))))
323 324

       ;; We must do it file-wise.
325
       (t
326
	(tramp-run-real-handler
327
	 'copy-directory (list dirname newname keep-date parents)))))))
328 329

(defun tramp-smb-handle-copy-file
Michael Albinus's avatar
Michael Albinus committed
330 331
  (filename newname &optional ok-if-already-exists keep-date
	    preserve-uid-gid preserve-selinux-context)
332
  "Like `copy-file' for Tramp files.
333 334
KEEP-DATE is not handled in case NEWNAME resides on an SMB server.
PRESERVE-UID-GID is completely ignored."
335 336
  (setq filename (expand-file-name filename)
	newname (expand-file-name newname))
337 338 339 340 341 342 343 344 345 346 347
  (with-progress-reporter
      (tramp-dissect-file-name (if (file-remote-p filename) filename newname))
      0 (format "Copying %s to %s" filename newname)

    (let ((tmpfile (file-local-copy filename)))

      (if tmpfile
	  ;; Remote filename.
	  (condition-case err
	      (rename-file tmpfile newname ok-if-already-exists)
	    ((error quit)
348
	     (delete-file tmpfile)
349 350 351 352 353 354 355 356 357 358 359
	     (signal (car err) (cdr err))))

	;; Remote newname.
	(when (file-directory-p newname)
	  (setq newname
		(expand-file-name (file-name-nondirectory filename) newname)))

	(with-parsed-tramp-file-name newname nil
	  (when (and (not ok-if-already-exists)
		     (file-exists-p newname))
	    (tramp-error v 'file-already-exists newname))
360

361 362 363 364 365 366 367 368 369 370 371
	  ;; We must also flush the cache of the directory, because
	  ;; `file-attributes' reads the values from there.
	  (tramp-flush-file-property v (file-name-directory localname))
	  (tramp-flush-file-property v localname)
	  (unless (tramp-smb-get-share v)
	    (tramp-error
	     v 'file-error "Target `%s' must contain a share name" newname))
	  (unless (tramp-smb-send-command
		   v (format "put \"%s\" \"%s\""
			     filename (tramp-smb-get-localname v)))
	    (tramp-error v 'file-error "Cannot copy `%s'" filename))))))
372 373 374

  ;; KEEP-DATE handling.
  (when keep-date (set-file-times newname (nth 5 (file-attributes filename)))))
375

376
(defun tramp-smb-handle-delete-directory (directory &optional recursive)
377
  "Like `delete-directory' for Tramp files."
378
  (setq directory (directory-file-name (expand-file-name directory)))
Michael Albinus's avatar
Michael Albinus committed
379
  (when (file-exists-p directory)
380 381 382 383
    (if recursive
	(mapc
	 (lambda (file)
	   (if (file-directory-p file)
384
	       (tramp-compat-delete-directory file recursive)
385
	     (tramp-compat-delete-file file 'trash)))
386 387 388
	 ;; We do not want to delete "." and "..".
	 (directory-files
	  directory 'full "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*")))
389

Michael Albinus's avatar
Michael Albinus committed
390
    (with-parsed-tramp-file-name directory nil
391
      ;; We must also flush the cache of the directory, because
392
      ;; `file-attributes' reads the values from there.
393 394
      (tramp-flush-file-property v (file-name-directory localname))
      (tramp-flush-directory-property v localname)
395 396 397 398 399 400 401 402 403 404 405
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_rmdir" "rmdir")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
	   v 'file-error "%s `%s'" (match-string 0) directory))))))
406

407
(defun tramp-smb-handle-delete-file (filename &optional trash)
408
  "Like `delete-file' for Tramp files."
409
  (setq filename (expand-file-name filename))
Michael Albinus's avatar
Michael Albinus committed
410 411
  (when (file-exists-p filename)
    (with-parsed-tramp-file-name filename nil
412
      ;; We must also flush the cache of the directory, because
413
      ;; `file-attributes' reads the values from there.
414 415
      (tramp-flush-file-property v (file-name-directory localname))
      (tramp-flush-file-property v localname)
416 417 418 419 420 421 422 423 424 425 426
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_unlink" "rm")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
	   v 'file-error "%s `%s'" (match-string 0) filename))))))
427 428 429

(defun tramp-smb-handle-directory-files
  (directory &optional full match nosort)
430 431 432
  "Like `directory-files' for Tramp files."
  (let ((result (mapcar 'directory-file-name
			(file-name-all-completions "" directory))))
433
    ;; Discriminate with regexp.
434 435 436 437 438
    (when match
      (setq result
	    (delete nil
		    (mapcar (lambda (x) (when (string-match match x) x))
			    result))))
439
    ;; Append directory.
440 441 442 443 444
    (when full
      (setq result
	    (mapcar
	     (lambda (x) (expand-file-name x directory))
	     result)))
445
    ;; Sort them if necessary.
446
    (unless nosort (setq result (sort result 'string-lessp)))
447
    ;; That's it.
448
    result))
449 450

(defun tramp-smb-handle-directory-files-and-attributes
451
  (directory &optional full match nosort id-format)
452
  "Like `directory-files-and-attributes' for Tramp files."
453 454
  (mapcar
   (lambda (x)
455
     (cons x (tramp-compat-file-attributes
456
	      (if full x (expand-file-name x directory)) id-format)))
457
   (directory-files directory full match nosort)))
458

459 460 461 462 463 464 465 466 467 468 469 470 471
(defun tramp-smb-handle-expand-file-name (name &optional dir)
  "Like `expand-file-name' for Tramp files."
  ;; If DIR is not given, use DEFAULT-DIRECTORY or "/".
  (setq dir (or dir default-directory "/"))
  ;; Unless NAME is absolute, concat DIR and NAME.
  (unless (file-name-absolute-p name)
    (setq name (concat (file-name-as-directory dir) name)))
  ;; If NAME is not a Tramp file, run the real handler.
  (if (not (tramp-tramp-file-p name))
      (tramp-run-real-handler 'expand-file-name (list name nil))
    ;; Dissect NAME.
    (with-parsed-tramp-file-name name nil
      ;; Tilde expansion if necessary.  We use the user name as share,
472 473
      ;; which is offen the case in domains.
      (when (string-match "\\`/?~\\([^/]*\\)" localname)
474 475
	(setq localname
	      (replace-match
476
	       (if (zerop (length (match-string 1 localname)))
477
		   (tramp-file-name-real-user v)
478
		 (match-string 1 localname))
479
	       nil nil localname)))
480 481 482
      ;; Make the file name absolute.
      (unless (tramp-run-real-handler 'file-name-absolute-p (list localname))
	(setq localname (concat "/" localname)))
483 484 485 486 487 488
      ;; No tilde characters in file name, do normal
      ;; `expand-file-name' (this does "/./" and "/../").
      (tramp-make-tramp-file-name
       method user host
       (tramp-run-real-handler 'expand-file-name (list localname))))))

489
(defun tramp-smb-handle-file-attributes (filename &optional id-format)
490
  "Like `file-attributes' for Tramp files."
491
  (unless id-format (setq id-format 'integer))
Michael Albinus's avatar
Michael Albinus committed
492
  (with-parsed-tramp-file-name filename nil
493
    (with-file-property v localname (format "file-attributes-%s" id-format)
494
      (if (and (tramp-smb-get-share v) (tramp-smb-get-stat-capability v))
495
	  (tramp-smb-do-file-attributes-with-stat v id-format)
496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525
	;; Reading just the filename entry via "dir localname" is not
	;; possible, because when filename is a directory, some
	;; smbclient versions return the content of the directory, and
	;; other versions don't.  Therefore, the whole content of the
	;; upper directory is retrieved, and the entry of the filename
	;; is extracted from.
	(let* ((entries (tramp-smb-get-file-entries
			 (file-name-directory filename)))
	       (entry (assoc (file-name-nondirectory filename) entries))
	       (uid (if (equal id-format 'string) "nobody" -1))
	       (gid (if (equal id-format 'string) "nogroup" -1))
	       (inode (tramp-get-inode v))
	       (device (tramp-get-device v)))

	  ;; Check result.
	  (when entry
	    (list (and (string-match "d" (nth 1 entry))
		       t)       ;0 file type
		  -1	        ;1 link count
		  uid	        ;2 uid
		  gid	        ;3 gid
		  '(0 0)	;4 atime
		  (nth 3 entry) ;5 mtime
		  '(0 0)	;6 ctime
		  (nth 2 entry) ;7 size
		  (nth 1 entry) ;8 mode
		  nil	        ;9 gid weird
		  inode	        ;10 inode number
		  device))))))) ;11 file system number

526
(defun tramp-smb-do-file-attributes-with-stat (vec &optional id-format)
527
  "Implement `file-attributes' for Tramp files using stat command."
528 529
  (tramp-message
   vec 5 "file attributes with stat: %s" (tramp-file-name-localname vec))
530
  (with-current-buffer (tramp-get-buffer vec)
531
    (let* (size id link uid gid atime mtime ctime mode inode)
532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589
      (when (tramp-smb-send-command
	     vec (format "stat \"%s\"" (tramp-smb-get-localname vec)))

	;; Loop the listing.
	(goto-char (point-min))
	(unless (re-search-forward tramp-smb-errors nil t)
	  (while (not (eobp))
	    (cond
	     ((looking-at
	       "Size:\\s-+\\([0-9]+\\)\\s-+Blocks:\\s-+[0-9]+\\s-+\\(\\w+\\)")
	      (setq size (string-to-number (match-string 1))
		    id (if (string-equal "directory" (match-string 2)) t
			 (if (string-equal "symbolic" (match-string 2)) ""))))
	     ((looking-at
	       "Inode:\\s-+\\([0-9]+\\)\\s-+Links:\\s-+\\([0-9]+\\)")
	      (setq inode (string-to-number (match-string 1))
		    link (string-to-number (match-string 2))))
	     ((looking-at
	       "Access:\\s-+([0-9]+/\\(\\S-+\\))\\s-+Uid:\\s-+\\([0-9]+\\)\\s-+Gid:\\s-+\\([0-9]+\\)")
	      (setq mode (match-string 1)
		    uid (if (equal id-format 'string) (match-string 2)
			  (string-to-number (match-string 2)))
		    gid (if (equal id-format 'string) (match-string 3)
			  (string-to-number (match-string 3)))))
	     ((looking-at
	       "Access:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq atime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Modify:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq mtime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Change:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq ctime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1)))))) ;; year
	    (forward-line))
	  ;; Return the result.
	  (list id link uid gid atime mtime ctime size mode nil inode
		(tramp-get-device vec)))))))
590 591

(defun tramp-smb-handle-file-directory-p (filename)
592 593 594
  "Like `file-directory-p' for Tramp files."
  (and (file-exists-p filename)
       (eq ?d (aref (nth 8 (file-attributes filename)) 0))))
595 596

(defun tramp-smb-handle-file-exists-p (filename)
597 598
  "Like `file-exists-p' for Tramp files."
  (not (null (file-attributes filename))))
599 600

(defun tramp-smb-handle-file-local-copy (filename)
601
  "Like `file-local-copy' for Tramp files."
602
  (with-parsed-tramp-file-name filename nil
603 604 605 606
    (unless (file-exists-p filename)
      (tramp-error
       v 'file-error
       "Cannot make local copy of non-existing file `%s'" filename))
607
    (let ((tmpfile (tramp-compat-make-temp-file filename)))
608 609 610 611 612 613
      (with-progress-reporter
	  v 3 (format "Fetching %s to tmp file %s" filename tmpfile)
	(unless (tramp-smb-send-command
		 v (format "get \"%s\" \"%s\""
			   (tramp-smb-get-localname v) tmpfile))
	  ;; Oops, an error.  We shall cleanup.
614
	  (delete-file tmpfile)
615 616
	  (tramp-error
	   v 'file-error "Cannot make local copy of file `%s'" filename)))
617
      tmpfile)))
618 619 620 621

;; This function should return "foo/" for directories and "bar" for
;; files.
(defun tramp-smb-handle-file-name-all-completions (filename directory)
622 623 624 625 626 627 628
  "Like `file-name-all-completions' for Tramp files."
  (all-completions
   filename
   (with-parsed-tramp-file-name directory nil
     (with-file-property v localname "file-name-all-completions"
       (save-match-data
	 (let ((entries (tramp-smb-get-file-entries directory)))
629 630 631 632 633 634 635 636 637
	   (mapcar
	    (lambda (x)
	      (list
	       (if (string-match "d" (nth 1 x))
		   (file-name-as-directory (nth 0 x))
		 (nth 0 x))))
	    entries)))))))

(defun tramp-smb-handle-file-newer-than-file-p (file1 file2)
638
  "Like `file-newer-than-file-p' for Tramp files."
639 640 641
  (cond
   ((not (file-exists-p file1)) nil)
   ((not (file-exists-p file2)) t)
642 643
   (t (tramp-time-less-p (nth 5 (file-attributes file2))
			 (nth 5 (file-attributes file1))))))
644 645

(defun tramp-smb-handle-file-writable-p (filename)
646 647 648 649 650 651
  "Like `file-writable-p' for Tramp files."
  (if (file-exists-p filename)
      (string-match "w" (or (nth 8 (file-attributes filename)) ""))
    (let ((dir (file-name-directory filename)))
      (and (file-exists-p dir)
	   (file-writable-p dir)))))
652 653 654

(defun tramp-smb-handle-insert-directory
  (filename switches &optional wildcard full-directory-p)
655
  "Like `insert-directory' for Tramp files."
656
  (setq filename (expand-file-name filename))
657 658 659 660
  (if full-directory-p
      ;; Called from `dired-add-entry'.
      (setq filename (file-name-as-directory filename))
    (setq filename (directory-file-name filename)))
Michael Albinus's avatar
Michael Albinus committed
661
  (with-parsed-tramp-file-name filename nil
662
    (save-match-data
663
      (let ((base (file-name-nondirectory filename))
664 665 666 667 668 669 670 671 672 673 674 675 676 677
	    ;; We should not destroy the cache entry.
	    (entries (copy-sequence
		      (tramp-smb-get-file-entries
		       (file-name-directory filename)))))

	(when wildcard
	  (string-match "\\." base)
	  (setq base (replace-match "\\\\." nil nil base))
	  (string-match "\\*" base)
	  (setq base (replace-match ".*" nil nil base))
	  (string-match "\\?" base)
	  (setq base (replace-match ".?" nil nil base)))

	;; Filter entries.
678
	(setq entries
679 680 681 682 683 684 685 686 687 688 689 690
	      (delq
	       nil
	       (if (or wildcard (zerop (length base)))
		   ;; Check for matching entries.
		   (mapcar
		    (lambda (x)
		      (when (string-match
			     (format "^%s" base) (nth 0 x))
			x))
		    entries)
		 ;; We just need the only and only entry FILENAME.
		 (list (assoc base entries)))))
691

Michael Albinus's avatar
Michael Albinus committed
692
	;; Sort entries.
693 694 695 696 697
	(setq entries
	      (sort
	       entries
	       (lambda (x y)
		 (if (string-match "t" switches)
698 699 700
		     ;; Sort by date.
		     (tramp-time-less-p (nth 3 y) (nth 3 x))
		   ;; Sort by name.
701 702
		   (string-lessp (nth 0 x) (nth 0 y))))))

Michael Albinus's avatar
Michael Albinus committed
703 704
	;; Handle "-F" switch.
	(when (string-match "F" switches)
705
	  (mapc
Michael Albinus's avatar
Michael Albinus committed
706 707 708 709 710 711 712 713 714
	   (lambda (x)
	     (when (not (zerop (length (car x))))
	       (cond
		((char-equal ?d (string-to-char (nth 1 x)))
		 (setcar x (concat (car x) "/")))
		((char-equal ?x (string-to-char (nth 1 x)))
		 (setcar x (concat (car x) "*"))))))
	   entries))

715
	;; Print entries.
716
	(mapc
717
	 (lambda (x)
718
	   (when (not (zerop (length (nth 0 x))))
719
	     (let ((attr
720
		    (when (tramp-smb-get-stat-capability v)
721
		      (ignore-errors
722
			(file-attributes filename 'string)))))
723 724
	       (insert
		(format
725
		 "%10s %3d %-8s %-8s %8s %s "
726
		 (or (nth 8 attr) (nth 1 x)) ; mode
727
		 (or (nth 1 attr) 1) ; inode
728 729
		 (or (nth 2 attr) "nobody") ; uid
		 (or (nth 3 attr) "nogroup") ; gid
730
		 (or (nth 7 attr) (nth 2 x)) ; size
731 732 733 734 735 736
		 (format-time-string
		  (if (tramp-time-less-p
		       (tramp-time-subtract (current-time) (nth 3 x))
		       tramp-half-a-year)
		      "%b %e %R"
		    "%b %e  %Y")
737
		  (nth 3 x)))) ; date
738 739 740
	       ;; We mark the file name.  The inserted name could be
	       ;; from somewhere else, so we use the relative file
	       ;; name of `default-directory'.
741
	       (let ((start (point)))
742 743 744
		 (insert
		  (format
		   "%s\n"
745 746 747
		   (file-relative-name
		    (expand-file-name
		     (nth 0 x) (file-name-directory filename)))))
748
		 (put-text-property start (1- (point)) 'dired-filename t))
749 750 751
	       (forward-line)
	       (beginning-of-line))))
	 entries)))))
752 753

(defun tramp-smb-handle-make-directory (dir &optional parents)
754
  "Like `make-directory' for Tramp files."
755 756
  (setq dir (directory-file-name (expand-file-name dir)))
  (unless (file-name-absolute-p dir)
757
    (setq dir (expand-file-name dir default-directory)))
Michael Albinus's avatar
Michael Albinus committed
758
  (with-parsed-tramp-file-name dir nil
759
    (save-match-data
760
      (let* ((ldir (file-name-directory dir)))
761
	;; Make missing directory parts.
762 763 764
	(when (and parents
		   (tramp-smb-get-share v)
		   (not (file-directory-p ldir)))
765
	  (make-directory ldir parents))
766
	;; Just do it.
767
	(when (file-directory-p ldir)
768
	  (make-directory-internal dir))
769
	(unless (file-directory-p dir)
770
	  (tramp-error v 'file-error "Couldn't make directory %s" dir))))))
771 772

(defun tramp-smb-handle-make-directory-internal (directory)
773
  "Like `make-directory-internal' for Tramp files."
774 775
  (setq directory (directory-file-name (expand-file-name directory)))
  (unless (file-name-absolute-p directory)
776
    (setq directory (expand-file-name directory default-directory)))
Michael Albinus's avatar
Michael Albinus committed
777
  (with-parsed-tramp-file-name directory nil
778
    (save-match-data
779
      (let* ((file (tramp-smb-get-localname v)))
780
	(when (file-directory-p (file-name-directory directory))
781 782
	  (tramp-smb-send-command
	   v
783
	   (if (tramp-smb-get-cifs-capabilities v)
784 785 786 787
	       (format
		"posix_mkdir \"%s\" %s"
		file (tramp-decimal-to-octal (default-file-modes)))
	     (format "mkdir \"%s\"" file)))
788
	  ;; We must also flush the cache of the directory, because
789 790 791
	  ;; `file-attributes' reads the values from there.
	  (tramp-flush-file-property v (file-name-directory localname))
	  (tramp-flush-file-property v localname))
792
	(unless (file-directory-p directory)
793 794
	  (tramp-error
	   v 'file-error "Couldn't make directory %s" directory))))))
795

796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840
(defun tramp-smb-handle-make-symbolic-link
  (filename linkname &optional ok-if-already-exists)
  "Like `make-symbolic-link' for Tramp files.
If LINKNAME is a non-Tramp file, it is used verbatim as the target of
the symlink.  If LINKNAME is a Tramp file, only the localname component is
used as the target of the symlink.

If LINKNAME is a Tramp file and the localname component is relative, then
it is expanded first, before the localname component is taken.  Note that
this can give surprising results if the user/host for the source and
target of the symlink differ."
  (unless (tramp-equal-remote filename linkname)
    (with-parsed-tramp-file-name
	(if (tramp-tramp-file-p filename) filename linkname) nil
      (tramp-error
       v 'file-error
       "make-symbolic-link: %s"
       "only implemented for same method, same user, same host")))
  (with-parsed-tramp-file-name filename v1
    (with-parsed-tramp-file-name linkname v2
      (when (file-directory-p filename)
	(tramp-error
	 v2 'file-error
	 "make-symbolic-link: %s must not be a directory" filename))
      (when (and (not ok-if-already-exists)
		 (file-exists-p linkname)
		 (not (numberp ok-if-already-exists))
		 (y-or-n-p
		  (format
		   "File %s already exists; make it a new name anyway? "
		   linkname)))
	(tramp-error
	 v2 'file-error
	 "make-symbolic-link: file %s already exists" linkname))
      (unless (tramp-smb-get-cifs-capabilities v1)
	(tramp-error v2 'file-error "make-symbolic-link not supported"))
      ;; We must also flush the cache of the directory, because
      ;; `file-attributes' reads the values from there.
      (tramp-flush-file-property v2 (file-name-directory v2-localname))
      (tramp-flush-file-property v2 v2-localname)
      (unless
	  (tramp-smb-send-command
	   v1
	   (format
	    "symlink \"%s\" \"%s\""
841 842
	    (tramp-smb-get-localname v1)
	    (tramp-smb-get-localname v2)))
843 844 845 846 847
	(tramp-error
	 v2 'file-error
	 "error with make-symbolic-link, see buffer `%s' for details"
	 (buffer-name))))))

848 849
(defun tramp-smb-handle-rename-file
  (filename newname &optional ok-if-already-exists)
850
  "Like `rename-file' for Tramp files."
851 852
  (setq filename (expand-file-name filename)
	newname (expand-file-name newname))
853 854 855 856 857 858 859 860 861 862 863
  (with-progress-reporter
      (tramp-dissect-file-name (if (file-remote-p filename) filename newname))
      0 (format "Renaming %s to %s" filename newname)

    (let ((tmpfile (file-local-copy filename)))

      (if tmpfile
	  ;; Remote filename.
	  (condition-case err
	      (rename-file tmpfile newname ok-if-already-exists)
	    ((error quit)
864
	     (delete-file tmpfile)
865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883
	     (signal (car err) (cdr err))))

	;; Remote newname.
	(when (file-directory-p newname)
	  (setq newname (expand-file-name
			 (file-name-nondirectory filename) newname)))

	(with-parsed-tramp-file-name newname nil
	  (when (and (not ok-if-already-exists)
		     (file-exists-p newname))
	    (tramp-error v 'file-already-exists newname))
	  ;; We must also flush the cache of the directory, because
	  ;; `file-attributes' reads the values from there.
	  (tramp-flush-file-property v (file-name-directory localname))
	  (tramp-flush-file-property v localname)
	  (unless (tramp-smb-send-command
		   v (format "put %s \"%s\""
			     filename (tramp-smb-get-localname v)))
	    (tramp-error v 'file-error "Cannot rename `%s'" filename)))))
884

885
    (delete-file filename)))
886

887 888 889
(defun tramp-smb-handle-set-file-modes (filename mode)
  "Like `set-file-modes' for Tramp files."
  (with-parsed-tramp-file-name filename nil
890 891 892 893
    (when (tramp-smb-get-cifs-capabilities v)
      (tramp-flush-file-property v localname)
      (unless (tramp-smb-send-command
	       v (format "chmod \"%s\" %s"
894
			 (tramp-smb-get-localname v)
895 896 897
			 (tramp-decimal-to-octal mode)))
	(tramp-error
	 v 'file-error "Error while changing file's mode %s" filename)))))
898

Michael Albinus's avatar
Michael Albinus committed
899
(defun tramp-smb-handle-substitute-in-file-name (filename)
900
  "Like `handle-substitute-in-file-name' for Tramp files.
901 902 903 904 905 906 907 908
\"//\" substitutes only in the local filename part.  Catches
errors for shares like \"C$/\", which are common in Microsoft Windows."
  (with-parsed-tramp-file-name filename nil
    ;; Ignore in LOCALNAME everything before "//".
    (when (and (stringp localname) (string-match ".+?/\\(/\\|~\\)" localname))
      (setq filename
	    (concat (file-remote-p filename)
		    (replace-match "\\1" nil nil localname)))))
Michael Albinus's avatar
Michael Albinus committed
909 910 911 912
  (condition-case nil
      (tramp-run-real-handler 'substitute-in-file-name (list filename))
    (error filename)))

913 914
(defun tramp-smb-handle-write-region
  (start end filename &optional append visit lockname confirm)
915
  "Like `write-region' for Tramp files."
916
  (setq filename (expand-file-name filename))
Michael Albinus's avatar
Michael Albinus committed
917
  (with-parsed-tramp-file-name filename nil
918 919
    (unless (eq append nil)
      (tramp-error
920
	 v 'file-error "Cannot append to file using Tramp (`%s')" filename))
921
    ;; XEmacs takes a coding system as the seventh argument, not `confirm'.
922 923 924 925 926 927
    (when (and (not (featurep 'xemacs))
	       confirm (file-exists-p filename))
      (unless (y-or-n-p (format "File %s exists; overwrite anyway? "
				filename))
	(tramp-error v 'file-error "File not overwritten")))
    ;; We must also flush the cache of the directory, because
928
    ;; `file-attributes' reads the values from there.
929 930
    (tramp-flush-file-property v (file-name-directory localname))
    (tramp-flush-file-property v localname)
931
    (let ((curbuf (current-buffer))
932
	  (tmpfile (tramp-compat-make-temp-file filename)))
933 934 935 936 937 938
      ;; We say `no-message' here because we don't want the visited file
      ;; modtime data to be clobbered from the temp file.  We call
      ;; `set-visited-file-modtime' ourselves later on.
      (tramp-run-real-handler
       'write-region
       (if confirm ; don't pass this arg unless defined for backward compat.
939 940
	   (list start end tmpfile append 'no-message lockname confirm)
	 (list start end tmpfile append 'no-message lockname)))
941

942 943 944 945 946 947 948
      (with-progress-reporter
	  v 3 (format "Moving tmp file %s to %s" tmpfile filename)
	(unwind-protect
	    (unless (tramp-smb-send-command
		     v (format "put %s \"%s\""
			       tmpfile (tramp-smb-get-localname v)))
	      (tramp-error v 'file-error "Cannot write `%s'" filename))
949
	  (delete-file tmpfile)))
950 951 952 953 954 955 956

      (unless (equal curbuf (current-buffer))
	(tramp-error
	 v 'file-error
	 "Buffer has changed from `%s' to `%s'" curbuf (current-buffer)))
      (when (eq visit t)
	(set-visited-file-modtime)))))
957 958


959
;; Internal file name functions.
960

961
(defun tramp-smb-get-share (vec)
Kai Großjohann's avatar
Kai Großjohann committed
962
  "Returns the share name of LOCALNAME."
963
  (save-match-data
964 965 966
    (let ((localname (tramp-file-name-localname vec)))
      (when (string-match "^/?\\([^/]+\\)/" localname)
	(match-string 1 localname)))))
967

968
(defun tramp-smb-get-localname (vec)
Kai Großjohann's avatar
Kai Großjohann committed
969
  "Returns the file name of LOCALNAME.
970
If VEC has no cifs capabilities, exchange \"/\" by \"\\\\\"."
971
  (save-match-data
972
    (let ((localname (tramp-file-name-localname vec)))
973
      (setq
974 975 976 977 978 979 980 981 982 983 984 985
       localname
       (if (string-match "^/?[^/]+\\(/.*\\)" localname)
	   ;; There is a share, sparated by "/".
	   (if (not (tramp-smb-get-cifs-capabilities vec))
	       (mapconcat
		(lambda (x) (if (equal x ?/) "\\" (char-to-string x)))
		(match-string 1 localname) ""