macroexp.el 22.7 KB
Newer Older
1
;;; macroexp.el --- Additional macro-expansion support -*- lexical-binding: t -*-
2
;;
Paul Eggert's avatar
Paul Eggert committed
3
;; Copyright (C) 2004-2019 Free Software Foundation, Inc.
4 5 6 7 8 9
;;
;; Author: Miles Bader <miles@gnu.org>
;; Keywords: lisp, compiler, macros

;; This file is part of GNU Emacs.

10
;; GNU Emacs is free software: you can redistribute it and/or modify
11
;; it under the terms of the GNU General Public License as published by
12 13
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
14 15 16 17 18 19 20

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
21
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
22 23 24 25 26 27 28 29 30 31 32 33 34

;;; Commentary:
;;
;; This file contains macro-expansions functions that are not defined in
;; the Lisp core, namely `macroexpand-all', which expands all macros in
;; a form, not just a top-level one.

;;; Code:

;; Bound by the top-level `macroexpand-all', and modified to include any
;; macros defined by `defmacro'.
(defvar macroexpand-all-environment nil)

35
(defun macroexp--cons (car cdr original-cons)
Lars Ingebrigtsen's avatar
Lars Ingebrigtsen committed
36 37
  "Return ORIGINAL-CONS if the car/cdr of it is `eq' to CAR and CDR, respectively.
If not, return (CAR . CDR)."
38 39 40 41 42 43
  (if (and (eq car (car original-cons)) (eq cdr (cdr original-cons)))
      original-cons
    (cons car cdr)))

;; We use this special macro to iteratively process forms and share list
;; structure of the result with the input.  Doing so recursively using
44
;; `macroexp--cons' results in excessively deep recursion for very long
45
;; input forms.
46
(defmacro macroexp--accumulate (var+list &rest body)
47 48 49 50 51
  "Return a list of the results of evaluating BODY for each element of LIST.
Evaluate BODY with VAR bound to each `car' from LIST, in turn.
Return a list of the values of the final form in BODY.
The list structure of the result will share as much with LIST as
possible (for instance, when BODY just returns VAR unchanged, the
52 53 54
result will be eq to LIST).

\(fn (VAR LIST) BODY...)"
55
  (declare (indent 1))
56 57
  (let ((var (car var+list))
	(list (cadr var+list))
58 59 60 61 62 63 64 65
	(shared (make-symbol "shared"))
	(unshared (make-symbol "unshared"))
	(tail (make-symbol "tail"))
	(new-el (make-symbol "new-el")))
    `(let* ((,shared ,list)
	    (,unshared nil)
	    (,tail ,shared)
	    ,var ,new-el)
66
       (while (consp ,tail)
67 68 69 70 71 72 73 74 75 76
	 (setq ,var (car ,tail)
	       ,new-el (progn ,@body))
	 (unless (eq ,var ,new-el)
	   (while (not (eq ,shared ,tail))
	     (push (pop ,shared) ,unshared))
	   (setq ,shared (cdr ,shared))
	   (push ,new-el ,unshared))
	 (setq ,tail (cdr ,tail)))
       (nconc (nreverse ,unshared) ,shared))))

77
(defun macroexp--all-forms (forms &optional skip)
78 79 80
  "Return FORMS with macros expanded.  FORMS is a list of forms.
If SKIP is non-nil, then don't expand that many elements at the start of
FORMS."
81
  (macroexp--accumulate (form forms)
82
    (if (or (null skip) (zerop skip))
83
	(macroexp--expand-all form)
84 85 86
      (setq skip (1- skip))
      form)))

87
(defun macroexp--all-clauses (clauses &optional skip)
88 89 90 91
  "Return CLAUSES with macros expanded.
CLAUSES is a list of lists of forms; any clause that's not a list is ignored.
If SKIP is non-nil, then don't expand that many elements at the start of
each clause."
92
  (macroexp--accumulate (clause clauses)
93
    (if (listp clause)
94
	(macroexp--all-forms clause skip)
95 96
      clause)))

97
(defun macroexp--compiler-macro (handler form)
98
  (condition-case-unless-debug err
99
      (apply handler form (cdr form))
100 101
    (error
     (message "Compiler-macro error for %S: %S" (car form) err)
102
           form)))
103

104
(defun macroexp--funcall-if-compiled (_form)
105 106
  "Pseudo function used internally by macroexp to delay warnings.
The purpose is to delay warnings to bytecomp.el, so they can use things
107
like `byte-compile-warn' to get better file-and-line-number data
108 109
and also to avoid outputting the warning during normal execution."
  nil)
