macroexp.el 30.1 KB
Newer Older
1
;;; macroexp.el --- Additional macro-expansion support -*- lexical-binding: t -*-
2
;;
Paul Eggert's avatar
Paul Eggert committed
3
;; Copyright (C) 2004-2021 Free Software Foundation, Inc.
4 5 6 7 8 9
;;
;; Author: Miles Bader <miles@gnu.org>
;; Keywords: lisp, compiler, macros

;; This file is part of GNU Emacs.

10
;; GNU Emacs is free software: you can redistribute it and/or modify
11
;; it under the terms of the GNU General Public License as published by
12 13
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
14 15 16 17 18 19 20

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
21
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
22 23 24 25 26 27 28 29 30 31 32 33 34

;;; Commentary:
;;
;; This file contains macro-expansions functions that are not defined in
;; the Lisp core, namely `macroexpand-all', which expands all macros in
;; a form, not just a top-level one.

;;; Code:

;; Bound by the top-level `macroexpand-all', and modified to include any
;; macros defined by `defmacro'.
(defvar macroexpand-all-environment nil)

35
(defun macroexp--cons (car cdr original-cons)
Lars Ingebrigtsen's avatar
Lars Ingebrigtsen committed
36 37
  "Return ORIGINAL-CONS if the car/cdr of it is `eq' to CAR and CDR, respectively.
If not, return (CAR . CDR)."
38 39 40 41 42 43
  (if (and (eq car (car original-cons)) (eq cdr (cdr original-cons)))
      original-cons
    (cons car cdr)))

;; We use this special macro to iteratively process forms and share list
;; structure of the result with the input.  Doing so recursively using
44
;; `macroexp--cons' results in excessively deep recursion for very long
45
;; input forms.
46
(defmacro macroexp--accumulate (var+list &rest body)
47 48 49 50 51
  "Return a list of the results of evaluating BODY for each element of LIST.
Evaluate BODY with VAR bound to each `car' from LIST, in turn.
Return a list of the values of the final form in BODY.
The list structure of the result will share as much with LIST as
possible (for instance, when BODY just returns VAR unchanged, the
52 53 54
result will be eq to LIST).

\(fn (VAR LIST) BODY...)"
55
  (declare (indent 1))
56 57
  (let ((var (car var+list))
	(list (cadr var+list))
58 59 60 61 62 63 64 65
	(shared (make-symbol "shared"))
	(unshared (make-symbol "unshared"))
	(tail (make-symbol "tail"))
	(new-el (make-symbol "new-el")))
    `(let* ((,shared ,list)
	    (,unshared nil)
	    (,tail ,shared)
	    ,var ,new-el)
66
       (while (consp ,tail)
67 68 69 70 71 72 73 74 75 76
	 (setq ,var (car ,tail)
	       ,new-el (progn ,@body))
	 (unless (eq ,var ,new-el)
	   (while (not (eq ,shared ,tail))
	     (push (pop ,shared) ,unshared))
	   (setq ,shared (cdr ,shared))
	   (push ,new-el ,unshared))
	 (setq ,tail (cdr ,tail)))
       (nconc (nreverse ,unshared) ,shared))))

77
(defun macroexp--all-forms (forms &optional skip)
78 79 80
  "Return FORMS with macros expanded.  FORMS is a list of forms.
If SKIP is non-nil, then don't expand that many elements at the start of
FORMS."
81
  (macroexp--accumulate (form forms)
82
    (if (or (null skip) (zerop skip))
83
	(macroexp--expand-all form)
84 85 86
      (setq skip (1- skip))
      form)))

87
(defun macroexp--all-clauses (clauses &optional skip)
88 89 90 91
  "Return CLAUSES with macros expanded.
CLAUSES is a list of lists of forms; any clause that's not a list is ignored.
If SKIP is non-nil, then don't expand that many elements at the start of
each clause."
92
  (macroexp--accumulate (clause clauses)
93
    (if (listp clause)
94
	(macroexp--all-forms clause skip)
95 96
      clause)))

97
(defun macroexp--compiler-macro (handler form)
98
  (condition-case-unless-debug err
99
      (apply handler form (cdr form))
100 101
    (error
     (message "Compiler-macro error for %S: %S" (car form) err)
102
           form)))
103

104
(defun macroexp--funcall-if-compiled (_form)
105 106
  "Pseudo function used internally by macroexp to delay warnings.
The purpose is to delay warnings to bytecomp.el, so they can use things
107
like `byte-compile-warn' to get better file-and-line-number data
108 109
and also to avoid outputting the warning during normal execution."
  nil)
