register.el 22.7 KB
Newer Older
1
;;; register.el --- register commands for Emacs      -*- lexical-binding: t; -*-
Eric S. Raymond's avatar
Eric S. Raymond committed
2

Paul Eggert's avatar
Paul Eggert committed
3
;; Copyright (C) 1985, 1993-1994, 2001-2019 Free Software Foundation,
4
;; Inc.
Eric S. Raymond's avatar
Eric S. Raymond committed
5

Eric S. Raymond's avatar
Eric S. Raymond committed
6
;; Keywords: internal
7
;; Package: emacs
Eric S. Raymond's avatar
Eric S. Raymond committed
8

Richard M. Stallman's avatar
Richard M. Stallman committed
9 10
;; This file is part of GNU Emacs.

11
;; GNU Emacs is free software: you can redistribute it and/or modify
Richard M. Stallman's avatar
Richard M. Stallman committed
12
;; it under the terms of the GNU General Public License as published by
13 14
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Richard M. Stallman's avatar
Richard M. Stallman committed
15 16 17 18 19 20 21

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
Richard M. Stallman's avatar
Richard M. Stallman committed
23

24 25 26 27 28
;;; Commentary:

;; This package of functions emulates and somewhat extends the venerable
;; TECO's `register' feature, which permits you to save various useful
;; pieces of buffer state to named variables.  The entry points are
29
;; documented in the Emacs user's manual: (info "(emacs) Registers").
30

