register.el 19.1 KB
Newer Older
1
;;; register.el --- register commands for Emacs      -*- lexical-binding: t; -*-
Eric S. Raymond's avatar
Eric S. Raymond committed
2

3 4
;; Copyright (C) 1985, 1993-1994, 2001-2014 Free Software Foundation,
;; Inc.
Eric S. Raymond's avatar
Eric S. Raymond committed
5

Eric S. Raymond's avatar
Eric S. Raymond committed
6
;; Maintainer: FSF
Eric S. Raymond's avatar
Eric S. Raymond committed
7
;; Keywords: internal
8
;; Package: emacs
Eric S. Raymond's avatar
Eric S. Raymond committed
9

Richard M. Stallman's avatar
Richard M. Stallman committed
10 11
;; This file is part of GNU Emacs.

12
;; GNU Emacs is free software: you can redistribute it and/or modify
Richard M. Stallman's avatar
Richard M. Stallman committed
13
;; it under the terms of the GNU General Public License as published by
14 15
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Richard M. Stallman's avatar
Richard M. Stallman committed
16 17 18 19 20 21 22

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
23
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
Richard M. Stallman's avatar
Richard M. Stallman committed
24

25 26 27 28 29 30 31
;;; Commentary:

;; This package of functions emulates and somewhat extends the venerable
;; TECO's `register' feature, which permits you to save various useful
;; pieces of buffer state to named variables.  The entry points are
;; documented in the Emacs user's manual.

Stefan Monnier's avatar
Stefan Monnier committed
32
(eval-when-compile (require 'cl-lib))
33

Eric S. Raymond's avatar
Eric S. Raymond committed
34
;;; Code:
Richard M. Stallman's avatar
Richard M. Stallman committed
35

Stefan Monnier's avatar
Stefan Monnier committed
36
(cl-defstruct
37 38 39 40 41 42 43 44 45 46 47
  (registerv (:constructor nil)
	     (:constructor registerv--make (&optional data print-func
						      jump-func insert-func))
	     (:copier nil)
	     (:type vector)
	     :named)
  (data        nil :read-only t)
  (print-func  nil :read-only t)
  (jump-func   nil :read-only t)
  (insert-func nil :read-only t))

Stefan Monnier's avatar
Stefan Monnier committed
48
(cl-defun registerv-make (data &key print-func jump-func insert-func)
49 50 51 52 53
  "Create a register value object.

DATA can be any value.
PRINT-FUNC if provided controls how `list-registers' and
`view-register' print the register.  It should be a function
Juanma Barranquero's avatar
Juanma Barranquero committed
54
receiving one argument DATA and print text that completes
55 56 57 58 59 60 61
this sentence:
  Register X contains [TEXT PRINTED BY PRINT-FUNC]
JUMP-FUNC if provided, controls how `jump-to-register' jumps to the register.
INSERT-FUNC if provided, controls how `insert-register' insert the register.
They both receive DATA as argument."
  (registerv--make data print-func jump-func insert-func))

Richard M. Stallman's avatar
Richard M. Stallman committed
62 63
(defvar register-alist nil
  "Alist of elements (NAME . CONTENTS), one for each Emacs register.
64 65
NAME is a character (a number).  CONTENTS is a string, number, marker, list
or a struct returned by `registerv-make'.
66
A list of strings represents a rectangle.
67 68 69 70
A list of the form (file . FILE-NAME) represents the file named FILE-NAME.
A list of the form (file-query FILE-NAME POSITION) represents
 position POSITION in the file named FILE-NAME, but query before
 visiting it.
Karl Heuer's avatar
Karl Heuer committed
71 72 73
A list of the form (WINDOW-CONFIGURATION POSITION)
 represents a saved window configuration plus a saved value of point.
A list of the form (FRAME-CONFIGURATION POSITION)
74
 represents a saved frame configuration plus a saved value of point.")
Richard M. Stallman's avatar
Richard M. Stallman committed
75

76 77 78
(defgroup register nil
  "Register commands."
  :group 'convenience
79
  :version "24.3")
80

81 82
(defcustom register-separator nil
  "Register containing the text to put between collected texts, or nil if none.
83 84 85 86 87 88 89 90 91

When collecting text with
`append-to-register' (resp. `prepend-to-register') contents of
this register is added to the beginning (resp. end) of the marked
text."
  :group 'register
  :type '(choice (const :tag "None" nil)
		 (character :tag "Use register" :value ?+)))

