vc-bzr.el 38.5 KB
Newer Older
Stefan Monnier's avatar
Stefan Monnier committed
1 2
;;; vc-bzr.el --- VC backend for the bzr revision control system

Glenn Morris's avatar
Glenn Morris committed
3
;; Copyright (C) 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
Stefan Monnier's avatar
Stefan Monnier committed
4

5 6
;; Author: Dave Love <fx@gnu.org>
;; 	   Riccardo Murri <riccardo.murri@gmail.com>
Stefan Monnier's avatar
Stefan Monnier committed
7 8
;; Keywords: tools
;; Created: Sept 2006
9
;; Version: 2008-01-04 (Bzr revno 25)
Stefan Monnier's avatar
Stefan Monnier committed
10 11
;; URL: http://launchpad.net/vc-bzr

12 13 14
;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
Stefan Monnier's avatar
Stefan Monnier committed
15
;; it under the terms of the GNU General Public License as published by
16 17
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Stefan Monnier's avatar
Stefan Monnier committed
18

19
;; GNU Emacs is distributed in the hope that it will be useful,
Stefan Monnier's avatar
Stefan Monnier committed
20 21 22 23 24
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
25
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
Stefan Monnier's avatar
Stefan Monnier committed
26 27 28

;;; Commentary:

29 30 31
;; See <URL:http://bazaar-vcs.org/> concerning bzr.  See
;; <URL:http://launchpad.net/vc-bzr> for alternate development
;; branches of `vc-bzr'.
Stefan Monnier's avatar
Stefan Monnier committed
32

33
;; Load this library to register bzr support in VC.
34 35 36 37 38 39 40

;; Known bugs
;; ==========

;; When edititing a symlink and *both* the symlink and its target
;; are bzr-versioned, `vc-bzr` presently runs `bzr status` on the
;; symlink, thereby not detecting whether the actual contents
41
;; (that is, the target contents) are changed.
42 43 44 45
;; See https://bugs.launchpad.net/vc-bzr/+bug/116607

;; For an up-to-date list of bugs, please see:
;;   https://bugs.launchpad.net/vc-bzr/+bugs
Stefan Monnier's avatar
Stefan Monnier committed
46

47 48 49 50
;;; Properties of the backend

(defun vc-bzr-revision-granularity () 'repository)
(defun vc-bzr-checkout-model (files) 'implicit)
Stefan Monnier's avatar
Stefan Monnier committed
51 52 53 54

;;; Code:

(eval-when-compile
55
  (require 'cl)
56 57
  (require 'vc)  ;; for vc-exec-after
  (require 'vc-dir))
Stefan Monnier's avatar
Stefan Monnier committed
58

59 60
;; Clear up the cache to force vc-call to check again and discover
;; new functions when we reload this file.
61
(put 'Bzr 'vc-functions nil)
62

Stefan Monnier's avatar
Stefan Monnier committed
63 64
(defgroup vc-bzr nil
  "VC bzr backend."
65
  :version "22.2"
Stefan Monnier's avatar
Stefan Monnier committed
66 67 68
  :group 'vc)

(defcustom vc-bzr-program "bzr"
69
  "Name of the bzr command (excluding any arguments)."
Stefan Monnier's avatar
Stefan Monnier committed
70 71 72 73
  :group 'vc-bzr
  :type 'string)

(defcustom vc-bzr-diff-switches nil
74 75 76 77
  "String or list of strings specifying switches for bzr diff under VC.
If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  :type '(choice (const :tag "Unspecified" nil)
                 (const :tag "None" t)
Stefan Monnier's avatar
Stefan Monnier committed
78 79 80 81
                 (string :tag "Argument String")
                 (repeat :tag "Argument List" :value ("") string))
  :group 'vc-bzr)

82
(defcustom vc-bzr-log-switches nil
83
  "String or list of strings specifying switches for bzr log under VC."
84 85 86 87 88
  :type '(choice (const :tag "None" nil)
                 (string :tag "Argument String")
                 (repeat :tag "Argument List" :value ("") string))
  :group 'vc-bzr)

89 90
;; since v0.9, bzr supports removing the progress indicators
;; by setting environment variable BZR_PROGRESS_BAR to "none".
91
(defun vc-bzr-command (bzr-command buffer okstatus file-or-list &rest args)
92
  "Wrapper round `vc-do-command' using `vc-bzr-program' as COMMAND.
93 94
Invoke the bzr command adding `BZR_PROGRESS_BAR=none' and
`LC_MESSAGES=C' to the environment."
95 96
  (let ((process-environment
         (list* "BZR_PROGRESS_BAR=none" ; Suppress progress output (bzr >=0.9)
97
                "LC_MESSAGES=C"         ; Force English output
98
                process-environment)))
99
    (apply 'vc-do-command (or buffer "*vc*") okstatus vc-bzr-program
100
           file-or-list bzr-command args)))
Stefan Monnier's avatar
Stefan Monnier committed
101

102 103

;;;###autoload
104
(defconst vc-bzr-admin-dirname ".bzr"
105
  "Name of the directory containing Bzr repository status files.")
106
;;;###autoload
107 108
(defconst vc-bzr-admin-checkout-format-file
  (concat vc-bzr-admin-dirname "/checkout/format"))
109
(defconst vc-bzr-admin-dirstate
110 111 112
  (concat vc-bzr-admin-dirname "/checkout/dirstate"))
(defconst vc-bzr-admin-branch-format-file
  (concat vc-bzr-admin-dirname "/branch/format"))
113
(defconst vc-bzr-admin-revhistory
114
  (concat vc-bzr-admin-dirname "/branch/revision-history"))
115 116
(defconst vc-bzr-admin-lastrev
  (concat vc-bzr-admin-dirname "/branch/last-revision"))
117 118

;;;###autoload (defun vc-bzr-registered (file)
119
;;;###autoload   (if (vc-find-root file vc-bzr-admin-checkout-format-file)
120 121 122
;;;###autoload       (progn
;;;###autoload         (load "vc-bzr")
;;;###autoload         (vc-bzr-registered file))))
Stefan Monnier's avatar
Stefan Monnier committed
123

