diff-mode.el 109 KB
Newer Older
1
;;; diff-mode.el --- a mode for viewing/editing context diffs -*- lexical-binding: t -*-
2

Paul Eggert's avatar
Paul Eggert committed
3
;; Copyright (C) 1998-2019 Free Software Foundation, Inc.
4

Stefan Monnier's avatar
Stefan Monnier committed
5
;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
6
;; Keywords: convenience patch diff vc
7 8 9

;; This file is part of GNU Emacs.

10
;; GNU Emacs is free software: you can redistribute it and/or modify
11
;; it under the terms of the GNU General Public License as published by
12 13
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
14 15 16 17 18 19 20

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
21
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
22 23 24

;;; Commentary:

25
;; Provides support for font-lock, outline, navigation
26 27 28
;; commands, editing and various conversions as well as jumping
;; to the corresponding source file.

29
;; Inspired by Pavel Machek's patch-mode.el (<pavel@@atrey.karlin.mff.cuni.cz>)
30
;; Some efforts were spent to have it somewhat compatible with XEmacs's
31 32 33 34
;; diff-mode as well as with compilation-minor-mode

;; Bugs:

35
;; - Reverse doesn't work with normal diffs.
36 37 38

;; Todo:

39 40
;; - Improve `diff-add-change-log-entries-other-window',
;;   it is very simplistic now.
Lute Kamstra's avatar
Lute Kamstra committed
41
;;
42 43 44 45 46 47 48
;; - Add a `delete-after-apply' so C-c C-a automatically deletes hunks.
;;   Also allow C-c C-a to delete already-applied hunks.
;;
;; - Try `diff <file> <hunk>' to try and fuzzily discover the source location
;;   of a hunk.  Show then the changes between <file> and <hunk> and make it
;;   possible to apply them to <file>, <hunk-src>, or <hunk-dst>.
;;   Or maybe just make it into a ".rej to diff3-markers converter".
49
;;   Maybe just use `wiggle' (by Neil Brown) to do it for us.
50
;;
51 52
;; - in diff-apply-hunk, strip context in replace-match to better
;;   preserve markers and spacing.
53
;; - Handle `diff -b' output in context->unified.
54 55

;;; Code:
Stefan Monnier's avatar
Stefan Monnier committed
56
(eval-when-compile (require 'cl-lib))
57

58
(autoload 'vc-find-revision "vc")
59
(autoload 'vc-find-revision-no-save "vc")
60
(defvar vc-find-revision-no-save)
61 62
(defvar add-log-buffer-file-name-function)

63 64

(defgroup diff-mode ()
65
  "Major mode for viewing/editing diffs."
66
  :version "21.1"
67 68 69
  :group 'tools
  :group 'diff)

70
(defcustom diff-default-read-only nil
71
  "If non-nil, `diff-mode' buffers default to being read-only."
72
  :type 'boolean)
73