92
(defcustom register-preview-delay 1
93 94 95
  "If non-nil, time to wait in seconds before popping up a preview window.
If nil, do not show register previews, unless `help-char' (or a member of
`help-event-list') is pressed."
96
  :version "24.4"
97
  :type '(choice number (const :tag "No preview unless requested" nil))
98 99
  :group 'register)

100 101 102
(defun get-register (register)
  "Return contents of Emacs register named REGISTER, or nil if none."
  (cdr (assq register register-alist)))
Richard M. Stallman's avatar
Richard M. Stallman committed
103

104 105
(defun set-register (register value)
  "Set contents of Emacs register named REGISTER to VALUE.  Returns VALUE.
106
See the documentation of the variable `register-alist' for possible VALUEs."
107
  (let ((aelt (assq register register-alist)))
Richard M. Stallman's avatar
Richard M. Stallman committed
108 109
    (if aelt
	(setcdr aelt value)
Stefan Monnier's avatar
Stefan Monnier committed
110
      (push (cons register value) register-alist))
Richard M. Stallman's avatar
Richard M. Stallman committed
111 112
    value))

113 114 115 116 117 118 119 120 121 122 123 124 125 126 127
(defun register-describe-oneline (c)
  "One-line description of register C."
  (let ((d (replace-regexp-in-string
            "\n[ \t]*" " "
            (with-output-to-string (describe-register-1 c)))))
    (if (string-match "Register.+? contains \\(?:an? \\|the \\)?" d)
        (substring d (match-end 0))
      d)))

(defvar register-preview-functions nil)

(defun register-preview (buffer &optional show-empty)
  "Pop up a window to show register preview in BUFFER.
If SHOW-EMPTY is non-nil show the window even if no registers."
  (when (or show-empty (consp register-alist))
128 129 130 131 132 133 134 135 136 137 138 139 140 141 142
    (with-temp-buffer-window
     buffer
     (cons 'display-buffer-below-selected
	   '((window-height . fit-window-to-buffer)))
     nil
     (with-current-buffer standard-output
       (setq cursor-in-non-selected-windows nil)
       (mapc
	(lambda (r)
	  (insert (or (run-hook-with-args-until-success
		       'register-preview-functions r)
		      (format "%s %s\n"
			      (concat (single-key-description (car r)) ":")
			      (register-describe-oneline (car r))))))
	register-alist)))))
143 144

(defun register-read-with-preview (prompt)
145 146 147 148 149
  "Read and return an event, prompting with PROMPT, possibly showing a preview.
If `register-alist' and `register-preview-delay' are both non-nil,
display a window listing registers after `register-preview-delay' seconds.
If `help-char' (or a member of `help-event-list') is pressed, display
such a window regardless."
150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170
  (let* ((buffer "*Register Preview*")
	 (timer (when (numberp register-preview-delay)
		  (run-with-timer register-preview-delay nil
				  (lambda ()
				    (unless (get-buffer-window buffer)
				      (register-preview buffer))))))
	 (help-chars (cl-loop for c in (cons help-char help-event-list)
			      when (not (get-register c))
			      collect c)))
    (unwind-protect
	(progn
	  (while (memq (read-event (propertize prompt 'face 'minibuffer-prompt))
		       help-chars)
	    (unless (get-buffer-window buffer)
	      (register-preview buffer 'show-empty)))
	  last-input-event)
      (and (timerp timer) (cancel-timer timer))
      (let ((w (get-buffer-window buffer)))
        (and (window-live-p w) (delete-window w)))
      (and (get-buffer buffer) (kill-buffer buffer)))))

171
(defun point-to-register (register &optional arg)
172
  "Store current location of point in register REGISTER.
Jim Blandy's avatar
Jim Blandy committed
173
With prefix argument, store current frame configuration.
174
Use \\[jump-to-register] to go to that location or restore that configuration.
Richard M. Stallman's avatar
Richard M. Stallman committed
175
Argument is a character, naming the register."
176 177
  (interactive (list (register-read-with-preview "Point to register: ")
		     current-prefix-arg))
Stefan Monnier's avatar
Stefan Monnier committed
178 179
  ;; Turn the marker into a file-ref if the buffer is killed.
  (add-hook 'kill-buffer-hook 'register-swap-out nil t)
180
  (set-register register
Karl Heuer's avatar
Karl Heuer committed
181 182
		(if arg (list (current-frame-configuration) (point-marker))
		  (point-marker))))
Richard M. Stallman's avatar
Richard M. Stallman committed
183

184
(defun window-configuration-to-register (register &optional _arg)
185 186 187
  "Store the window configuration of the selected frame in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Argument is a character, naming the register."
188 189 190
  (interactive (list (register-read-with-preview
		      "Window configuration to register: ")
		     current-prefix-arg))
191 192
  ;; current-window-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
193
  (set-register register (list (current-window-configuration) (point-marker))))
194

195
(defun frame-configuration-to-register (register &optional _arg)
196 197 198
  "Store the window configuration of all frames in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Argument is a character, naming the register."
199 200 201
  (interactive (list (register-read-with-preview
		      "Frame configuration to register: ")
		     current-prefix-arg))
202 203
  ;; current-frame-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
204
  (set-register register (list (current-frame-configuration) (point-marker))))
205

206
(defalias 'register-to-point 'jump-to-register)
207
(defun jump-to-register (register &optional delete)
Richard M. Stallman's avatar
Richard M. Stallman committed
208
  "Move point to location stored in a register.
209
If the register contains a file name, find that file.
210
\(To put a file name in a register, you must use `set-register'.)
211 212
If the register contains a window configuration (one frame) or a frameset
\(all frames), restore that frame or all frames accordingly.
213
First argument is a character, naming the register.
214
Optional second arg non-nil (interactively, prefix argument) says to
215
delete any existing frames that the frameset doesn't mention.
216
\(Otherwise, these frames are iconified.)"
217 218
  (interactive (list (register-read-with-preview "Jump to register: ")
		     current-prefix-arg))
219
  (let ((val (get-register register)))
220
    (cond
221
     ((registerv-p val)
Stefan Monnier's avatar
Stefan Monnier committed
222
      (cl-assert (registerv-jump-func val) nil
223 224 225
              "Don't know how to jump to register %s"
              (single-key-description register))
      (funcall (registerv-jump-func val) (registerv-data val)))
226 227 228 229 230 231
     ((and (consp val) (frame-configuration-p (car val)))
      (set-frame-configuration (car val) (not delete))
      (goto-char (cadr val)))
     ((and (consp val) (window-configuration-p (car val)))
      (set-window-configuration (car val))
      (goto-char (cadr val)))
232
     ((markerp val)
233 234
      (or (marker-buffer val)
	  (error "That register's buffer no longer exists"))
235 236
      (switch-to-buffer (marker-buffer val))
      (goto-char val))
237 238
     ((and (consp val) (eq (car val) 'file))
      (find-file (cdr val)))
239 240 241 242 243 244
     ((and (consp val) (eq (car val) 'file-query))
      (or (find-buffer-visiting (nth 1 val))
	  (y-or-n-p (format "Visit file %s again? " (nth 1 val)))
	  (error "Register access aborted"))
      (find-file (nth 1 val))
      (goto-char (nth 2 val)))
245 246
     (t
      (error "Register doesn't contain a buffer position or configuration")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
247

248
(defun register-swap-out ()
Stefan Monnier's avatar
Stefan Monnier committed
249
  "Turn markers into file-query references when a buffer is killed."
250
  (and buffer-file-name
Stefan Monnier's avatar
Stefan Monnier committed
251 252 253 254 255 256 257
       (dolist (elem register-alist)
	 (and (markerp (cdr elem))
	      (eq (marker-buffer (cdr elem)) (current-buffer))
	      (setcdr elem
		      (list 'file-query
			    buffer-file-name
			    (marker-position (cdr elem))))))))
258

259
(defun number-to-register (number register)
Karl Heuer's avatar
Karl Heuer committed
260 261
  "Store a number in a register.
Two args, NUMBER and REGISTER (a character, naming the register).
262 263
If NUMBER is nil, a decimal number is read from the buffer starting
at point, and point moves to the end of that number.
Karl Heuer's avatar
Karl Heuer committed
264
Interactively, NUMBER is the prefix arg (none means nil)."
265 266
  (interactive (list current-prefix-arg
		     (register-read-with-preview "Number to register: ")))
267
  (set-register register
268 269
		(if number
		    (prefix-numeric-value number)
270 271 272
		  (if (looking-at "\\s-*-?[0-9]+")
		      (progn
			(goto-char (match-end 0))
273
			(string-to-number (match-string 0)))
Karl Heuer's avatar
Karl Heuer committed
274 275
		    0))))

276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293
(defun increment-register (prefix register)
  "Augment contents of REGISTER.
Interactively, PREFIX is in raw form.

If REGISTER contains a number, add `prefix-numeric-value' of
PREFIX to it.

If REGISTER is empty or if it contains text, call
`append-to-register' with `delete-flag' set to PREFIX."
  (interactive "P\ncIncrement register: ")
  (let ((register-val (get-register register)))
    (cond
     ((numberp register-val)
      (let ((number (prefix-numeric-value prefix)))
	(set-register register (+ number register-val))))
     ((or (not register-val) (stringp register-val))
      (append-to-register register (region-beginning) (region-end) prefix))
     (t (error "Register does not contain a number or text")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
294

295
(defun view-register (register)
Richard M. Stallman's avatar
Richard M. Stallman committed
296
  "Display what is contained in register named REGISTER.
297
The Lisp value REGISTER is a character."
298
  (interactive (list (register-read-with-preview "View register: ")))
299
  (let ((val (get-register register)))
Richard M. Stallman's avatar
Richard M. Stallman committed
300
    (if (null val)
301
	(message "Register %s is empty" (single-key-description register))
Richard M. Stallman's avatar
Richard M. Stallman committed
302
      (with-output-to-temp-buffer "*Output*"
303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319
	(describe-register-1 register t)))))

(defun list-registers ()
  "Display a list of nonempty registers saying briefly what they contain."
  (interactive)
  (let ((list (copy-sequence register-alist)))
    (setq list (sort list (lambda (a b) (< (car a) (car b)))))
    (with-output-to-temp-buffer "*Output*"
      (dolist (elt list)
	(when (get-register (car elt))
	  (describe-register-1 (car elt))
	  (terpri))))))

(defun describe-register-1 (register &optional verbose)
  (princ "Register ")
  (princ (single-key-description register))
  (princ " contains ")
320 321
  (let ((val (get-register register)))
    (cond
322 323 324 325 326
     ((registerv-p val)
      (if (registerv-print-func val)
          (funcall (registerv-print-func val) (registerv-data val))
        (princ "[UNPRINTABLE CONTENTS].")))

327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369
     ((numberp val)
      (princ val))

     ((markerp val)
      (let ((buf (marker-buffer val)))
	(if (null buf)
	    (princ "a marker in no buffer")
	  (princ "a buffer position:\n    buffer ")
	  (princ (buffer-name buf))
	  (princ ", position ")
	  (princ (marker-position val)))))

     ((and (consp val) (window-configuration-p (car val)))
      (princ "a window configuration."))

     ((and (consp val) (frame-configuration-p (car val)))
      (princ "a frame configuration."))

     ((and (consp val) (eq (car val) 'file))
      (princ "the file ")
      (prin1 (cdr val))
      (princ "."))

     ((and (consp val) (eq (car val) 'file-query))
      (princ "a file-query reference:\n    file ")
      (prin1 (car (cdr val)))
      (princ ",\n    position ")
      (princ (car (cdr (cdr val))))
      (princ "."))

     ((consp val)
      (if verbose
	  (progn
	    (princ "the rectangle:\n")
	    (while val
	      (princ "    ")
	      (princ (car val))
	      (terpri)
	      (setq val (cdr val))))
	(princ "a rectangle starting with ")
	(princ (car val))))

     ((stringp val)
370
      (setq val (copy-sequence val))
371 372 373 374
      (if (eq yank-excluded-properties t)
	  (set-text-properties 0 (length val) nil val)
	(remove-list-of-text-properties 0 (length val)
					yank-excluded-properties val))
375 376 377 378
      (if verbose
	  (progn
	    (princ "the text:\n")
	    (princ val))
379
	(cond
380 381 382 383 384 385 386 387 388 389 390
	 ;; Extract first N characters starting with first non-whitespace.
	 ((string-match (format "[^ \t\n].\\{,%d\\}"
				;; Deduct 6 for the spaces inserted below.
				(min 20 (max 0 (- (window-width) 6))))
			val)
	  (princ "text starting with\n    ")
	  (princ (match-string 0 val)))
	 ((string-match "^[ \t\n]+$" val)
	  (princ "whitespace"))
	 (t
	  (princ "the empty string")))))
391 392 393
     (t
      (princ "Garbage:\n")
      (if verbose (prin1 val))))))
Richard M. Stallman's avatar
Richard M. Stallman committed
394

395 396
(defun insert-register (register &optional arg)
  "Insert contents of register REGISTER.  (REGISTER is a character.)
Richard M. Stallman's avatar
Richard M. Stallman committed
397 398 399
Normally puts point before and mark after the inserted text.
If optional second arg is non-nil, puts mark before and point after.
Interactively, second arg is non-nil if prefix arg is supplied."
400 401
  (interactive (progn
		 (barf-if-buffer-read-only)
402 403
		 (list (register-read-with-preview "Insert register: ")
		       current-prefix-arg)))
Richard M. Stallman's avatar
Richard M. Stallman committed
404
  (push-mark)
405
  (let ((val (get-register register)))
406
    (cond
407
     ((registerv-p val)
Stefan Monnier's avatar
Stefan Monnier committed
408
      (cl-assert (registerv-insert-func val) nil
409 410 411
              "Don't know how to insert register %s"
              (single-key-description register))
      (funcall (registerv-insert-func val) (registerv-data val)))
412 413
     ((consp val)
      (insert-rectangle val))
414
     ((stringp val)
415
      (insert-for-yank val))
Karl Heuer's avatar
Karl Heuer committed
416
     ((numberp val)
417 418 419 420 421
      (princ val (current-buffer)))
     ((and (markerp val) (marker-position val))
      (princ (marker-position val) (current-buffer)))
     (t
      (error "Register does not contain text"))))
Richard M. Stallman's avatar
Richard M. Stallman committed
422 423
  (if (not arg) (exchange-point-and-mark)))

424
(defun copy-to-register (register start end &optional delete-flag region)
425 426
  "Copy region into register REGISTER.
With prefix arg, delete as well.
427
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
428 429 430
START and END are buffer positions indicating what to copy.
The optional argument REGION if non-nil, indicates that we're not just copying
some text between START and END, but we're copying the region."
431 432 433
  (interactive (list (register-read-with-preview "Copy to register: ")
		     (region-beginning)
		     (region-end)
434 435 436 437 438 439
		     current-prefix-arg
		     t))
  (set-register register (if region
			     (funcall region-extract-function delete-flag)
			   (prog1 (filter-buffer-substring start end)
			     (if delete-flag (delete-region start end)))))
440
  (setq deactivate-mark t)
441
  (cond (delete-flag)
442 443
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
444

445 446 447 448
(defun append-to-register (register start end &optional delete-flag)
  "Append region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
449
START and END are buffer positions indicating what to append."
450 451 452 453
  (interactive (list (register-read-with-preview "Append to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
454
  (let ((reg (get-register register))
455
        (text (filter-buffer-substring start end))
456
	(separator (and register-separator (get-register register-separator))))
457 458
    (set-register
     register (cond ((not reg) text)
459
                    ((stringp reg) (concat reg separator text))
460
                    (t (error "Register does not contain text")))))
461
  (setq deactivate-mark t)
462 463 464 465
  (cond (delete-flag
	 (delete-region start end))
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
466

467 468 469 470
(defun prepend-to-register (register start end &optional delete-flag)
  "Prepend region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
471
START and END are buffer positions indicating what to prepend."
472 473 474 475
  (interactive (list (register-read-with-preview "Prepend to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
476
  (let ((reg (get-register register))
477
        (text (filter-buffer-substring start end))
478
	(separator (and register-separator (get-register register-separator))))
479 480
    (set-register
     register (cond ((not reg) text)
481
                    ((stringp reg) (concat text separator reg))
482
                    (t (error "Register does not contain text")))))
483
  (setq deactivate-mark t)
484 485 486 487
  (cond (delete-flag
	 (delete-region start end))
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
488

489 490
(defun copy-rectangle-to-register (register start end &optional delete-flag)
  "Copy rectangular region into register REGISTER.
491 492
With prefix arg, delete as well.
To insert this register in the buffer, use \\[insert-register].
493 494

Called from a program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
495
START and END are buffer positions giving two corners of rectangle."
496 497 498 499 500
  (interactive (list (register-read-with-preview
		      "Copy rectangle to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
501 502 503 504 505 506 507 508 509
  (let ((rectangle (if delete-flag
		       (delete-extract-rectangle start end)
		     (extract-rectangle start end))))
    (set-register register rectangle)
    (when (and (null delete-flag)
	       (called-interactively-p 'interactive))
      (setq deactivate-mark t)
      (indicate-copied-region (length (car rectangle))))))

Masatake YAMATO's avatar
Masatake YAMATO committed
510
(provide 'register)
Eric S. Raymond's avatar
Eric S. Raymond committed
511
;;; register.el ends here