register.el 21.1 KB
Newer Older
1
;;; register.el --- register commands for Emacs      -*- lexical-binding: t; -*-
Eric S. Raymond's avatar
Eric S. Raymond committed
2

Paul Eggert's avatar
Paul Eggert committed
3
;; Copyright (C) 1985, 1993-1994, 2001-2018 Free Software Foundation,
4
;; Inc.
Eric S. Raymond's avatar
Eric S. Raymond committed
5

6
;; Maintainer: emacs-devel@gnu.org
Eric S. Raymond's avatar
Eric S. Raymond committed
7
;; Keywords: internal
8
;; Package: emacs
Eric S. Raymond's avatar
Eric S. Raymond committed
9

Richard M. Stallman's avatar
Richard M. Stallman committed
10 11
;; This file is part of GNU Emacs.

12
;; GNU Emacs is free software: you can redistribute it and/or modify
Richard M. Stallman's avatar
Richard M. Stallman committed
13
;; it under the terms of the GNU General Public License as published by
14 15
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Richard M. Stallman's avatar
Richard M. Stallman committed
16 17 18 19 20 21 22

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
23
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
Richard M. Stallman's avatar
Richard M. Stallman committed
24

25 26 27 28 29
;;; Commentary:

;; This package of functions emulates and somewhat extends the venerable
;; TECO's `register' feature, which permits you to save various useful
;; pieces of buffer state to named variables.  The entry points are
30
;; documented in the Emacs user's manual: (info "(emacs) Registers").
31