Stefan Monnier's avatar
Stefan Monnier committed
31
(eval-when-compile (require 'cl-lib))
32

Eric S. Raymond's avatar
Eric S. Raymond committed
33
;;; Code:
Richard M. Stallman's avatar
Richard M. Stallman committed
34

35 36
;; FIXME: Clean up namespace usage!

Stefan Monnier's avatar
Stefan Monnier committed
37
(cl-defstruct
38 39 40
  (registerv (:constructor nil)
	     (:constructor registerv--make (&optional data print-func
						      jump-func insert-func))
41
	     (:copier nil))
42 43 44 45 46
  (data        nil :read-only t)
  (print-func  nil :read-only t)
  (jump-func   nil :read-only t)
  (insert-func nil :read-only t))

Stefan Monnier's avatar
Stefan Monnier committed
47
(cl-defun registerv-make (data &key print-func jump-func insert-func)
48 49 50 51 52
  "Create a register value object.

DATA can be any value.
PRINT-FUNC if provided controls how `list-registers' and
`view-register' print the register.  It should be a function
Juanma Barranquero's avatar
Juanma Barranquero committed
53
receiving one argument DATA and print text that completes
54 55 56 57 58
this sentence:
  Register X contains [TEXT PRINTED BY PRINT-FUNC]
JUMP-FUNC if provided, controls how `jump-to-register' jumps to the register.
INSERT-FUNC if provided, controls how `insert-register' insert the register.
They both receive DATA as argument."
59
  (declare (obsolete "Use your own type with methods on register-val-(insert|describe|jump-to)" "27.1"))
60 61
  (registerv--make data print-func jump-func insert-func))

Richard M. Stallman's avatar
Richard M. Stallman committed
62 63
(defvar register-alist nil
  "Alist of elements (NAME . CONTENTS), one for each Emacs register.
64 65
NAME is a character (a number).  CONTENTS is a string, number, marker, list
or a struct returned by `registerv-make'.
66
A list of strings represents a rectangle.
67 68 69 70
A list of the form (file . FILE-NAME) represents the file named FILE-NAME.
A list of the form (file-query FILE-NAME POSITION) represents
 position POSITION in the file named FILE-NAME, but query before
 visiting it.
Karl Heuer's avatar
Karl Heuer committed
71 72 73
A list of the form (WINDOW-CONFIGURATION POSITION)
 represents a saved window configuration plus a saved value of point.
A list of the form (FRAME-CONFIGURATION POSITION)
74
 represents a saved frame configuration plus a saved value of point.")
Richard M. Stallman's avatar
Richard M. Stallman committed
75

76 77 78
(defgroup register nil
  "Register commands."
  :group 'convenience
79
  :version "24.3")
80

81 82
(defcustom register-separator nil
  "Register containing the text to put between collected texts, or nil if none.
83

84 85 86
When collecting text with \\[append-to-register] (or \\[prepend-to-register]),
contents of this register is added to the beginning (or end, respectively)
of the marked text."
87 88 89 90
  :group 'register
  :type '(choice (const :tag "None" nil)
		 (character :tag "Use register" :value ?+)))

91
(defcustom register-preview-delay 1
92 93 94
  "If non-nil, time to wait in seconds before popping up a preview window.
If nil, do not show register previews, unless `help-char' (or a member of
`help-event-list') is pressed."
95
  :version "24.4"
96
  :type '(choice number (const :tag "No preview unless requested" nil))
97 98
  :group 'register)

99 100
(defun get-register (register)
  "Return contents of Emacs register named REGISTER, or nil if none."
101
  (alist-get register register-alist))
Richard M. Stallman's avatar
Richard M. Stallman committed
102

103 104
(defun set-register (register value)
  "Set contents of Emacs register named REGISTER to VALUE.  Returns VALUE.
105
See the documentation of the variable `register-alist' for possible VALUEs."
106
  (setf (alist-get register register-alist) value))
Richard M. Stallman's avatar
Richard M. Stallman committed
107

108 109 110 111 112 113 114 115 116
(defun register-describe-oneline (c)
  "One-line description of register C."
  (let ((d (replace-regexp-in-string
            "\n[ \t]*" " "
            (with-output-to-string (describe-register-1 c)))))
    (if (string-match "Register.+? contains \\(?:an? \\|the \\)?" d)
        (substring d (match-end 0))
      d)))

Glenn Morris's avatar
Glenn Morris committed
117 118
(defun register-preview-default (r)
  "Default function for the variable `register-preview-function'."
119 120
  (format "%s: %s\n"
	  (single-key-description (car r))
Glenn Morris's avatar
Glenn Morris committed
121 122 123 124 125 126
	  (register-describe-oneline (car r))))

(defvar register-preview-function #'register-preview-default
  "Function to format a register for previewing.
Takes one argument, a cons (NAME . CONTENTS) as found in `register-alist'.
Returns a string.")
127 128 129

(defun register-preview (buffer &optional show-empty)
  "Pop up a window to show register preview in BUFFER.
Glenn Morris's avatar
Glenn Morris committed
130 131
If SHOW-EMPTY is non-nil show the window even if no registers.
Format of each entry is controlled by the variable `register-preview-function'."
132
  (when (or show-empty (consp register-alist))
133
    (with-current-buffer-window
134 135
     buffer
     (cons 'display-buffer-below-selected
136 137
	   '((window-height . fit-window-to-buffer)
	     (preserve-size . (nil . t))))
138 139 140
     nil
     (with-current-buffer standard-output
       (setq cursor-in-non-selected-windows nil)
Glenn Morris's avatar
Glenn Morris committed
141
       (insert (mapconcat register-preview-function register-alist ""))))))
142 143

(defun register-read-with-preview (prompt)
Glenn Morris's avatar
Glenn Morris committed
144 145 146 147 148 149
  "Read and return a register name, possibly showing existing registers.
Prompt with the string PROMPT.  If `register-alist' and
`register-preview-delay' are both non-nil, display a window
listing existing registers after `register-preview-delay' seconds.
If `help-char' (or a member of `help-event-list') is pressed,
display such a window regardless."
150 151 152 153 154 155 156 157 158 159 160
  (let* ((buffer "*Register Preview*")
	 (timer (when (numberp register-preview-delay)
		  (run-with-timer register-preview-delay nil
				  (lambda ()
				    (unless (get-buffer-window buffer)
				      (register-preview buffer))))))
	 (help-chars (cl-loop for c in (cons help-char help-event-list)
			      when (not (get-register c))
			      collect c)))
    (unwind-protect
	(progn
161
	  (while (memq (read-key (propertize prompt 'face 'minibuffer-prompt))
162 163 164
		       help-chars)
	    (unless (get-buffer-window buffer)
	      (register-preview buffer 'show-empty)))
165 166 167 168
          (when (or (eq ?\C-g last-input-event)
                    (eq 'escape last-input-event)
                    (eq ?\C-\[ last-input-event))
            (keyboard-quit))
Glenn Morris's avatar
Glenn Morris committed
169 170
	  (if (characterp last-input-event) last-input-event
	    (error "Non-character input-event")))
171 172 173 174 175
      (and (timerp timer) (cancel-timer timer))
      (let ((w (get-buffer-window buffer)))
        (and (window-live-p w) (delete-window w)))
      (and (get-buffer buffer) (kill-buffer buffer)))))

176
(defun point-to-register (register &optional arg)
177
  "Store current location of point in register REGISTER.
Jim Blandy's avatar
Jim Blandy committed
178
With prefix argument, store current frame configuration.
179
Use \\[jump-to-register] to go to that location or restore that configuration.
Glenn Morris's avatar
Glenn Morris committed
180 181 182
Argument is a character, naming the register.

Interactively, reads the register using `register-read-with-preview'."
183 184 185 186 187
  (interactive (list (register-read-with-preview
                      (if current-prefix-arg
                          "Frame configuration to register: "
                        "Point to register: "))
                     current-prefix-arg))
Stefan Monnier's avatar
Stefan Monnier committed
188 189
  ;; Turn the marker into a file-ref if the buffer is killed.
  (add-hook 'kill-buffer-hook 'register-swap-out nil t)
190
  (set-register register
Karl Heuer's avatar
Karl Heuer committed
191 192
		(if arg (list (current-frame-configuration) (point-marker))
		  (point-marker))))
Richard M. Stallman's avatar
Richard M. Stallman committed
193

194
(defun window-configuration-to-register (register &optional _arg)
195 196
  "Store the window configuration of the selected frame in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Glenn Morris's avatar
Glenn Morris committed
197 198 199
Argument is a character, naming the register.

Interactively, reads the register using `register-read-with-preview'."
200 201 202
  (interactive (list (register-read-with-preview
		      "Window configuration to register: ")
		     current-prefix-arg))
203 204
  ;; current-window-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
205
  (set-register register (list (current-window-configuration) (point-marker))))
206

207 208 209 210
;; It has had the optional arg for ages, but never used it.
(set-advertised-calling-convention 'window-configuration-to-register
				   '(register) "24.4")

211
(defun frame-configuration-to-register (register &optional _arg)
212 213
  "Store the window configuration of all frames in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Glenn Morris's avatar
Glenn Morris committed
214 215 216
Argument is a character, naming the register.

Interactively, reads the register using `register-read-with-preview'."
217 218 219
  (interactive (list (register-read-with-preview
		      "Frame configuration to register: ")
		     current-prefix-arg))
220 221
  ;; current-frame-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
222
  (set-register register (list (current-frame-configuration) (point-marker))))
223

224 225 226 227
;; It has had the optional arg for ages, but never used it.
(set-advertised-calling-convention 'frame-configuration-to-register
				   '(register) "24.4")

228
(make-obsolete 'frame-configuration-to-register 'frameset-to-register "24.4")
229

230
(defalias 'register-to-point 'jump-to-register)
231
(defun jump-to-register (register &optional delete)
Richard M. Stallman's avatar
Richard M. Stallman committed
232
  "Move point to location stored in a register.
233
Push the mark if jumping moves point, unless called in succession.
234
If the register contains a file name, find that file.
235
\(To put a file name in a register, you must use `set-register'.)
236 237
If the register contains a window configuration (one frame) or a frameset
\(all frames), restore that frame or all frames accordingly.
238
First argument is a character, naming the register.
239
Optional second arg non-nil (interactively, prefix argument) says to
240
delete any existing frames that the frameset doesn't mention.
Glenn Morris's avatar
Glenn Morris committed
241 242 243
\(Otherwise, these frames are iconified.)

Interactively, reads the register using `register-read-with-preview'."
244 245
  (interactive (list (register-read-with-preview "Jump to register: ")
		     current-prefix-arg))
246
  (let ((val (get-register register)))
247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284
    (register-val-jump-to val delete)))

(cl-defgeneric register-val-jump-to (_val _arg)
  "Execute the \"jump\" operation of VAL.
ARG is the value of the prefix argument or nil."
  (user-error "Register doesn't contain a buffer position or configuration"))

(cl-defmethod register-val-jump-to ((val registerv) _arg)
  (cl-assert (registerv-jump-func val) nil
             "Don't know how to jump to register value %S" val)
  (funcall (registerv-jump-func val) (registerv-data val)))

(cl-defmethod register-val-jump-to ((val marker) _arg)
  (or (marker-buffer val)
      (user-error "That register's buffer no longer exists"))
  (switch-to-buffer (marker-buffer val))
  (unless (or (= (point) (marker-position val))
              (eq last-command 'jump-to-register))
    (push-mark))
  (goto-char val))

(cl-defmethod register-val-jump-to ((val cons) delete)
  (cond
   ((frame-configuration-p (car val))
    (set-frame-configuration (car val) (not delete))
    (goto-char (cadr val)))
   ((window-configuration-p (car val))
    (set-window-configuration (car val))
    (goto-char (cadr val)))
   ((eq (car val) 'file)
    (find-file (cdr val)))
   ((eq (car val) 'file-query)
    (or (find-buffer-visiting (nth 1 val))
	(y-or-n-p (format "Visit file %s again? " (nth 1 val)))
	(user-error "Register access aborted"))
    (find-file (nth 1 val))
    (goto-char (nth 2 val)))
   (t (cl-call-next-method val delete))))
Richard M. Stallman's avatar
Richard M. Stallman committed
285

286
(defun register-swap-out ()
Stefan Monnier's avatar
Stefan Monnier committed
287
  "Turn markers into file-query references when a buffer is killed."
288
  (and buffer-file-name
Stefan Monnier's avatar
Stefan Monnier committed
289 290 291 292 293 294 295
       (dolist (elem register-alist)
	 (and (markerp (cdr elem))
	      (eq (marker-buffer (cdr elem)) (current-buffer))
	      (setcdr elem
		      (list 'file-query
			    buffer-file-name
			    (marker-position (cdr elem))))))))
296

297
(defun number-to-register (number register)
Karl Heuer's avatar
Karl Heuer committed
298 299
  "Store a number in a register.
Two args, NUMBER and REGISTER (a character, naming the register).
300 301
If NUMBER is nil, a decimal number is read from the buffer starting
at point, and point moves to the end of that number.
Glenn Morris's avatar
Glenn Morris committed
302 303 304
Interactively, NUMBER is the prefix arg (none means nil).

Interactively, reads the register using `register-read-with-preview'."
305 306
  (interactive (list current-prefix-arg
		     (register-read-with-preview "Number to register: ")))
307
  (set-register register
308 309
		(if number
		    (prefix-numeric-value number)
310 311 312
		  (if (looking-at "\\s-*-?[0-9]+")
		      (progn
			(goto-char (match-end 0))
313
			(string-to-number (match-string 0)))
Karl Heuer's avatar
Karl Heuer committed
314 315
		    0))))

316 317 318 319 320 321 322 323
(defun increment-register (prefix register)
  "Augment contents of REGISTER.
Interactively, PREFIX is in raw form.

If REGISTER contains a number, add `prefix-numeric-value' of
PREFIX to it.

If REGISTER is empty or if it contains text, call
324 325 326 327 328
`append-to-register' with `delete-flag' set to PREFIX.

Interactively, reads the register using `register-read-with-preview'."
  (interactive (list current-prefix-arg
		     (register-read-with-preview "Increment register: ")))
329 330 331 332 333 334 335
  (let ((register-val (get-register register)))
    (cond
     ((numberp register-val)
      (let ((number (prefix-numeric-value prefix)))
	(set-register register (+ number register-val))))
     ((or (not register-val) (stringp register-val))
      (append-to-register register (region-beginning) (region-end) prefix))
336
     (t (user-error "Register does not contain a number or text")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
337

338
(defun view-register (register)
Richard M. Stallman's avatar
Richard M. Stallman committed
339
  "Display what is contained in register named REGISTER.
Glenn Morris's avatar
Glenn Morris committed
340 341 342
The Lisp value REGISTER is a character.

Interactively, reads the register using `register-read-with-preview'."
343
  (interactive (list (register-read-with-preview "View register: ")))
344
  (let ((val (get-register register)))
Richard M. Stallman's avatar
Richard M. Stallman committed
345
    (if (null val)
346
	(message "Register %s is empty" (single-key-description register))
Richard M. Stallman's avatar
Richard M. Stallman committed
347
      (with-output-to-temp-buffer "*Output*"
348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364
	(describe-register-1 register t)))))

(defun list-registers ()
  "Display a list of nonempty registers saying briefly what they contain."
  (interactive)
  (let ((list (copy-sequence register-alist)))
    (setq list (sort list (lambda (a b) (< (car a) (car b)))))
    (with-output-to-temp-buffer "*Output*"
      (dolist (elt list)
	(when (get-register (car elt))
	  (describe-register-1 (car elt))
	  (terpri))))))

(defun describe-register-1 (register &optional verbose)
  (princ "Register ")
  (princ (single-key-description register))
  (princ " contains ")
365
  (let ((val (get-register register)))
366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392
    (register-val-describe val verbose)))

(cl-defgeneric register-val-describe (val verbose)
  "Print description of register value VAL to `standard-output'."
  (princ "Garbage:\n")
  (if verbose (prin1 val)))

(cl-defmethod register-val-describe ((val registerv) _verbose)
  (if (registerv-print-func val)
      (funcall (registerv-print-func val) (registerv-data val))
    (princ "[UNPRINTABLE CONTENTS].")))

(cl-defmethod register-val-describe ((val number) _verbose)
  (princ val))

(cl-defmethod register-val-describe ((val marker) _verbose)
  (let ((buf (marker-buffer val)))
    (if (null buf)
	(princ "a marker in no buffer")
      (princ "a buffer position:\n    buffer ")
      (princ (buffer-name buf))
      (princ ", position ")
      (princ (marker-position val)))))

(cl-defmethod register-val-describe ((val cons) verbose)
  (cond
   ((window-configuration-p (car val))
393 394 395 396 397 398 399 400 401 402 403 404 405 406
    (let* ((stored-window-config (car val))
           (window-config-frame (window-configuration-frame stored-window-config))
           (current-frame (selected-frame)))
      (princ (format "a window configuration: %s."
                     (if (frame-live-p window-config-frame)
                         (with-selected-frame window-config-frame
                           (save-window-excursion
                             (set-window-configuration stored-window-config)
                             (concat
                              (mapconcat (lambda (w) (buffer-name (window-buffer w)))
                                         (window-list (selected-frame)) ", ")
                              (unless (eq current-frame window-config-frame)
                                " in another frame"))))
                       "dead frame")))))
407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444

   ((frame-configuration-p (car val))
    (princ "a frame configuration."))

   ((eq (car val) 'file)
    (princ "the file ")
    (prin1 (cdr val))
    (princ "."))

   ((eq (car val) 'file-query)
    (princ "a file-query reference:\n    file ")
    (prin1 (car (cdr val)))
    (princ ",\n    position ")
    (princ (car (cdr (cdr val))))
    (princ "."))

   (t
    (if verbose
	(progn
	  (princ "the rectangle:\n")
	  (while val
	    (princ "    ")
	    (princ (car val))
	    (terpri)
	    (setq val (cdr val))))
      (princ "a rectangle starting with ")
      (princ (car val))))))

(cl-defmethod register-val-describe ((val string) verbose)
  (setq val (copy-sequence val))
  (if (eq yank-excluded-properties t)
      (set-text-properties 0 (length val) nil val)
    (remove-list-of-text-properties 0 (length val)
				    yank-excluded-properties val))
  (if verbose
      (progn
	(princ "the text:\n")
	(princ val))
445
    (cond
446 447 448 449 450 451 452 453 454
     ;; Extract first N characters starting with first non-whitespace.
     ((string-match (format "[^ \t\n].\\{,%d\\}"
			    ;; Deduct 6 for the spaces inserted below.
			    (min 20 (max 0 (- (window-width) 6))))
		    val)
      (princ "text starting with\n    ")
      (princ (match-string 0 val)))
     ((string-match "^[ \t\n]+$" val)
      (princ "whitespace"))
455
     (t
456
      (princ "the empty string")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
457

458 459
(defun insert-register (register &optional arg)
  "Insert contents of register REGISTER.  (REGISTER is a character.)
Richard M. Stallman's avatar
Richard M. Stallman committed
460 461
Normally puts point before and mark after the inserted text.
If optional second arg is non-nil, puts mark before and point after.
462 463
Interactively, second arg is nil if prefix arg is supplied and t
otherwise.
Glenn Morris's avatar
Glenn Morris committed
464 465

Interactively, reads the register using `register-read-with-preview'."
466 467
  (interactive (progn
		 (barf-if-buffer-read-only)
468
		 (list (register-read-with-preview "Insert register: ")
469
		       (not current-prefix-arg))))
Richard M. Stallman's avatar
Richard M. Stallman committed
470
  (push-mark)
471
  (let ((val (get-register register)))
472
    (register-val-insert val))
Richard M. Stallman's avatar
Richard M. Stallman committed
473 474
  (if (not arg) (exchange-point-and-mark)))

475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497
(cl-defgeneric register-val-insert (_val)
  "Insert register value VAL."
  (user-error "Register does not contain text"))

(cl-defmethod register-val-insert ((val registerv))
  (cl-assert (registerv-insert-func val) nil
             "Don't know how to insert register value %S" val)
  (funcall (registerv-insert-func val) (registerv-data val)))

(cl-defmethod register-val-insert ((val cons))
  (insert-rectangle val))

(cl-defmethod register-val-insert ((val string))
  (insert-for-yank val))

(cl-defmethod register-val-insert ((val number))
  (princ val (current-buffer)))

(cl-defmethod register-val-insert ((val marker))
  (if (marker-position val)
      (princ (marker-position val) (current-buffer))
    (cl-call-next-method val)))

498
(defun copy-to-register (register start end &optional delete-flag region)
499 500
  "Copy region into register REGISTER.
With prefix arg, delete as well.
501 502 503 504
Called from program, takes five args: REGISTER, START, END, DELETE-FLAG,
and REGION.  START and END are buffer positions indicating what to copy.
The optional argument REGION if non-nil, indicates that we're not just
copying some text between START and END, but we're copying the region.
Glenn Morris's avatar
Glenn Morris committed
505 506

Interactively, reads the register using `register-read-with-preview'."
507 508 509
  (interactive (list (register-read-with-preview "Copy to register: ")
		     (region-beginning)
		     (region-end)
510 511 512 513 514 515
		     current-prefix-arg
		     t))
  (set-register register (if region
			     (funcall region-extract-function delete-flag)
			   (prog1 (filter-buffer-substring start end)
			     (if delete-flag (delete-region start end)))))
516
  (setq deactivate-mark t)
517
  (cond (delete-flag)
518 519
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
520

521 522 523 524
(defun append-to-register (register start end &optional delete-flag)
  "Append region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Glenn Morris's avatar
Glenn Morris committed
525 526 527
START and END are buffer positions indicating what to append.

Interactively, reads the register using `register-read-with-preview'."
528 529 530 531
  (interactive (list (register-read-with-preview "Append to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
532
  (let ((reg (get-register register))
533
        (text (filter-buffer-substring start end))
534
	(separator (and register-separator (get-register register-separator))))
535 536
    (set-register
     register (cond ((not reg) text)
537
                    ((stringp reg) (concat reg separator text))
538
                    (t (user-error "Register does not contain text")))))
539
  (setq deactivate-mark t)
540 541 542 543
  (cond (delete-flag
	 (delete-region start end))
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
544

545 546 547 548
(defun prepend-to-register (register start end &optional delete-flag)
  "Prepend region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Glenn Morris's avatar
Glenn Morris committed
549 550 551
START and END are buffer positions indicating what to prepend.

Interactively, reads the register using `register-read-with-preview'."
552 553 554 555
  (interactive (list (register-read-with-preview "Prepend to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
556
  (let ((reg (get-register register))
557
        (text (filter-buffer-substring start end))
558
	(separator (and register-separator (get-register register-separator))))
559 560
    (set-register
     register (cond ((not reg) text)
561
                    ((stringp reg) (concat text separator reg))
562
                    (t (user-error "Register does not contain text")))))
563
  (setq deactivate-mark t)
564 565 566 567
  (cond (delete-flag
	 (delete-region start end))
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
568

569 570
(defun copy-rectangle-to-register (register start end &optional delete-flag)
  "Copy rectangular region into register REGISTER.
571 572
With prefix arg, delete as well.
To insert this register in the buffer, use \\[insert-register].
573 574

Called from a program, takes four args: REGISTER, START, END and DELETE-FLAG.
Glenn Morris's avatar
Glenn Morris committed
575 576 577
START and END are buffer positions giving two corners of rectangle.

Interactively, reads the register using `register-read-with-preview'."
578 579 580 581 582
  (interactive (list (register-read-with-preview
		      "Copy rectangle to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
583 584 585 586 587 588 589 590 591
  (let ((rectangle (if delete-flag
		       (delete-extract-rectangle start end)
		     (extract-rectangle start end))))
    (set-register register rectangle)
    (when (and (null delete-flag)
	       (called-interactively-p 'interactive))
      (setq deactivate-mark t)
      (indicate-copied-region (length (car rectangle))))))

Masatake YAMATO's avatar
Masatake YAMATO committed
592
(provide 'register)
Eric S. Raymond's avatar
Eric S. Raymond committed
593
;;; register.el ends here