110
(put 'macroexp--funcall-if-compiled 'byte-compile
111
     (lambda (form)
112
       (funcall (eval (cadr form)))
113 114
       (byte-compile-constant nil)))

115
(defun macroexp-compiling-p ()
116 117 118 119 120 121 122
  "Return non-nil if we're macroexpanding for the compiler."
  ;; FIXME: ¡¡Major Ugly Hack!! To determine whether the output of this
  ;; macro-expansion will be processed by the byte-compiler, we check
  ;; circumstantial evidence.
  (member '(declare-function . byte-compile-macroexpand-declare-function)
          macroexpand-all-environment))

123 124 125 126 127 128 129
(defun macroexp-file-name ()
  "Return the name of the file from which the code comes.
Returns nil when we do not know.
A non-nil result is expected to be reliable when called from a macro in order
to find the file in which the macro's call was found, and it should be
reliable as well when used at the top-level of a file.
Other uses risk returning non-nil value that point to the wrong file."
130 131 132 133 134
  ;; `eval-buffer' binds `current-load-list' but not `load-file-name',
  ;; so prefer using it over using `load-file-name'.
  (let ((file (car (last current-load-list))))
    (or (if (stringp file) file)
        (bound-and-true-p byte-compile-current-file))))
135

136
(defvar macroexp--warned (make-hash-table :test #'equal :weakness 'key))
137

138 139 140 141
(defun macroexp--warn-wrap (msg form category)
  (let ((when-compiled (lambda ()
                         (when (byte-compile-warning-enabled-p category)
                           (byte-compile-warn "%s" msg)))))
142 143 144 145 146 147
    `(progn
       (macroexp--funcall-if-compiled ',when-compiled)
       ,form)))

(define-obsolete-function-alias 'macroexp--warn-and-return
  #'macroexp-warn-and-return "28.1")
148
(defun macroexp-warn-and-return (msg form &optional category compile-only)
149
  "Return code equivalent to FORM labeled with warning MSG.
150 151
CATEGORY is the category of the warning, like the categories that
can appear in `byte-compile-warnings'.
152 153
COMPILE-ONLY non-nil means no warning should be emitted if the code
is executed without being compiled first."
154 155 156 157 158 159 160 161 162
  (cond
   ((null msg) form)
   ((macroexp-compiling-p)
    (if (and (consp form) (gethash form macroexp--warned))
        ;; Already wrapped this exp with a warning: avoid inf-looping
        ;; where we keep adding the same warning onto `form' because
        ;; macroexpand-all gets right back to macroexpanding `form'.
        form
      (puthash form form macroexp--warned)
163
      (macroexp--warn-wrap msg form category)))
164 165 166 167 168 169 170 171
   (t
    (unless compile-only
      (message "%sWarning: %s"
               (if (stringp load-file-name)
                   (concat (file-relative-name load-file-name) ": ")
                 "")
               msg))
    form)))
172 173 174 175

(defun macroexp--obsolete-warning (fun obsolescence-data type)
  (let ((instead (car obsolescence-data))
        (asof (nth 2 obsolescence-data)))
176
    (format-message
177
     "`%s' is an obsolete %s%s%s" fun type
178
     (if asof (concat " (as of " asof ")") "")
179
     (cond ((stringp instead) (concat "; " (substitute-command-keys instead)))
180
           (instead (format-message "; use `%s' instead." instead))
181
           (t ".")))))
Glenn Morris's avatar
Glenn Morris committed
182

