register.el 15.4 KB
Newer Older
1
;;; register.el --- register commands for Emacs
Eric S. Raymond's avatar
Eric S. Raymond committed
2

3 4
;; Copyright (C) 1985, 1993-1994, 2001-2013 Free Software Foundation,
;; Inc.
Eric S. Raymond's avatar
Eric S. Raymond committed
5

Eric S. Raymond's avatar
Eric S. Raymond committed
6
;; Maintainer: FSF
Eric S. Raymond's avatar
Eric S. Raymond committed
7
;; Keywords: internal
8
;; Package: emacs
Eric S. Raymond's avatar
Eric S. Raymond committed
9

Richard M. Stallman's avatar
Richard M. Stallman committed
10 11
;; This file is part of GNU Emacs.

12
;; GNU Emacs is free software: you can redistribute it and/or modify
Richard M. Stallman's avatar
Richard M. Stallman committed
13
;; it under the terms of the GNU General Public License as published by
14 15
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Richard M. Stallman's avatar
Richard M. Stallman committed
16 17 18 19 20 21 22

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
23
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
Richard M. Stallman's avatar
Richard M. Stallman committed
24

25 26 27 28 29 30 31
;;; Commentary:

;; This package of functions emulates and somewhat extends the venerable
;; TECO's `register' feature, which permits you to save various useful
;; pieces of buffer state to named variables.  The entry points are
;; documented in the Emacs user's manual.

Stefan Monnier's avatar
Stefan Monnier committed
32
(eval-when-compile (require 'cl-lib))
33

Eric S. Raymond's avatar
Eric S. Raymond committed
34
;;; Code:
Richard M. Stallman's avatar
Richard M. Stallman committed
35

Stefan Monnier's avatar
Stefan Monnier committed
36
(cl-defstruct
37 38 39 40 41 42 43 44 45 46 47
  (registerv (:constructor nil)
	     (:constructor registerv--make (&optional data print-func
						      jump-func insert-func))
	     (:copier nil)
	     (:type vector)
	     :named)
  (data        nil :read-only t)
  (print-func  nil :read-only t)
  (jump-func   nil :read-only t)
  (insert-func nil :read-only t))

Stefan Monnier's avatar
Stefan Monnier committed
48
(cl-defun registerv-make (data &key print-func jump-func insert-func)
49 50 51 52 53
  "Create a register value object.

DATA can be any value.
PRINT-FUNC if provided controls how `list-registers' and
`view-register' print the register.  It should be a function
Juanma Barranquero's avatar
Juanma Barranquero committed
54
receiving one argument DATA and print text that completes
55 56 57 58 59 60 61
this sentence:
  Register X contains [TEXT PRINTED BY PRINT-FUNC]
JUMP-FUNC if provided, controls how `jump-to-register' jumps to the register.
INSERT-FUNC if provided, controls how `insert-register' insert the register.
They both receive DATA as argument."
  (registerv--make data print-func jump-func insert-func))

Richard M. Stallman's avatar
Richard M. Stallman committed
62 63
(defvar register-alist nil
  "Alist of elements (NAME . CONTENTS), one for each Emacs register.
64 65
NAME is a character (a number).  CONTENTS is a string, number, marker, list
or a struct returned by `registerv-make'.
66
A list of strings represents a rectangle.
67 68 69 70
A list of the form (file . FILE-NAME) represents the file named FILE-NAME.
A list of the form (file-query FILE-NAME POSITION) represents
 position POSITION in the file named FILE-NAME, but query before
 visiting it.
Karl Heuer's avatar
Karl Heuer committed
71 72 73
A list of the form (WINDOW-CONFIGURATION POSITION)
 represents a saved window configuration plus a saved value of point.
A list of the form (FRAME-CONFIGURATION POSITION)
74
 represents a saved frame configuration plus a saved value of point.")
Richard M. Stallman's avatar
Richard M. Stallman committed
75

76 77 78
(defgroup register nil
  "Register commands."
  :group 'convenience
79
  :version "24.3")
80

81 82
(defcustom register-separator nil
  "Register containing the text to put between collected texts, or nil if none.
83 84 85 86 87 88 89 90 91

When collecting text with
`append-to-register' (resp. `prepend-to-register') contents of
this register is added to the beginning (resp. end) of the marked
text."
  :group 'register
  :type '(choice (const :tag "None" nil)
		 (character :tag "Use register" :value ?+)))

92 93 94
(defun get-register (register)
  "Return contents of Emacs register named REGISTER, or nil if none."
  (cdr (assq register register-alist)))
Richard M. Stallman's avatar
Richard M. Stallman committed
95