Stefan Monnier's avatar
Stefan Monnier committed
32
(eval-when-compile (require 'cl-lib))
33

Eric S. Raymond's avatar
Eric S. Raymond committed
34
;;; Code:
Richard M. Stallman's avatar
Richard M. Stallman committed
35

36 37
;; FIXME: Clean up namespace usage!

Stefan Monnier's avatar
Stefan Monnier committed
38
(cl-defstruct
39 40 41 42 43 44 45 46 47 48 49
  (registerv (:constructor nil)
	     (:constructor registerv--make (&optional data print-func
						      jump-func insert-func))
	     (:copier nil)
	     (:type vector)
	     :named)
  (data        nil :read-only t)
  (print-func  nil :read-only t)
  (jump-func   nil :read-only t)
  (insert-func nil :read-only t))

Stefan Monnier's avatar
Stefan Monnier committed
50
(cl-defun registerv-make (data &key print-func jump-func insert-func)
51 52 53 54 55
  "Create a register value object.

DATA can be any value.
PRINT-FUNC if provided controls how `list-registers' and
`view-register' print the register.  It should be a function
Juanma Barranquero's avatar
Juanma Barranquero committed
56
receiving one argument DATA and print text that completes
57 58 59 60 61 62 63
this sentence:
  Register X contains [TEXT PRINTED BY PRINT-FUNC]
JUMP-FUNC if provided, controls how `jump-to-register' jumps to the register.
INSERT-FUNC if provided, controls how `insert-register' insert the register.
They both receive DATA as argument."
  (registerv--make data print-func jump-func insert-func))

Richard M. Stallman's avatar
Richard M. Stallman committed
64 65
(defvar register-alist nil
  "Alist of elements (NAME . CONTENTS), one for each Emacs register.
66 67
NAME is a character (a number).  CONTENTS is a string, number, marker, list
or a struct returned by `registerv-make'.
68
A list of strings represents a rectangle.
69 70 71 72
A list of the form (file . FILE-NAME) represents the file named FILE-NAME.
A list of the form (file-query FILE-NAME POSITION) represents
 position POSITION in the file named FILE-NAME, but query before
 visiting it.
Karl Heuer's avatar
Karl Heuer committed
73 74 75
A list of the form (WINDOW-CONFIGURATION POSITION)
 represents a saved window configuration plus a saved value of point.
A list of the form (FRAME-CONFIGURATION POSITION)
76
 represents a saved frame configuration plus a saved value of point.")
Richard M. Stallman's avatar
Richard M. Stallman committed
77

78 79 80
(defgroup register nil
  "Register commands."
  :group 'convenience
81
  :version "24.3")
82

83 84
(defcustom register-separator nil
  "Register containing the text to put between collected texts, or nil if none.
85

86 87 88
When collecting text with \\[append-to-register] (or \\[prepend-to-register]),
contents of this register is added to the beginning (or end, respectively)
of the marked text."
89 90 91 92
  :group 'register
  :type '(choice (const :tag "None" nil)
		 (character :tag "Use register" :value ?+)))

93
(defcustom register-preview-delay 1
94 95 96
  "If non-nil, time to wait in seconds before popping up a preview window.
If nil, do not show register previews, unless `help-char' (or a member of
`help-event-list') is pressed."
97
  :version "24.4"
98
  :type '(choice number (const :tag "No preview unless requested" nil))
99 100
  :group 'register)

101 102
(defun get-register (register)
  "Return contents of Emacs register named REGISTER, or nil if none."
103
  (alist-get register register-alist))
Richard M. Stallman's avatar
Richard M. Stallman committed
104

105 106
(defun set-register (register value)
  "Set contents of Emacs register named REGISTER to VALUE.  Returns VALUE.
107
See the documentation of the variable `register-alist' for possible VALUEs."
108
  (setf (alist-get register register-alist) value))
Richard M. Stallman's avatar
Richard M. Stallman committed
109

110 111 112 113 114 115 116 117 118
(defun register-describe-oneline (c)
  "One-line description of register C."
  (let ((d (replace-regexp-in-string
            "\n[ \t]*" " "
            (with-output-to-string (describe-register-1 c)))))
    (if (string-match "Register.+? contains \\(?:an? \\|the \\)?" d)
        (substring d (match-end 0))
      d)))

Glenn Morris's avatar
Glenn Morris committed
119 120
(defun register-preview-default (r)
  "Default function for the variable `register-preview-function'."
121 122
  (format "%s: %s\n"
	  (single-key-description (car r))
Glenn Morris's avatar
Glenn Morris committed
123 124 125 126 127 128
	  (register-describe-oneline (car r))))

(defvar register-preview-function #'register-preview-default
  "Function to format a register for previewing.
Takes one argument, a cons (NAME . CONTENTS) as found in `register-alist'.
Returns a string.")
129 130 131

(defun register-preview (buffer &optional show-empty)
  "Pop up a window to show register preview in BUFFER.
Glenn Morris's avatar
Glenn Morris committed
132 133
If SHOW-EMPTY is non-nil show the window even if no registers.
Format of each entry is controlled by the variable `register-preview-function'."
134
  (when (or show-empty (consp register-alist))
135
    (with-current-buffer-window
136 137
     buffer
     (cons 'display-buffer-below-selected
138 139
	   '((window-height . fit-window-to-buffer)
	     (preserve-size . (nil . t))))
140 141 142
     nil
     (with-current-buffer standard-output
       (setq cursor-in-non-selected-windows nil)
Glenn Morris's avatar
Glenn Morris committed
143
       (insert (mapconcat register-preview-function register-alist ""))))))
144 145

(defun register-read-with-preview (prompt)
Glenn Morris's avatar
Glenn Morris committed
146 147 148 149 150 151
  "Read and return a register name, possibly showing existing registers.
Prompt with the string PROMPT.  If `register-alist' and
`register-preview-delay' are both non-nil, display a window
listing existing registers after `register-preview-delay' seconds.
If `help-char' (or a member of `help-event-list') is pressed,
display such a window regardless."
152 153 154 155 156 157 158 159 160 161 162
  (let* ((buffer "*Register Preview*")
	 (timer (when (numberp register-preview-delay)
		  (run-with-timer register-preview-delay nil
				  (lambda ()
				    (unless (get-buffer-window buffer)
				      (register-preview buffer))))))
	 (help-chars (cl-loop for c in (cons help-char help-event-list)
			      when (not (get-register c))
			      collect c)))
    (unwind-protect
	(progn
163
	  (while (memq (read-key (propertize prompt 'face 'minibuffer-prompt))
164 165 166
		       help-chars)
	    (unless (get-buffer-window buffer)
	      (register-preview buffer 'show-empty)))
167 168 169 170
          (when (or (eq ?\C-g last-input-event)
                    (eq 'escape last-input-event)
                    (eq ?\C-\[ last-input-event))
            (keyboard-quit))
Glenn Morris's avatar
Glenn Morris committed
171 172
	  (if (characterp last-input-event) last-input-event
	    (error "Non-character input-event")))
173 174 175 176 177
      (and (timerp timer) (cancel-timer timer))
      (let ((w (get-buffer-window buffer)))
        (and (window-live-p w) (delete-window w)))
      (and (get-buffer buffer) (kill-buffer buffer)))))

178
(defun point-to-register (register &optional arg)
179
  "Store current location of point in register REGISTER.
Jim Blandy's avatar
Jim Blandy committed
180
With prefix argument, store current frame configuration.
181
Use \\[jump-to-register] to go to that location or restore that configuration.
Glenn Morris's avatar
Glenn Morris committed
182 183 184
Argument is a character, naming the register.

Interactively, reads the register using `register-read-with-preview'."
185 186
  (interactive (list (register-read-with-preview "Point to register: ")
		     current-prefix-arg))
Stefan Monnier's avatar
Stefan Monnier committed
187 188
  ;; Turn the marker into a file-ref if the buffer is killed.
  (add-hook 'kill-buffer-hook 'register-swap-out nil t)
189
  (set-register register
Karl Heuer's avatar
Karl Heuer committed
190 191
		(if arg (list (current-frame-configuration) (point-marker))
		  (point-marker))))
Richard M. Stallman's avatar
Richard M. Stallman committed
192

193
(defun window-configuration-to-register (register &optional _arg)
194 195
  "Store the window configuration of the selected frame in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Glenn Morris's avatar
Glenn Morris committed
196 197 198
Argument is a character, naming the register.

Interactively, reads the register using `register-read-with-preview'."
199 200 201
  (interactive (list (register-read-with-preview
		      "Window configuration to register: ")
		     current-prefix-arg))
202 203
  ;; current-window-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
204
  (set-register register (list (current-window-configuration) (point-marker))))
205

206 207 208 209
;; It has had the optional arg for ages, but never used it.
(set-advertised-calling-convention 'window-configuration-to-register
				   '(register) "24.4")

210
(defun frame-configuration-to-register (register &optional _arg)
211 212
  "Store the window configuration of all frames in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Glenn Morris's avatar
Glenn Morris committed
213 214 215
Argument is a character, naming the register.

Interactively, reads the register using `register-read-with-preview'."
216 217 218
  (interactive (list (register-read-with-preview
		      "Frame configuration to register: ")
		     current-prefix-arg))
219 220
  ;; current-frame-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
221
  (set-register register (list (current-frame-configuration) (point-marker))))
222

223 224 225 226
;; It has had the optional arg for ages, but never used it.
(set-advertised-calling-convention 'frame-configuration-to-register
				   '(register) "24.4")

227
(make-obsolete 'frame-configuration-to-register 'frameset-to-register "24.4")
228

229
(defalias 'register-to-point 'jump-to-register)
230
(defun jump-to-register (register &optional delete)
Richard M. Stallman's avatar
Richard M. Stallman committed
231
  "Move point to location stored in a register.
232
If the register contains a file name, find that file.
233
\(To put a file name in a register, you must use `set-register'.)
234 235
If the register contains a window configuration (one frame) or a frameset
\(all frames), restore that frame or all frames accordingly.
236
First argument is a character, naming the register.
237
Optional second arg non-nil (interactively, prefix argument) says to
238
delete any existing frames that the frameset doesn't mention.
Glenn Morris's avatar
Glenn Morris committed
239 240 241
\(Otherwise, these frames are iconified.)

Interactively, reads the register using `register-read-with-preview'."
242 243
  (interactive (list (register-read-with-preview "Jump to register: ")
		     current-prefix-arg))
244
  (let ((val (get-register register)))
245
    (cond
246
     ((registerv-p val)
Stefan Monnier's avatar
Stefan Monnier committed
247
      (cl-assert (registerv-jump-func val) nil
248 249 250
              "Don't know how to jump to register %s"
              (single-key-description register))
      (funcall (registerv-jump-func val) (registerv-data val)))
251 252 253 254 255 256
     ((and (consp val) (frame-configuration-p (car val)))
      (set-frame-configuration (car val) (not delete))
      (goto-char (cadr val)))
     ((and (consp val) (window-configuration-p (car val)))
      (set-window-configuration (car val))
      (goto-char (cadr val)))
257
     ((markerp val)
258
      (or (marker-buffer val)
259
	  (user-error "That register's buffer no longer exists"))
260
      (switch-to-buffer (marker-buffer val))
261 262 263
      (unless (or (= (point) (marker-position val))
                  (eq last-command 'jump-to-register))
        (push-mark))
264
      (goto-char val))
265 266
     ((and (consp val) (eq (car val) 'file))
      (find-file (cdr val)))
267 268 269
     ((and (consp val) (eq (car val) 'file-query))
      (or (find-buffer-visiting (nth 1 val))
	  (y-or-n-p (format "Visit file %s again? " (nth 1 val)))
270
	  (user-error "Register access aborted"))
271 272
      (find-file (nth 1 val))
      (goto-char (nth 2 val)))
273
     (t
274
      (user-error "Register doesn't contain a buffer position or configuration")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
275

276
(defun register-swap-out ()
Stefan Monnier's avatar
Stefan Monnier committed
277
  "Turn markers into file-query references when a buffer is killed."
278
  (and buffer-file-name
Stefan Monnier's avatar
Stefan Monnier committed
279 280 281 282 283 284 285
       (dolist (elem register-alist)
	 (and (markerp (cdr elem))
	      (eq (marker-buffer (cdr elem)) (current-buffer))
	      (setcdr elem
		      (list 'file-query
			    buffer-file-name
			    (marker-position (cdr elem))))))))
286

287
(defun number-to-register (number register)
Karl Heuer's avatar
Karl Heuer committed
288 289
  "Store a number in a register.
Two args, NUMBER and REGISTER (a character, naming the register).
290 291
If NUMBER is nil, a decimal number is read from the buffer starting
at point, and point moves to the end of that number.
Glenn Morris's avatar
Glenn Morris committed
292 293 294
Interactively, NUMBER is the prefix arg (none means nil).

Interactively, reads the register using `register-read-with-preview'."
295 296
  (interactive (list current-prefix-arg
		     (register-read-with-preview "Number to register: ")))
297
  (set-register register
298 299
		(if number
		    (prefix-numeric-value number)
300 301 302
		  (if (looking-at "\\s-*-?[0-9]+")
		      (progn
			(goto-char (match-end 0))
303
			(string-to-number (match-string 0)))
Karl Heuer's avatar
Karl Heuer committed
304 305
		    0))))

306 307 308 309 310 311 312 313
(defun increment-register (prefix register)
  "Augment contents of REGISTER.
Interactively, PREFIX is in raw form.

If REGISTER contains a number, add `prefix-numeric-value' of
PREFIX to it.

If REGISTER is empty or if it contains text, call
314 315 316 317 318
`append-to-register' with `delete-flag' set to PREFIX.

Interactively, reads the register using `register-read-with-preview'."
  (interactive (list current-prefix-arg
		     (register-read-with-preview "Increment register: ")))
319 320 321 322 323 324 325
  (let ((register-val (get-register register)))
    (cond
     ((numberp register-val)
      (let ((number (prefix-numeric-value prefix)))
	(set-register register (+ number register-val))))
     ((or (not register-val) (stringp register-val))
      (append-to-register register (region-beginning) (region-end) prefix))
326
     (t (user-error "Register does not contain a number or text")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
327

328
(defun view-register (register)
Richard M. Stallman's avatar
Richard M. Stallman committed
329
  "Display what is contained in register named REGISTER.
Glenn Morris's avatar
Glenn Morris committed
330 331 332
The Lisp value REGISTER is a character.

Interactively, reads the register using `register-read-with-preview'."
333
  (interactive (list (register-read-with-preview "View register: ")))
334
  (let ((val (get-register register)))
Richard M. Stallman's avatar
Richard M. Stallman committed
335
    (if (null val)
336
	(message "Register %s is empty" (single-key-description register))
Richard M. Stallman's avatar
Richard M. Stallman committed
337
      (with-output-to-temp-buffer "*Output*"
338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354
	(describe-register-1 register t)))))

(defun list-registers ()
  "Display a list of nonempty registers saying briefly what they contain."
  (interactive)
  (let ((list (copy-sequence register-alist)))
    (setq list (sort list (lambda (a b) (< (car a) (car b)))))
    (with-output-to-temp-buffer "*Output*"
      (dolist (elt list)
	(when (get-register (car elt))
	  (describe-register-1 (car elt))
	  (terpri))))))

(defun describe-register-1 (register &optional verbose)
  (princ "Register ")
  (princ (single-key-description register))
  (princ " contains ")
355 356
  (let ((val (get-register register)))
    (cond
357 358 359 360 361
     ((registerv-p val)
      (if (registerv-print-func val)
          (funcall (registerv-print-func val) (registerv-data val))
        (princ "[UNPRINTABLE CONTENTS].")))

362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404
     ((numberp val)
      (princ val))

     ((markerp val)
      (let ((buf (marker-buffer val)))
	(if (null buf)
	    (princ "a marker in no buffer")
	  (princ "a buffer position:\n    buffer ")
	  (princ (buffer-name buf))
	  (princ ", position ")
	  (princ (marker-position val)))))

     ((and (consp val) (window-configuration-p (car val)))
      (princ "a window configuration."))

     ((and (consp val) (frame-configuration-p (car val)))
      (princ "a frame configuration."))

     ((and (consp val) (eq (car val) 'file))
      (princ "the file ")
      (prin1 (cdr val))
      (princ "."))

     ((and (consp val) (eq (car val) 'file-query))
      (princ "a file-query reference:\n    file ")
      (prin1 (car (cdr val)))
      (princ ",\n    position ")
      (princ (car (cdr (cdr val))))
      (princ "."))

     ((consp val)
      (if verbose
	  (progn
	    (princ "the rectangle:\n")
	    (while val
	      (princ "    ")
	      (princ (car val))
	      (terpri)
	      (setq val (cdr val))))
	(princ "a rectangle starting with ")
	(princ (car val))))

     ((stringp val)
405
      (setq val (copy-sequence val))
406 407 408 409
      (if (eq yank-excluded-properties t)
	  (set-text-properties 0 (length val) nil val)
	(remove-list-of-text-properties 0 (length val)
					yank-excluded-properties val))
410 411 412 413
      (if verbose
	  (progn
	    (princ "the text:\n")
	    (princ val))
414
	(cond
415 416 417 418 419 420 421 422 423 424 425
	 ;; Extract first N characters starting with first non-whitespace.
	 ((string-match (format "[^ \t\n].\\{,%d\\}"
				;; Deduct 6 for the spaces inserted below.
				(min 20 (max 0 (- (window-width) 6))))
			val)
	  (princ "text starting with\n    ")
	  (princ (match-string 0 val)))
	 ((string-match "^[ \t\n]+$" val)
	  (princ "whitespace"))
	 (t
	  (princ "the empty string")))))
426 427 428
     (t
      (princ "Garbage:\n")
      (if verbose (prin1 val))))))
Richard M. Stallman's avatar
Richard M. Stallman committed
429

430 431
(defun insert-register (register &optional arg)
  "Insert contents of register REGISTER.  (REGISTER is a character.)
Richard M. Stallman's avatar
Richard M. Stallman committed
432 433
Normally puts point before and mark after the inserted text.
If optional second arg is non-nil, puts mark before and point after.
434 435
Interactively, second arg is nil if prefix arg is supplied and t
otherwise.
Glenn Morris's avatar
Glenn Morris committed
436 437

Interactively, reads the register using `register-read-with-preview'."
438 439
  (interactive (progn
		 (barf-if-buffer-read-only)
440
		 (list (register-read-with-preview "Insert register: ")
441
		       (not current-prefix-arg))))
Richard M. Stallman's avatar
Richard M. Stallman committed
442
  (push-mark)
443
  (let ((val (get-register register)))
444
    (cond
445
     ((registerv-p val)
Stefan Monnier's avatar
Stefan Monnier committed
446
      (cl-assert (registerv-insert-func val) nil
447 448 449
              "Don't know how to insert register %s"
              (single-key-description register))
      (funcall (registerv-insert-func val) (registerv-data val)))
450 451
     ((consp val)
      (insert-rectangle val))
452
     ((stringp val)
453
      (insert-for-yank val))
Karl Heuer's avatar
Karl Heuer committed
454
     ((numberp val)
455 456 457 458
      (princ val (current-buffer)))
     ((and (markerp val) (marker-position val))
      (princ (marker-position val) (current-buffer)))
     (t
459
      (user-error "Register does not contain text"))))
Richard M. Stallman's avatar
Richard M. Stallman committed
460 461
  (if (not arg) (exchange-point-and-mark)))

462
(defun copy-to-register (register start end &optional delete-flag region)
463 464
  "Copy region into register REGISTER.
With prefix arg, delete as well.
465 466 467 468
Called from program, takes five args: REGISTER, START, END, DELETE-FLAG,
and REGION.  START and END are buffer positions indicating what to copy.
The optional argument REGION if non-nil, indicates that we're not just
copying some text between START and END, but we're copying the region.
Glenn Morris's avatar
Glenn Morris committed
469 470

Interactively, reads the register using `register-read-with-preview'."
471 472 473
  (interactive (list (register-read-with-preview "Copy to register: ")
		     (region-beginning)
		     (region-end)
474 475 476 477 478 479
		     current-prefix-arg
		     t))
  (set-register register (if region
			     (funcall region-extract-function delete-flag)
			   (prog1 (filter-buffer-substring start end)
			     (if delete-flag (delete-region start end)))))
480
  (setq deactivate-mark t)
481
  (cond (delete-flag)
482 483
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
484

485 486 487 488
(defun append-to-register (register start end &optional delete-flag)
  "Append region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Glenn Morris's avatar
Glenn Morris committed
489 490 491
START and END are buffer positions indicating what to append.

Interactively, reads the register using `register-read-with-preview'."
492 493 494 495
  (interactive (list (register-read-with-preview "Append to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
496
  (let ((reg (get-register register))
497
        (text (filter-buffer-substring start end))
498
	(separator (and register-separator (get-register register-separator))))
499 500
    (set-register
     register (cond ((not reg) text)
501
                    ((stringp reg) (concat reg separator text))
502
                    (t (user-error "Register does not contain text")))))
503
  (setq deactivate-mark t)
504 505 506 507
  (cond (delete-flag
	 (delete-region start end))
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
508

509 510 511 512
(defun prepend-to-register (register start end &optional delete-flag)
  "Prepend region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Glenn Morris's avatar
Glenn Morris committed
513 514 515
START and END are buffer positions indicating what to prepend.

Interactively, reads the register using `register-read-with-preview'."
516 517 518 519
  (interactive (list (register-read-with-preview "Prepend to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
520
  (let ((reg (get-register register))
521
        (text (filter-buffer-substring start end))
522
	(separator (and register-separator (get-register register-separator))))
523 524
    (set-register
     register (cond ((not reg) text)
525
                    ((stringp reg) (concat text separator reg))
526
                    (t (user-error "Register does not contain text")))))
527
  (setq deactivate-mark t)
528 529 530 531
  (cond (delete-flag
	 (delete-region start end))
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
532

533 534
(defun copy-rectangle-to-register (register start end &optional delete-flag)
  "Copy rectangular region into register REGISTER.
535 536
With prefix arg, delete as well.
To insert this register in the buffer, use \\[insert-register].
537 538

Called from a program, takes four args: REGISTER, START, END and DELETE-FLAG.
Glenn Morris's avatar
Glenn Morris committed
539 540 541
START and END are buffer positions giving two corners of rectangle.

Interactively, reads the register using `register-read-with-preview'."
542 543 544 545 546
  (interactive (list (register-read-with-preview
		      "Copy rectangle to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
547 548 549 550 551 552 553 554 555
  (let ((rectangle (if delete-flag
		       (delete-extract-rectangle start end)
		     (extract-rectangle start end))))
    (set-register register rectangle)
    (when (and (null delete-flag)
	       (called-interactively-p 'interactive))
      (setq deactivate-mark t)
      (indicate-copied-region (length (car rectangle))))))

Masatake YAMATO's avatar
Masatake YAMATO committed
556
(provide 'register)
Eric S. Raymond's avatar
Eric S. Raymond committed
557
;;; register.el ends here