183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206
(defun macroexpand-1 (form &optional environment)
  "Perform (at most) one step of macroexpansion."
  (cond
   ((consp form)
    (let* ((head (car form))
           (env-expander (assq head environment)))
      (if env-expander
          (if (cdr env-expander)
              (apply (cdr env-expander) (cdr form))
            form)
        (if (not (and (symbolp head) (fboundp head)))
            form
          (let ((def (autoload-do-load (symbol-function head) head 'macro)))
            (cond
             ;; Follow alias, but only for macros, otherwise we may end up
             ;; skipping an important compiler-macro (e.g. cl--block-wrapper).
             ((and (symbolp def) (macrop def)) (cons def (cdr form)))
             ((not (consp def)) form)
             (t
              (if (eq 'macro (car def))
                  (apply (cdr def) (cdr form))
                form))))))))
   (t form)))

207 208
(defun macroexp-macroexpand (form env)
  "Like `macroexpand' but checking obsolescence."
209 210 211
  (let* ((macroexpand-all-environment env)
         (new-form
          (macroexpand form env)))
212 213 214
    (if (and (not (eq form new-form))   ;It was a macro call.
             (car-safe form)
             (symbolp (car form))
215
             (get (car form) 'byte-obsolete-info))
216 217
        (let* ((fun (car form))
               (obsolete (get fun 'byte-obsolete-info)))
218
          (macroexp-warn-and-return
219 220 221 222
           (macroexp--obsolete-warning
            fun obsolete
            (if (symbolp (symbol-function fun))
                "alias" "macro"))
223
           new-form 'obsolete))
224 225
      new-form)))

226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272
(defun macroexp--unfold-lambda (form &optional name)
  ;; In lexical-binding mode, let and functions don't bind vars in the same way
  ;; (let obey special-variable-p, but functions don't).  But luckily, this
  ;; doesn't matter here, because function's behavior is underspecified so it
  ;; can safely be turned into a `let', even though the reverse is not true.
  (or name (setq name "anonymous lambda"))
  (let* ((lambda (car form))
         (values (cdr form))
         (arglist (nth 1 lambda))
         (body (cdr (cdr lambda)))
         optionalp restp
         bindings)
    (if (and (stringp (car body)) (cdr body))
        (setq body (cdr body)))
    (if (and (consp (car body)) (eq 'interactive (car (car body))))
        (setq body (cdr body)))
    ;; FIXME: The checks below do not belong in an optimization phase.
    (while arglist
      (cond ((eq (car arglist) '&optional)
             ;; ok, I'll let this slide because funcall_lambda() does...
             ;; (if optionalp (error "multiple &optional keywords in %s" name))
             (if restp (error "&optional found after &rest in %s" name))
             (if (null (cdr arglist))
                 (error "nothing after &optional in %s" name))
             (setq optionalp t))
            ((eq (car arglist) '&rest)
             ;; ...but it is by no stretch of the imagination a reasonable
             ;; thing that funcall_lambda() allows (&rest x y) and
             ;; (&rest x &optional y) in arglists.
             (if (null (cdr arglist))
                 (error "nothing after &rest in %s" name))
             (if (cdr (cdr arglist))
                 (error "multiple vars after &rest in %s" name))
             (setq restp t))
            (restp
             (setq bindings (cons (list (car arglist)
                                        (and values (cons 'list values)))
                                  bindings)
                   values nil))
            ((and (not optionalp) (null values))
             (setq arglist nil values 'too-few))
            (t
             (setq bindings (cons (list (car arglist) (car values))
                                  bindings)
                   values (cdr values))))
      (setq arglist (cdr arglist)))
    (if values
273
        (macroexp-warn-and-return
274 275 276 277 278 279 280 281 282 283 284 285 286 287 288
         (format (if (eq values 'too-few)
                     "attempt to open-code `%s' with too few arguments"
                   "attempt to open-code `%s' with too many arguments")
                 name)
         form)

      ;; The following leads to infinite recursion when loading a
      ;; file containing `(defsubst f () (f))', and then trying to
      ;; byte-compile that file.
      ;;(setq body (mapcar 'byte-optimize-form body)))

      (if bindings
          `(let ,(nreverse bindings) . ,body)
        (macroexp-progn body)))))

289
(defun macroexp--expand-all (form)
290 291 292
  "Expand all macros in FORM.
This is an internal version of `macroexpand-all'.
Assumes the caller has bound `macroexpand-all-environment'."
293
  (if (eq (car-safe form) 'backquote-list*)
294 295 296 297
      ;; Special-case `backquote-list*', as it is normally a macro that
      ;; generates exceedingly deep expansions from relatively shallow input
      ;; forms.  We just process it `in reverse' -- first we expand all the
      ;; arguments, _then_ we expand the top-level definition.
298
      (macroexpand (macroexp--all-forms form 1)
299 300
		   macroexpand-all-environment)
    ;; Normal form; get its expansion, and then expand arguments.
301
    (setq form (macroexp-macroexpand form macroexpand-all-environment))
302 303
    ;; FIXME: It'd be nice to use `byte-optimize--pcase' here, but when
    ;; I tried it, it broke the bootstrap :-(
304 305
    (pcase form
      (`(cond . ,clauses)
306
       (macroexp--cons 'cond (macroexp--all-clauses clauses) form))
307
      (`(condition-case . ,(or `(,err ,body . ,handlers) pcase--dontcare))
308
       (macroexp--cons
309
        'condition-case
310
        (macroexp--cons err
311 312 313 314
                        (macroexp--cons (macroexp--expand-all body)
                                        (macroexp--all-clauses handlers 1)
                                        (cddr form))
                        (cdr form))
315
        form))
316
      (`(,(or 'defvar 'defconst) . ,_) (macroexp--all-forms form 2))
317
      (`(function ,(and f `(lambda . ,_)))
318
       (macroexp--cons 'function
319 320 321 322
                       (macroexp--cons (macroexp--all-forms f 2)
                                       nil
                                       (cdr form))
                       form))
323
      (`(,(or 'function 'quote) . ,_) form)
324 325
      (`(,(and fun (or 'let 'let*)) . ,(or `(,bindings . ,body)
                                           pcase--dontcare))
326 327 328 329 330 331 332
       (macroexp--cons
        fun
        (macroexp--cons
         (macroexp--all-clauses bindings 1)
         (if (null body)
             (macroexp-unprogn
              (macroexp-warn-and-return
333 334
               (format "Empty %s body" fun)
               nil nil 'compile-only))
335 336 337
           (macroexp--all-forms body))
         (cdr form))
        form))
338 339
      (`(,(and fun `(lambda . ,_)) . ,args)
       ;; Embedded lambda in function position.
340 341 342 343
       ;; If the byte-optimizer is loaded, try to unfold this,
       ;; i.e. rewrite it to (let (<args>) <body>).  We'd do it in the optimizer
       ;; anyway, but doing it here (i.e. earlier) can sometimes avoid the
       ;; creation of a closure, thus resulting in much better code.
344 345
       (let ((newform (macroexp--unfold-lambda form)))
	 (if (eq newform form)
346 347 348 349 350 351
	     ;; Unfolding failed for some reason, avoid infinite recursion.
	     (macroexp--cons (macroexp--all-forms fun 2)
                             (macroexp--all-forms args)
                             form)
	   (macroexp--expand-all newform))))

352
      (`(funcall . ,(or `(,exp . ,args) pcase--dontcare))
353 354 355 356 357 358 359
       (let ((eexp (macroexp--expand-all exp))
             (eargs (macroexp--all-forms args)))
         ;; Rewrite (funcall #'foo bar) to (foo bar), in case `foo'
         ;; has a compiler-macro, or to unfold it.
         (pcase eexp
           (`#',f (macroexp--expand-all `(,f . ,eargs)))
           (_ `(funcall ,eexp . ,eargs)))))
360
      (`(,func . ,_)
361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376
       (let ((handler (function-get func 'compiler-macro))
             (funargs (function-get func 'funarg-positions)))
         ;; Check functions quoted with ' rather than with #'
         (dolist (funarg funargs)
           (let ((arg (nth funarg form)))
             (when (and (eq 'quote (car-safe arg))
                        (eq 'lambda (car-safe (cadr arg))))
               (setcar (nthcdr funarg form)
                       (macroexp-warn-and-return
                        (format "%S quoted with ' rather than with #'"
                                (let ((f (cadr arg)))
                                  (if (symbolp f) f `(lambda ,(nth 1 f) ...))))
                        arg)))))
         ;; Macro expand compiler macros.  This cannot be delayed to
         ;; byte-optimize-form because the output of the compiler-macro can
         ;; use macros.
377 378 379 380
         (if (null handler)
             ;; No compiler macro.  We just expand each argument (for
             ;; setq/setq-default this works alright because the variable names
             ;; are symbols).
381
             (macroexp--all-forms form 1)
382 383
           ;; If the handler is not loaded yet, try (auto)loading the
           ;; function itself, which may in turn load the handler.
384
           (unless (functionp handler)
385
             (with-demoted-errors "macroexp--expand-all: %S"
386
               (autoload-do-load (indirect-function func) func)))
387
           (let ((newform (macroexp--compiler-macro handler form)))
388 389
             (if (eq form newform)
                 ;; The compiler macro did not find anything to do.
390
                 (if (equal form (setq newform (macroexp--all-forms form 1)))
391 392 393
                     form
                   ;; Maybe after processing the args, some new opportunities
                   ;; appeared, so let's try the compiler macro again.
394
                   (setq form (macroexp--compiler-macro handler newform))
395
                   (if (eq newform form)
396
                       newform
397 398
                     (macroexp--expand-all newform)))
               (macroexp--expand-all newform))))))
399

400
      (_ form))))
401

402 403
;; Record which arguments expect functions, so we can warn when those
;; are accidentally quoted with ' rather than with #'
404 405
(dolist (f '( funcall apply mapcar mapatoms mapconcat mapc cl-mapcar maphash
              map-char-table map-keymap map-keymap-internal))
406 407 408 409 410 411 412 413 414
  (put f 'funarg-positions '(1)))
(dolist (f '( add-hook remove-hook advice-remove advice--remove-function
              defalias fset global-set-key run-after-idle-timeout
              set-process-filter set-process-sentinel sort))
  (put f 'funarg-positions '(2)))
(dolist (f '( advice-add define-key
              run-at-time run-with-idle-timer run-with-timer ))
  (put f 'funarg-positions '(3)))

415 416 417 418 419 420 421
;;;###autoload
(defun macroexpand-all (form &optional environment)
  "Return result of expanding macros at all levels in FORM.
If no macros are expanded, FORM is returned unchanged.
The second optional arg ENVIRONMENT specifies an environment of macro
definitions to shadow the loaded ones for use in file byte-compilation."
  (let ((macroexpand-all-environment environment))
422
    (macroexp--expand-all form)))
423

424 425
;;; Handy functions to use in macros.

426 427 428 429 430 431 432 433 434 435
(defun macroexp-parse-body (body)
  "Parse a function BODY into (DECLARATIONS . EXPS)."
  (let ((decls ()))
    (while (and (cdr body)
                (let ((e (car body)))
                  (or (stringp e)
                      (memq (car-safe e)
                            '(:documentation declare interactive cl-declare)))))
      (push (pop body) decls))
    (cons (nreverse decls) body)))
Leo Liu's avatar
Leo Liu committed
436

437
(defun macroexp-progn (exps)
438 439 440
  "Return EXPS (a list of expressions) with `progn' prepended.
If EXPS is a list with a single expression, `progn' is not
prepended, but that expression is returned instead."
441 442
  (if (cdr exps) `(progn ,@exps) (car exps)))

443
(defun macroexp-unprogn (exp)
444 445 446
  "Turn EXP into a list of expressions to execute in sequence.
Never returns an empty list."
  (if (eq (car-safe exp) 'progn) (or (cdr exp) '(nil)) (list exp)))
447

448
(defun macroexp-let* (bindings exp)
Lars Ingebrigtsen's avatar
Lars Ingebrigtsen committed
449
  "Return an expression equivalent to \\=`(let* ,BINDINGS ,EXP)."
450 451 452 453 454 455
  (cond
   ((null bindings) exp)
   ((eq 'let* (car-safe exp)) `(let* (,@bindings ,@(cadr exp)) ,@(cddr exp)))
   (t `(let* ,bindings ,exp))))

(defun macroexp-if (test then else)
456
  "Return an expression equivalent to \\=`(if ,TEST ,THEN ,ELSE)."
457 458
  (cond
   ((eq (car-safe else) 'if)
459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476
    (cond
     ;; Drop this optimization: It's unsafe (it assumes that `test' is
     ;; pure, or at least idempotent), and it's not used even a single
     ;; time while compiling Emacs's sources.
     ;;((equal test (nth 1 else))
     ;; ;; Doing a test a second time: get rid of the redundancy.
     ;; (message "macroexp-if: sharing 'test' %S" test)
     ;; `(if ,test ,then ,@(nthcdr 3 else)))
     ((equal then (nth 2 else))
      ;; (message "macroexp-if: sharing 'then' %S" then)
      `(if (or ,test ,(nth 1 else)) ,then ,@(nthcdr 3 else)))
     ((equal (macroexp-unprogn then) (nthcdr 3 else))
      ;; (message "macroexp-if: sharing 'then' with not %S" then)
      `(if (or ,test (not ,(nth 1 else)))
           ,then ,@(macroexp-unprogn (nth 2 else))))
     (t
      `(cond (,test ,@(macroexp-unprogn then))
             (,(nth 1 else) ,@(macroexp-unprogn (nth 2 else)))
477
             ,@(let ((def (nthcdr 3 else))) (if def `((t ,@def))))))))
478
   ((eq (car-safe else) 'cond)
479
    `(cond (,test ,@(macroexp-unprogn then)) ,@(cdr else)))
480 481
   ;; Invert the test if that lets us reduce the depth of the tree.
   ((memq (car-safe then) '(if cond)) (macroexp-if `(not ,test) else then))
482
   (t `(if ,test ,then ,@(if else (macroexp-unprogn else))))))
483

484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512
(defmacro macroexp-let2 (test sym exp &rest body)
  "Evaluate BODY with SYM bound to an expression for EXP's value.
The intended usage is that BODY generates an expression that
will refer to EXP's value multiple times, but will evaluate
EXP only once.  As BODY generates that expression, it should
use SYM to stand for the value of EXP.

If EXP is a simple, safe expression, then SYM's value is EXP itself.
Otherwise, SYM's value is a symbol which holds the value produced by
evaluating EXP.  The return value incorporates the value of BODY, plus
additional code to evaluate EXP once and save the result so SYM can
refer to it.

If BODY consists of multiple forms, they are all evaluated
but only the last one's value matters.

TEST is a predicate to determine whether EXP qualifies as simple and
safe; if TEST is nil, only constant expressions qualify.

Example:
 (macroexp-let2 nil foo EXP
   \\=`(* ,foo ,foo))
generates an expression that evaluates EXP once,
then returns the square of that value.
You could do this with
  (let ((foovar EXP))
    (* foovar foovar))
but using `macroexp-let2' produces more efficient code in
cases where EXP is a constant."
513
  (declare (indent 3) (debug (sexp sexp form body)))
514 515 516
  (let ((bodysym (make-symbol "body"))
        (expsym (make-symbol "exp")))
    `(let* ((,expsym ,exp)
517 518 519 520 521
            (,sym (if (funcall #',(or test #'macroexp-const-p) ,expsym)
                      ,expsym (make-symbol ,(symbol-name sym))))
            (,bodysym ,(macroexp-progn body)))
       (if (eq ,sym ,expsym) ,bodysym
         (macroexp-let* (list (list ,sym ,expsym))
522 523
                        ,bodysym)))))

Leo Liu's avatar
Leo Liu committed
524
(defmacro macroexp-let2* (test bindings &rest body)
525 526 527 528
  "Multiple binding version of `macroexp-let2'.

BINDINGS is a list of elements of the form (SYM EXP).  Each EXP
can refer to symbols specified earlier in the binding list."
Leo Liu's avatar
Leo Liu committed
529 530
  (declare (indent 2) (debug (sexp (&rest (sexp form)) body)))
  (pcase-exhaustive bindings
531
    ('nil (macroexp-progn body))
Leo Liu's avatar
Leo Liu committed
532 533 534 535
    (`((,var ,exp) . ,tl)
     `(macroexp-let2 ,test ,var ,exp
        (macroexp-let2* ,test ,tl ,@body)))))

536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556
(defun macroexp--maxsize (exp size)
  (cond ((< size 0) size)
        ((symbolp exp) (1- size))
        ((stringp exp) (- size (/ (length exp) 16)))
        ((vectorp exp)
         (dotimes (i (length exp))
           (setq size (macroexp--maxsize (aref exp i) size)))
         (1- size))
        ((consp exp)
         ;; We could try to be more clever with quote&function,
         ;; but it is difficult to do so correctly, and it's not obvious that
         ;; it would be worth the effort.
         (dolist (e exp)
           (setq size (macroexp--maxsize e size)))
         (1- size))
        (t -1)))

(defun macroexp-small-p (exp)
  "Return non-nil if EXP can be considered small."
  (> (macroexp--maxsize exp 10) 0))

557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586
(defsubst macroexp--const-symbol-p (symbol &optional any-value)
  "Non-nil if SYMBOL is constant.
If ANY-VALUE is nil, only return non-nil if the value of the symbol is the
symbol itself."
  (or (memq symbol '(nil t))
      (keywordp symbol)
      (if any-value
	  (or (memq symbol byte-compile-const-variables)
	      ;; FIXME: We should provide a less intrusive way to find out
	      ;; if a variable is "constant".
	      (and (boundp symbol)
		   (condition-case nil
		       (progn (set symbol (symbol-value symbol)) nil)
		     (setting-constant t)))))))

(defun macroexp-const-p (exp)
  "Return non-nil if EXP will always evaluate to the same value."
  (cond ((consp exp) (or (eq (car exp) 'quote)
                         (and (eq (car exp) 'function)
                              (symbolp (cadr exp)))))
        ;; It would sometimes make sense to pass `any-value', but it's not
        ;; always safe since a "constant" variable may not actually always have
        ;; the same value.
        ((symbolp exp) (macroexp--const-symbol-p exp))
        (t t)))

(defun macroexp-copyable-p (exp)
  "Return non-nil if EXP can be copied without extra cost."
  (or (symbolp exp) (macroexp-const-p exp)))

587
(defun macroexp-quote (v)
588
  "Return an expression E such that `(eval E)' is V.
589 590 591 592 593 594 595 596 597 598

E is either V or (quote V) depending on whether V evaluates to
itself or not."
  (if (and (not (consp v))
	   (or (keywordp v)
	       (not (symbolp v))
	       (memq v '(nil t))))
      v
    (list 'quote v)))

599 600 601 602 603 604 605 606 607 608 609 610 611 612
(defun macroexp--fgrep (bindings sexp)
  "Return those of the BINDINGS which might be used in SEXP.
It is used as a poor-man's \"free variables\" test.  It differs from a true
test of free variables in the following ways:
- It does not distinguish variables from functions, so it can be used
  both to detect whether a given variable is used by SEXP and to
  detect whether a given function is used by SEXP.
- It does not actually know ELisp syntax, so it only looks for the presence
  of symbols in SEXP and can't distinguish if those symbols are truly
  references to the given variable (or function).  That can make the result
  include bindings which actually aren't used.
- For the same reason it may cause the result to fail to include bindings
  which will be used if SEXP is not yet fully macro-expanded and the
  use of the binding will only be revealed by macro expansion."
613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641
  (let ((res '())
        ;; Cyclic code should not happen, but code can contain cyclic data :-(
        (seen (make-hash-table :test #'eq))
        (sexpss (list (list sexp))))
    ;; Use a nested while loop to reduce the amount of heap allocations for
    ;; pushes to `sexpss' and the `gethash' overhead.
    (while (and sexpss bindings)
      (let ((sexps (pop sexpss)))
        (unless (gethash sexps seen)
          (puthash sexps t seen) ;; Using `setf' here causes bootstrap problems.
          (if (vectorp sexps) (setq sexps (mapcar #'identity sexps)))
          (let ((tortoise sexps) (skip t))
            (while sexps
              (let ((sexp (if (consp sexps) (pop sexps)
                            (prog1 sexps (setq sexps nil)))))
                (if skip
                    (setq skip nil)
                  (setq tortoise (cdr tortoise))
                  (if (eq tortoise sexps)
                      (setq sexps nil) ;; Found a cycle: we're done!
                    (setq skip t)))
                (cond
                 ((or (consp sexp) (vectorp sexp)) (push sexp sexpss))
                 (t
                  (let ((tmp (assq sexp bindings)))
                    (when tmp
                      (push tmp res)
                      (setq bindings (remove tmp bindings))))))))))))
    res))
642

643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677
;;; Load-time macro-expansion.

;; Because macro-expansion used to be more lazy, eager macro-expansion
;; tends to bump into previously harmless/unnoticeable cyclic-dependencies.
;; So, we have to delay macro-expansion like we used to when we detect
;; such a cycle, and we also want to help coders resolve those cycles (since
;; they can be non-obvious) by providing a usefully trimmed backtrace
;; (hopefully) highlighting the problem.

(defun macroexp--backtrace ()
  "Return the Elisp backtrace, more recent frames first."
  (let ((bt ())
        (i 0))
    (while
        (let ((frame (backtrace-frame i)))
          (when frame
            (push frame bt)
            (setq i (1+ i)))))
    (nreverse bt)))

(defun macroexp--trim-backtrace-frame (frame)
  (pcase frame
    (`(,_ macroexpand (,head . ,_) . ,_) `(macroexpand (,head )))
    (`(,_ internal-macroexpand-for-load (,head ,second . ,_) . ,_)
     (if (or (symbolp second)
             (and (eq 'quote (car-safe second))
                  (symbolp (cadr second))))
         `(macroexpand-all (,head ,second ))
       '(macroexpand-all )))
    (`(,_ load-with-code-conversion ,name . ,_)
     `(load ,(file-name-nondirectory name)))))

(defvar macroexp--pending-eager-loads nil
  "Stack of files currently undergoing eager macro-expansion.")

678 679
(defvar macroexp--debug-eager nil)

680
(defun internal-macroexpand-for-load (form full-p)
681 682 683 684 685 686 687 688 689 690 691 692 693 694
  ;; Called from the eager-macroexpansion in readevalloop.
  (cond
   ;; Don't repeat the same warning for every top-level element.
   ((eq 'skip (car macroexp--pending-eager-loads)) form)
   ;; If we detect a cycle, skip macro-expansion for now, and output a warning
   ;; with a trimmed backtrace.
   ((and load-file-name (member load-file-name macroexp--pending-eager-loads))
    (let* ((bt (delq nil
                     (mapcar #'macroexp--trim-backtrace-frame
                             (macroexp--backtrace))))
           (elem `(load ,(file-name-nondirectory load-file-name)))
           (tail (member elem (cdr (member elem bt)))))
      (if tail (setcdr tail (list ')))
      (if (eq (car-safe (car bt)) 'macroexpand-all) (setq bt (cdr bt)))
695 696 697 698
      (if macroexp--debug-eager
          (debug 'eager-macroexp-cycle)
        (message "Warning: Eager macro-expansion skipped due to cycle:\n  %s"
                 (mapconcat #'prin1-to-string (nreverse bt) " => ")))
699 700 701 702 703 704
      (push 'skip macroexp--pending-eager-loads)
      form))
   (t
    (condition-case err
        (let ((macroexp--pending-eager-loads
               (cons load-file-name macroexp--pending-eager-loads)))
705 706 707
          (if full-p
              (macroexpand-all form)
            (macroexpand form)))
708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728
      (error
       ;; Hopefully this shouldn't happen thanks to the cycle detection,
       ;; but in case it does happen, let's catch the error and give the
       ;; code a chance to macro-expand later.
       (message "Eager macro-expansion failure: %S" err)
       form)))))

;; ¡¡¡ Big Ugly Hack !!!
;; src/bootstrap-emacs is mostly used to compile .el files, so it needs
;; macroexp, bytecomp, cconv, and byte-opt to be fast.  Generally this is done
;; by compiling those files first, but this only makes a difference if those
;; files are not preloaded.  But macroexp.el is preloaded so we reload it if
;; the current version is interpreted and there's a compiled version available.
(eval-when-compile
  (add-hook 'emacs-startup-hook
            (lambda ()
              (and (not (byte-code-function-p
                         (symbol-function 'macroexpand-all)))
                   (locate-library "macroexp.elc")
                   (load "macroexp.elc")))))

729 730 731
(provide 'macroexp)

;;; macroexp.el ends here