tramp-smb.el 50.2 KB
Newer Older
Michael Albinus's avatar
Michael Albinus committed
1
;;; tramp-smb.el --- Tramp access functions for SMB servers
2

3
;; Copyright (C) 2002-2011 Free Software Foundation, Inc.
4

Michael Albinus's avatar
Michael Albinus committed
5
;; Author: Michael Albinus <michael.albinus@gmx.de>
6
;; Keywords: comm, processes
7
;; Package: tramp
8 9 10

;; This file is part of GNU Emacs.

11
;; GNU Emacs is free software: you can redistribute it and/or modify
12
;; it under the terms of the GNU General Public License as published by
13 14
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
15 16 17 18 19 20 21

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
23 24 25 26 27 28 29

;;; Commentary:

;; Access functions for SMB servers like SAMBA or M$ Windows from Tramp.

;;; Code:

Glenn Morris's avatar
Glenn Morris committed
30
(eval-when-compile (require 'cl))	; block, return
31 32 33
(require 'tramp)

;; Define SMB method ...
34 35 36
;;;###tramp-autoload
(defconst tramp-smb-method "smb"
  "*Method to connect SAMBA and M$ SMB servers.")
37 38

;; ... and add it to the method list.
39 40 41
;;;###tramp-autoload
(unless (memq system-type '(cygwin windows-nt))
  (add-to-list 'tramp-methods (cons tramp-smb-method nil)))
42 43 44

;; Add a default for `tramp-default-method-alist'. Rule: If there is
;; a domain in USER, it must be the SMB method.
45
;;;###tramp-autoload
46
(add-to-list 'tramp-default-method-alist
47
	     `(nil ,tramp-prefix-domain-regexp ,tramp-smb-method))
48 49 50

;; Add a default for `tramp-default-user-alist'. Rule: For the SMB method,
;; the anonymous user is chosen.
51
;;;###tramp-autoload
52
(add-to-list 'tramp-default-user-alist
53
	     `(,(concat "\\`" tramp-smb-method "\\'") nil nil))
54 55 56 57 58 59 60 61 62 63 64

;; Add completion function for SMB method.
(tramp-set-completion-function
 tramp-smb-method
 '((tramp-parse-netrc "~/.netrc")))

(defcustom tramp-smb-program "smbclient"
  "*Name of SMB client to run."
  :group 'tramp
  :type 'string)

65 66 67 68 69 70 71
(defcustom tramp-smb-conf "/dev/null"
  "*Path of the smb.conf file.
If it is nil, no smb.conf will be added to the `tramp-smb-program'
call, letting the SMB client use the default one."
  :group 'tramp
  :type '(choice (const nil) (file :must-match t)))

72 73 74
(defvar tramp-smb-version nil
  "*Version string of the SMB client.")

Michael Albinus's avatar
Michael Albinus committed
75
(defconst tramp-smb-prompt "^smb: .+> \\|^\\s-+Server\\s-+Comment$"
76 77 78 79 80
  "Regexp used as prompt in smbclient.")

(defconst tramp-smb-errors
  (mapconcat
   'identity
81 82
   `(;; Connection error / timeout / unknown command.
     "Connection\\( to \\S-+\\)? failed"
83
     "Read from server failed, maybe it closed the connection"
84
     "Call timed out: server did not respond"
85 86
     "\\S-+: command not found"
     "Server doesn't support UNIX CIFS calls"
87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120
     ,(regexp-opt
       '(;; Samba.
	 "ERRDOS"
	 "ERRHRD"
	 "ERRSRV"
	 "ERRbadfile"
	 "ERRbadpw"
	 "ERRfilexists"
	 "ERRnoaccess"
	 "ERRnomem"
	 "ERRnosuchshare"
	 ;; Windows 4.0 (Windows NT), Windows 5.0 (Windows 2000),
	 ;; Windows 5.1 (Windows XP), Windows 5.2 (Windows Server 2003).
	 "NT_STATUS_ACCESS_DENIED"
	 "NT_STATUS_ACCOUNT_LOCKED_OUT"
	 "NT_STATUS_BAD_NETWORK_NAME"
	 "NT_STATUS_CANNOT_DELETE"
	 "NT_STATUS_CONNECTION_REFUSED"
	 "NT_STATUS_DIRECTORY_NOT_EMPTY"
	 "NT_STATUS_DUPLICATE_NAME"
	 "NT_STATUS_FILE_IS_A_DIRECTORY"
	 "NT_STATUS_IO_TIMEOUT"
	 "NT_STATUS_LOGON_FAILURE"
	 "NT_STATUS_NETWORK_ACCESS_DENIED"
	 "NT_STATUS_NOT_IMPLEMENTED"
	 "NT_STATUS_NO_SUCH_FILE"
	 "NT_STATUS_NO_SUCH_USER"
	 "NT_STATUS_OBJECT_NAME_COLLISION"
	 "NT_STATUS_OBJECT_NAME_INVALID"
	 "NT_STATUS_OBJECT_NAME_NOT_FOUND"
	 "NT_STATUS_SHARING_VIOLATION"
	 "NT_STATUS_TRUSTED_RELATIONSHIP_FAILURE"
	 "NT_STATUS_UNSUCCESSFUL"
	 "NT_STATUS_WRONG_PASSWORD")))
121 122 123 124
   "\\|")
  "Regexp for possible error strings of SMB servers.
Used instead of analyzing error codes of commands.")

125 126 127 128 129 130 131 132 133 134
(defconst tramp-smb-actions-with-share
  '((tramp-smb-prompt tramp-action-succeed)
    (tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-process-alive))
  "List of pattern/action pairs.
This list is used for login to SMB servers.

See `tramp-actions-before-shell' for more info.")
135

136 137 138 139 140 141 142
(defconst tramp-smb-actions-without-share
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-out-of-band))
  "List of pattern/action pairs.
This list is used for login to SMB servers.
143

144
See `tramp-actions-before-shell' for more info.")
145

146 147 148
;; New handlers should be added here.
(defconst tramp-smb-file-name-handler-alist
  '(
149
    ;; `access-file' performed by default handler.
150
    (add-name-to-file . tramp-smb-handle-add-name-to-file)
151 152
    ;; `byte-compiler-base-file-name' performed by default handler.
    (copy-directory . tramp-smb-handle-copy-directory)
153 154 155
    (copy-file . tramp-smb-handle-copy-file)
    (delete-directory . tramp-smb-handle-delete-directory)
    (delete-file . tramp-smb-handle-delete-file)
156
    ;; `diff-latest-backup-file' performed by default handler.
157
    (directory-file-name . tramp-handle-directory-file-name)
158
    (directory-files . tramp-smb-handle-directory-files)
159
    (directory-files-and-attributes
160
     . tramp-handle-directory-files-and-attributes)
161 162
    (dired-call-process . ignore)
    (dired-compress-file . ignore)
163
    (dired-uncache . tramp-handle-dired-uncache)
164
    (expand-file-name . tramp-smb-handle-expand-file-name)
165 166 167
    (file-accessible-directory-p . tramp-smb-handle-file-directory-p)
    (file-attributes . tramp-smb-handle-file-attributes)
    (file-directory-p .  tramp-smb-handle-file-directory-p)
168 169
    (file-executable-p . tramp-handle-file-exists-p)
    (file-exists-p . tramp-handle-file-exists-p)
170 171 172
    (file-local-copy . tramp-smb-handle-file-local-copy)
    (file-modes . tramp-handle-file-modes)
    (file-name-all-completions . tramp-smb-handle-file-name-all-completions)
173
    (file-name-as-directory . tramp-handle-file-name-as-directory)
174 175 176
    (file-name-completion . tramp-handle-file-name-completion)
    (file-name-directory . tramp-handle-file-name-directory)
    (file-name-nondirectory . tramp-handle-file-name-nondirectory)
177
    ;; `file-name-sans-versions' performed by default handler.
178
    (file-newer-than-file-p . tramp-handle-file-newer-than-file-p)
179
    (file-ownership-preserved-p . ignore)
180
    (file-readable-p . tramp-handle-file-exists-p)
181
    (file-regular-p . tramp-handle-file-regular-p)
Michael Albinus's avatar
Michael Albinus committed
182 183
    (file-remote-p . tramp-handle-file-remote-p)
    ;; `file-selinux-context' performed by default handler.
184
    (file-symlink-p . tramp-handle-file-symlink-p)
185
    ;; `file-truename' performed by default handler.
186
    (file-writable-p . tramp-smb-handle-file-writable-p)
187
    (find-backup-file-name . tramp-handle-find-backup-file-name)
188 189
    ;; `find-file-noselect' performed by default handler.
    ;; `get-file-buffer' performed by default handler.
190 191 192 193 194
    (insert-directory . tramp-smb-handle-insert-directory)
    (insert-file-contents . tramp-handle-insert-file-contents)
    (load . tramp-handle-load)
    (make-directory . tramp-smb-handle-make-directory)
    (make-directory-internal . tramp-smb-handle-make-directory-internal)
195
    (make-symbolic-link . tramp-smb-handle-make-symbolic-link)
196
    (rename-file . tramp-smb-handle-rename-file)
197
    (set-file-modes . tramp-smb-handle-set-file-modes)
Michael Albinus's avatar
Michael Albinus committed
198
    ;; `set-file-selinux-context' performed by default handler.
199
    (set-file-times . ignore)
200 201
    (set-visited-file-modtime . ignore)
    (shell-command . ignore)
Michael Albinus's avatar
Michael Albinus committed
202
    (substitute-in-file-name . tramp-smb-handle-substitute-in-file-name)
203
    (unhandled-file-name-directory . tramp-handle-unhandled-file-name-directory)
204 205
    (vc-registered . ignore)
    (verify-visited-file-modtime . ignore)
206 207 208 209 210
    (write-region . tramp-smb-handle-write-region)
)
  "Alist of handler functions for Tramp SMB method.
Operations not mentioned here will be handled by the default Emacs primitives.")

211 212
;;;###tramp-autoload
(defsubst tramp-smb-file-name-p (filename)
213 214
  "Check if it's a filename for SMB servers."
  (let ((v (tramp-dissect-file-name filename)))
215
    (string= (tramp-file-name-method v) tramp-smb-method)))
216

217
;;;###tramp-autoload
218 219 220 221 222 223
(defun tramp-smb-file-name-handler (operation &rest args)
  "Invoke the SMB related OPERATION.
First arg specifies the OPERATION, second arg is a list of arguments to
pass to the OPERATION."
  (let ((fn (assoc operation tramp-smb-file-name-handler-alist)))
    (if fn
224
	(save-match-data (apply (cdr fn) args))
225 226
      (tramp-run-real-handler operation args))))

227 228 229 230
;;;###tramp-autoload
(unless (memq system-type '(cygwin windows-nt))
  (add-to-list 'tramp-foreign-file-name-handler-alist
	       (cons 'tramp-smb-file-name-p 'tramp-smb-file-name-handler)))
231 232


233 234
;; File name primitives.

235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264
(defun tramp-smb-handle-add-name-to-file
  (filename newname &optional ok-if-already-exists)
  "Like `add-name-to-file' for Tramp files."
  (unless (tramp-equal-remote filename newname)
    (with-parsed-tramp-file-name
	(if (tramp-tramp-file-p filename) filename newname) nil
      (tramp-error
       v 'file-error
       "add-name-to-file: %s"
       "only implemented for same method, same user, same host")))
  (with-parsed-tramp-file-name filename v1
    (with-parsed-tramp-file-name newname v2
      (when (file-directory-p filename)
	(tramp-error
	 v2 'file-error
	 "add-name-to-file: %s must not be a directory" filename))
      (when (and (not ok-if-already-exists)
		 (file-exists-p newname)
		 (not (numberp ok-if-already-exists))
		 (y-or-n-p
		  (format
		   "File %s already exists; make it a new name anyway? "
		   newname)))
	(tramp-error
	 v2 'file-error
	 "add-name-to-file: file %s already exists" newname))
      ;; We must also flush the cache of the directory, because
      ;; `file-attributes' reads the values from there.
      (tramp-flush-file-property v2 (file-name-directory v2-localname))
      (tramp-flush-file-property v2 v2-localname)
265 266 267 268 269 270 271 272 273 274 275 276
      (unless
	  (tramp-smb-send-command
	   v1
	   (format
	    "%s \"%s\" \"%s\""
	    (if (tramp-smb-get-cifs-capabilities v1) "link" "hardlink")
	    (tramp-smb-get-localname v1)
	    (tramp-smb-get-localname v2)))
	(tramp-error
	 v2 'file-error
	 "error with add-name-to-file, see buffer `%s' for details"
	 (buffer-name))))))
277

278 279
(defun tramp-smb-handle-copy-directory
  (dirname newname &optional keep-date parents)
280
  "Like `copy-directory' for Tramp files.  KEEP-DATE is not handled."
281 282 283 284 285
  (setq dirname (expand-file-name dirname)
	newname (expand-file-name newname))
  (let ((t1 (tramp-tramp-file-p dirname))
	(t2 (tramp-tramp-file-p newname)))
    (with-parsed-tramp-file-name (if t1 dirname newname) nil
286
      (cond
287
       ;; We must use a local temporary directory.
288 289 290 291 292 293 294 295
       ((and t1 t2)
	(let ((tmpdir
	       (make-temp-name
		(expand-file-name
		 tramp-temp-name-prefix
		 (tramp-compat-temporary-file-directory)))))
	  (unwind-protect
	      (progn
296 297 298
		(tramp-compat-copy-directory dirname tmpdir keep-date parents)
		(tramp-compat-copy-directory tmpdir newname keep-date parents))
	    (tramp-compat-delete-directory tmpdir 'recursive))))
299 300

       ;; We can copy recursively.
301 302
       ((or t1 t2)
	(let ((prompt (tramp-smb-send-command v "prompt"))
303
	      (recurse (tramp-smb-send-command v "recurse")))
304 305 306 307 308 309 310
	  (unless (file-directory-p newname)
	    (make-directory newname parents))
	  (unwind-protect
	      (unless
		  (and
		   prompt recurse
		   (tramp-smb-send-command
311
		    v (format "cd \"%s\"" (tramp-smb-get-localname v)))
312 313 314 315 316 317 318 319 320 321 322 323
		   (tramp-smb-send-command
		    v (format "lcd \"%s\"" (if t1 newname dirname)))
		   (if t1
		       (tramp-smb-send-command v "mget *")
		     (tramp-smb-send-command v "mput *")))
		;; Error.
		(with-current-buffer (tramp-get-connection-buffer v)
		  (goto-char (point-min))
		  (search-forward-regexp tramp-smb-errors nil t)
		  (tramp-error
		   v 'file-error
		   "%s `%s'" (match-string 0) (if t1 dirname newname))))
324
	    ;; Go home.
325 326 327
	    (tramp-smb-send-command
	     v (format
		"cd %s" (if (tramp-smb-get-cifs-capabilities v) "/" "\\")))
328 329 330
	    ;; Toggle prompt and recurse OFF.
	    (if prompt (tramp-smb-send-command v "prompt"))
	    (if recurse (tramp-smb-send-command v "recurse")))))
331 332

       ;; We must do it file-wise.
333
       (t
334
	(tramp-run-real-handler
335
	 'copy-directory (list dirname newname keep-date parents)))))))
336 337

(defun tramp-smb-handle-copy-file
Michael Albinus's avatar
Michael Albinus committed
338 339
  (filename newname &optional ok-if-already-exists keep-date
	    preserve-uid-gid preserve-selinux-context)
340
  "Like `copy-file' for Tramp files.
341 342
KEEP-DATE is not handled in case NEWNAME resides on an SMB server.
PRESERVE-UID-GID is completely ignored."
343 344
  (setq filename (expand-file-name filename)
	newname (expand-file-name newname))
345 346 347 348 349 350 351 352 353 354 355
  (with-progress-reporter
      (tramp-dissect-file-name (if (file-remote-p filename) filename newname))
      0 (format "Copying %s to %s" filename newname)

    (let ((tmpfile (file-local-copy filename)))

      (if tmpfile
	  ;; Remote filename.
	  (condition-case err
	      (rename-file tmpfile newname ok-if-already-exists)
	    ((error quit)
356
	     (delete-file tmpfile)
357 358 359 360 361 362 363 364 365 366 367
	     (signal (car err) (cdr err))))

	;; Remote newname.
	(when (file-directory-p newname)
	  (setq newname
		(expand-file-name (file-name-nondirectory filename) newname)))

	(with-parsed-tramp-file-name newname nil
	  (when (and (not ok-if-already-exists)
		     (file-exists-p newname))
	    (tramp-error v 'file-already-exists newname))
368

369 370 371 372 373 374 375 376 377 378 379
	  ;; We must also flush the cache of the directory, because
	  ;; `file-attributes' reads the values from there.
	  (tramp-flush-file-property v (file-name-directory localname))
	  (tramp-flush-file-property v localname)
	  (unless (tramp-smb-get-share v)
	    (tramp-error
	     v 'file-error "Target `%s' must contain a share name" newname))
	  (unless (tramp-smb-send-command
		   v (format "put \"%s\" \"%s\""
			     filename (tramp-smb-get-localname v)))
	    (tramp-error v 'file-error "Cannot copy `%s'" filename))))))
380 381 382

  ;; KEEP-DATE handling.
  (when keep-date (set-file-times newname (nth 5 (file-attributes filename)))))
383

384
(defun tramp-smb-handle-delete-directory (directory &optional recursive)
385
  "Like `delete-directory' for Tramp files."
386
  (setq directory (directory-file-name (expand-file-name directory)))
Michael Albinus's avatar
Michael Albinus committed
387
  (when (file-exists-p directory)
388 389 390 391
    (if recursive
	(mapc
	 (lambda (file)
	   (if (file-directory-p file)
392
	       (tramp-compat-delete-directory file recursive)
393
	     (delete-file file)))
394 395 396
	 ;; We do not want to delete "." and "..".
	 (directory-files
	  directory 'full "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*")))
397

Michael Albinus's avatar
Michael Albinus committed
398
    (with-parsed-tramp-file-name directory nil
399
      ;; We must also flush the cache of the directory, because
400
      ;; `file-attributes' reads the values from there.
401 402
      (tramp-flush-file-property v (file-name-directory localname))
      (tramp-flush-directory-property v localname)
403 404 405 406 407 408 409 410 411 412 413
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_rmdir" "rmdir")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
	   v 'file-error "%s `%s'" (match-string 0) directory))))))
414

415
(defun tramp-smb-handle-delete-file (filename &optional trash)
416
  "Like `delete-file' for Tramp files."
417
  (setq filename (expand-file-name filename))
Michael Albinus's avatar
Michael Albinus committed
418 419
  (when (file-exists-p filename)
    (with-parsed-tramp-file-name filename nil
420
      ;; We must also flush the cache of the directory, because
421
      ;; `file-attributes' reads the values from there.
422 423
      (tramp-flush-file-property v (file-name-directory localname))
      (tramp-flush-file-property v localname)
424 425 426 427 428 429 430 431 432 433 434
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_unlink" "rm")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
	   v 'file-error "%s `%s'" (match-string 0) filename))))))
435 436 437

(defun tramp-smb-handle-directory-files
  (directory &optional full match nosort)
438 439 440
  "Like `directory-files' for Tramp files."
  (let ((result (mapcar 'directory-file-name
			(file-name-all-completions "" directory))))
441
    ;; Discriminate with regexp.
442 443 444 445 446
    (when match
      (setq result
	    (delete nil
		    (mapcar (lambda (x) (when (string-match match x) x))
			    result))))
447
    ;; Append directory.
448 449 450 451 452
    (when full
      (setq result
	    (mapcar
	     (lambda (x) (expand-file-name x directory))
	     result)))
453
    ;; Sort them if necessary.
454
    (unless nosort (setq result (sort result 'string-lessp)))
455
    ;; That's it.
456
    result))
457

458 459 460 461 462 463 464 465 466 467 468 469 470
(defun tramp-smb-handle-expand-file-name (name &optional dir)
  "Like `expand-file-name' for Tramp files."
  ;; If DIR is not given, use DEFAULT-DIRECTORY or "/".
  (setq dir (or dir default-directory "/"))
  ;; Unless NAME is absolute, concat DIR and NAME.
  (unless (file-name-absolute-p name)
    (setq name (concat (file-name-as-directory dir) name)))
  ;; If NAME is not a Tramp file, run the real handler.
  (if (not (tramp-tramp-file-p name))
      (tramp-run-real-handler 'expand-file-name (list name nil))
    ;; Dissect NAME.
    (with-parsed-tramp-file-name name nil
      ;; Tilde expansion if necessary.  We use the user name as share,
471 472
      ;; which is offen the case in domains.
      (when (string-match "\\`/?~\\([^/]*\\)" localname)
473 474
	(setq localname
	      (replace-match
475
	       (if (zerop (length (match-string 1 localname)))
476
		   (tramp-file-name-real-user v)
477
		 (match-string 1 localname))
478
	       nil nil localname)))
479 480 481
      ;; Make the file name absolute.
      (unless (tramp-run-real-handler 'file-name-absolute-p (list localname))
	(setq localname (concat "/" localname)))
482 483 484 485 486 487
      ;; No tilde characters in file name, do normal
      ;; `expand-file-name' (this does "/./" and "/../").
      (tramp-make-tramp-file-name
       method user host
       (tramp-run-real-handler 'expand-file-name (list localname))))))

488
(defun tramp-smb-handle-file-attributes (filename &optional id-format)
489
  "Like `file-attributes' for Tramp files."
490
  (unless id-format (setq id-format 'integer))
Michael Albinus's avatar
Michael Albinus committed
491
  (with-parsed-tramp-file-name filename nil
492
    (with-file-property v localname (format "file-attributes-%s" id-format)
493
      (if (and (tramp-smb-get-share v) (tramp-smb-get-stat-capability v))
494
	  (tramp-smb-do-file-attributes-with-stat v id-format)
495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524
	;; Reading just the filename entry via "dir localname" is not
	;; possible, because when filename is a directory, some
	;; smbclient versions return the content of the directory, and
	;; other versions don't.  Therefore, the whole content of the
	;; upper directory is retrieved, and the entry of the filename
	;; is extracted from.
	(let* ((entries (tramp-smb-get-file-entries
			 (file-name-directory filename)))
	       (entry (assoc (file-name-nondirectory filename) entries))
	       (uid (if (equal id-format 'string) "nobody" -1))
	       (gid (if (equal id-format 'string) "nogroup" -1))
	       (inode (tramp-get-inode v))
	       (device (tramp-get-device v)))

	  ;; Check result.
	  (when entry
	    (list (and (string-match "d" (nth 1 entry))
		       t)       ;0 file type
		  -1	        ;1 link count
		  uid	        ;2 uid
		  gid	        ;3 gid
		  '(0 0)	;4 atime
		  (nth 3 entry) ;5 mtime
		  '(0 0)	;6 ctime
		  (nth 2 entry) ;7 size
		  (nth 1 entry) ;8 mode
		  nil	        ;9 gid weird
		  inode	        ;10 inode number
		  device))))))) ;11 file system number

525
(defun tramp-smb-do-file-attributes-with-stat (vec &optional id-format)
526
  "Implement `file-attributes' for Tramp files using stat command."
527 528
  (tramp-message
   vec 5 "file attributes with stat: %s" (tramp-file-name-localname vec))
529
  (with-current-buffer (tramp-get-buffer vec)
530
    (let* (size id link uid gid atime mtime ctime mode inode)
531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588
      (when (tramp-smb-send-command
	     vec (format "stat \"%s\"" (tramp-smb-get-localname vec)))

	;; Loop the listing.
	(goto-char (point-min))
	(unless (re-search-forward tramp-smb-errors nil t)
	  (while (not (eobp))
	    (cond
	     ((looking-at
	       "Size:\\s-+\\([0-9]+\\)\\s-+Blocks:\\s-+[0-9]+\\s-+\\(\\w+\\)")
	      (setq size (string-to-number (match-string 1))
		    id (if (string-equal "directory" (match-string 2)) t
			 (if (string-equal "symbolic" (match-string 2)) ""))))
	     ((looking-at
	       "Inode:\\s-+\\([0-9]+\\)\\s-+Links:\\s-+\\([0-9]+\\)")
	      (setq inode (string-to-number (match-string 1))
		    link (string-to-number (match-string 2))))
	     ((looking-at
	       "Access:\\s-+([0-9]+/\\(\\S-+\\))\\s-+Uid:\\s-+\\([0-9]+\\)\\s-+Gid:\\s-+\\([0-9]+\\)")
	      (setq mode (match-string 1)
		    uid (if (equal id-format 'string) (match-string 2)
			  (string-to-number (match-string 2)))
		    gid (if (equal id-format 'string) (match-string 3)
			  (string-to-number (match-string 3)))))
	     ((looking-at
	       "Access:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq atime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Modify:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq mtime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Change:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq ctime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1)))))) ;; year
	    (forward-line))
	  ;; Return the result.
	  (list id link uid gid atime mtime ctime size mode nil inode
		(tramp-get-device vec)))))))
589 590

(defun tramp-smb-handle-file-directory-p (filename)
591 592 593
  "Like `file-directory-p' for Tramp files."
  (and (file-exists-p filename)
       (eq ?d (aref (nth 8 (file-attributes filename)) 0))))
594 595

(defun tramp-smb-handle-file-local-copy (filename)
596
  "Like `file-local-copy' for Tramp files."
597
  (with-parsed-tramp-file-name filename nil
598 599 600 601
    (unless (file-exists-p filename)
      (tramp-error
       v 'file-error
       "Cannot make local copy of non-existing file `%s'" filename))
602
    (let ((tmpfile (tramp-compat-make-temp-file filename)))
603 604 605 606 607 608
      (with-progress-reporter
	  v 3 (format "Fetching %s to tmp file %s" filename tmpfile)
	(unless (tramp-smb-send-command
		 v (format "get \"%s\" \"%s\""
			   (tramp-smb-get-localname v) tmpfile))
	  ;; Oops, an error.  We shall cleanup.
609
	  (delete-file tmpfile)
610 611
	  (tramp-error
	   v 'file-error "Cannot make local copy of file `%s'" filename)))
612
      tmpfile)))
613 614 615 616

;; This function should return "foo/" for directories and "bar" for
;; files.
(defun tramp-smb-handle-file-name-all-completions (filename directory)
617 618 619 620 621 622 623
  "Like `file-name-all-completions' for Tramp files."
  (all-completions
   filename
   (with-parsed-tramp-file-name directory nil
     (with-file-property v localname "file-name-all-completions"
       (save-match-data
	 (let ((entries (tramp-smb-get-file-entries directory)))
624 625 626 627 628 629 630 631 632
	   (mapcar
	    (lambda (x)
	      (list
	       (if (string-match "d" (nth 1 x))
		   (file-name-as-directory (nth 0 x))
		 (nth 0 x))))
	    entries)))))))

(defun tramp-smb-handle-file-writable-p (filename)
633 634 635 636 637 638
  "Like `file-writable-p' for Tramp files."
  (if (file-exists-p filename)
      (string-match "w" (or (nth 8 (file-attributes filename)) ""))
    (let ((dir (file-name-directory filename)))
      (and (file-exists-p dir)
	   (file-writable-p dir)))))
639 640 641

(defun tramp-smb-handle-insert-directory
  (filename switches &optional wildcard full-directory-p)
642
  "Like `insert-directory' for Tramp files."
643
  (setq filename (expand-file-name filename))
644 645 646 647
  (if full-directory-p
      ;; Called from `dired-add-entry'.
      (setq filename (file-name-as-directory filename))
    (setq filename (directory-file-name filename)))
Michael Albinus's avatar
Michael Albinus committed
648
  (with-parsed-tramp-file-name filename nil
649
    (save-match-data
650
      (let ((base (file-name-nondirectory filename))
651 652 653 654 655 656 657 658 659 660 661 662 663 664
	    ;; We should not destroy the cache entry.
	    (entries (copy-sequence
		      (tramp-smb-get-file-entries
		       (file-name-directory filename)))))

	(when wildcard
	  (string-match "\\." base)
	  (setq base (replace-match "\\\\." nil nil base))
	  (string-match "\\*" base)
	  (setq base (replace-match ".*" nil nil base))
	  (string-match "\\?" base)
	  (setq base (replace-match ".?" nil nil base)))

	;; Filter entries.
665
	(setq entries
666 667 668 669 670 671 672 673 674 675 676 677
	      (delq
	       nil
	       (if (or wildcard (zerop (length base)))
		   ;; Check for matching entries.
		   (mapcar
		    (lambda (x)
		      (when (string-match
			     (format "^%s" base) (nth 0 x))
			x))
		    entries)
		 ;; We just need the only and only entry FILENAME.
		 (list (assoc base entries)))))
678

Michael Albinus's avatar
Michael Albinus committed
679
	;; Sort entries.
680 681 682 683 684
	(setq entries
	      (sort
	       entries
	       (lambda (x y)
		 (if (string-match "t" switches)
685 686 687
		     ;; Sort by date.
		     (tramp-time-less-p (nth 3 y) (nth 3 x))
		   ;; Sort by name.
688 689
		   (string-lessp (nth 0 x) (nth 0 y))))))

Michael Albinus's avatar
Michael Albinus committed
690 691
	;; Handle "-F" switch.
	(when (string-match "F" switches)
692
	  (mapc
Michael Albinus's avatar
Michael Albinus committed
693 694 695 696 697 698 699 700 701
	   (lambda (x)
	     (when (not (zerop (length (car x))))
	       (cond
		((char-equal ?d (string-to-char (nth 1 x)))
		 (setcar x (concat (car x) "/")))
		((char-equal ?x (string-to-char (nth 1 x)))
		 (setcar x (concat (car x) "*"))))))
	   entries))

702
	;; Print entries.
703
	(mapc
704
	 (lambda (x)
705
	   (when (not (zerop (length (nth 0 x))))
706
	     (let ((attr
707
		    (when (tramp-smb-get-stat-capability v)
708
		      (ignore-errors
709
			(file-attributes filename 'string)))))
710 711
	       (insert
		(format
712
		 "%10s %3d %-8s %-8s %8s %s "
713
		 (or (nth 8 attr) (nth 1 x)) ; mode
714
		 (or (nth 1 attr) 1) ; inode
715 716
		 (or (nth 2 attr) "nobody") ; uid
		 (or (nth 3 attr) "nogroup") ; gid
717
		 (or (nth 7 attr) (nth 2 x)) ; size
718 719 720 721 722 723
		 (format-time-string
		  (if (tramp-time-less-p
		       (tramp-time-subtract (current-time) (nth 3 x))
		       tramp-half-a-year)
		      "%b %e %R"
		    "%b %e  %Y")
724
		  (nth 3 x)))) ; date
725 726 727
	       ;; We mark the file name.  The inserted name could be
	       ;; from somewhere else, so we use the relative file
	       ;; name of `default-directory'.
728
	       (let ((start (point)))
729 730 731
		 (insert
		  (format
		   "%s\n"
732 733 734
		   (file-relative-name
		    (expand-file-name
		     (nth 0 x) (file-name-directory filename)))))
735
		 (put-text-property start (1- (point)) 'dired-filename t))
736 737 738
	       (forward-line)
	       (beginning-of-line))))
	 entries)))))
739 740

(defun tramp-smb-handle-make-directory (dir &optional parents)
741
  "Like `make-directory' for Tramp files."
742 743
  (setq dir (directory-file-name (expand-file-name dir)))
  (unless (file-name-absolute-p dir)
744
    (setq dir (expand-file-name dir default-directory)))
Michael Albinus's avatar
Michael Albinus committed
745
  (with-parsed-tramp-file-name dir nil
746
    (save-match-data
747
      (let* ((ldir (file-name-directory dir)))
748
	;; Make missing directory parts.
749 750 751
	(when (and parents
		   (tramp-smb-get-share v)
		   (not (file-directory-p ldir)))
752
	  (make-directory ldir parents))
753
	;; Just do it.
754
	(when (file-directory-p ldir)
755
	  (make-directory-internal dir))
756
	(unless (file-directory-p dir)
757
	  (tramp-error v 'file-error "Couldn't make directory %s" dir))))))
758 759

(defun tramp-smb-handle-make-directory-internal (directory)
760
  "Like `make-directory-internal' for Tramp files."
761 762
  (setq directory (directory-file-name (expand-file-name directory)))
  (unless (file-name-absolute-p directory)
763
    (setq directory (expand-file-name directory default-directory)))
Michael Albinus's avatar
Michael Albinus committed
764
  (with-parsed-tramp-file-name directory nil
765
    (save-match-data
766
      (let* ((file (tramp-smb-get-localname v)))
767
	(when (file-directory-p (file-name-directory directory))
768 769
	  (tramp-smb-send-command
	   v
770
	   (if (tramp-smb-get-cifs-capabilities v)
771 772
	       (format
		"posix_mkdir \"%s\" %s"
773
		file (tramp-compat-decimal-to-octal (default-file-modes)))
774
	     (format "mkdir \"%s\"" file)))
775
	  ;; We must also flush the cache of the directory, because
776 777 778
	  ;; `file-attributes' reads the values from there.
	  (tramp-flush-file-property v (file-name-directory localname))
	  (tramp-flush-file-property v localname))
779
	(unless (file-directory-p directory)
780 781
	  (tramp-error
	   v 'file-error "Couldn't make directory %s" directory))))))
782

783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827
(defun tramp-smb-handle-make-symbolic-link
  (filename linkname &optional ok-if-already-exists)
  "Like `make-symbolic-link' for Tramp files.
If LINKNAME is a non-Tramp file, it is used verbatim as the target of
the symlink.  If LINKNAME is a Tramp file, only the localname component is
used as the target of the symlink.

If LINKNAME is a Tramp file and the localname component is relative, then
it is expanded first, before the localname component is taken.  Note that
this can give surprising results if the user/host for the source and
target of the symlink differ."
  (unless (tramp-equal-remote filename linkname)
    (with-parsed-tramp-file-name
	(if (tramp-tramp-file-p filename) filename linkname) nil
      (tramp-error
       v 'file-error
       "make-symbolic-link: %s"
       "only implemented for same method, same user, same host")))
  (with-parsed-tramp-file-name filename v1
    (with-parsed-tramp-file-name linkname v2
      (when (file-directory-p filename)
	(tramp-error
	 v2 'file-error
	 "make-symbolic-link: %s must not be a directory" filename))
      (when (and (not ok-if-already-exists)
		 (file-exists-p linkname)
		 (not (numberp ok-if-already-exists))
		 (y-or-n-p
		  (format
		   "File %s already exists; make it a new name anyway? "
		   linkname)))
	(tramp-error
	 v2 'file-error
	 "make-symbolic-link: file %s already exists" linkname))
      (unless (tramp-smb-get-cifs-capabilities v1)
	(tramp-error v2 'file-error "make-symbolic-link not supported"))
      ;; We must also flush the cache of the directory, because
      ;; `file-attributes' reads the values from there.
      (tramp-flush-file-property v2 (file-name-directory v2-localname))
      (tramp-flush-file-property v2 v2-localname)
      (unless
	  (tramp-smb-send-command
	   v1
	   (format
	    "symlink \"%s\" \"%s\""
828 829
	    (tramp-smb-get-localname v1)
	    (tramp-smb-get-localname v2)))
830 831 832 833 834
	(tramp-error
	 v2 'file-error
	 "error with make-symbolic-link, see buffer `%s' for details"
	 (buffer-name))))))

835 836
(defun tramp-smb-handle-rename-file
  (filename newname &optional ok-if-already-exists)
837
  "Like `rename-file' for Tramp files."
838 839
  (setq filename (expand-file-name filename)
	newname (expand-file-name newname))
840 841 842 843 844 845 846 847 848 849 850
  (with-progress-reporter
      (tramp-dissect-file-name (if (file-remote-p filename) filename newname))
      0 (format "Renaming %s to %s" filename newname)

    (let ((tmpfile (file-local-copy filename)))

      (if tmpfile
	  ;; Remote filename.
	  (condition-case err
	      (rename-file tmpfile newname ok-if-already-exists)
	    ((error quit)
851
	     (delete-file tmpfile)
852 853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870
	     (signal (car err) (cdr err))))

	;; Remote newname.
	(when (file-directory-p newname)
	  (setq newname (expand-file-name
			 (file-name-nondirectory filename) newname)))

	(with-parsed-tramp-file-name newname nil
	  (when (and (not ok-if-already-exists)
		     (file-exists-p newname))
	    (tramp-error v 'file-already-exists newname))
	  ;; We must also flush the cache of the directory, because
	  ;; `file-attributes' reads the values from there.
	  (tramp-flush-file-property v (file-name-directory localname))
	  (tramp-flush-file-property v localname)
	  (unless (tramp-smb-send-command
		   v (format "put %s \"%s\""
			     filename (tramp-smb-get-localname v)))
	    (tramp-error v 'file-error "Cannot rename `%s'" filename)))))
871

872
    (delete-file filename)))
873

874 875 876
(defun tramp-smb-handle-set-file-modes (filename mode)
  "Like `set-file-modes' for Tramp files."
  (with-parsed-tramp-file-name filename nil
877 878 879 880
    (when (tramp-smb-get-cifs-capabilities v)
      (tramp-flush-file-property v localname)
      (unless (tramp-smb-send-command
	       v (format "chmod \"%s\" %s"
881
			 (tramp-smb-get-localname v)
882
			 (tramp-compat-decimal-to-octal mode)))
883 884
	(tramp-error
	 v 'file-error "Error while changing file's mode %s" filename)))))
885

Michael Albinus's avatar
Michael Albinus committed
886
(defun tramp-smb-handle-substitute-in-file-name (filename)
887
  "Like `handle-substitute-in-file-name' for Tramp files.
888 889 890 891 892 893 894 895
\"//\" substitutes only in the local filename part.  Catches
errors for shares like \"C$/\", which are common in Microsoft Windows."
  (with-parsed-tramp-file-name filename nil
    ;; Ignore in LOCALNAME everything before "//".
    (when (and (stringp localname) (string-match ".+?/\\(/\\|~\\)" localname))
      (setq filename
	    (concat (file-remote-p filename)
		    (replace-match "\\1" nil nil localname)))))
Michael Albinus's avatar
Michael Albinus committed
896 897 898 899
  (condition-case nil
      (tramp-run-real-handler 'substitute-in-file-name (list filename))
    (error filename)))

900 901
(defun tramp-smb-handle-write-region
  (start end filename &optional append visit lockname confirm)
902
  "Like `write-region' for Tramp files."
903
  (setq filename (expand-file-name filename))
Michael Albinus's avatar
Michael Albinus committed
904
  (with-parsed-tramp-file-name filename nil
905 906
    (unless (eq append nil)
      (tramp-error
907
	 v 'file-error "Cannot append to file using Tramp (`%s')" filename))
908
    ;; XEmacs takes a coding system as the seventh argument, not `confirm'.
909 910 911 912 913 914
    (when (and (not (featurep 'xemacs))
	       confirm (file-exists-p filename))
      (unless (y-or-n-p (format "File %s exists; overwrite anyway? "
				filename))
	(tramp-error v 'file-error "File not overwritten")))
    ;; We must also flush the cache of the directory, because
915
    ;; `file-attributes' reads the values from there.
916 917
    (tramp-flush-file-property v (file-name-directory localname))
    (tramp-flush-file-property v localname)
918
    (let ((curbuf (current-buffer))
919
	  (tmpfile (tramp-compat-make-temp-file filename)))
920 921 922 923 924 925
      ;; We say `no-message' here because we don't want the visited file
      ;; modtime data to be clobbered from the temp file.  We call
      ;; `set-visited-file-modtime' ourselves later on.
      (tramp-run-real-handler
       'write-region
       (if confirm ; don't pass this arg unless defined for backward compat.
926 927
	   (list start end tmpfile append 'no-message lockname confirm)
	 (list start end tmpfile append 'no-message lockname)))
928

929 930 931 932 933 934 935
      (with-progress-reporter
	  v 3 (format "Moving tmp file %s to %s" tmpfile filename)
	(unwind-protect
	    (unless (tramp-smb-send-command
		     v (format "put %s \"%s\""
			       tmpfile (tramp-smb-get-localname v)))
	      (tramp-error v 'file-error "Cannot write `%s'" filename))
936
	  (delete-file tmpfile)))
937 938 939 940 941 942 943

      (unless (equal curbuf (current-buffer))
	(tramp-error
	 v 'file-error
	 "Buffer has changed from `%s' to `%s'" curbuf (current-buffer)))
      (when (eq visit t)
	(set-visited-file-modtime)))))
944 945


946
;; Internal file name functions.
947

948
(defun tramp-smb-get-share (vec)
Kai Großjohann's avatar
Kai Großjohann committed
949
  "Returns the share name of LOCALNAME."
950
  (save-match-data
951 952 953
    (let ((localname (tramp-file-name-localname vec)))
      (when (string-match "^/?\\([^/]+\\)/" localname)
	(match-string 1 localname)))))
954

955
(defun tramp-smb-get-localname (vec)
Kai Großjohann's avatar
Kai Großjohann committed
956
  "Returns the file name of LOCALNAME.
957
If VEC has no cifs capabilities, exchange \"/\" by \"\\\\\"."
958
  (save-match-data
959
    (let ((localname (tramp-file-name-localname vec)))
960
      (setq
961 962 963 964 965 966 967 968 969 970 971 972
       localname
       (if (string-match "^/?[^/]+\\(/.*\\)" localname)
	   ;; There is a share, sparated by "/".
	   (if (not (tramp-smb-get-cifs-capabilities vec))
	       (mapconcat
		(lambda (x) (if (equal x ?/) "\\" (char-to-string x)))
		(match-string 1 localname) "")
	     (match-string 1 localname))
	 ;; There is just a share.
	 (if (string-match "^/?\\([^/]+\\)$" localname)
	     (match-string 1 localname)
	   "")))
973

974
      ;; Sometimes we have discarded `substitute-in-file-name'.
975 976
      (when (string-match "\\(\\$\\$\\)\\(/\\|$\\)" localname)
	(setq localname (replace-match "$" nil nil localname 1)))
977

978
      localname)))
979 980 981

;; Share names of a host are cached. It is very unlikely that the
;; shares do change during connection.
982 983
(defun tramp-smb-get-file-entries (directory)
  "Read entries which match DIRECTORY.
984
Either the shares are listed, or the `dir' command is executed.
Kai Großjohann's avatar
Kai Großjohann committed
985
Result is a list of (LOCALNAME MODE SIZE MONTH DAY TIME YEAR)."
986
  (with-parsed-tramp-file-name (file-name-as-directory directory) nil
987 988 989
    (setq localname (or localname "/"))
    (with-file-property v localname "file-entries"
      (with-current-buffer (tramp-get-buffer v)
990
	(let* ((share (tramp-smb-get-share v))