124 125 126 127
(defun vc-bzr-root (file)
  "Return the root directory of the bzr repository containing FILE."
  ;; Cache technique copied from vc-arch.el.
  (or (vc-file-getprop file 'bzr-root)
128 129
      (let ((root (vc-find-root file vc-bzr-admin-checkout-format-file)))
	(when root (vc-file-setprop file 'bzr-root root)))))
Stefan Monnier's avatar
Stefan Monnier committed
130

Stefan Monnier's avatar
Stefan Monnier committed
131
(require 'sha1)                         ;For sha1-program
132

Stefan Monnier's avatar
Stefan Monnier committed
133 134 135 136
(defun vc-bzr-sha1 (file)
  (with-temp-buffer
    (set-buffer-multibyte nil)
    (let ((prog sha1-program)
137 138
          (args nil)
	  process-file-side-effects)
Stefan Monnier's avatar
Stefan Monnier committed
139 140 141
      (when (consp prog)
	(setq args (cdr prog))
        (setq prog (car prog)))
142
      (apply 'process-file prog (file-relative-name file) t nil args)
Stefan Monnier's avatar
Stefan Monnier committed
143 144 145 146
      (buffer-substring (point-min) (+ (point-min) 40)))))

(defun vc-bzr-state-heuristic (file)
  "Like `vc-bzr-state' but hopefully without running Bzr."
147
  ;; `bzr status' was excrutiatingly slow with large histories and
Stefan Monnier's avatar
Stefan Monnier committed
148 149 150 151 152 153 154 155 156
  ;; pending merges, so try to avoid using it until they fix their
  ;; performance problems.
  ;; This function tries first to parse Bzr internal file
  ;; `checkout/dirstate', but it may fail if Bzr internal file format
  ;; has changed.  As a safeguard, the `checkout/dirstate' file is
  ;; only parsed if it contains the string `#bazaar dirstate flat
  ;; format 3' in the first line.
  ;; If the `checkout/dirstate' file cannot be parsed, fall back to
  ;; running `vc-bzr-state'."
157 158 159 160 161
  (lexical-let ((root (vc-bzr-root file)))
    (when root    ; Short cut.
      ;; This looks at internal files.  May break if they change
      ;; their format.
      (lexical-let ((dirstate (expand-file-name vc-bzr-admin-dirstate root)))
162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178
        (condition-case nil
            (with-temp-buffer
              (insert-file-contents dirstate)
              (goto-char (point-min))
              (if (not (looking-at "#bazaar dirstate flat format 3"))
                  (vc-bzr-state file)   ; Some other unknown format?
                (let* ((relfile (file-relative-name file root))
                       (reldir (file-name-directory relfile)))
                  (if (re-search-forward
                       (concat "^\0"
                               (if reldir (regexp-quote
                                           (directory-file-name reldir)))
                               "\0"
                               (regexp-quote (file-name-nondirectory relfile))
                               "\0"
                               "[^\0]*\0"     ;id?
                               "\\([^\0]*\\)\0" ;"a/f/d", a=removed?
179 180
                               "\\([^\0]*\\)\0" ;sha1 (empty if conflicted)?
                               "\\([^\0]*\\)\0" ;size?p
181 182 183 184
                               "[^\0]*\0"       ;"y/n", executable?
                               "[^\0]*\0"       ;?
                               "\\([^\0]*\\)\0" ;"a/f/d" a=added?
                               "\\([^\0]*\\)\0" ;sha1 again?
185
                               "\\([^\0]*\\)\0" ;size again?
186 187 188 189 190 191 192 193 194 195 196
                               "[^\0]*\0" ;"y/n", executable again?
                               "[^\0]*\0" ;last revid?
                               ;; There are more fields when merges are pending.
                               )
                       nil t)
                      ;; Apparently the second sha1 is the one we want: when
                      ;; there's a conflict, the first sha1 is absent (and the
                      ;; first size seems to correspond to the file with
                      ;; conflict markers).
                      (cond
                       ((eq (char-after (match-beginning 1)) ?a) 'removed)
197 198
                       ((eq (char-after (match-beginning 4)) ?a) 'added)
                       ((or (and (eq (string-to-number (match-string 3))
199
                                 (nth 7 (file-attributes file)))
200
                             (equal (match-string 5)
201
                                    (vc-bzr-sha1 file)))
202 203 204 205 206 207 208 209 210
			    (and
			     ;; It looks like for lightweight
			     ;; checkouts \2 is empty and we need to
			     ;; look for size in \6.
			     (eq (match-beginning 2) (match-end 2))
			     (eq (string-to-number (match-string 6))
				 (nth 7 (file-attributes file)))
			     (equal (match-string 5)
				    (vc-bzr-sha1 file))))
211 212 213 214 215 216 217 218 219
                        'up-to-date)
                       (t 'edited))
                    'unregistered))))
          ;; Either the dirstate file can't be read, or the sha1
          ;; executable is missing, or ...
          ;; In either case, recent versions of Bzr aren't that slow
          ;; any more.
          (error (vc-bzr-state file)))))))

Stefan Monnier's avatar
Stefan Monnier committed
220 221 222 223 224

(defun vc-bzr-registered (file)
  "Return non-nil if FILE is registered with bzr."
  (let ((state (vc-bzr-state-heuristic file)))
    (not (memq state '(nil unregistered ignored)))))
225 226

(defconst vc-bzr-state-words
227
  "added\\|ignored\\|kind changed\\|modified\\|removed\\|renamed\\|unknown"
228 229
  "Regexp matching file status words as reported in `bzr' output.")

230 231 232 233
(defun vc-bzr-file-name-relative (filename)
  "Return file name FILENAME stripped of the initial Bzr repository path."
  (lexical-let*
      ((filename* (expand-file-name filename))
234
       (rootdir (vc-bzr-root filename*)))
235
    (when rootdir
236 237
         (file-relative-name filename* rootdir))))

238 239 240
(defun vc-bzr-status (file)
  "Return FILE status according to Bzr.
Return value is a cons (STATUS . WARNING), where WARNING is a
241 242
string or nil, and STATUS is one of the symbols: `added',
`ignored', `kindchanged', `modified', `removed', `renamed', `unknown',
243 244 245 246 247 248
which directly correspond to `bzr status' output, or 'unchanged
for files whose copy in the working tree is identical to the one
in the branch repository, or nil for files that are not
registered with Bzr.

If any error occurred in running `bzr status', then return nil."
249
  (with-temp-buffer
250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265
    (let ((ret (condition-case nil
                   (vc-bzr-command "status" t 0 file)
                 (file-error nil)))     ; vc-bzr-program not found.
          (status 'unchanged))
          ;; the only secure status indication in `bzr status' output
          ;; is a couple of lines following the pattern::
          ;;   | <status>:
          ;;   |   <file name>
          ;; if the file is up-to-date, we get no status report from `bzr',
          ;; so if the regexp search for the above pattern fails, we consider
          ;; the file to be up-to-date.
          (goto-char (point-min))
          (when (re-search-forward
                 ;; bzr prints paths relative to the repository root.
                 (concat "^\\(" vc-bzr-state-words "\\):[ \t\n]+"
                         (regexp-quote (vc-bzr-file-name-relative file))
266 267 268
                         ;; Bzr appends a '/' to directory names and
                         ;; '*' to executable files
                         (if (file-directory-p file) "/?" "\\*?")
269 270
                         "[ \t\n]*$")
                 nil t)
271
            (lexical-let ((statusword (match-string 1)))
272 273
              ;; Erase the status text that matched.
              (delete-region (match-beginning 0) (match-end 0))
274
              (setq status
275
                    (intern (replace-regexp-in-string " " "" statusword)))))
276 277 278 279 280 281 282 283 284 285 286 287
          (when status
            (goto-char (point-min))
            (skip-chars-forward " \n\t") ;Throw away spaces.
            (cons status
                  ;; "bzr" will output warnings and informational messages to
                  ;; stderr; due to Emacs' `vc-do-command' (and, it seems,
                  ;; `start-process' itself) limitations, we cannot catch stderr
                  ;; and stdout into different buffers.  So, if there's anything
                  ;; left in the buffer after removing the above status
                  ;; keywords, let us just presume that any other message from
                  ;; "bzr" is a user warning, and display it.
                  (unless (eobp) (buffer-substring (point) (point-max))))))))
288

289 290 291
(defun vc-bzr-state (file)
  (lexical-let ((result (vc-bzr-status file)))
    (when (consp result)
292 293
      (when (cdr result)
	(message "Warnings in `bzr' output: %s" (cdr result)))
294
      (cdr (assq (car result)
Dan Nicolaescu's avatar
Dan Nicolaescu committed
295
                 '((added . added)
296
                   (kindchanged . edited)
297 298
                   (renamed . edited)
                   (modified . edited)
299
                   (removed . removed)
300
                   (ignored . ignored)
301
                   (unknown . unregistered)
302
                   (unchanged . up-to-date)))))))
Stefan Monnier's avatar
Stefan Monnier committed
303

304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330
(defun vc-bzr-resolve-when-done ()
  "Call \"bzr resolve\" if the conflict markers have been removed."
  (save-excursion
    (goto-char (point-min))
    (unless (re-search-forward "^<<<<<<< " nil t)
      (vc-bzr-command "resolve" nil 0 buffer-file-name)
      ;; Remove the hook so that it is not called multiple times.
      (remove-hook 'after-save-hook 'vc-bzr-resolve-when-done t))))

(defun vc-bzr-find-file-hook ()
  (when (and buffer-file-name
             ;; FIXME: We should check that "bzr status" says "conflict".
             (file-exists-p (concat buffer-file-name ".BASE"))
             (file-exists-p (concat buffer-file-name ".OTHER"))
             (file-exists-p (concat buffer-file-name ".THIS"))
             ;; If "bzr status" says there's a conflict but there are no
             ;; conflict markers, it's not clear what we should do.
             (save-excursion
               (goto-char (point-min))
               (re-search-forward "^<<<<<<< " nil t)))
    ;; TODO: the merge algorithm used in `bzr merge' is nicely configurable,
    ;; but the one in `bzr pull' isn't, so it would be good to provide an
    ;; elisp function to remerge from the .BASE/OTHER/THIS files.
    (smerge-start-session)
    (add-hook 'after-save-hook 'vc-bzr-resolve-when-done nil t)
    (message "There are unresolved conflicts in this file")))

Stefan Monnier's avatar
Stefan Monnier committed
331
(defun vc-bzr-workfile-unchanged-p (file)
332
  (eq 'unchanged (car (vc-bzr-status file))))
Stefan Monnier's avatar
Stefan Monnier committed
333

Eric S. Raymond's avatar
Eric S. Raymond committed
334
(defun vc-bzr-working-revision (file)
Stefan Monnier's avatar
Stefan Monnier committed
335 336
  ;; Together with the code in vc-state-heuristic, this makes it possible
  ;; to get the initial VC state of a Bzr file even if Bzr is not installed.
337 338
  (lexical-let*
      ((rootdir (vc-bzr-root file))
339 340 341 342 343 344
       (branch-format-file (expand-file-name vc-bzr-admin-branch-format-file
                                             rootdir))
       (revhistory-file (expand-file-name vc-bzr-admin-revhistory rootdir))
       (lastrev-file (expand-file-name vc-bzr-admin-lastrev rootdir)))
    ;; This looks at internal files to avoid forking a bzr process.
    ;; May break if they change their format.
345 346 347 348 349 350 351 352 353 354 355 356 357 358
    (if (and (file-exists-p branch-format-file)
	     ;; For lightweight checkouts (obtained with bzr checkout --lightweight)
	     ;; the branch-format-file does not contain the revision
	     ;; information, we need to look up the branch-format-file
	     ;; in the place where the lightweight checkout comes
	     ;; from.  We only do that if it's a local file.
	     (let ((location-fname (expand-file-name
				    (concat vc-bzr-admin-dirname
					    "/branch/location") rootdir)))
	       ;; The existence of this file is how we distinguish
	       ;; lightweight checkouts.
	       (if (file-exists-p location-fname)
		   (with-temp-buffer
		     (insert-file-contents location-fname)
359 360 361 362 363 364 365 366 367 368 369 370 371
		     ;; If the lightweight checkout points to a
		     ;; location in the local file system, then we can
		     ;; look there for the version information.
		     (when (re-search-forward "file://\\(.+\\)" nil t)
		       (let ((l-c-parent-dir (match-string 1)))
			 (setq branch-format-file
			       (expand-file-name vc-bzr-admin-branch-format-file
						 l-c-parent-dir))
			 (setq lastrev-file
			       (expand-file-name vc-bzr-admin-lastrev l-c-parent-dir))
			 ;; FIXME: maybe it's overkill to check if both these files exist.
			 (and (file-exists-p branch-format-file)
			      (file-exists-p lastrev-file)))))
372
		 t)))
373
        (with-temp-buffer
374
          (insert-file-contents branch-format-file)
375 376 377 378 379 380
          (goto-char (point-min))
          (cond
           ((or
             (looking-at "Bazaar-NG branch, format 0.0.4")
             (looking-at "Bazaar-NG branch format 5"))
            ;; count lines in .bzr/branch/revision-history
381
            (insert-file-contents revhistory-file)
382
            (number-to-string (count-lines (line-end-position) (point-max))))
383 384 385
           ((or
	     (looking-at "Bazaar Branch Format 6 (bzr 0.15)")
	     (looking-at "Bazaar Branch Format 7 (needs bzr 1.6)"))
386
            ;; revno is the first number in .bzr/branch/last-revision
387
            (insert-file-contents lastrev-file)
388 389
            (when (re-search-forward "[0-9]+" nil t)
	      (buffer-substring (match-beginning 0) (match-end 0))))))
390
      ;; fallback to calling "bzr revno"
391
      (lexical-let*
392
          ((result (vc-bzr-command-discarding-stderr
393
                    vc-bzr-program "revno" (file-relative-name file)))
394 395 396 397 398
           (exitcode (car result))
           (output (cdr result)))
        (cond
         ((eq exitcode 0) (substring output 0 -1))
         (t nil))))))
Stefan Monnier's avatar
Stefan Monnier committed
399

400
(defun vc-bzr-create-repo ()
401
  "Create a new Bzr repository."
402 403
  (vc-bzr-command "init" nil 0 nil))

404
(defun vc-bzr-init-revision (&optional file)
405 406 407
  "Always return nil, as Bzr cannot register explicit versions."
  nil)

408 409 410 411 412 413 414 415 416 417
(defun vc-bzr-previous-revision (file rev)
  (if (string-match "\\`[0-9]+\\'" rev)
      (number-to-string (1- (string-to-number rev)))
    (concat "before:" rev)))

(defun vc-bzr-next-revision (file rev)
  (if (string-match "\\`[0-9]+\\'" rev)
      (number-to-string (1+ (string-to-number rev)))
    (error "Don't know how to compute the next revision of %s" rev)))

418
(defun vc-bzr-register (files &optional rev comment)
Stefan Monnier's avatar
Stefan Monnier committed
419 420 421
  "Register FILE under bzr.
Signal an error unless REV is nil.
COMMENT is ignored."
422
  (if rev (error "Can't register explicit revision with bzr"))
423
  (vc-bzr-command "add" nil 0 files))
Stefan Monnier's avatar
Stefan Monnier committed
424 425 426

;; Could run `bzr status' in the directory and see if it succeeds, but
;; that's relatively expensive.
427
(defalias 'vc-bzr-responsible-p 'vc-bzr-root
Stefan Monnier's avatar
Stefan Monnier committed
428 429
  "Return non-nil if FILE is (potentially) controlled by bzr.
The criterion is that there is a `.bzr' directory in the same
430
or a superior directory.")
Stefan Monnier's avatar
Stefan Monnier committed
431 432 433 434 435 436 437 438 439

(defun vc-bzr-could-register (file)
  "Return non-nil if FILE could be registered under bzr."
  (and (vc-bzr-responsible-p file)      ; shortcut
       (condition-case ()
           (with-temp-buffer
             (vc-bzr-command "add" t 0 file "--dry-run")
             ;; The command succeeds with no output if file is
             ;; registered (in bzr 0.8).
440
             (goto-char (point-min))
Stefan Monnier's avatar
Stefan Monnier committed
441 442 443 444 445
             (looking-at "added "))
         (error))))

(defun vc-bzr-unregister (file)
  "Unregister FILE from bzr."
446
  (vc-bzr-command "remove" nil 0 file "--keep"))
Stefan Monnier's avatar
Stefan Monnier committed
447

448
(defun vc-bzr-checkin (files rev comment)
Stefan Monnier's avatar
Stefan Monnier committed
449 450
  "Check FILE in to bzr with log message COMMENT.
REV non-nil gets an error."
451
  (if rev (error "Can't check in a specific revision with bzr"))
452
  (vc-bzr-command "commit" nil 0 files "-m" comment))
Stefan Monnier's avatar
Stefan Monnier committed
453

454 455
(defun vc-bzr-find-revision (file rev buffer)
  "Fetch revision REV of file FILE and put it into BUFFER."
456 457 458 459 460
    (with-current-buffer buffer
      (if (and rev (stringp rev) (not (string= rev "")))
          (vc-bzr-command "cat" t 0 file "-r" rev)
        (vc-bzr-command "cat" t 0 file))))

Stefan Monnier's avatar
Stefan Monnier committed
461 462 463 464
(defun vc-bzr-checkout (file &optional editable rev)
  (if rev (error "Operation not supported")
    ;; Else, there's nothing to do.
    nil))
Stefan Monnier's avatar
Stefan Monnier committed
465 466 467

(defun vc-bzr-revert (file &optional contents-done)
  (unless contents-done
468
    (with-temp-buffer (vc-bzr-command "revert" t 0 file))))
Stefan Monnier's avatar
Stefan Monnier committed
469

470 471 472 473
(defvar log-view-message-re)
(defvar log-view-file-re)
(defvar log-view-font-lock-keywords)
(defvar log-view-current-tag-function)
474
(defvar log-view-per-file-logs)
475
(defvar vc-short-log)
476 477 478

(define-derived-mode vc-bzr-log-view-mode log-view-mode "Bzr-Log-View"
  (remove-hook 'log-view-mode-hook 'vc-bzr-log-view-mode) ;Deactivate the hack.
Stefan Monnier's avatar
Stefan Monnier committed
479
  (require 'add-log)
480
  (set (make-local-variable 'log-view-per-file-logs) nil)
481
  (set (make-local-variable 'log-view-file-re) "\\`a\\`")
482
  (set (make-local-variable 'log-view-message-re)
483
       (if vc-short-log
484
	   "^ *\\([0-9.]+\\) \\(.*?\\)[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)\\( \\[merge\\]\\)?"
485
	 "^ *\\(?:revno: \\([0-9.]+\\)\\|merged: .+\\)"))
Stefan Monnier's avatar
Stefan Monnier committed
486
  (set (make-local-variable 'log-view-font-lock-keywords)
487 488
       ;; log-view-font-lock-keywords is careful to use the buffer-local
       ;; value of log-view-message-re only since Emacs-23.
489 490 491 492 493
       (if vc-short-log
	 (append `((,log-view-message-re
		    (1 'log-view-message-face)
		    (2 'change-log-name)
		    (3 'change-log-date)
494
		    (4 'change-log-list nil lax))))
495 496
	 (append `((,log-view-message-re . 'log-view-message-face))
		 ;; log-view-font-lock-keywords
497
		 '(("^ *\\(?:committer\\|author\\): \
498
\\([^<(]+?\\)[  ]*[(<]\\([[:alnum:]_.+-]+@[[:alnum:]_.-]+\\)[>)]"
499 500 501
		    (1 'change-log-name)
		    (2 'change-log-email))
		   ("^ *timestamp: \\(.*\\)" (1 'change-log-date-face)))))))
Stefan Monnier's avatar
Stefan Monnier committed
502

503
(defun vc-bzr-print-log (files buffer &optional shortlog start-revision limit)
504
  "Get bzr change log for FILES into specified BUFFER."
505 506 507 508 509
  ;; `vc-do-command' creates the buffer, but we need it before running
  ;; the command.
  (vc-setup-buffer buffer)
  ;; If the buffer exists from a previous invocation it might be
  ;; read-only.
Stefan Monnier's avatar
Stefan Monnier committed
510 511 512
  ;; FIXME: `vc-bzr-command' runs `bzr log' with `LC_MESSAGES=C', so
  ;; the log display may not what the user wants - but I see no other
  ;; way of getting the above regexps working.
513 514
  (with-current-buffer buffer
    (apply 'vc-bzr-command "log" buffer 'async files
515 516
	   (append
	    (when shortlog '("--short"))
517
	    (when start-revision (list (format "-r..%s" start-revision)))
518 519 520 521
	    (when limit (list "-l" (format "%s" limit)))
	    (if (stringp vc-bzr-log-switches)
		(list vc-bzr-log-switches)
	      vc-bzr-log-switches)))))
Stefan Monnier's avatar
Stefan Monnier committed
522

523 524
(defun vc-bzr-show-log-entry (revision)
  "Find entry for patch name REVISION in bzr change log buffer."
Stefan Monnier's avatar
Stefan Monnier committed
525
  (goto-char (point-min))
526
  (when revision
527 528
    (let (case-fold-search
	  found)
529 530 531 532 533 534 535
      (if (re-search-forward
	   ;; "revno:" can appear either at the beginning of a line,
	   ;; or indented.
	   (concat "^[ ]*-+\n[ ]*revno: "
		   ;; The revision can contain ".", quote it so that it
		   ;; does not interfere with regexp matching.
		   (regexp-quote revision) "$") nil t)
536 537 538 539 540
	  (progn
	    (beginning-of-line 0)
	    (setq found t))
	(goto-char (point-min)))
      found)))
Stefan Monnier's avatar
Stefan Monnier committed
541

542
(defun vc-bzr-diff (files &optional rev1 rev2 buffer)
Stefan Monnier's avatar
Stefan Monnier committed
543
  "VC bzr backend for diff."
544
  ;; `bzr diff' exits with code 1 if diff is non-empty.
545 546
  (apply #'vc-bzr-command "diff" (or buffer "*vc-diff*")
	 (if vc-disable-async-diff 1 'async) files
547
         "--diff-options" (mapconcat 'identity
548
                                     (vc-switches 'bzr 'diff)
Miles Bader's avatar
Miles Bader committed
549
				     " ")
550 551 552 553
         ;; This `when' is just an optimization because bzr-1.2 is *much*
         ;; faster when the revision argument is not given.
         (when (or rev1 rev2)
           (list "-r" (format "%s..%s"
554
                              (or rev1 "revno:-1")
555
                              (or rev2 ""))))))
Stefan Monnier's avatar
Stefan Monnier committed
556 557


558 559
;; FIXME: vc-{next,previous}-revision need fixing in vc.el to deal with
;; straight integer revisions.
Stefan Monnier's avatar
Stefan Monnier committed
560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575

(defun vc-bzr-delete-file (file)
  "Delete FILE and delete it in the bzr repository."
  (condition-case ()
      (delete-file file)
    (file-error nil))
  (vc-bzr-command "remove" nil 0 file))

(defun vc-bzr-rename-file (old new)
  "Rename file from OLD to NEW using `bzr mv'."
  (vc-bzr-command "mv" nil 0 new old))

(defvar vc-bzr-annotation-table nil
  "Internal use.")
(make-variable-buffer-local 'vc-bzr-annotation-table)

576
(defun vc-bzr-annotate-command (file buffer &optional revision)
Stefan Monnier's avatar
Stefan Monnier committed
577 578 579
  "Prepare BUFFER for `vc-annotate' on FILE.
Each line is tagged with the revision number, which has a `help-echo'
property containing author and date information."
580
  (apply #'vc-bzr-command "annotate" buffer 'async file "--long" "--all"
Dan Nicolaescu's avatar
Dan Nicolaescu committed
581
         (if revision (list "-r" revision)))
582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598
  (lexical-let ((table (make-hash-table :test 'equal)))
    (set-process-filter
     (get-buffer-process buffer)
     (lambda (proc string)
       (when (process-buffer proc)
         (with-current-buffer (process-buffer proc)
           (setq string (concat (process-get proc :vc-left-over) string))
           (while (string-match "^\\( *[0-9.]+ *\\) \\([^\n ]+\\) +\\([0-9]\\{8\\}\\)\\( |.*\n\\)" string)
             (let* ((rev (match-string 1 string))
                    (author (match-string 2 string))
                    (date (match-string 3 string))
                    (key (substring string (match-beginning 0)
                                    (match-beginning 4)))
                    (line (match-string 4 string))
                    (tag (gethash key table))
                    (inhibit-read-only t))
               (setq string (substring string (match-end 0)))
599 600 601
	       (unless tag
		 (setq tag
		       (propertize
602
			(format "%s %-7.7s" rev author)
603 604 605 606
			'help-echo (format "Revision: %d, author: %s, date: %s"
					   (string-to-number rev)
					   author date)
			'mouse-face 'highlight))
607 608 609 610 611
                 (puthash key tag table))
               (goto-char (process-mark proc))
               (insert tag line)
               (move-marker (process-mark proc) (point))))
           (process-put proc :vc-left-over string)))))))
Stefan Monnier's avatar
Stefan Monnier committed
612

613 614
(declare-function vc-annotate-convert-time "vc-annotate" (time))

Stefan Monnier's avatar
Stefan Monnier committed
615
(defun vc-bzr-annotate-time ()
616
  (when (re-search-forward "^ *[0-9.]+ +[^\n ]* +|" nil t)
Dan Nicolaescu's avatar
Dan Nicolaescu committed
617 618
    (let ((prop (get-text-property (line-beginning-position) 'help-echo)))
      (string-match "[0-9]+\\'" prop)
619
      (let ((str (match-string-no-properties 0 prop)))
Stefan Monnier's avatar
Stefan Monnier committed
620 621
      (vc-annotate-convert-time
       (encode-time 0 0 0
622 623 624
                      (string-to-number (substring str 6 8))
                      (string-to-number (substring str 4 6))
                      (string-to-number (substring str 0 4))))))))
Stefan Monnier's avatar
Stefan Monnier committed
625 626 627 628 629 630

(defun vc-bzr-annotate-extract-revision-at-line ()
  "Return revision for current line of annoation buffer, or nil.
Return nil if current line isn't annotated."
  (save-excursion
    (beginning-of-line)
631
    (if (looking-at "^ *\\([0-9.]+\\) +[^\n ]* +|")
Dan Nicolaescu's avatar
Dan Nicolaescu committed
632
        (match-string-no-properties 1))))
Stefan Monnier's avatar
Stefan Monnier committed
633

634 635
(defun vc-bzr-command-discarding-stderr (command &rest args)
  "Execute shell command COMMAND (with ARGS); return its output and exitcode.
636 637 638 639 640
Return value is a cons (EXITCODE . OUTPUT), where EXITCODE is
the (numerical) exit code of the process, and OUTPUT is a string
containing whatever the process sent to its standard output
stream.  Standard error output is discarded."
  (with-temp-buffer
641
    (cons
642
     (apply #'process-file command nil (list (current-buffer) nil) nil args)
643
     (buffer-substring (point-min) (point-max)))))
Stefan Monnier's avatar
Stefan Monnier committed
644

645 646 647 648 649 650
(defstruct (vc-bzr-extra-fileinfo
            (:copier nil)
            (:constructor vc-bzr-create-extra-fileinfo (extra-name))
            (:conc-name vc-bzr-extra-fileinfo->))
  extra-name)         ;; original name for rename targets, new name for

651
(defun vc-bzr-dir-printer (info)
652 653
  "Pretty-printer for the vc-dir-fileinfo structure."
  (let ((extra (vc-dir-fileinfo->extra info)))
654
    (vc-default-dir-printer 'Bzr info)
655 656 657 658 659 660
    (when extra
      (insert (propertize
	       (format "   (renamed from %s)"
		       (vc-bzr-extra-fileinfo->extra-name extra))
	       'face 'font-lock-comment-face)))))

661
;; FIXME: this needs testing, it's probably incomplete.
662
(defun vc-bzr-after-dir-status (update-function relative-dir)
663
  (let ((status-str nil)
664 665 666 667 668 669 670
	(translation '(("+N " . added)
		       ("-D " . removed)
		       (" M " . edited) ;; file text modified
		       ("  *" . edited) ;; execute bit changed
		       (" M*" . edited) ;; text modified + execute bit changed
		       ;; FIXME: what about ignored files?
		       (" D " . missing)
671
                       ;; For conflicts, should we list the .THIS/.BASE/.OTHER?
672 673
		       ("C  " . conflict)
		       ("?  " . unregistered)
674 675 676
		       ("?  " . unregistered)
		       ;; No such state, but we need to distinguish this case.
		       ("R  " . renamed)
677 678 679
		       ;; For a non existent file FOO, the output is:
		       ;; bzr: ERROR: Path(s) do not exist: FOO
		       ("bzr" . not-found)
680 681 682 683 684
		       ;; If the tree is not up to date, bzr will print this warning:
		       ;; working tree is out of date, run 'bzr update'
		       ;; ignore it.
		       ;; FIXME: maybe this warning can be put in the vc-dir header...
		       ("wor" . not-found)
685 686
                       ;; Ignore "P " and "P." for pending patches.
                       ))
687 688 689 690 691
	(translated nil)
	(result nil))
      (goto-char (point-min))
      (while (not (eobp))
	(setq status-str
692
	      (buffer-substring-no-properties (point) (+ (point) 3)))
693
	(setq translated (cdr (assoc status-str translation)))
694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709
	(cond
	 ((eq translated 'conflict)
	  ;; For conflicts the file appears twice in the listing: once
	  ;; with the M flag and once with the C flag, so take care
	  ;; not to add it twice to `result'.  Ugly.
	  (let* ((file
		  (buffer-substring-no-properties
		   ;;For files with conflicts the format is:
		   ;;C   Text conflict in FILENAME
		   ;; Bah.
		   (+ (point) 21) (line-end-position)))
		 (entry (assoc file result)))
	    (when entry
	      (setf (nth 1 entry) 'conflict))))
	 ((eq translated 'renamed)
	  (re-search-forward "R   \\(.*\\) => \\(.*\\)$" (line-end-position) t)
710 711
	  (let ((new-name (file-relative-name (match-string 2) relative-dir))
		(old-name (file-relative-name (match-string 1) relative-dir)))
712 713
	    (push (list new-name 'edited
		      (vc-bzr-create-extra-fileinfo old-name)) result)))
714 715
	 ;; do nothing for non existent files
	 ((eq translated 'not-found))
716
	 (t
717 718 719 720
	  (push (list (file-relative-name
		       (buffer-substring-no-properties
			(+ (point) 4)
			(line-end-position)) relative-dir)
721
		      translated) result)))
722
	(forward-line))
723
      (funcall update-function result)))
724

725
(defun vc-bzr-dir-status (dir update-function)
726
  "Return a list of conses (file . state) for DIR."
727 728
  (vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S")
  (vc-exec-after
729 730 731 732 733 734 735 736 737
   `(vc-bzr-after-dir-status (quote ,update-function)
			     ;; "bzr status" results are relative to
			     ;; the bzr root directory, NOT to the
			     ;; directory "bzr status" was invoked in.
			     ;; Ugh.
			     ;; We pass the relative directory here so
			     ;; that `vc-bzr-after-dir-status' can
			     ;; frob the results accordingly.
			     (file-relative-name ,dir (vc-bzr-root ,dir)))))
738

739 740 741 742
(defun vc-bzr-dir-status-files (dir files default-state update-function)
  "Return a list of conses (file . state) for DIR."
  (apply 'vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S" files)
  (vc-exec-after
743 744
   `(vc-bzr-after-dir-status (quote ,update-function)
			     (file-relative-name ,dir (vc-bzr-root ,dir)))))
745

746 747 748 749 750 751 752 753 754
(defvar vc-bzr-shelve-map
  (let ((map (make-sparse-keymap)))
    ;; Turn off vc-dir marking
    (define-key map [mouse-2] 'ignore)

    (define-key map [down-mouse-3] 'vc-bzr-shelve-menu)
    (define-key map "\C-k" 'vc-bzr-shelve-delete-at-point)
    ;; (define-key map "=" 'vc-bzr-shelve-show-at-point)
    ;; (define-key map "\C-m" 'vc-bzr-shelve-show-at-point)
755
    (define-key map "P" 'vc-bzr-shelve-apply-at-point)
756 757 758 759 760 761 762
    map))

(defvar vc-bzr-shelve-menu-map
  (let ((map (make-sparse-keymap "Bzr Shelve")))
    (define-key map [de]
      '(menu-item "Delete shelf" vc-bzr-shelve-delete-at-point
		  :help "Delete the current shelf"))
763 764 765
    (define-key map [po]
      '(menu-item "Apply and remove shelf (pop)" vc-bzr-shelve-apply-at-point
		  :help "Apply the current shelf and remove it"))
766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781
    ;; (define-key map [sh]
    ;;   '(menu-item "Show shelve" vc-bzr-shelve-show-at-point
    ;; 		  :help "Show the contents of the current shelve"))
    map))

(defvar vc-bzr-extra-menu-map
  (let ((map (make-sparse-keymap)))
    (define-key map [bzr-sh]
      '(menu-item "Shelve..." vc-bzr-shelve
		  :help "Shelve changes"))
    map))

(defun vc-bzr-extra-menu () vc-bzr-extra-menu-map)

(defun vc-bzr-extra-status-menu () vc-bzr-extra-menu-map)

782
(defun vc-bzr-dir-extra-headers (dir)
783 784 785 786
  (let*
      ((str (with-temp-buffer
	      (vc-bzr-command "info" t 0 dir)
	      (buffer-string)))
787 788
       (shelve (vc-bzr-shelve-list))
       (shelve-help-echo "Use M-x vc-bzr-shelve to create shelves")
789 790 791 792 793 794 795
       (light-checkout
	(when (string-match ".+light checkout root: \\(.+\\)$" str)
	  (match-string 1 str)))
       (light-checkout-branch
	(when light-checkout
	  (when (string-match ".+checkout of branch: \\(.+\\)$" str)
	    (match-string 1 str)))))
796
    (concat
797 798
     (propertize "Parent branch      : " 'face 'font-lock-type-face)
     (propertize
799
      (if (string-match "parent branch: \\(.+\\)$" str)
800 801 802 803 804 805 806 807 808 809 810 811 812
 	  (match-string 1 str)
 	"None")
       'face 'font-lock-variable-name-face)
     "\n"
      (when light-checkout
	(concat
	 (propertize "Light checkout root: " 'face 'font-lock-type-face)
	 (propertize light-checkout 'face 'font-lock-variable-name-face)
	 "\n"))
      (when light-checkout-branch
	(concat
	 (propertize "Checkout of branch : " 'face 'font-lock-type-face)
	 (propertize light-checkout-branch 'face 'font-lock-variable-name-face)
813
	 "\n"))
814 815 816 817 818 819 820 821 822
     (if shelve
	 (concat
	  (propertize "Shelves            :\n" 'face 'font-lock-type-face
		      'help-echo shelve-help-echo)
	  (mapconcat
	   (lambda (x)
	     (propertize x
			 'face 'font-lock-variable-name-face
			 'mouse-face 'highlight
823
			 'help-echo "mouse-3: Show shelve menu\nP: Apply and remove shelf (pop)\nC-k: Delete shelf"
824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852
			 'keymap vc-bzr-shelve-map))
	   shelve "\n"))
       (concat
	(propertize "Shelves            : " 'face 'font-lock-type-face
		    'help-echo shelve-help-echo)
	(propertize "No shelved changes"
		    'help-echo shelve-help-echo
		    'face 'font-lock-variable-name-face))))))

(defun vc-bzr-shelve (name)
  "Create a shelve."
  (interactive "sShelf name: ")
  (let ((root (vc-bzr-root default-directory)))
    (when root
      (vc-bzr-command "shelve" nil 0 nil "--all" "-m" name)
      (vc-resynch-buffer root t t))))

;; (defun vc-bzr-shelve-show (name)
;;   "Show the contents of shelve NAME."
;;   (interactive "sShelve name: ")
;;   (vc-setup-buffer "*vc-bzr-shelve*")
;;   ;; FIXME: how can you show the contents of a shelf?
;;   (vc-bzr-command "shelve" "*vc-bzr-shelve*" 'async nil name)
;;   (set-buffer "*vc-bzr-shelve*")
;;   (diff-mode)
;;   (setq buffer-read-only t)
;;   (pop-to-buffer (current-buffer)))

(defun vc-bzr-shelve-apply (name)
853 854
  "Apply shelve NAME and remove it afterwards."
  (interactive "sApply (and remove) shelf: ")
855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892
  (vc-bzr-command "unshelve" "*vc-bzr-shelve*" 0 nil "--apply" name)
  (vc-resynch-buffer (vc-bzr-root default-directory) t t))

(defun vc-bzr-shelve-list ()
  (with-temp-buffer
    (vc-bzr-command "shelve" (current-buffer) 1 nil "--list" "-q")
    (delete
     ""
     (split-string
      (buffer-substring (point-min) (point-max))
      "\n"))))

(defun vc-bzr-shelve-get-at-point (point)
  (save-excursion
    (goto-char point)
    (beginning-of-line)
    (if (looking-at "^ +\\([0-9]+\\):")
	(match-string 1)
      (error "Cannot find shelf at point"))))

(defun vc-bzr-shelve-delete-at-point ()
  (interactive)
  (let ((shelve (vc-bzr-shelve-get-at-point (point))))
    (when (y-or-n-p (format "Remove shelf %s ?" shelve))
      (vc-bzr-command "unshelve" nil 0 nil "--delete-only" shelve)
      (vc-dir-refresh))))

;; (defun vc-bzr-shelve-show-at-point ()
;;   (interactive)
;;   (vc-bzr-shelve-show (vc-bzr-shelve-get-at-point (point))))

(defun vc-bzr-shelve-apply-at-point ()
  (interactive)
  (vc-bzr-shelve-apply (vc-bzr-shelve-get-at-point (point))))

(defun vc-bzr-shelve-menu (e)
  (interactive "e")
  (vc-dir-at-event e (popup-menu vc-bzr-shelve-menu-map e)))
893

894 895
;;; Revision completion

896 897 898 899 900
(eval-and-compile
  (defconst vc-bzr-revision-keywords
    '("revno" "revid" "last" "before"
      "tag" "date" "ancestor" "branch" "submit")))

901 902 903 904 905 906 907
(defun vc-bzr-revision-completion-table (files)
  (lexical-let ((files files))
    ;; What about using `files'?!?  --Stef
    (lambda (string pred action)
      (cond
       ((string-match "\\`\\(ancestor\\|branch\\|\\(revno:\\)?[-0-9]+:\\):"
                      string)
908
        (completion-table-with-context (substring string 0 (match-end 0))
909
                                       'completion-file-name-table
910
                                       (substring string (match-end 0))
911 912
                                       ;; Dropping `pred' for no good reason.
                                       'file-directory-p
913
                                       action))
914
       ((string-match "\\`\\(before\\):" string)
915 916 917 918 919
        (completion-table-with-context (substring string 0 (match-end 0))
                                       (vc-bzr-revision-completion-table files)
                                       (substring string (match-end 0))
                                       pred
                                       action))
920 921 922
       ((string-match "\\`\\(tag\\):" string)
        (let ((prefix (substring string 0 (match-end 0)))
              (tag (substring string (match-end 0)))
923 924
              (table nil)
	      process-file-side-effects)
925 926
          (with-temp-buffer
            ;; "bzr-1.2 tags" is much faster with --show-ids.
927
            (process-file vc-bzr-program nil '(t) nil "tags" "--show-ids")
928 929 930 931 932
            ;; The output is ambiguous, unless we assume that revids do not
            ;; contain spaces.
            (goto-char (point-min))
            (while (re-search-forward "^\\(.*[^ \n]\\) +[^ \n]*$" nil t)
              (push (match-string-no-properties 1) table)))
933
          (completion-table-with-context prefix table tag pred action)))
934

935 936 937 938 939 940 941 942 943 944 945 946
       ((string-match "\\`\\([a-z]+\\):" string)
        ;; no actual completion for the remaining keywords.
        (completion-table-with-context (substring string 0 (match-end 0))
                                       (if (member (match-string 1 string)
                                                   vc-bzr-revision-keywords)
                                           ;; If it's a valid keyword,
                                           ;; use a non-empty table to
                                           ;; indicate it.
                                           '("") nil)
                                       (substring string (match-end 0))
                                       pred
                                       action))
947
       (t
948 949 950
        ;; Could use completion-table-with-terminator, except that it
        ;; currently doesn't work right w.r.t pcm and doesn't give
        ;; the *Completions* output we want.
951 952 953
        (complete-with-action action (eval-when-compile
                                       (mapcar (lambda (s) (concat s ":"))
                                               vc-bzr-revision-keywords))
954 955
                              string pred))))))

Stefan Monnier's avatar
Stefan Monnier committed
956
(eval-after-load "vc"
957
  '(add-to-list 'vc-directory-exclusion-list vc-bzr-admin-dirname t))
Stefan Monnier's avatar
Stefan Monnier committed
958 959 960 961

(provide 'vc-bzr)
;; arch-tag: 8101bad8-4e92-4e7d-85ae-d8e08b4e7c06
;;; vc-bzr.el ends here