110
(put 'macroexp--funcall-if-compiled 'byte-compile
111
     (lambda (form)
112
       (funcall (eval (cadr form)))
113 114
       (byte-compile-constant nil)))

115 116 117 118 119 120 121 122
(defun macroexp--compiling-p ()
  "Return non-nil if we're macroexpanding for the compiler."
  ;; FIXME: ¡¡Major Ugly Hack!! To determine whether the output of this
  ;; macro-expansion will be processed by the byte-compiler, we check
  ;; circumstantial evidence.
  (member '(declare-function . byte-compile-macroexpand-declare-function)
          macroexpand-all-environment))

123
(defvar macroexp--warned (make-hash-table :test #'equal :weakness 'key))
124

125
(defun macroexp--warn-and-return (msg form &optional compile-only)
126
  (let ((when-compiled (lambda () (byte-compile-warn "%s" msg))))
127 128
    (cond
     ((null msg) form)
129
     ((macroexp--compiling-p)
130 131 132 133 134 135 136 137 138
      (if (gethash form macroexp--warned)
          ;; Already wrapped this exp with a warning: avoid inf-looping
          ;; where we keep adding the same warning onto `form' because
          ;; macroexpand-all gets right back to macroexpanding `form'.
          form
        (puthash form form macroexp--warned)
        `(progn
           (macroexp--funcall-if-compiled ',when-compiled)
           ,form)))
139
     (t
140 141 142 143 144
      (unless compile-only
        (message "%s%s" (if (stringp load-file-name)
                            (concat (file-relative-name load-file-name) ": ")
                          "")
                 msg))
145 146 147 148 149
      form))))

(defun macroexp--obsolete-warning (fun obsolescence-data type)
  (let ((instead (car obsolescence-data))
        (asof (nth 2 obsolescence-data)))
150
    (format-message
151
     "`%s' is an obsolete %s%s%s" fun type
152
     (if asof (concat " (as of " asof ")") "")
153
     (cond ((stringp instead) (concat "; " (substitute-command-keys instead)))
154
           (instead (format-message "; use `%s' instead." instead))
155
           (t ".")))))
Glenn Morris's avatar
Glenn Morris committed
156

157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180
(defun macroexpand-1 (form &optional environment)
  "Perform (at most) one step of macroexpansion."
  (cond
   ((consp form)
    (let* ((head (car form))
           (env-expander (assq head environment)))
      (if env-expander
          (if (cdr env-expander)
              (apply (cdr env-expander) (cdr form))
            form)
        (if (not (and (symbolp head) (fboundp head)))
            form
          (let ((def (autoload-do-load (symbol-function head) head 'macro)))
            (cond
             ;; Follow alias, but only for macros, otherwise we may end up
             ;; skipping an important compiler-macro (e.g. cl--block-wrapper).
             ((and (symbolp def) (macrop def)) (cons def (cdr form)))
             ((not (consp def)) form)
             (t
              (if (eq 'macro (car def))
                  (apply (cdr def) (cdr form))
                form))))))))
   (t form)))

181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200
(defun macroexp-macroexpand (form env)
  "Like `macroexpand' but checking obsolescence."
  (let ((new-form
         (macroexpand form env)))
    (if (and (not (eq form new-form))   ;It was a macro call.
             (car-safe form)
             (symbolp (car form))
             (get (car form) 'byte-obsolete-info)
             (or (not (fboundp 'byte-compile-warning-enabled-p))
                 (byte-compile-warning-enabled-p 'obsolete)))
        (let* ((fun (car form))
               (obsolete (get fun 'byte-obsolete-info)))
          (macroexp--warn-and-return
           (macroexp--obsolete-warning
            fun obsolete
            (if (symbolp (symbol-function fun))
                "alias" "macro"))
           new-form))
      new-form)))

201
(defun macroexp--expand-all (form)
202 203 204
  "Expand all macros in FORM.
This is an internal version of `macroexpand-all'.
Assumes the caller has bound `macroexpand-all-environment'."
205
  (if (eq (car-safe form) 'backquote-list*)
206 207 208 209
      ;; Special-case `backquote-list*', as it is normally a macro that
      ;; generates exceedingly deep expansions from relatively shallow input
      ;; forms.  We just process it `in reverse' -- first we expand all the
      ;; arguments, _then_ we expand the top-level definition.
210
      (macroexpand (macroexp--all-forms form 1)
211 212
		   macroexpand-all-environment)
    ;; Normal form; get its expansion, and then expand arguments.
213
    (setq form (macroexp-macroexpand form macroexpand-all-environment))
214 215
    (pcase form
      (`(cond . ,clauses)
216
       (macroexp--cons 'cond (macroexp--all-clauses clauses) form))
217
      (`(condition-case . ,(or `(,err ,body . ,handlers) dontcare))
218
       (macroexp--cons
219
        'condition-case
220
        (macroexp--cons err
221 222 223 224
                        (macroexp--cons (macroexp--expand-all body)
                                        (macroexp--all-clauses handlers 1)
                                        (cddr form))
                        (cdr form))
225
        form))
226
      (`(,(or 'defvar 'defconst) . ,_) (macroexp--all-forms form 2))
227
      (`(function ,(and f `(lambda . ,_)))
228
       (macroexp--cons 'function
229 230 231 232
                       (macroexp--cons (macroexp--all-forms f 2)
                                       nil
                                       (cdr form))
                       form))
233 234
      (`(,(or 'function 'quote) . ,_) form)
      (`(,(and fun (or 'let 'let*)) . ,(or `(,bindings . ,body) dontcare))
235
       (macroexp--cons fun
236 237 238 239
                       (macroexp--cons (macroexp--all-clauses bindings 1)
                                       (macroexp--all-forms body)
                                       (cdr form))
                       form))
240 241
      (`(,(and fun `(lambda . ,_)) . ,args)
       ;; Embedded lambda in function position.
242
       (macroexp--cons (macroexp--all-forms fun 2)
243 244
                       (macroexp--all-forms args)
                       form))
245 246 247 248 249 250 251 252
      ;; The following few cases are for normal function calls that
      ;; are known to funcall one of their arguments.  The byte
      ;; compiler has traditionally handled these functions specially
      ;; by treating a lambda expression quoted by `quote' as if it
      ;; were quoted by `function'.  We make the same transformation
      ;; here, so that any code that cares about the difference will
      ;; see the same transformation.
      ;; First arg is a function:
253
      (`(,(and fun (or 'funcall 'apply 'mapcar 'mapatoms 'mapconcat 'mapc))
Stefan Monnier's avatar
Stefan Monnier committed
254
         ',(and f `(lambda . ,_)) . ,args)
255
       (macroexp--warn-and-return
256 257
        (format "%s quoted with ' rather than with #'"
                (list 'lambda (nth 1 f) '...))
258
        (macroexp--expand-all `(,fun ,f . ,args))))
259
      ;; Second arg is a function:
260
      (`(,(and fun (or 'sort)) ,arg1 ',(and f `(lambda . ,_)) . ,args)
261
       (macroexp--warn-and-return
262 263
        (format "%s quoted with ' rather than with #'"
                (list 'lambda (nth 1 f) '...))
264
        (macroexp--expand-all `(,fun ,arg1 ,f . ,args))))
265
      (`(funcall #',(and f (pred symbolp)) . ,args)
266 267 268
       ;; Rewrite (funcall #'foo bar) to (foo bar), in case `foo'
       ;; has a compiler-macro.
       (macroexp--expand-all `(,f . ,args)))
269 270 271 272
      (`(,func . ,_)
       ;; Macro expand compiler macros.  This cannot be delayed to
       ;; byte-optimize-form because the output of the compiler-macro can
       ;; use macros.
273
       (let ((handler (function-get func 'compiler-macro)))
274 275 276 277
         (if (null handler)
             ;; No compiler macro.  We just expand each argument (for
             ;; setq/setq-default this works alright because the variable names
             ;; are symbols).
278
             (macroexp--all-forms form 1)
279 280
           ;; If the handler is not loaded yet, try (auto)loading the
           ;; function itself, which may in turn load the handler.
281
           (unless (functionp handler)
282
             (with-demoted-errors "macroexp--expand-all: %S"
283
               (autoload-do-load (indirect-function func) func)))
284
           (let ((newform (macroexp--compiler-macro handler form)))
285 286
             (if (eq form newform)
                 ;; The compiler macro did not find anything to do.
287
                 (if (equal form (setq newform (macroexp--all-forms form 1)))
288 289 290
                     form
                   ;; Maybe after processing the args, some new opportunities
                   ;; appeared, so let's try the compiler macro again.
291
                   (setq form (macroexp--compiler-macro handler newform))
292
                   (if (eq newform form)
293
                       newform
294 295
                     (macroexp--expand-all newform)))
               (macroexp--expand-all newform))))))
296

297
      (_ form))))
298 299 300 301 302 303 304 305

;;;###autoload
(defun macroexpand-all (form &optional environment)
  "Return result of expanding macros at all levels in FORM.
If no macros are expanded, FORM is returned unchanged.
The second optional arg ENVIRONMENT specifies an environment of macro
definitions to shadow the loaded ones for use in file byte-compilation."
  (let ((macroexpand-all-environment environment))
306
    (macroexp--expand-all form)))
307

308 309
;;; Handy functions to use in macros.

310 311 312 313 314 315 316 317 318 319
(defun macroexp-parse-body (body)
  "Parse a function BODY into (DECLARATIONS . EXPS)."
  (let ((decls ()))
    (while (and (cdr body)
                (let ((e (car body)))
                  (or (stringp e)
                      (memq (car-safe e)
                            '(:documentation declare interactive cl-declare)))))
      (push (pop body) decls))
    (cons (nreverse decls) body)))
Leo Liu's avatar
Leo Liu committed
320

321
(defun macroexp-progn (exps)
322
  "Return an expression equivalent to \\=`(progn ,@EXPS)."
323 324
  (if (cdr exps) `(progn ,@exps) (car exps)))

325
(defun macroexp-unprogn (exp)
326 327 328
  "Turn EXP into a list of expressions to execute in sequence.
Never returns an empty list."
  (if (eq (car-safe exp) 'progn) (or (cdr exp) '(nil)) (list exp)))
329

330
(defun macroexp-let* (bindings exp)
331
  "Return an expression equivalent to \\=`(let* ,bindings ,exp)."
332 333 334 335 336 337
  (cond
   ((null bindings) exp)
   ((eq 'let* (car-safe exp)) `(let* (,@bindings ,@(cadr exp)) ,@(cddr exp)))
   (t `(let* ,bindings ,exp))))

(defun macroexp-if (test then else)
338
  "Return an expression equivalent to \\=`(if ,TEST ,THEN ,ELSE)."
339 340
  (cond
   ((eq (car-safe else) 'if)
341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359
    (cond
     ;; Drop this optimization: It's unsafe (it assumes that `test' is
     ;; pure, or at least idempotent), and it's not used even a single
     ;; time while compiling Emacs's sources.
     ;;((equal test (nth 1 else))
     ;; ;; Doing a test a second time: get rid of the redundancy.
     ;; (message "macroexp-if: sharing 'test' %S" test)
     ;; `(if ,test ,then ,@(nthcdr 3 else)))
     ((equal then (nth 2 else))
      ;; (message "macroexp-if: sharing 'then' %S" then)
      `(if (or ,test ,(nth 1 else)) ,then ,@(nthcdr 3 else)))
     ((equal (macroexp-unprogn then) (nthcdr 3 else))
      ;; (message "macroexp-if: sharing 'then' with not %S" then)
      `(if (or ,test (not ,(nth 1 else)))
           ,then ,@(macroexp-unprogn (nth 2 else))))
     (t
      `(cond (,test ,@(macroexp-unprogn then))
             (,(nth 1 else) ,@(macroexp-unprogn (nth 2 else)))
             (t ,@(nthcdr 3 else))))))
360
   ((eq (car-safe else) 'cond)
361
    `(cond (,test ,@(macroexp-unprogn then)) ,@(cdr else)))
362 363
   ;; Invert the test if that lets us reduce the depth of the tree.
   ((memq (car-safe then) '(if cond)) (macroexp-if `(not ,test) else then))
364
   (t `(if ,test ,then ,@(macroexp-unprogn else)))))
365

366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394
(defmacro macroexp-let2 (test sym exp &rest body)
  "Evaluate BODY with SYM bound to an expression for EXP's value.
The intended usage is that BODY generates an expression that
will refer to EXP's value multiple times, but will evaluate
EXP only once.  As BODY generates that expression, it should
use SYM to stand for the value of EXP.

If EXP is a simple, safe expression, then SYM's value is EXP itself.
Otherwise, SYM's value is a symbol which holds the value produced by
evaluating EXP.  The return value incorporates the value of BODY, plus
additional code to evaluate EXP once and save the result so SYM can
refer to it.

If BODY consists of multiple forms, they are all evaluated
but only the last one's value matters.

TEST is a predicate to determine whether EXP qualifies as simple and
safe; if TEST is nil, only constant expressions qualify.

Example:
 (macroexp-let2 nil foo EXP
   \\=`(* ,foo ,foo))
generates an expression that evaluates EXP once,
then returns the square of that value.
You could do this with
  (let ((foovar EXP))
    (* foovar foovar))
but using `macroexp-let2' produces more efficient code in
cases where EXP is a constant."
395
  (declare (indent 3) (debug (sexp sexp form body)))
396 397 398
  (let ((bodysym (make-symbol "body"))
        (expsym (make-symbol "exp")))
    `(let* ((,expsym ,exp)
399 400 401 402 403
            (,sym (if (funcall #',(or test #'macroexp-const-p) ,expsym)
                      ,expsym (make-symbol ,(symbol-name sym))))
            (,bodysym ,(macroexp-progn body)))
       (if (eq ,sym ,expsym) ,bodysym
         (macroexp-let* (list (list ,sym ,expsym))
404 405
                        ,bodysym)))))

Leo Liu's avatar
Leo Liu committed
406 407 408 409
(defmacro macroexp-let2* (test bindings &rest body)
  "Bind each binding in BINDINGS as `macroexp-let2' does."
  (declare (indent 2) (debug (sexp (&rest (sexp form)) body)))
  (pcase-exhaustive bindings
410
    ('nil (macroexp-progn body))
Leo Liu's avatar
Leo Liu committed
411 412 413 414
    (`((,var ,exp) . ,tl)
     `(macroexp-let2 ,test ,var ,exp
        (macroexp-let2* ,test ,tl ,@body)))))

415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435
(defun macroexp--maxsize (exp size)
  (cond ((< size 0) size)
        ((symbolp exp) (1- size))
        ((stringp exp) (- size (/ (length exp) 16)))
        ((vectorp exp)
         (dotimes (i (length exp))
           (setq size (macroexp--maxsize (aref exp i) size)))
         (1- size))
        ((consp exp)
         ;; We could try to be more clever with quote&function,
         ;; but it is difficult to do so correctly, and it's not obvious that
         ;; it would be worth the effort.
         (dolist (e exp)
           (setq size (macroexp--maxsize e size)))
         (1- size))
        (t -1)))

(defun macroexp-small-p (exp)
  "Return non-nil if EXP can be considered small."
  (> (macroexp--maxsize exp 10) 0))

436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465
(defsubst macroexp--const-symbol-p (symbol &optional any-value)
  "Non-nil if SYMBOL is constant.
If ANY-VALUE is nil, only return non-nil if the value of the symbol is the
symbol itself."
  (or (memq symbol '(nil t))
      (keywordp symbol)
      (if any-value
	  (or (memq symbol byte-compile-const-variables)
	      ;; FIXME: We should provide a less intrusive way to find out
	      ;; if a variable is "constant".
	      (and (boundp symbol)
		   (condition-case nil
		       (progn (set symbol (symbol-value symbol)) nil)
		     (setting-constant t)))))))

(defun macroexp-const-p (exp)
  "Return non-nil if EXP will always evaluate to the same value."
  (cond ((consp exp) (or (eq (car exp) 'quote)
                         (and (eq (car exp) 'function)
                              (symbolp (cadr exp)))))
        ;; It would sometimes make sense to pass `any-value', but it's not
        ;; always safe since a "constant" variable may not actually always have
        ;; the same value.
        ((symbolp exp) (macroexp--const-symbol-p exp))
        (t t)))

(defun macroexp-copyable-p (exp)
  "Return non-nil if EXP can be copied without extra cost."
  (or (symbolp exp) (macroexp-const-p exp)))

466
(defun macroexp-quote (v)
467
  "Return an expression E such that `(eval E)' is V.
468 469 470 471 472 473 474 475 476 477

E is either V or (quote V) depending on whether V evaluates to
itself or not."
  (if (and (not (consp v))
	   (or (keywordp v)
	       (not (symbolp v))
	       (memq v '(nil t))))
      v
    (list 'quote v)))

478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512
;;; Load-time macro-expansion.

;; Because macro-expansion used to be more lazy, eager macro-expansion
;; tends to bump into previously harmless/unnoticeable cyclic-dependencies.
;; So, we have to delay macro-expansion like we used to when we detect
;; such a cycle, and we also want to help coders resolve those cycles (since
;; they can be non-obvious) by providing a usefully trimmed backtrace
;; (hopefully) highlighting the problem.

(defun macroexp--backtrace ()
  "Return the Elisp backtrace, more recent frames first."
  (let ((bt ())
        (i 0))
    (while
        (let ((frame (backtrace-frame i)))
          (when frame
            (push frame bt)
            (setq i (1+ i)))))
    (nreverse bt)))

(defun macroexp--trim-backtrace-frame (frame)
  (pcase frame
    (`(,_ macroexpand (,head . ,_) . ,_) `(macroexpand (,head )))
    (`(,_ internal-macroexpand-for-load (,head ,second . ,_) . ,_)
     (if (or (symbolp second)
             (and (eq 'quote (car-safe second))
                  (symbolp (cadr second))))
         `(macroexpand-all (,head ,second ))
       '(macroexpand-all )))
    (`(,_ load-with-code-conversion ,name . ,_)
     `(load ,(file-name-nondirectory name)))))

(defvar macroexp--pending-eager-loads nil
  "Stack of files currently undergoing eager macro-expansion.")

513 514
(defvar macroexp--debug-eager nil)

515
(defun internal-macroexpand-for-load (form full-p)
516 517 518 519 520 521 522 523 524 525 526 527 528 529
  ;; Called from the eager-macroexpansion in readevalloop.
  (cond
   ;; Don't repeat the same warning for every top-level element.
   ((eq 'skip (car macroexp--pending-eager-loads)) form)
   ;; If we detect a cycle, skip macro-expansion for now, and output a warning
   ;; with a trimmed backtrace.
   ((and load-file-name (member load-file-name macroexp--pending-eager-loads))
    (let* ((bt (delq nil
                     (mapcar #'macroexp--trim-backtrace-frame
                             (macroexp--backtrace))))
           (elem `(load ,(file-name-nondirectory load-file-name)))
           (tail (member elem (cdr (member elem bt)))))
      (if tail (setcdr tail (list ')))
      (if (eq (car-safe (car bt)) 'macroexpand-all) (setq bt (cdr bt)))
530 531 532 533
      (if macroexp--debug-eager
          (debug 'eager-macroexp-cycle)
        (message "Warning: Eager macro-expansion skipped due to cycle:\n  %s"
                 (mapconcat #'prin1-to-string (nreverse bt) " => ")))
534 535 536 537 538 539
      (push 'skip macroexp--pending-eager-loads)
      form))
   (t
    (condition-case err
        (let ((macroexp--pending-eager-loads
               (cons load-file-name macroexp--pending-eager-loads)))
540 541 542
          (if full-p
              (macroexpand-all form)
            (macroexpand form)))
543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563
      (error
       ;; Hopefully this shouldn't happen thanks to the cycle detection,
       ;; but in case it does happen, let's catch the error and give the
       ;; code a chance to macro-expand later.
       (message "Eager macro-expansion failure: %S" err)
       form)))))

;; ¡¡¡ Big Ugly Hack !!!
;; src/bootstrap-emacs is mostly used to compile .el files, so it needs
;; macroexp, bytecomp, cconv, and byte-opt to be fast.  Generally this is done
;; by compiling those files first, but this only makes a difference if those
;; files are not preloaded.  But macroexp.el is preloaded so we reload it if
;; the current version is interpreted and there's a compiled version available.
(eval-when-compile
  (add-hook 'emacs-startup-hook
            (lambda ()
              (and (not (byte-code-function-p
                         (symbol-function 'macroexpand-all)))
                   (locate-library "macroexp.elc")
                   (load "macroexp.elc")))))

564 565 566
(provide 'macroexp)

;;; macroexp.el ends here