96 97
(defun set-register (register value)
  "Set contents of Emacs register named REGISTER to VALUE.  Returns VALUE.
98
See the documentation of the variable `register-alist' for possible VALUEs."
99
  (let ((aelt (assq register register-alist)))
Richard M. Stallman's avatar
Richard M. Stallman committed
100 101
    (if aelt
	(setcdr aelt value)
Stefan Monnier's avatar
Stefan Monnier committed
102
      (push (cons register value) register-alist))
Richard M. Stallman's avatar
Richard M. Stallman committed
103 104
    value))

105
(defun point-to-register (register &optional arg)
106
  "Store current location of point in register REGISTER.
Jim Blandy's avatar
Jim Blandy committed
107
With prefix argument, store current frame configuration.
108
Use \\[jump-to-register] to go to that location or restore that configuration.
Richard M. Stallman's avatar
Richard M. Stallman committed
109
Argument is a character, naming the register."
110
  (interactive "cPoint to register: \nP")
Stefan Monnier's avatar
Stefan Monnier committed
111 112
  ;; Turn the marker into a file-ref if the buffer is killed.
  (add-hook 'kill-buffer-hook 'register-swap-out nil t)
113
  (set-register register
Karl Heuer's avatar
Karl Heuer committed
114 115
		(if arg (list (current-frame-configuration) (point-marker))
		  (point-marker))))
Richard M. Stallman's avatar
Richard M. Stallman committed
116

117
(defun window-configuration-to-register (register &optional _arg)
118 119 120
  "Store the window configuration of the selected frame in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Argument is a character, naming the register."
121
  (interactive "cWindow configuration to register: \nP")
122 123
  ;; current-window-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
124
  (set-register register (list (current-window-configuration) (point-marker))))
125

126
(defun frame-configuration-to-register (register &optional _arg)
127 128 129
  "Store the window configuration of all frames in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Argument is a character, naming the register."
130
  (interactive "cFrame configuration to register: \nP")
131 132
  ;; current-frame-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
133
  (set-register register (list (current-frame-configuration) (point-marker))))
134

135
(defalias 'register-to-point 'jump-to-register)
136
(defun jump-to-register (register &optional delete)
Richard M. Stallman's avatar
Richard M. Stallman committed
137
  "Move point to location stored in a register.
138
If the register contains a file name, find that file.
139
\(To put a file name in a register, you must use `set-register'.)
140 141
If the register contains a window configuration (one frame) or a frameset
\(all frames), restore that frame or all frames accordingly.
142
First argument is a character, naming the register.
143
Optional second arg non-nil (interactively, prefix argument) says to
144
delete any existing frames that the frameset doesn't mention.
145
\(Otherwise, these frames are iconified.)"
146
  (interactive "cJump to register: \nP")
147
  (let ((val (get-register register)))
148
    (cond
149
     ((registerv-p val)
Stefan Monnier's avatar
Stefan Monnier committed
150
      (cl-assert (registerv-jump-func val) nil
151 152 153
              "Don't know how to jump to register %s"
              (single-key-description register))
      (funcall (registerv-jump-func val) (registerv-data val)))
154 155 156 157 158 159
     ((and (consp val) (frame-configuration-p (car val)))
      (set-frame-configuration (car val) (not delete))
      (goto-char (cadr val)))
     ((and (consp val) (window-configuration-p (car val)))
      (set-window-configuration (car val))
      (goto-char (cadr val)))
160
     ((markerp val)
161 162
      (or (marker-buffer val)
	  (error "That register's buffer no longer exists"))
163 164
      (switch-to-buffer (marker-buffer val))
      (goto-char val))
165 166
     ((and (consp val) (eq (car val) 'file))
      (find-file (cdr val)))
167 168 169 170 171 172
     ((and (consp val) (eq (car val) 'file-query))
      (or (find-buffer-visiting (nth 1 val))
	  (y-or-n-p (format "Visit file %s again? " (nth 1 val)))
	  (error "Register access aborted"))
      (find-file (nth 1 val))
      (goto-char (nth 2 val)))
173 174
     (t
      (error "Register doesn't contain a buffer position or configuration")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
175

176
(defun register-swap-out ()
Stefan Monnier's avatar
Stefan Monnier committed
177
  "Turn markers into file-query references when a buffer is killed."
178
  (and buffer-file-name
Stefan Monnier's avatar
Stefan Monnier committed
179 180 181 182 183 184 185
       (dolist (elem register-alist)
	 (and (markerp (cdr elem))
	      (eq (marker-buffer (cdr elem)) (current-buffer))
	      (setcdr elem
		      (list 'file-query
			    buffer-file-name
			    (marker-position (cdr elem))))))))
186

187
(defun number-to-register (number register)
Karl Heuer's avatar
Karl Heuer committed
188 189
  "Store a number in a register.
Two args, NUMBER and REGISTER (a character, naming the register).
190 191
If NUMBER is nil, a decimal number is read from the buffer starting
at point, and point moves to the end of that number.
Karl Heuer's avatar
Karl Heuer committed
192 193
Interactively, NUMBER is the prefix arg (none means nil)."
  (interactive "P\ncNumber to register: ")
194
  (set-register register
195 196
		(if number
		    (prefix-numeric-value number)
197 198 199
		  (if (looking-at "\\s-*-?[0-9]+")
		      (progn
			(goto-char (match-end 0))
200
			(string-to-number (match-string 0)))
Karl Heuer's avatar
Karl Heuer committed
201 202
		    0))))

203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220
(defun increment-register (prefix register)
  "Augment contents of REGISTER.
Interactively, PREFIX is in raw form.

If REGISTER contains a number, add `prefix-numeric-value' of
PREFIX to it.

If REGISTER is empty or if it contains text, call
`append-to-register' with `delete-flag' set to PREFIX."
  (interactive "P\ncIncrement register: ")
  (let ((register-val (get-register register)))
    (cond
     ((numberp register-val)
      (let ((number (prefix-numeric-value prefix)))
	(set-register register (+ number register-val))))
     ((or (not register-val) (stringp register-val))
      (append-to-register register (region-beginning) (region-end) prefix))
     (t (error "Register does not contain a number or text")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
221

222
(defun view-register (register)
Richard M. Stallman's avatar
Richard M. Stallman committed
223
  "Display what is contained in register named REGISTER.
224
The Lisp value REGISTER is a character."
Richard M. Stallman's avatar
Richard M. Stallman committed
225
  (interactive "cView register: ")
226
  (let ((val (get-register register)))
Richard M. Stallman's avatar
Richard M. Stallman committed
227
    (if (null val)
228
	(message "Register %s is empty" (single-key-description register))
Richard M. Stallman's avatar
Richard M. Stallman committed
229
      (with-output-to-temp-buffer "*Output*"
230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246
	(describe-register-1 register t)))))

(defun list-registers ()
  "Display a list of nonempty registers saying briefly what they contain."
  (interactive)
  (let ((list (copy-sequence register-alist)))
    (setq list (sort list (lambda (a b) (< (car a) (car b)))))
    (with-output-to-temp-buffer "*Output*"
      (dolist (elt list)
	(when (get-register (car elt))
	  (describe-register-1 (car elt))
	  (terpri))))))

(defun describe-register-1 (register &optional verbose)
  (princ "Register ")
  (princ (single-key-description register))
  (princ " contains ")
247 248
  (let ((val (get-register register)))
    (cond
249 250 251 252 253
     ((registerv-p val)
      (if (registerv-print-func val)
          (funcall (registerv-print-func val) (registerv-data val))
        (princ "[UNPRINTABLE CONTENTS].")))

254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296
     ((numberp val)
      (princ val))

     ((markerp val)
      (let ((buf (marker-buffer val)))
	(if (null buf)
	    (princ "a marker in no buffer")
	  (princ "a buffer position:\n    buffer ")
	  (princ (buffer-name buf))
	  (princ ", position ")
	  (princ (marker-position val)))))

     ((and (consp val) (window-configuration-p (car val)))
      (princ "a window configuration."))

     ((and (consp val) (frame-configuration-p (car val)))
      (princ "a frame configuration."))

     ((and (consp val) (eq (car val) 'file))
      (princ "the file ")
      (prin1 (cdr val))
      (princ "."))

     ((and (consp val) (eq (car val) 'file-query))
      (princ "a file-query reference:\n    file ")
      (prin1 (car (cdr val)))
      (princ ",\n    position ")
      (princ (car (cdr (cdr val))))
      (princ "."))

     ((consp val)
      (if verbose
	  (progn
	    (princ "the rectangle:\n")
	    (while val
	      (princ "    ")
	      (princ (car val))
	      (terpri)
	      (setq val (cdr val))))
	(princ "a rectangle starting with ")
	(princ (car val))))

     ((stringp val)
297 298 299 300
      (if (eq yank-excluded-properties t)
	  (set-text-properties 0 (length val) nil val)
	(remove-list-of-text-properties 0 (length val)
					yank-excluded-properties val))
301 302 303 304
      (if verbose
	  (progn
	    (princ "the text:\n")
	    (princ val))
305
	(cond
306 307 308 309 310 311 312 313 314 315 316
	 ;; Extract first N characters starting with first non-whitespace.
	 ((string-match (format "[^ \t\n].\\{,%d\\}"
				;; Deduct 6 for the spaces inserted below.
				(min 20 (max 0 (- (window-width) 6))))
			val)
	  (princ "text starting with\n    ")
	  (princ (match-string 0 val)))
	 ((string-match "^[ \t\n]+$" val)
	  (princ "whitespace"))
	 (t
	  (princ "the empty string")))))
317 318 319
     (t
      (princ "Garbage:\n")
      (if verbose (prin1 val))))))
Richard M. Stallman's avatar
Richard M. Stallman committed
320

321 322
(defun insert-register (register &optional arg)
  "Insert contents of register REGISTER.  (REGISTER is a character.)
Richard M. Stallman's avatar
Richard M. Stallman committed
323 324 325
Normally puts point before and mark after the inserted text.
If optional second arg is non-nil, puts mark before and point after.
Interactively, second arg is non-nil if prefix arg is supplied."
326
  (interactive "*cInsert register: \nP")
Richard M. Stallman's avatar
Richard M. Stallman committed
327
  (push-mark)
328
  (let ((val (get-register register)))
329
    (cond
330
     ((registerv-p val)
Stefan Monnier's avatar
Stefan Monnier committed
331
      (cl-assert (registerv-insert-func val) nil
332 333 334
              "Don't know how to insert register %s"
              (single-key-description register))
      (funcall (registerv-insert-func val) (registerv-data val)))
335 336
     ((consp val)
      (insert-rectangle val))
337
     ((stringp val)
338
      (insert-for-yank val))
Karl Heuer's avatar
Karl Heuer committed
339
     ((numberp val)
340 341 342 343 344
      (princ val (current-buffer)))
     ((and (markerp val) (marker-position val))
      (princ (marker-position val) (current-buffer)))
     (t
      (error "Register does not contain text"))))
Richard M. Stallman's avatar
Richard M. Stallman committed
345 346
  (if (not arg) (exchange-point-and-mark)))

347
(defun copy-to-register (register start end &optional delete-flag)
348 349
  "Copy region into register REGISTER.
With prefix arg, delete as well.
350
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
351 352
START and END are buffer positions indicating what to copy."
  (interactive "cCopy to register: \nr\nP")
353
  (set-register register (filter-buffer-substring start end))
354 355 356 357 358
  (setq deactivate-mark t)
  (cond (delete-flag
	 (delete-region start end))
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
359

360 361 362 363
(defun append-to-register (register start end &optional delete-flag)
  "Append region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
364 365
START and END are buffer positions indicating what to append."
  (interactive "cAppend to register: \nr\nP")
366
  (let ((reg (get-register register))
367
        (text (filter-buffer-substring start end))
368
	(separator (and register-separator (get-register register-separator))))
369 370
    (set-register
     register (cond ((not reg) text)
371
                    ((stringp reg) (concat reg separator text))
372
                    (t (error "Register does not contain text")))))
373
  (setq deactivate-mark t)
374 375 376 377
  (cond (delete-flag
	 (delete-region start end))
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
378

379 380 381 382
(defun prepend-to-register (register start end &optional delete-flag)
  "Prepend region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
383 384
START and END are buffer positions indicating what to prepend."
  (interactive "cPrepend to register: \nr\nP")
385
  (let ((reg (get-register register))
386
        (text (filter-buffer-substring start end))
387
	(separator (and register-separator (get-register register-separator))))
388 389
    (set-register
     register (cond ((not reg) text)
390
                    ((stringp reg) (concat text separator reg))
391
                    (t (error "Register does not contain text")))))
392
  (setq deactivate-mark t)
393 394 395 396
  (cond (delete-flag
	 (delete-region start end))
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
397

398 399
(defun copy-rectangle-to-register (register start end &optional delete-flag)
  "Copy rectangular region into register REGISTER.
400 401
With prefix arg, delete as well.
To insert this register in the buffer, use \\[insert-register].
402 403

Called from a program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
404 405
START and END are buffer positions giving two corners of rectangle."
  (interactive "cCopy rectangle to register: \nr\nP")
406 407 408 409 410 411 412 413 414
  (let ((rectangle (if delete-flag
		       (delete-extract-rectangle start end)
		     (extract-rectangle start end))))
    (set-register register rectangle)
    (when (and (null delete-flag)
	       (called-interactively-p 'interactive))
      (setq deactivate-mark t)
      (indicate-copied-region (length (car rectangle))))))

Eric S. Raymond's avatar
Eric S. Raymond committed
415

Masatake YAMATO's avatar
Masatake YAMATO committed
416
(provide 'register)
Eric S. Raymond's avatar
Eric S. Raymond committed
417
;;; register.el ends here