74
(defcustom diff-jump-to-old-file nil
75
  "Non-nil means `diff-goto-source' jumps to the old file.
76
Else, it jumps to the new file."
77
  :type 'boolean)
78

79
(defcustom diff-update-on-the-fly t
Lute Kamstra's avatar
Lute Kamstra committed
80
  "Non-nil means hunk headers are kept up-to-date on-the-fly.
81 82 83 84 85
When editing a diff file, the line numbers in the hunk headers
need to be kept consistent with the actual diff.  This can
either be done on the fly (but this sometimes interacts poorly with the
undo mechanism) or whenever the file is written (can be slow
when editing big diffs)."
86
  :type 'boolean)
87

88
(defcustom diff-advance-after-apply-hunk t
Lute Kamstra's avatar
Lute Kamstra committed
89
  "Non-nil means `diff-apply-hunk' will move to the next hunk after applying."
90
  :type 'boolean)
91

92 93 94
(defcustom diff-mode-hook nil
  "Run after setting up the `diff-mode' major mode."
  :type 'hook
95 96 97 98 99 100
  :options '(diff-delete-empty-files diff-make-unified))

(defcustom diff-font-lock-refine t
  "If non-nil, font-lock highlighting includes hunk refinement."
  :version "27.1"
  :type 'boolean)
101

102 103 104 105 106
(defcustom diff-font-lock-prettify nil
  "If non-nil, font-lock will try and make the format prettier."
  :version "27.1"
  :type 'boolean)

107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132
(defcustom diff-font-lock-syntax t
  "If non-nil, diff hunk font-lock includes source language syntax highlighting.
This highlighting is the same as added by `font-lock-mode'
when corresponding source files are visited normally.
Syntax highlighting is added over diff own highlighted changes.

If t, the default, highlight syntax only in Diff buffers created by Diff
commands that compare files or by VC commands that compare revisions.
These provide all necessary context for reliable highlighting.  This value
requires support from a VC backend to find the files being compared.
For diffs against the working-tree version of a file, the highlighting is
based on the current file contents.  File-based fontification tries to
infer fontification from the compared files.

If revision-based or file-based method fails, use hunk-based method to get
fontification from hunk alone if the value is `hunk-also'.

If `hunk-only', fontification is based on hunk alone, without full source.
It tries to highlight hunks without enough context that sometimes might result
in wrong fontification.  This is the fastest option, but less reliable."
  :version "27.1"
  :type '(choice (const :tag "Don't highlight syntax" nil)
                 (const :tag "Hunk-based also" hunk-also)
                 (const :tag "Hunk-based only" hunk-only)
                 (const :tag "Highlight syntax" t)))

133 134 135
(defvar diff-vc-backend nil
  "The VC backend that created the current Diff buffer, if any.")

136 137 138
(defvar diff-vc-revisions nil
  "The VC revisions compared in the current Diff buffer, if any.")

139 140 141 142
(defvar diff-default-directory nil
  "The default directory where the current Diff buffer was created.")
(make-variable-buffer-local 'diff-default-directory)

143 144 145
(defvar diff-outline-regexp
  "\\([*+][*+][*+] [^0-9]\\|@@ ...\\|\\*\\*\\* [0-9].\\|--- [0-9]..\\)")

146
;;;;
147
;;;; keymap, menu, ...
148
;;;;
149

150
(easy-mmode-defmap diff-mode-shared-map
151
  '(("n" . diff-hunk-next)
152 153 154
    ("N" . diff-file-next)
    ("p" . diff-hunk-prev)
    ("P" . diff-file-prev)
155 156
    ("\t" . diff-hunk-next)
    ([backtab] . diff-hunk-prev)
157 158
    ("k" . diff-hunk-kill)
    ("K" . diff-file-kill)
159
    ("}" . diff-file-next)	; From compilation-minor-mode.
160
    ("{" . diff-file-prev)
161
    ("\C-m" . diff-goto-source)
162
    ([mouse-2] . diff-goto-source)
163
    ("W" . widen)
164
    ("o" . diff-goto-source)	; other-window
165 166
    ("A" . diff-ediff-patch)
    ("r" . diff-restrict-view)
167 168
    ("R" . diff-reverse-direction)
    ([remap undo] . diff-undo))
169 170
  "Basic keymap for `diff-mode', bound to various prefix keys."
  :inherit special-mode-map)
171

172
(easy-mmode-defmap diff-mode-map
173 174 175 176 177
  `(("\e" . ,(let ((map (make-sparse-keymap)))
               ;; We want to inherit most bindings from diff-mode-shared-map,
               ;; but not all since they may hide useful M-<foo> global
               ;; bindings when editing.
               (set-keymap-parent map diff-mode-shared-map)
178
               (dolist (key '("A" "r" "R" "g" "q" "W" "z"))
179 180
                 (define-key map key nil))
               map))
181 182
    ;; From compilation-minor-mode.
    ("\C-c\C-c" . diff-goto-source)
183 184
    ;; By analogy with the global C-x 4 a binding.
    ("\C-x4A" . diff-add-change-log-entries-other-window)
185
    ;; Misc operations.
186
    ("\C-c\C-a" . diff-apply-hunk)
187 188 189
    ("\C-c\C-e" . diff-ediff-patch)
    ("\C-c\C-n" . diff-restrict-view)
    ("\C-c\C-s" . diff-split-hunk)
190
    ("\C-c\C-t" . diff-test-hunk)
Stefan Monnier's avatar
Stefan Monnier committed
191
    ("\C-c\C-r" . diff-reverse-direction)
192
    ("\C-c\C-u" . diff-context->unified)
193 194
    ;; `d' because it duplicates the context :-(  --Stef
    ("\C-c\C-d" . diff-unified->context)
Stefan Monnier's avatar
Stefan Monnier committed
195 196
    ("\C-c\C-w" . diff-ignore-whitespace-hunk)
    ("\C-c\C-b" . diff-refine-hunk)  ;No reason for `b' :-(
197
    ("\C-c\C-f" . next-error-follow-minor-mode))
198 199 200 201 202
  "Keymap for `diff-mode'.  See also `diff-mode-shared-map'.")

(easy-menu-define diff-mode-menu diff-mode-map
  "Menu for `diff-mode'."
  '("Diff"
Dan Nicolaescu's avatar
Dan Nicolaescu committed
203 204 205 206 207 208 209 210
    ["Jump to Source"		diff-goto-source
     :help "Jump to the corresponding source line"]
    ["Apply hunk"		diff-apply-hunk
     :help "Apply the current hunk to the source file and go to the next"]
    ["Test applying hunk"	diff-test-hunk
     :help "See whether it's possible to apply the current hunk"]
    ["Apply diff with Ediff"	diff-ediff-patch
     :help "Call `ediff-patch-file' on the current buffer"]
211
    ["Create Change Log entries" diff-add-change-log-entries-other-window
Dan Nicolaescu's avatar
Dan Nicolaescu committed
212
     :help "Create ChangeLog entries for the changes in the diff buffer"]
Stefan Monnier's avatar
Stefan Monnier committed
213
    "-----"
Dan Nicolaescu's avatar
Dan Nicolaescu committed
214 215 216 217 218 219
    ["Reverse direction"	diff-reverse-direction
     :help "Reverse the direction of the diffs"]
    ["Context -> Unified"	diff-context->unified
     :help "Convert context diffs to unified diffs"]
    ["Unified -> Context"	diff-unified->context
     :help "Convert unified diffs to context diffs"]
220
    ;;["Fixup Headers"		diff-fixup-modifs	(not buffer-read-only)]
221
    ["Remove trailing whitespace" diff-delete-trailing-whitespace
222
     :help "Remove trailing whitespace problems introduced by the diff"]
223
    ["Show trailing whitespace" whitespace-mode
224
     :style toggle :selected (bound-and-true-p whitespace-mode)
225
     :help "Show trailing whitespace in modified lines"]
Stefan Monnier's avatar
Stefan Monnier committed
226
    "-----"
Dan Nicolaescu's avatar
Dan Nicolaescu committed
227 228 229 230 231 232 233 234 235 236 237
    ["Split hunk"		diff-split-hunk
     :active (diff-splittable-p)
     :help "Split the current (unified diff) hunk at point into two hunks"]
    ["Ignore whitespace changes" diff-ignore-whitespace-hunk
     :help "Re-diff the current hunk, ignoring whitespace differences"]
    ["Highlight fine changes"	diff-refine-hunk
     :help "Highlight changes of hunk at point at a finer granularity"]
    ["Kill current hunk"	diff-hunk-kill
     :help "Kill current hunk"]
    ["Kill current file's hunks" diff-file-kill
     :help "Kill all current file's hunks"]
Stefan Monnier's avatar
Stefan Monnier committed
238
    "-----"
Dan Nicolaescu's avatar
Dan Nicolaescu committed
239 240 241 242 243 244 245 246
    ["Previous Hunk"		diff-hunk-prev
     :help "Go to the previous count'th hunk"]
    ["Next Hunk"		diff-hunk-next
     :help "Go to the next count'th hunk"]
    ["Previous File"		diff-file-prev
     :help "Go to the previous count'th file"]
    ["Next File"		diff-file-next
     :help "Go to the next count'th file"]
247 248
    ))

249
(defcustom diff-minor-mode-prefix "\C-c="
250
  "Prefix key for `diff-minor-mode' commands."
251
  :type '(choice (string "\e") (string "C-c=") string))
252

253 254
(easy-mmode-defmap diff-minor-mode-map
  `((,diff-minor-mode-prefix . ,diff-mode-shared-map))
255 256
  "Keymap for `diff-minor-mode'.  See also `diff-mode-shared-map'.")

257
(define-minor-mode diff-auto-refine-mode
258
  "Toggle automatic diff hunk finer highlighting (Diff Auto Refine mode).
Chong Yidong's avatar
Chong Yidong committed
259 260 261 262 263 264

Diff Auto Refine mode is a buffer-local minor mode used with
`diff-mode'.  When enabled, Emacs automatically highlights
changes in detail as the user visits hunks.  When transitioning
from disabled to enabled, it tries to refine the current hunk, as
well."
265
  :group 'diff-mode :init-value t :lighter nil ;; " Auto-Refine"
266
  (when diff-auto-refine-mode
267
    (condition-case-unless-debug nil (diff-refine-hunk) (error nil))))
268

269
;;;;
270
;;;; font-lock support
271
;;;;
272

273
(defface diff-header
274
  '((((class color) (min-colors 88) (background light))
275
     :background "grey85")
276
    (((class color) (min-colors 88) (background dark))
277
     :background "grey45")
278
    (((class color))
279 280
     :foreground "blue1" :weight bold)
    (t :weight bold))
281
  "`diff-mode' face inherited by hunk and index header faces.")
Stefan Monnier's avatar
Stefan Monnier committed
282

283
(defface diff-file-header
284
  '((((class color) (min-colors 88) (background light))
285
     :background "grey75" :weight bold)
286
    (((class color) (min-colors 88) (background dark))
287
     :background "grey60" :weight bold)
288
    (((class color))
289 290
     :foreground "cyan" :weight bold)
    (t :weight bold))			; :height 1.3
291
  "`diff-mode' face used to highlight file header lines.")
292

293 294
(defface diff-index
  '((t :inherit diff-file-header))
295
  "`diff-mode' face used to highlight index header lines.")
296

297 298
(defface diff-hunk-header
  '((t :inherit diff-header))
299
  "`diff-mode' face used to highlight hunk header lines.")
300

301
(defface diff-removed
302 303 304
  '((default
     :inherit diff-changed)
    (((class color) (min-colors 88) (background light))
305
     :background "#ffeeee")
306 307 308 309
    (((class color) (min-colors 88) (background dark))
     :background "#553333")
    (((class color))
     :foreground "red"))
310
  "`diff-mode' face used to highlight removed lines.")
311

312
(defface diff-added
313 314 315
  '((default
     :inherit diff-changed)
    (((class color) (min-colors 88) (background light))
316
     :background "#eeffee")
317 318 319 320
    (((class color) (min-colors 88) (background dark))
     :background "#335533")
    (((class color))
     :foreground "green"))
321
  "`diff-mode' face used to highlight added lines.")
322

323
(defface diff-changed
324
  '((t nil))
325
  "`diff-mode' face used to highlight changed lines."
326
  :version "25.1")
327

328
(defface diff-indicator-removed
329 330 331
  '((default :inherit diff-removed)
    (((class color) (min-colors 88))
     :foreground "#aa2222"))
332 333 334 335 336
  "`diff-mode' face used to highlight indicator of removed lines (-, <)."
  :version "22.1")
(defvar diff-indicator-removed-face 'diff-indicator-removed)

(defface diff-indicator-added
337 338 339
  '((default :inherit diff-added)
    (((class color) (min-colors 88))
     :foreground "#22aa22"))
340 341 342 343 344
  "`diff-mode' face used to highlight indicator of added lines (+, >)."
  :version "22.1")
(defvar diff-indicator-added-face 'diff-indicator-added)

(defface diff-indicator-changed
345 346 347
  '((default :inherit diff-changed)
    (((class color) (min-colors 88))
     :foreground "#aaaa22"))
348 349 350 351
  "`diff-mode' face used to highlight indicator of changed lines."
  :version "22.1")
(defvar diff-indicator-changed-face 'diff-indicator-changed)

352
(defface diff-function
353
  '((t :inherit diff-header))
354
  "`diff-mode' face used to highlight function names produced by \"diff -p\".")
355

356
(defface diff-context
357
  '((t nil))
358
  "`diff-mode' face used to highlight context and other side-information."
359
  :version "25.1")
Stefan Monnier's avatar
Stefan Monnier committed
360

361 362
(defface diff-nonexistent
  '((t :inherit diff-file-header))
363
  "`diff-mode' face used to highlight nonexistent files in recursive diffs.")
364

365 366
(defconst diff-yank-handler '(diff-yank-function))
(defun diff-yank-function (text)
367 368 369
  ;; FIXME: the yank-handler is now called separately on each piece of text
  ;; with a yank-handler property, so the next-single-property-change call
  ;; below will always return nil :-(   --stef
370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385
  (let ((mixed (next-single-property-change 0 'yank-handler text))
	(start (point)))
    ;; First insert the text.
    (insert text)
    ;; If the text does not include any diff markers and if we're not
    ;; yanking back into a diff-mode buffer, get rid of the prefixes.
    (unless (or mixed (derived-mode-p 'diff-mode))
      (undo-boundary)		; Just in case the user wanted the prefixes.
      (let ((re (save-excursion
		  (if (re-search-backward "^[><!][ \t]" start t)
		      (if (eq (char-after) ?!)
			  "^[!+- ][ \t]" "^[<>][ \t]")
		    "^[ <>!+-]"))))
	(save-excursion
	  (while (re-search-backward re start t)
	    (replace-match "" t t)))))))
386

387
(defconst diff-hunk-header-re-unified
388
  "^@@ -\\([0-9]+\\)\\(?:,\\([0-9]+\\)\\)? \\+\\([0-9]+\\)\\(?:,\\([0-9]+\\)\\)? @@")
389 390
(defconst diff-context-mid-hunk-header-re
  "--- \\([0-9]+\\)\\(?:,\\([0-9]+\\)\\)? ----$")
391

392 393 394
(defvar diff-use-changed-face (and (face-differs-from-default-p 'diff-changed)
				   (not (face-equal 'diff-changed 'diff-added))
				   (not (face-equal 'diff-changed 'diff-removed)))
395 396 397 398
  "If non-nil, use the face `diff-changed' for changed lines in context diffs.
Otherwise, use the face `diff-removed' for removed lines,
and the face `diff-added' for added lines.")

399
(defvar diff-font-lock-keywords
400
  `((,(concat "\\(" diff-hunk-header-re-unified "\\)\\(.*\\)$")
401
     (1 'diff-hunk-header) (6 'diff-function))
402
    ("^\\(\\*\\{15\\}\\)\\(.*\\)$"                        ;context
403 404 405 406 407
     (1 'diff-hunk-header) (2 'diff-function))
    ("^\\*\\*\\* .+ \\*\\*\\*\\*". 'diff-hunk-header) ;context
    (,diff-context-mid-hunk-header-re . 'diff-hunk-header) ;context
    ("^[0-9,]+[acd][0-9,]+$"     . 'diff-hunk-header) ;normal
    ("^---$"                     . 'diff-hunk-header) ;normal
408 409 410
    ;; For file headers, accept files with spaces, but be careful to rule
    ;; out false-positives when matching hunk headers.
    ("^\\(---\\|\\+\\+\\+\\|\\*\\*\\*\\) \\([^\t\n]+?\\)\\(?:\t.*\\| \\(\\*\\*\\*\\*\\|----\\)\\)?\n"
411 412
     (0 'diff-header)
     (2 (if (not (match-end 3)) 'diff-file-header) prepend))
413
    ("^\\([-<]\\)\\(.*\n\\)"
414
     (1 diff-indicator-removed-face) (2 'diff-removed))
415
    ("^\\([+>]\\)\\(.*\n\\)"
416
     (1 diff-indicator-added-face) (2 'diff-added))
417
    ("^\\(!\\)\\(.*\n\\)"
418 419 420
     (1 (if diff-use-changed-face
	    diff-indicator-changed-face
	  ;; Otherwise, search for `diff-context-mid-hunk-header-re' and
421 422
	  ;; if the line of context diff is above, use `diff-removed';
	  ;; if below, use `diff-added'.
423 424 425 426 427 428
	  (save-match-data
	    (let ((limit (save-excursion (diff-beginning-of-hunk))))
	      (if (save-excursion (re-search-backward diff-context-mid-hunk-header-re limit t))
		  diff-indicator-added-face
		diff-indicator-removed-face)))))
     (2 (if diff-use-changed-face
429
	    'diff-changed
430 431 432 433
	  ;; Otherwise, use the same method as above.
	  (save-match-data
	    (let ((limit (save-excursion (diff-beginning-of-hunk))))
	      (if (save-excursion (re-search-backward diff-context-mid-hunk-header-re limit t))
434 435
		  'diff-added
		'diff-removed))))))
436
    ("^\\(?:Index\\|revno\\): \\(.+\\).*\n"
437
     (0 'diff-header) (1 'diff-index prepend))
438
    ("^\\(?:index .*\\.\\.\\|diff \\).*\n" . 'diff-header)
439
    ("^Only in .*\n" . 'diff-nonexistent)
440
    ("^Binary files .* differ\n" . 'diff-file-header)
441
    ("^\\(#\\)\\(.*\\)"
442 443
     (1 font-lock-comment-delimiter-face)
     (2 font-lock-comment-face))
444
    ("^[^-=+*!<>#].*\n" (0 'diff-context))
445
    (,#'diff--font-lock-syntax)
446
    (,#'diff--font-lock-prettify)
447
    (,#'diff--font-lock-refined)))
448 449

(defconst diff-font-lock-defaults
450
  '(diff-font-lock-keywords t nil nil nil (font-lock-multiline . nil)))
451

452 453
(defvar diff-imenu-generic-expression
  ;; Prefer second name as first is most likely to be a backup or
454 455 456
  ;; version-control name.  The [\t\n] at the end of the unidiff pattern
  ;; catches Debian source diff files (which lack the trailing date).
  '((nil "\\+\\+\\+\\ \\([^\t\n]+\\)[\t\n]" 1) ; unidiffs
457 458
    (nil "^--- \\([^\t\n]+\\)\t.*\n\\*" 1))) ; context diffs

459
;;;;
460
;;;; Movement
461
;;;;
462

463 464 465 466
(defvar diff-valid-unified-empty-line t
  "If non-nil, empty lines are valid in unified diffs.
Some versions of diff replace all-blank context lines in unified format with
empty lines.  This makes the format less robust, but is tolerated.
467
See https://lists.gnu.org/r/emacs-devel/2007-11/msg01990.html")
468 469 470

(defconst diff-hunk-header-re
  (concat "^\\(?:" diff-hunk-header-re-unified ".*\\|\\*\\{15\\}.*\n\\*\\*\\* .+ \\*\\*\\*\\*\\|[0-9]+\\(,[0-9]+\\)?[acd][0-9]+\\(,[0-9]+\\)?\\)$"))
471
(defconst diff-file-header-re (concat "^\\(--- .+\n\\+\\+\\+ \\|\\*\\*\\* .+\n--- \\|[^-+!<>0-9@* \n]\\).+\n" (substring diff-hunk-header-re 1)))
472 473 474

(defconst diff-separator-re "^--+ ?$")

475 476
(defvar diff-narrowed-to nil)

Stefan Monnier's avatar
Stefan Monnier committed
477
(defun diff-hunk-style (&optional style)
478
  (when (looking-at diff-hunk-header-re)
Stefan Monnier's avatar
Stefan Monnier committed
479
    (setq style (cdr (assq (char-after) '((?@ . unified) (?* . context)))))
480
    (goto-char (match-end 0)))
Stefan Monnier's avatar
Stefan Monnier committed
481 482
  style)

483
(defun diff-end-of-hunk (&optional style donttrustheader)
Chong Yidong's avatar
Chong Yidong committed
484
  "Advance to the end of the current hunk, and return its position."
485 486 487 488 489 490
  (let (end)
    (when (looking-at diff-hunk-header-re)
      ;; Especially important for unified (because headers are ambiguous).
      (setq style (diff-hunk-style style))
      (goto-char (match-end 0))
      (when (and (not donttrustheader) (match-end 2))
491 492
        (let* ((nold (string-to-number (or (match-string 2) "1")))
               (nnew (string-to-number (or (match-string 4) "1")))
493
               (endold
494 495 496
                (save-excursion
                  (re-search-forward (if diff-valid-unified-empty-line
                                         "^[- \n]" "^[- ]")
497
                                     nil t nold)
498 499 500
                  (line-beginning-position
                   ;; Skip potential "\ No newline at end of file".
                   (if (looking-at ".*\n\\\\") 3 2))))
501 502 503 504 505 506 507
               (endnew
                ;; The hunk may end with a bunch of "+" lines, so the `end' is
                ;; then further than computed above.
                (save-excursion
                  (re-search-forward (if diff-valid-unified-empty-line
                                         "^[+ \n]" "^[+ ]")
                                     nil t nnew)
508 509 510
                  (line-beginning-position
                   ;; Skip potential "\ No newline at end of file".
                   (if (looking-at ".*\n\\\\") 3 2)))))
511
          (setq end (max endold endnew)))))
512 513 514
    ;; We may have a first evaluation of `end' thanks to the hunk header.
    (unless end
      (setq end (and (re-search-forward
Stefan Monnier's avatar
Stefan Monnier committed
515
                      (pcase style
516
                        ('unified
Stefan Monnier's avatar
Stefan Monnier committed
517 518 519 520
                         (concat (if diff-valid-unified-empty-line
                                     "^[^-+# \\\n]\\|" "^[^-+# \\]\\|")
                                 ;; A `unified' header is ambiguous.
                                 diff-file-header-re))
521 522
                        ('context "^[^-+#! \\]")
                        ('normal "^[^<>#\\]")
Stefan Monnier's avatar
Stefan Monnier committed
523
                        (_ "^[^-+#!<> \\]"))
524 525 526 527 528 529 530 531 532
                      nil t)
                     (match-beginning 0)))
      (when diff-valid-unified-empty-line
        ;; While empty lines may be valid inside hunks, they are also likely
        ;; to be unrelated to the hunk.
        (goto-char (or end (point-max)))
        (while (eq ?\n (char-before (1- (point))))
          (forward-char -1)
          (setq end (point)))))
533 534
    ;; The return value is used by easy-mmode-define-navigation.
    (goto-char (or end (point-max)))))
535

536 537 538
;; "index ", "old mode", "new mode", "new file mode" and
;; "deleted file mode" are output by git-diff.
(defconst diff-file-junk-re
539
  (concat "Index: \\|Prereq: \\|=\\{20,\\}\\|" ; SVN
Tino Calancha's avatar
Tino Calancha committed
540
          "diff \\|index \\|\\(?:deleted file\\|new\\(?: file\\)?\\|old\\) mode\\|=== modified file"))
541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568

;; If point is in a diff header, then return beginning
;; of hunk position otherwise return nil.
(defun diff--at-diff-header-p ()
  "Return non-nil if point is inside a diff header."
  (let ((regexp-hunk diff-hunk-header-re)
        (regexp-file diff-file-header-re)
        (regexp-junk diff-file-junk-re)
        (orig (point)))
    (catch 'headerp
      (save-excursion
        (forward-line 0)
        (when (looking-at regexp-hunk) ; Hunk header.
          (throw 'headerp (point)))
        (forward-line -1)
        (when (re-search-forward regexp-file (point-at-eol 4) t) ; File header.
          (forward-line 0)
          (throw 'headerp (point)))
        (goto-char orig)
        (forward-line 0)
        (when (looking-at regexp-junk) ; Git diff junk.
          (while (and (looking-at regexp-junk)
                      (not (bobp)))
            (forward-line -1))
          (re-search-forward regexp-file nil t)
          (forward-line 0)
          (throw 'headerp (point)))) nil)))

569
(defun diff-beginning-of-hunk (&optional try-harder)
Chong Yidong's avatar
Chong Yidong committed
570 571 572
  "Move back to the previous hunk beginning, and return its position.
If point is in a file header rather than a hunk, advance to the
next hunk if TRY-HARDER is non-nil; otherwise signal an error."
573
  (beginning-of-line)
574
  (if (looking-at diff-hunk-header-re) ; At hunk header.
Chong Yidong's avatar
Chong Yidong committed
575
      (point)
576 577 578 579 580 581 582 583
    (let ((pos (diff--at-diff-header-p))
          (regexp diff-hunk-header-re))
      (cond (pos ; At junk diff header.
             (if try-harder
                 (goto-char pos)
               (error "Can't find the beginning of the hunk")))
            ((re-search-backward regexp nil t)) ; In the middle of a hunk.
            ((re-search-forward regexp nil t) ; At first hunk header.
Tino Calancha's avatar
Tino Calancha committed
584 585
             (forward-line 0)
             (point))
586
            (t (error "Can't find the beginning of the hunk"))))))
587

588 589 590 591 592 593
(defun diff-unified-hunk-p ()
  (save-excursion
    (ignore-errors
      (diff-beginning-of-hunk)
      (looking-at "^@@"))))

594 595 596
(defun diff-beginning-of-file ()
  (beginning-of-line)
  (unless (looking-at diff-file-header-re)
597 598 599 600 601 602 603 604 605 606 607 608 609
    (let ((start (point))
          res)
      ;; diff-file-header-re may need to match up to 4 lines, so in case
      ;; we're inside the header, we need to move up to 3 lines forward.
      (forward-line 3)
      (if (and (setq res (re-search-backward diff-file-header-re nil t))
               ;; Maybe the 3 lines forward were too much and we matched
               ;; a file header after our starting point :-(
               (or (<= (point) start)
                   (setq res (re-search-backward diff-file-header-re nil t))))
          res
        (goto-char start)
        (error "Can't find the beginning of the file")))))
Lute Kamstra's avatar
Lute Kamstra committed
610

611 612

(defun diff-end-of-file ()
613
  (re-search-forward "^[-+#!<>0-9@* \\]" nil t)
614 615 616 617 618
  (re-search-forward (concat "^[^-+#!<>0-9@* \\]\\|" diff-file-header-re)
		     nil 'move)
  (if (match-beginning 1)
      (goto-char (match-beginning 1))
    (beginning-of-line)))
619

620 621
(defvar diff--auto-refine-data nil)

622 623
;; Define diff-{hunk,file}-{prev,next}
(easy-mmode-define-navigation
624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640
 diff-hunk diff-hunk-header-re "hunk" diff-end-of-hunk diff-restrict-view
 (when diff-auto-refine-mode
   (unless (prog1 diff--auto-refine-data
             (setq diff--auto-refine-data
                   (cons (current-buffer) (point-marker))))
     (run-at-time 0.0 nil
                  (lambda ()
                    (when diff--auto-refine-data
                      (let ((buffer (car diff--auto-refine-data))
                            (point (cdr diff--auto-refine-data)))
                        (setq diff--auto-refine-data nil)
                        (with-local-quit
                          (when (buffer-live-p buffer)
                            (with-current-buffer buffer
                              (save-excursion
                                (goto-char point)
                                (diff-refine-hunk))))))))))))
Stefan Monnier's avatar
Stefan Monnier committed
641

642
(easy-mmode-define-navigation
643
 diff-file diff-file-header-re "file" diff-end-of-file)
644

Chong Yidong's avatar
Chong Yidong committed
645 646 647 648 649 650 651 652 653
(defun diff-bounds-of-hunk ()
  "Return the bounds of the diff hunk at point.
The return value is a list (BEG END), which are the hunk's start
and end positions.  Signal an error if no hunk is found.  If
point is in a file header, return the bounds of the next hunk."
  (save-excursion
    (let ((pos (point))
	  (beg (diff-beginning-of-hunk t))
	  (end (diff-end-of-hunk)))
654
      (cond ((>= end pos)
Chong Yidong's avatar
Chong Yidong committed
655 656 657 658
	     (list beg end))
	    ;; If this hunk ends above POS, consider the next hunk.
	    ((re-search-forward diff-hunk-header-re nil t)
	     (list (match-beginning 0) (diff-end-of-hunk)))
659
	    (t (error "No hunk found"))))))
Chong Yidong's avatar
Chong Yidong committed
660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676

(defun diff-bounds-of-file ()
  "Return the bounds of the file segment at point.
The return value is a list (BEG END), which are the segment's
start and end positions."
  (save-excursion
    (let ((pos (point))
	  (beg (progn (diff-beginning-of-file-and-junk)
		      (point))))
      (diff-end-of-file)
      ;; bzr puts a newline after the last hunk.
      (while (looking-at "^\n")
	(forward-char 1))
      (if (> pos (point))
	  (error "Not inside a file diff"))
      (list beg (point)))))

677 678 679 680
(defun diff-restrict-view (&optional arg)
  "Restrict the view to the current hunk.
If the prefix ARG is given, restrict the view to the current file instead."
  (interactive "P")
Chong Yidong's avatar
Chong Yidong committed
681 682 683
  (apply 'narrow-to-region
	 (if arg (diff-bounds-of-file) (diff-bounds-of-hunk)))
  (set (make-local-variable 'diff-narrowed-to) (if arg 'file 'hunk)))
684

685 686 687 688 689
(defun diff--some-hunks-p ()
  (save-excursion
    (goto-char (point-min))
    (re-search-forward diff-hunk-header-re nil t)))

690
(defun diff-hunk-kill ()
Chong Yidong's avatar
Chong Yidong committed
691
  "Kill the hunk at point."
692
  (interactive)
693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714
  (if (not (diff--some-hunks-p))
      (error "No hunks")
    (diff-beginning-of-hunk t)
    (let* ((hunk-bounds (diff-bounds-of-hunk))
           (file-bounds (ignore-errors (diff-bounds-of-file)))
           ;; If the current hunk is the only one for its file, kill the
           ;; file header too.
           (bounds (if (and file-bounds
                            (progn (goto-char (car file-bounds))
                                   (= (progn (diff-hunk-next) (point))
                                      (car hunk-bounds)))
                            (progn (goto-char (cadr hunk-bounds))
                                   ;; bzr puts a newline after the last hunk.
                                   (while (looking-at "^\n")
                                     (forward-char 1))
                                   (= (point) (cadr file-bounds))))
                       file-bounds
                     hunk-bounds))
           (inhibit-read-only t))
      (apply 'kill-region bounds)
      (goto-char (car bounds))
      (ignore-errors (diff-beginning-of-hunk t)))))
715

716 717 718 719
(defun diff-beginning-of-file-and-junk ()
  "Go to the beginning of file-related diff-info.
This is like `diff-beginning-of-file' except it tries to skip back over leading
data such as \"Index: ...\" and such."
720 721 722 723 724 725 726
  (let* ((orig (point))
         ;; Skip forward over what might be "leading junk" so as to get
         ;; closer to the actual diff.
         (_ (progn (beginning-of-line)
                   (while (looking-at diff-file-junk-re)
                     (forward-line 1))))
         (start (point))
727 728 729 730 731 732 733 734 735 736 737 738 739
         (prevfile (condition-case err
                       (save-excursion (diff-beginning-of-file) (point))
                     (error err)))
         (err (if (consp prevfile) prevfile))
         (nextfile (ignore-errors
                     (save-excursion
                       (goto-char start) (diff-file-next) (point))))
         ;; prevhunk is one of the limits.
         (prevhunk (save-excursion
                     (ignore-errors
                       (if (numberp prevfile) (goto-char prevfile))
                       (diff-hunk-prev) (point))))
         (previndex (save-excursion
740
                      (forward-line 1)  ;In case we're looking at "Index:".
741 742 743 744 745 746 747 748
                      (re-search-backward "^Index: " prevhunk t))))
    ;; If we're in the junk, we should use nextfile instead of prevfile.
    (if (and (numberp nextfile)
             (or (not (numberp prevfile))
                 (and previndex (> previndex prevfile))))
        (setq prevfile nextfile))
    (if (and previndex (numberp prevfile) (< previndex prevfile))
        (setq prevfile previndex))
749
    (if (and (numberp prevfile) (<= prevfile start))
750 751 752 753 754 755 756 757
          (progn
            (goto-char prevfile)
            ;; Now skip backward over the leading junk we may have before the
            ;; diff itself.
            (while (save-excursion
                     (and (zerop (forward-line -1))
                          (looking-at diff-file-junk-re)))
              (forward-line -1)))
758 759
      ;; File starts *after* the starting point: we really weren't in
      ;; a file diff but elsewhere.
760
      (goto-char orig)
761
      (signal (car err) (cdr err)))))
Lute Kamstra's avatar
Lute Kamstra committed
762

763
(defun diff-file-kill ()
764 765
  "Kill current file's hunks."
  (interactive)
766 767 768 769 770 771
  (if (not (diff--some-hunks-p))
      (error "No hunks")
    (diff-beginning-of-hunk t)
    (let ((inhibit-read-only t))
      (apply 'kill-region (diff-bounds-of-file)))
    (ignore-errors (diff-beginning-of-hunk t))))
772

773 774 775 776 777 778 779 780 781 782 783 784 785 786 787
(defun diff-kill-junk ()
  "Kill spurious empty diffs."
  (interactive)
  (save-excursion
    (let ((inhibit-read-only t))
      (goto-char (point-min))
      (while (re-search-forward (concat "^\\(Index: .*\n\\)"
					"\\([^-+!* <>].*\n\\)*?"
					"\\(\\(Index:\\) \\|"
					diff-file-header-re "\\)")
				nil t)
	(delete-region (if (match-end 4) (match-beginning 0) (match-end 1))
		       (match-beginning 3))
	(beginning-of-line)))))

788 789 790 791
(defun diff-count-matches (re start end)
  (save-excursion
    (let ((n 0))
      (goto-char start)
Stefan Monnier's avatar
Stefan Monnier committed
792
      (while (re-search-forward re end t) (cl-incf n))
793 794
      n)))

795 796 797 798 799 800 801
(defun diff-splittable-p ()
  (save-excursion
    (beginning-of-line)
    (and (looking-at "^[-+ ]")
         (progn (forward-line -1) (looking-at "^[-+ ]"))
         (diff-unified-hunk-p))))

802 803 804 805 806
(defun diff-split-hunk ()
  "Split the current (unified diff) hunk at point into two hunks."
  (interactive)
  (beginning-of-line)
  (let ((pos (point))
Chong Yidong's avatar
Chong Yidong committed
807
	(start (diff-beginning-of-hunk)))
808
    (unless (looking-at diff-hunk-header-re-unified)
809 810 811
      (error "diff-split-hunk only works on unified context diffs"))
    (forward-line 1)
    (let* ((start1 (string-to-number (match-string 1)))
812
	   (start2 (string-to-number (match-string 3)))
813
	   (newstart1 (+ start1 (diff-count-matches "^[- \t]" (point) pos)))
814 815
	   (newstart2 (+ start2 (diff-count-matches "^[+ \t]" (point) pos)))
	   (inhibit-read-only t))
816 817 818 819 820 821
      (goto-char pos)
      ;; Hopefully the after-change-function will not screw us over.
      (insert "@@ -" (number-to-string newstart1) ",1 +"
	      (number-to-string newstart2) ",1 @@\n")
      ;; Fix the original hunk-header.
      (diff-fixup-modifs start pos))))
822

823

824 825 826 827
;;;;
;;;; jump to other buffers
;;;;

828
(defvar diff-remembered-files-alist nil)
829
(defvar diff-remembered-defdir nil)
830

831 832 833
(defun diff-filename-drop-dir (file)
  (when (string-match "/" file) (substring file (match-end 0))))

834 835 836
(defun diff-merge-strings (ancestor from to)
  "Merge the diff between ANCESTOR and FROM into TO.
Returns the merged string if successful or nil otherwise.
837
The strings are assumed not to contain any \"\\n\" (i.e. end of line).
838 839 840 841 842 843 844 845
If ANCESTOR = FROM, returns TO.
If ANCESTOR = TO, returns FROM.
The heuristic is simplistic and only really works for cases
like \(diff-merge-strings \"b/foo\" \"b/bar\" \"/a/c/foo\")."
  ;; Ideally, we want:
  ;;   AMB ANB CMD -> CND
  ;; but that's ambiguous if `foo' or `bar' is empty:
  ;; a/foo a/foo1 b/foo.c -> b/foo1.c but not 1b/foo.c or b/foo.c1
846
  (let ((str (concat ancestor "\n" from "\n" to)))
847
    (when (and (string-match (concat
848 849
			      "\\`\\(.*?\\)\\(.*\\)\\(.*\\)\n"
			      "\\1\\(.*\\)\\3\n"
850 851 852 853 854 855
			      "\\(.*\\(\\2\\).*\\)\\'") str)
	       (equal to (match-string 5 str)))
      (concat (substring str (match-beginning 5) (match-beginning 6))
	      (match-string 4 str)
	      (substring str (match-end 6) (match-end 5))))))

856 857 858 859 860 861 862 863
(defun diff-tell-file-name (old name)
  "Tell Emacs where the find the source file of the current hunk.
If the OLD prefix arg is passed, tell the file NAME of the old file."
  (interactive
   (let* ((old current-prefix-arg)
	  (fs (diff-hunk-file-names current-prefix-arg)))
     (unless fs (error "No file name to look for"))
     (list old (read-file-name (format "File for %s: " (car fs))
864
			       nil (diff-find-file-name old 'noprompt) t))))
865 866 867
  (let ((fs (diff-hunk-file-names old)))
    (unless fs (error "No file name to look for"))
    (push (cons fs name) diff-remembered-files-alist)))
868

869 870
(defun diff-hunk-file-names (&optional old)
  "Give the list of file names textually mentioned for the current hunk."
871 872 873 874
  (save-excursion
    (unless (looking-at diff-file-header-re)
      (or (ignore-errors (diff-beginning-of-file))
	  (re-search-forward diff-file-header-re nil t)))
875
    (let ((limit (save-excursion
876
		   (condition-case ()
877
		       (progn (diff-hunk-prev) (point))
878
		     (error (point-min)))))
879
	  (header-files
880
           ;; handle filenames with spaces;
881
           ;; cf. diff-font-lock-keywords / diff-file-header
882
	   (if (looking-at "[-*][-*][-*] \\([^\t\n]+\\).*\n[-+][-+][-+] \\([^\t\n]+\\)")
883 884
	       (list (if old (match-string 1) (match-string 2))
		     (if old (match-string 2) (match-string 1)))
885 886 887 888 889 890 891 892
	     (forward-line 1) nil)))
      (delq nil
	    (append
	     (when (and (not old)
			(save-excursion
			  (re-search-backward "^Index: \\(.+\\)" limit t)))
	       (list (match-string 1)))
	     header-files
893
             ;; this assumes that there are no spaces in filenames
894 895 896 897 898 899
	     (when (re-search-backward
		    "^diff \\(-\\S-+ +\\)*\\(\\S-+\\)\\( +\\(\\S-+\\)\\)?"
		    nil t)
	       (list (if old (match-string 2) (match-string 4))
		     (if old (match-string 4) (match-string 2)))))))))

900
(defun diff-find-file-name (&optional old noprompt prefix)
901
  "Return the file corresponding to the current patch.
902
Non-nil OLD means that we want the old file.
903
Non-nil NOPROMPT means to prefer returning nil than to prompt the user.
904
PREFIX is only used internally: don't use it."
905 906 907 908
  (unless (equal diff-remembered-defdir default-directory)
    ;; Flush diff-remembered-files-alist if the default-directory is changed.
    (set (make-local-variable 'diff-remembered-defdir) default-directory)
    (set (make-local-variable 'diff-remembered-files-alist) nil))
909
  (save-excursion
910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925
    (save-restriction
      (widen)
      (unless (looking-at diff-file-header-re)
        (or (ignore-errors (diff-beginning-of-file))
	    (re-search-forward diff-file-header-re nil t)))
      (let ((fs (diff-hunk-file-names old)))
        (if prefix (setq fs (mapcar (lambda (f) (concat prefix f)) fs)))
        (or
         ;; use any previously used preference
         (cdr (assoc fs diff-remembered-files-alist))
         ;; try to be clever and use previous choices as an inspiration
         (cl-dolist (rf diff-remembered-files-alist)
	   (let ((newfile (diff-merge-strings (caar rf) (car fs) (cdr rf))))
	     (if (and newfile (file-exists-p newfile)) (cl-return newfile))))
         ;; look for each file in turn.  If none found, try again but
         ;; ignoring the first level of directory, ...
926
         (cl-do* ((files fs (delq nil (mapcar #'diff-filename-drop-dir files)))
927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956
                  (file nil nil))
	     ((or (null files)
		  (setq file (cl-do* ((files files (cdr files))
                                      (file (car files) (car files)))
			         ;; Use file-regular-p to avoid
			         ;; /dev/null, directories, etc.
			         ((or (null file) (file-regular-p file))
				  file))))
	      file))
         ;; <foo>.rej patches implicitly apply to <foo>
         (and (string-match "\\.rej\\'" (or buffer-file-name ""))
	      (let ((file (substring buffer-file-name 0 (match-beginning 0))))
	        (when (file-exists-p file) file)))
         ;; If we haven't found the file, maybe it's because we haven't paid
         ;; attention to the PCL-CVS hint.
         (and (not prefix)
	      (boundp 'cvs-pcl-cvs-dirchange-re)
	      (save-excursion
	        (re-search-backward cvs-pcl-cvs-dirchange-re nil t))
	      (diff-find-file-name old noprompt (match-string 1)))
         ;; if all else fails, ask the user
         (unless noprompt
           (let ((file (expand-file-name (or (car fs) ""))))
	     (setq file
		   (read-file-name (format "Use file %s: " file)
				   (file-name-directory file) file t
				   (file-name-nondirectory file)))
             (set (make-local-variable 'diff-remembered-files-alist)
                  (cons (cons fs file) diff-remembered-files-alist))
             file)))))))
957

958

959 960 961
(defun diff-ediff-patch ()
  "Call `ediff-patch-file' on the current buffer."
  (interactive)
962
  (condition-case nil
963
      (ediff-patch-file nil (current-buffer))
964 965
    (wrong-number-of-arguments (ediff-patch-file))))

966
;;;;
967
;;;; Conversion functions
968
;;;;
969 970 971 972 973 974 975

;;(defvar diff-inhibit-after-change nil
;;  "Non-nil means inhibit `diff-mode's after-change functions.")

(defun diff-unified->context (start end)
  "Convert unified diffs to context diffs.
START and END are either taken from the region (if a prefix arg is given) or
976
else cover the whole buffer."
977
  (interactive (if (or current-prefix-arg (use-region-p))
978
		   (list (region-beginning) (region-end))
979
		 (list (point-min) (point-max))))
Stefan Monnier's avatar