tramp-smb.el 65 KB
Newer Older
Michael Albinus's avatar
Michael Albinus committed
1
;;; tramp-smb.el --- Tramp access functions for SMB servers
2

3
;; Copyright (C) 2002-2012 Free Software Foundation, Inc.
4

Michael Albinus's avatar
Michael Albinus committed
5
;; Author: Michael Albinus <michael.albinus@gmx.de>
6
;; Keywords: comm, processes
7
;; Package: tramp
8 9 10

;; This file is part of GNU Emacs.

11
;; GNU Emacs is free software: you can redistribute it and/or modify
12
;; it under the terms of the GNU General Public License as published by
13 14
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
15 16 17 18 19 20 21

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
23 24 25 26 27 28 29

;;; Commentary:

;; Access functions for SMB servers like SAMBA or M$ Windows from Tramp.

;;; Code:

Glenn Morris's avatar
Glenn Morris committed
30
(eval-when-compile (require 'cl))	; block, return
31 32 33
(require 'tramp)

;; Define SMB method ...
34 35
;;;###tramp-autoload
(defconst tramp-smb-method "smb"
36
  "Method to connect SAMBA and M$ SMB servers.")
37 38

;; ... and add it to the method list.
39 40
;;;###tramp-autoload
(unless (memq system-type '(cygwin windows-nt))
41 42 43 44 45
  (add-to-list 'tramp-methods
    `(,tramp-smb-method
      ;; We define an empty command, because `tramp-smb-call-winexe'
      ;; opens already the powershell.  Used in `tramp-handle-shell-command'.
      (tramp-remote-shell "")
Michael Albinus's avatar
Michael Albinus committed
46
      ;; This is just a guess.  We don't know whether the share "C$"
47 48 49
      ;; is available for public use, and whether the user has write
      ;; access.
      (tramp-tmpdir "/C$/Temp"))))
50 51 52

;; Add a default for `tramp-default-method-alist'. Rule: If there is
;; a domain in USER, it must be the SMB method.
53
;;;###tramp-autoload
54
(add-to-list 'tramp-default-method-alist
55
	     `(nil ,tramp-prefix-domain-regexp ,tramp-smb-method))
56 57 58

;; Add a default for `tramp-default-user-alist'. Rule: For the SMB method,
;; the anonymous user is chosen.
59
;;;###tramp-autoload
60
(add-to-list 'tramp-default-user-alist
61
	     `(,(concat "\\`" tramp-smb-method "\\'") nil nil))
62 63

;; Add completion function for SMB method.
64 65 66 67 68
;;;###tramp-autoload
(eval-after-load 'tramp
  '(tramp-set-completion-function
    tramp-smb-method
    '((tramp-parse-netrc "~/.netrc"))))
69 70

(defcustom tramp-smb-program "smbclient"
71
  "Name of SMB client to run."
72 73 74
  :group 'tramp
  :type 'string)

75
(defcustom tramp-smb-conf "/dev/null"
76
  "Path of the smb.conf file.
77 78 79 80 81
If it is nil, no smb.conf will be added to the `tramp-smb-program'
call, letting the SMB client use the default one."
  :group 'tramp
  :type '(choice (const nil) (file :must-match t)))

82
(defvar tramp-smb-version nil
83
  "Version string of the SMB client.")
84

Michael Albinus's avatar
Michael Albinus committed
85 86 87 88 89 90 91 92 93 94 95 96
(defconst tramp-smb-server-version
  "Domain=\\[[^]]*\\] OS=\\[[^]]*\\] Server=\\[[^]]*\\]"
  "Regexp of SMB server identification.")

(defconst tramp-smb-prompt "^\\(smb:\\|PS\\) .+> \\|^\\s-+Server\\s-+Comment$"
  "Regexp used as prompt in smbclient or powershell.")

(defconst tramp-smb-wrong-passwd-regexp
  (regexp-opt
   '("NT_STATUS_LOGON_FAILURE"
     "NT_STATUS_WRONG_PASSWORD"))
  "Regexp for login error strings of SMB servers.")
97 98 99 100

(defconst tramp-smb-errors
  (mapconcat
   'identity
101 102
   `(;; Connection error / timeout / unknown command.
     "Connection\\( to \\S-+\\)? failed"
103
     "Read from server failed, maybe it closed the connection"
104
     "Call timed out: server did not respond"
105 106
     "\\S-+: command not found"
     "Server doesn't support UNIX CIFS calls"
107 108 109 110 111 112 113 114 115 116 117 118
     ,(regexp-opt
       '(;; Samba.
	 "ERRDOS"
	 "ERRHRD"
	 "ERRSRV"
	 "ERRbadfile"
	 "ERRbadpw"
	 "ERRfilexists"
	 "ERRnoaccess"
	 "ERRnomem"
	 "ERRnosuchshare"
	 ;; Windows 4.0 (Windows NT), Windows 5.0 (Windows 2000),
119 120
	 ;; Windows 5.1 (Windows XP), Windows 5.2 (Windows Server 2003),
	 ;; Windows 6.0 (Windows Vista), Windows 6.1 (Windows 7).
121 122 123 124 125 126 127 128
	 "NT_STATUS_ACCESS_DENIED"
	 "NT_STATUS_ACCOUNT_LOCKED_OUT"
	 "NT_STATUS_BAD_NETWORK_NAME"
	 "NT_STATUS_CANNOT_DELETE"
	 "NT_STATUS_CONNECTION_REFUSED"
	 "NT_STATUS_DIRECTORY_NOT_EMPTY"
	 "NT_STATUS_DUPLICATE_NAME"
	 "NT_STATUS_FILE_IS_A_DIRECTORY"
129
	 "NT_STATUS_IMAGE_ALREADY_LOADED"
130 131 132 133 134 135 136 137 138 139 140 141 142
	 "NT_STATUS_IO_TIMEOUT"
	 "NT_STATUS_LOGON_FAILURE"
	 "NT_STATUS_NETWORK_ACCESS_DENIED"
	 "NT_STATUS_NOT_IMPLEMENTED"
	 "NT_STATUS_NO_SUCH_FILE"
	 "NT_STATUS_NO_SUCH_USER"
	 "NT_STATUS_OBJECT_NAME_COLLISION"
	 "NT_STATUS_OBJECT_NAME_INVALID"
	 "NT_STATUS_OBJECT_NAME_NOT_FOUND"
	 "NT_STATUS_SHARING_VIOLATION"
	 "NT_STATUS_TRUSTED_RELATIONSHIP_FAILURE"
	 "NT_STATUS_UNSUCCESSFUL"
	 "NT_STATUS_WRONG_PASSWORD")))
143 144 145 146
   "\\|")
  "Regexp for possible error strings of SMB servers.
Used instead of analyzing error codes of commands.")

147 148 149 150 151 152 153 154 155 156
(defconst tramp-smb-actions-with-share
  '((tramp-smb-prompt tramp-action-succeed)
    (tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-process-alive))
  "List of pattern/action pairs.
This list is used for login to SMB servers.

See `tramp-actions-before-shell' for more info.")
157

158 159 160 161 162 163 164
(defconst tramp-smb-actions-without-share
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-out-of-band))
  "List of pattern/action pairs.
This list is used for login to SMB servers.
165

166
See `tramp-actions-before-shell' for more info.")
167

Michael Albinus's avatar
Michael Albinus committed
168 169 170 171 172 173 174 175 176 177
(defconst tramp-smb-actions-with-tar
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-smb-action-with-tar))
  "List of pattern/action pairs.
This list is used for tar-like copy of directories.

See `tramp-actions-before-shell' for more info.")

178 179 180
;; New handlers should be added here.
(defconst tramp-smb-file-name-handler-alist
  '(
181
    ;; `access-file' performed by default handler.
182
    (add-name-to-file . tramp-smb-handle-add-name-to-file)
183 184
    ;; `byte-compiler-base-file-name' performed by default handler.
    (copy-directory . tramp-smb-handle-copy-directory)
185 186 187
    (copy-file . tramp-smb-handle-copy-file)
    (delete-directory . tramp-smb-handle-delete-directory)
    (delete-file . tramp-smb-handle-delete-file)
188
    ;; `diff-latest-backup-file' performed by default handler.
189
    (directory-file-name . tramp-handle-directory-file-name)
190
    (directory-files . tramp-smb-handle-directory-files)
191
    (directory-files-and-attributes
192
     . tramp-handle-directory-files-and-attributes)
193 194
    (dired-call-process . ignore)
    (dired-compress-file . ignore)
195
    (dired-uncache . tramp-handle-dired-uncache)
196
    (expand-file-name . tramp-smb-handle-expand-file-name)
197 198 199
    (file-accessible-directory-p . tramp-smb-handle-file-directory-p)
    (file-attributes . tramp-smb-handle-file-attributes)
    (file-directory-p .  tramp-smb-handle-file-directory-p)
200 201
    (file-executable-p . tramp-handle-file-exists-p)
    (file-exists-p . tramp-handle-file-exists-p)
202 203 204
    (file-local-copy . tramp-smb-handle-file-local-copy)
    (file-modes . tramp-handle-file-modes)
    (file-name-all-completions . tramp-smb-handle-file-name-all-completions)
205
    (file-name-as-directory . tramp-handle-file-name-as-directory)
206 207 208
    (file-name-completion . tramp-handle-file-name-completion)
    (file-name-directory . tramp-handle-file-name-directory)
    (file-name-nondirectory . tramp-handle-file-name-nondirectory)
209
    ;; `file-name-sans-versions' performed by default handler.
210
    (file-newer-than-file-p . tramp-handle-file-newer-than-file-p)
211
    (file-ownership-preserved-p . ignore)
212
    (file-readable-p . tramp-handle-file-exists-p)
213
    (file-regular-p . tramp-handle-file-regular-p)
Michael Albinus's avatar
Michael Albinus committed
214 215
    (file-remote-p . tramp-handle-file-remote-p)
    ;; `file-selinux-context' performed by default handler.
216
    (file-symlink-p . tramp-handle-file-symlink-p)
217
    ;; `file-truename' performed by default handler.
218
    (file-writable-p . tramp-smb-handle-file-writable-p)
219
    (find-backup-file-name . tramp-handle-find-backup-file-name)
220 221
    ;; `find-file-noselect' performed by default handler.
    ;; `get-file-buffer' performed by default handler.
222 223 224 225 226
    (insert-directory . tramp-smb-handle-insert-directory)
    (insert-file-contents . tramp-handle-insert-file-contents)
    (load . tramp-handle-load)
    (make-directory . tramp-smb-handle-make-directory)
    (make-directory-internal . tramp-smb-handle-make-directory-internal)
227
    (make-symbolic-link . tramp-smb-handle-make-symbolic-link)
Michael Albinus's avatar
Michael Albinus committed
228
    (process-file . tramp-smb-handle-process-file)
229
    (rename-file . tramp-smb-handle-rename-file)
230
    (set-file-modes . tramp-smb-handle-set-file-modes)
Michael Albinus's avatar
Michael Albinus committed
231
    ;; `set-file-selinux-context' performed by default handler.
232
    (set-file-times . ignore)
233
    (set-visited-file-modtime . ignore)
Michael Albinus's avatar
Michael Albinus committed
234 235
    (shell-command . tramp-handle-shell-command)
    (start-file-process . tramp-smb-handle-start-file-process)
Michael Albinus's avatar
Michael Albinus committed
236
    (substitute-in-file-name . tramp-smb-handle-substitute-in-file-name)
237
    (unhandled-file-name-directory . tramp-handle-unhandled-file-name-directory)
238 239
    (vc-registered . ignore)
    (verify-visited-file-modtime . ignore)
240 241 242 243 244
    (write-region . tramp-smb-handle-write-region)
)
  "Alist of handler functions for Tramp SMB method.
Operations not mentioned here will be handled by the default Emacs primitives.")

Michael Albinus's avatar
Michael Albinus committed
245 246 247 248 249 250 251
;; Options for remote processes via winexe.
(defcustom tramp-smb-winexe-program "winexe"
  "Name of winexe client to run.
If it isn't found in the local $PATH, the absolute path of winexe
shall be given.  This is needed for remote processes."
  :group 'tramp
  :type 'string
252
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
253 254 255 256 257 258

(defcustom tramp-smb-winexe-shell-command "powershell.exe"
  "Shell to be used for processes on remote machines.
This must be Powershell V2 compatible."
  :group 'tramp
  :type 'string
259
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
260 261 262 263 264 265

(defcustom tramp-smb-winexe-shell-command-switch "-file -"
  "Command switch used together with `tramp-smb-winexe-shell-command'.
This can be used to disable echo etc."
  :group 'tramp
  :type 'string
266
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
267

268 269
;;;###tramp-autoload
(defsubst tramp-smb-file-name-p (filename)
270
  "Check if it's a filename for SMB servers."
Michael Albinus's avatar
Michael Albinus committed
271 272
  (string= (tramp-file-name-method (tramp-dissect-file-name filename))
	   tramp-smb-method))
273

274
;;;###tramp-autoload
275 276 277 278 279 280
(defun tramp-smb-file-name-handler (operation &rest args)
  "Invoke the SMB related OPERATION.
First arg specifies the OPERATION, second arg is a list of arguments to
pass to the OPERATION."
  (let ((fn (assoc operation tramp-smb-file-name-handler-alist)))
    (if fn
281
	(save-match-data (apply (cdr fn) args))
282 283
      (tramp-run-real-handler operation args))))

284 285 286 287
;;;###tramp-autoload
(unless (memq system-type '(cygwin windows-nt))
  (add-to-list 'tramp-foreign-file-name-handler-alist
	       (cons 'tramp-smb-file-name-p 'tramp-smb-file-name-handler)))
288 289


290 291
;; File name primitives.

292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321
(defun tramp-smb-handle-add-name-to-file
  (filename newname &optional ok-if-already-exists)
  "Like `add-name-to-file' for Tramp files."
  (unless (tramp-equal-remote filename newname)
    (with-parsed-tramp-file-name
	(if (tramp-tramp-file-p filename) filename newname) nil
      (tramp-error
       v 'file-error
       "add-name-to-file: %s"
       "only implemented for same method, same user, same host")))
  (with-parsed-tramp-file-name filename v1
    (with-parsed-tramp-file-name newname v2
      (when (file-directory-p filename)
	(tramp-error
	 v2 'file-error
	 "add-name-to-file: %s must not be a directory" filename))
      (when (and (not ok-if-already-exists)
		 (file-exists-p newname)
		 (not (numberp ok-if-already-exists))
		 (y-or-n-p
		  (format
		   "File %s already exists; make it a new name anyway? "
		   newname)))
	(tramp-error
	 v2 'file-error
	 "add-name-to-file: file %s already exists" newname))
      ;; We must also flush the cache of the directory, because
      ;; `file-attributes' reads the values from there.
      (tramp-flush-file-property v2 (file-name-directory v2-localname))
      (tramp-flush-file-property v2 v2-localname)
322 323 324 325 326 327 328 329 330 331 332 333
      (unless
	  (tramp-smb-send-command
	   v1
	   (format
	    "%s \"%s\" \"%s\""
	    (if (tramp-smb-get-cifs-capabilities v1) "link" "hardlink")
	    (tramp-smb-get-localname v1)
	    (tramp-smb-get-localname v2)))
	(tramp-error
	 v2 'file-error
	 "error with add-name-to-file, see buffer `%s' for details"
	 (buffer-name))))))
334

Michael Albinus's avatar
Michael Albinus committed
335 336 337 338 339 340 341 342 343 344 345 346 347 348 349
(defun tramp-smb-action-with-tar (proc vec)
  "Untar from connection buffer."
  (if (not (memq (process-status proc) '(run open)))
      (throw 'tramp-action 'process-died)

    (with-current-buffer (tramp-get-connection-buffer vec)
      (goto-char (point-min))
      (when (search-forward-regexp tramp-smb-server-version nil t)
	;; There might be a hidden password prompt.
	(widen)
	(forward-line)
	(tramp-message vec 6 (buffer-substring (point-min) (point)))
	(delete-region (point-min) (point))
	(throw 'tramp-action 'ok)))))

350
(defun tramp-smb-handle-copy-directory
351
  (dirname newname &optional keep-date parents copy-contents)
Michael Albinus's avatar
Michael Albinus committed
352
  "Like `copy-directory' for Tramp files."
353 354 355 356 357
  (setq dirname (expand-file-name dirname)
	newname (expand-file-name newname))
  (let ((t1 (tramp-tramp-file-p dirname))
	(t2 (tramp-tramp-file-p newname)))
    (with-parsed-tramp-file-name (if t1 dirname newname) nil
358
      (with-tramp-progress-reporter
Michael Albinus's avatar
Michael Albinus committed
359
	  v 0 (format "Copying %s to %s" dirname newname)
360
      (cond
361
       ;; We must use a local temporary directory.
362 363 364 365 366 367 368 369
       ((and t1 t2)
	(let ((tmpdir
	       (make-temp-name
		(expand-file-name
		 tramp-temp-name-prefix
		 (tramp-compat-temporary-file-directory)))))
	  (unwind-protect
	      (progn
370 371 372
		(tramp-compat-copy-directory dirname tmpdir keep-date parents)
		(tramp-compat-copy-directory tmpdir newname keep-date parents))
	    (tramp-compat-delete-directory tmpdir 'recursive))))
373 374

       ;; We can copy recursively.
375
       ((or t1 t2)
Michael Albinus's avatar
Michael Albinus committed
376 377 378 379 380 381 382 383
	(when (and (file-directory-p newname)
		   (not (string-equal (file-name-nondirectory dirname)
				      (file-name-nondirectory newname))))
	  (setq newname
		(expand-file-name
		 (file-name-nondirectory dirname) newname))
	  (if t2 (setq v (tramp-dissect-file-name newname))))
	(if (not (file-directory-p newname))
384
	    (make-directory newname parents))
Michael Albinus's avatar
Michael Albinus committed
385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427

	(setq tramp-current-method (tramp-file-name-method v)
	      tramp-current-user (tramp-file-name-user v)
	      tramp-current-host (tramp-file-name-real-host v))

	(let* ((real-user (tramp-file-name-real-user v))
	       (real-host (tramp-file-name-real-host v))
	       (domain    (tramp-file-name-domain v))
	       (port      (tramp-file-name-port v))
	       (share     (tramp-smb-get-share v))
	       (localname (file-name-as-directory
			   (replace-regexp-in-string
			    "\\\\" "/" (tramp-smb-get-localname v))))
	       (tmpdir    (make-temp-name
			   (expand-file-name
			    tramp-temp-name-prefix
			    (tramp-compat-temporary-file-directory))))
	       (args      (list tramp-smb-program
				(concat "//" real-host "/" share) "-E")))

	  (if (not (zerop (length real-user)))
	      (setq args (append args (list "-U" real-user)))
	    (setq args (append args (list "-N"))))

	  (when domain (setq args (append args (list "-W" domain))))
	  (when port   (setq args (append args (list "-p" port))))
	  (when tramp-smb-conf
	    (setq args (append args (list "-s" tramp-smb-conf))))
	  (setq args
		(if t1
		    ;; Source is remote.
		    (append args
			    (list "-D" (shell-quote-argument localname)
				  "-c" (shell-quote-argument "tar qc - *")
				  "|" "tar" "xfC" "-"
				  (shell-quote-argument tmpdir)))
		  ;; Target is remote.
		  (append (list "tar" "cfC" "-" (shell-quote-argument dirname)
				"." "|")
			  args
			  (list "-D" (shell-quote-argument localname)
				"-c" (shell-quote-argument "tar qx -")))))

428
	  (unwind-protect
Michael Albinus's avatar
Michael Albinus committed
429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479
	      (with-temp-buffer
		;; Set the transfer process properties.
		(tramp-set-connection-property
		 v "process-name" (buffer-name (current-buffer)))
		(tramp-set-connection-property
		 v "process-buffer" (current-buffer))

		(when t1
		  ;; The smbclient tar command creates always complete
		  ;; paths.  We must emulate the directory structure,
		  ;; and symlink to the real target.
		  (make-directory
		   (expand-file-name ".." (concat tmpdir localname)) 'parents)
		  (make-symbolic-link
		   newname (directory-file-name (concat tmpdir localname))))

		;; Use an asynchronous processes.  By this, password
		;; can be handled.
		(let* ((default-directory tmpdir)
		       (p (start-process-shell-command
			   (tramp-get-connection-name v)
			   (tramp-get-connection-buffer v)
			   (mapconcat 'identity args " "))))

		  (tramp-message
		   v 6 "%s" (mapconcat 'identity (process-command p) " "))
		  (tramp-compat-set-process-query-on-exit-flag p nil)
		  (tramp-process-actions p v nil tramp-smb-actions-with-tar)

		  (while (memq (process-status p) '(run open))
		    (sit-for 0.1))
		  (tramp-message v 6 "\n%s" (buffer-string))))

	    ;; Reset the transfer process properties.
	    (tramp-set-connection-property v "process-name" nil)
	    (tramp-set-connection-property v "process-buffer" nil)
	    (when t1 (delete-directory tmpdir 'recurse))))

	;; Handle KEEP-DATE argument.
	(when keep-date
	  (set-file-times newname (nth 5 (file-attributes dirname))))

	;; Set the mode.
	(unless keep-date
	  (set-file-modes newname (tramp-default-file-modes dirname)))

	;; When newname did exist, we have wrong cached values.
	(when t2
	  (with-parsed-tramp-file-name newname nil
	    (tramp-flush-file-property v (file-name-directory localname))
	    (tramp-flush-file-property v localname))))
480 481

       ;; We must do it file-wise.
482
       (t
483
	(tramp-run-real-handler
Michael Albinus's avatar
Michael Albinus committed
484
	 'copy-directory (list dirname newname keep-date parents))))))))
485 486

(defun tramp-smb-handle-copy-file
Michael Albinus's avatar
Michael Albinus committed
487 488
  (filename newname &optional ok-if-already-exists keep-date
	    preserve-uid-gid preserve-selinux-context)
489
  "Like `copy-file' for Tramp files.
Michael Albinus's avatar
Michael Albinus committed
490
KEEP-DATE has no effect in case NEWNAME resides on an SMB server.
491
PRESERVE-UID-GID and PRESERVE-SELINUX-CONTEXT are completely ignored."
492 493
  (setq filename (expand-file-name filename)
	newname (expand-file-name newname))
494
  (with-tramp-progress-reporter
495 496 497
      (tramp-dissect-file-name (if (file-remote-p filename) filename newname))
      0 (format "Copying %s to %s" filename newname)

Michael Albinus's avatar
Michael Albinus committed
498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530
    (if (file-directory-p filename)
	(tramp-compat-copy-directory filename newname keep-date t t)

      (let ((tmpfile (file-local-copy filename)))
	(if tmpfile
	    ;; Remote filename.
	    (condition-case err
		(rename-file tmpfile newname ok-if-already-exists)
	      ((error quit)
	       (delete-file tmpfile)
	       (signal (car err) (cdr err))))

	  ;; Remote newname.
	  (when (file-directory-p newname)
	    (setq newname
		  (expand-file-name (file-name-nondirectory filename) newname)))

	  (with-parsed-tramp-file-name newname nil
	    (when (and (not ok-if-already-exists)
		       (file-exists-p newname))
	      (tramp-error v 'file-already-exists newname))

	    ;; We must also flush the cache of the directory, because
	    ;; `file-attributes' reads the values from there.
	    (tramp-flush-file-property v (file-name-directory localname))
	    (tramp-flush-file-property v localname)
	    (unless (tramp-smb-get-share v)
	      (tramp-error
	       v 'file-error "Target `%s' must contain a share name" newname))
	    (unless (tramp-smb-send-command
		     v (format "put \"%s\" \"%s\""
			       filename (tramp-smb-get-localname v)))
	      (tramp-error v 'file-error "Cannot copy `%s'" filename))))))
531

Michael Albinus's avatar
Michael Albinus committed
532 533 534
    ;; KEEP-DATE handling.
    (when keep-date
      (set-file-times newname (nth 5 (file-attributes filename))))))
535

536
(defun tramp-smb-handle-delete-directory (directory &optional recursive)
537
  "Like `delete-directory' for Tramp files."
538
  (setq directory (directory-file-name (expand-file-name directory)))
Michael Albinus's avatar
Michael Albinus committed
539
  (when (file-exists-p directory)
540 541 542 543
    (if recursive
	(mapc
	 (lambda (file)
	   (if (file-directory-p file)
544
	       (tramp-compat-delete-directory file recursive)
545
	     (delete-file file)))
546 547 548
	 ;; We do not want to delete "." and "..".
	 (directory-files
	  directory 'full "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*")))
549

Michael Albinus's avatar
Michael Albinus committed
550
    (with-parsed-tramp-file-name directory nil
551
      ;; We must also flush the cache of the directory, because
552
      ;; `file-attributes' reads the values from there.
553 554
      (tramp-flush-file-property v (file-name-directory localname))
      (tramp-flush-directory-property v localname)
555 556 557 558 559 560 561 562 563 564 565
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_rmdir" "rmdir")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
	   v 'file-error "%s `%s'" (match-string 0) directory))))))
566

567
(defun tramp-smb-handle-delete-file (filename &optional trash)
568
  "Like `delete-file' for Tramp files."
569
  (setq filename (expand-file-name filename))
Michael Albinus's avatar
Michael Albinus committed
570 571
  (when (file-exists-p filename)
    (with-parsed-tramp-file-name filename nil
572
      ;; We must also flush the cache of the directory, because
573
      ;; `file-attributes' reads the values from there.
574 575
      (tramp-flush-file-property v (file-name-directory localname))
      (tramp-flush-file-property v localname)
576 577 578 579 580 581 582 583 584 585 586
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_unlink" "rm")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
	   v 'file-error "%s `%s'" (match-string 0) filename))))))
587 588 589

(defun tramp-smb-handle-directory-files
  (directory &optional full match nosort)
590 591 592
  "Like `directory-files' for Tramp files."
  (let ((result (mapcar 'directory-file-name
			(file-name-all-completions "" directory))))
593
    ;; Discriminate with regexp.
594 595 596 597 598
    (when match
      (setq result
	    (delete nil
		    (mapcar (lambda (x) (when (string-match match x) x))
			    result))))
599
    ;; Append directory.
600 601 602 603 604
    (when full
      (setq result
	    (mapcar
	     (lambda (x) (expand-file-name x directory))
	     result)))
605
    ;; Sort them if necessary.
606
    (unless nosort (setq result (sort result 'string-lessp)))
607
    ;; That's it.
608
    result))
609

610 611 612 613 614 615 616 617 618 619 620 621 622
(defun tramp-smb-handle-expand-file-name (name &optional dir)
  "Like `expand-file-name' for Tramp files."
  ;; If DIR is not given, use DEFAULT-DIRECTORY or "/".
  (setq dir (or dir default-directory "/"))
  ;; Unless NAME is absolute, concat DIR and NAME.
  (unless (file-name-absolute-p name)
    (setq name (concat (file-name-as-directory dir) name)))
  ;; If NAME is not a Tramp file, run the real handler.
  (if (not (tramp-tramp-file-p name))
      (tramp-run-real-handler 'expand-file-name (list name nil))
    ;; Dissect NAME.
    (with-parsed-tramp-file-name name nil
      ;; Tilde expansion if necessary.  We use the user name as share,
Paul Eggert's avatar
Paul Eggert committed
623
      ;; which is often the case in domains.
624
      (when (string-match "\\`/?~\\([^/]*\\)" localname)
625 626
	(setq localname
	      (replace-match
627
	       (if (zerop (length (match-string 1 localname)))
628
		   (tramp-file-name-real-user v)
629
		 (match-string 1 localname))
630
	       nil nil localname)))
631 632 633
      ;; Make the file name absolute.
      (unless (tramp-run-real-handler 'file-name-absolute-p (list localname))
	(setq localname (concat "/" localname)))
634 635 636 637 638 639
      ;; No tilde characters in file name, do normal
      ;; `expand-file-name' (this does "/./" and "/../").
      (tramp-make-tramp-file-name
       method user host
       (tramp-run-real-handler 'expand-file-name (list localname))))))

640
(defun tramp-smb-handle-file-attributes (filename &optional id-format)
641
  "Like `file-attributes' for Tramp files."
642
  (unless id-format (setq id-format 'integer))
643 644
  (ignore-errors
    (with-parsed-tramp-file-name filename nil
645 646
      (with-tramp-file-property
	  v localname (format "file-attributes-%s" id-format)
647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677
	(if (and (tramp-smb-get-share v) (tramp-smb-get-stat-capability v))
	    (tramp-smb-do-file-attributes-with-stat v id-format)
	  ;; Reading just the filename entry via "dir localname" is not
	  ;; possible, because when filename is a directory, some
	  ;; smbclient versions return the content of the directory, and
	  ;; other versions don't.  Therefore, the whole content of the
	  ;; upper directory is retrieved, and the entry of the filename
	  ;; is extracted from.
	  (let* ((entries (tramp-smb-get-file-entries
			   (file-name-directory filename)))
		 (entry (assoc (file-name-nondirectory filename) entries))
		 (uid (if (equal id-format 'string) "nobody" -1))
		 (gid (if (equal id-format 'string) "nogroup" -1))
		 (inode (tramp-get-inode v))
		 (device (tramp-get-device v)))

	    ;; Check result.
	    (when entry
	      (list (and (string-match "d" (nth 1 entry))
			 t)        ;0 file type
		    -1	           ;1 link count
		    uid	           ;2 uid
		    gid	           ;3 gid
		    '(0 0)	   ;4 atime
		    (nth 3 entry)  ;5 mtime
		    '(0 0)	   ;6 ctime
		    (nth 2 entry)  ;7 size
		    (nth 1 entry)  ;8 mode
		    nil	           ;9 gid weird
		    inode	   ;10 inode number
		    device)))))))) ;11 file system number
678

679
(defun tramp-smb-do-file-attributes-with-stat (vec &optional id-format)
680
  "Implement `file-attributes' for Tramp files using stat command."
681 682
  (tramp-message
   vec 5 "file attributes with stat: %s" (tramp-file-name-localname vec))
Michael Albinus's avatar
Michael Albinus committed
683
  (with-current-buffer (tramp-get-connection-buffer vec)
684
    (let* (size id link uid gid atime mtime ctime mode inode)
685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742
      (when (tramp-smb-send-command
	     vec (format "stat \"%s\"" (tramp-smb-get-localname vec)))

	;; Loop the listing.
	(goto-char (point-min))
	(unless (re-search-forward tramp-smb-errors nil t)
	  (while (not (eobp))
	    (cond
	     ((looking-at
	       "Size:\\s-+\\([0-9]+\\)\\s-+Blocks:\\s-+[0-9]+\\s-+\\(\\w+\\)")
	      (setq size (string-to-number (match-string 1))
		    id (if (string-equal "directory" (match-string 2)) t
			 (if (string-equal "symbolic" (match-string 2)) ""))))
	     ((looking-at
	       "Inode:\\s-+\\([0-9]+\\)\\s-+Links:\\s-+\\([0-9]+\\)")
	      (setq inode (string-to-number (match-string 1))
		    link (string-to-number (match-string 2))))
	     ((looking-at
	       "Access:\\s-+([0-9]+/\\(\\S-+\\))\\s-+Uid:\\s-+\\([0-9]+\\)\\s-+Gid:\\s-+\\([0-9]+\\)")
	      (setq mode (match-string 1)
		    uid (if (equal id-format 'string) (match-string 2)
			  (string-to-number (match-string 2)))
		    gid (if (equal id-format 'string) (match-string 3)
			  (string-to-number (match-string 3)))))
	     ((looking-at
	       "Access:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq atime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Modify:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq mtime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Change:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq ctime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1)))))) ;; year
	    (forward-line))
	  ;; Return the result.
	  (list id link uid gid atime mtime ctime size mode nil inode
		(tramp-get-device vec)))))))
743 744

(defun tramp-smb-handle-file-directory-p (filename)
745 746 747
  "Like `file-directory-p' for Tramp files."
  (and (file-exists-p filename)
       (eq ?d (aref (nth 8 (file-attributes filename)) 0))))
748 749

(defun tramp-smb-handle-file-local-copy (filename)
750
  "Like `file-local-copy' for Tramp files."
751
  (with-parsed-tramp-file-name filename nil
752 753 754 755
    (unless (file-exists-p filename)
      (tramp-error
       v 'file-error
       "Cannot make local copy of non-existing file `%s'" filename))
756
    (let ((tmpfile (tramp-compat-make-temp-file filename)))
757
      (with-tramp-progress-reporter
758 759 760 761 762
	  v 3 (format "Fetching %s to tmp file %s" filename tmpfile)
	(unless (tramp-smb-send-command
		 v (format "get \"%s\" \"%s\""
			   (tramp-smb-get-localname v) tmpfile))
	  ;; Oops, an error.  We shall cleanup.
763
	  (delete-file tmpfile)
764 765
	  (tramp-error
	   v 'file-error "Cannot make local copy of file `%s'" filename)))
766
      tmpfile)))
767 768 769 770

;; This function should return "foo/" for directories and "bar" for
;; files.
(defun tramp-smb-handle-file-name-all-completions (filename directory)
771 772 773 774
  "Like `file-name-all-completions' for Tramp files."
  (all-completions
   filename
   (with-parsed-tramp-file-name directory nil
775
     (with-tramp-file-property v localname "file-name-all-completions"
776 777
       (save-match-data
	 (let ((entries (tramp-smb-get-file-entries directory)))
778 779 780 781 782 783 784 785 786
	   (mapcar
	    (lambda (x)
	      (list
	       (if (string-match "d" (nth 1 x))
		   (file-name-as-directory (nth 0 x))
		 (nth 0 x))))
	    entries)))))))

(defun tramp-smb-handle-file-writable-p (filename)
787 788 789 790 791 792
  "Like `file-writable-p' for Tramp files."
  (if (file-exists-p filename)
      (string-match "w" (or (nth 8 (file-attributes filename)) ""))
    (let ((dir (file-name-directory filename)))
      (and (file-exists-p dir)
	   (file-writable-p dir)))))
793 794 795

(defun tramp-smb-handle-insert-directory
  (filename switches &optional wildcard full-directory-p)
796
  "Like `insert-directory' for Tramp files."
797
  (setq filename (expand-file-name filename))
798 799 800 801
  (if full-directory-p
      ;; Called from `dired-add-entry'.
      (setq filename (file-name-as-directory filename))
    (setq filename (directory-file-name filename)))
Michael Albinus's avatar
Michael Albinus committed
802
  (with-parsed-tramp-file-name filename nil
803
    (save-match-data
804
      (let ((base (file-name-nondirectory filename))
805 806 807 808 809 810 811 812 813 814 815 816 817 818
	    ;; We should not destroy the cache entry.
	    (entries (copy-sequence
		      (tramp-smb-get-file-entries
		       (file-name-directory filename)))))

	(when wildcard
	  (string-match "\\." base)
	  (setq base (replace-match "\\\\." nil nil base))
	  (string-match "\\*" base)
	  (setq base (replace-match ".*" nil nil base))
	  (string-match "\\?" base)
	  (setq base (replace-match ".?" nil nil base)))

	;; Filter entries.
819
	(setq entries
820 821 822 823 824 825 826 827 828 829 830 831
	      (delq
	       nil
	       (if (or wildcard (zerop (length base)))
		   ;; Check for matching entries.
		   (mapcar
		    (lambda (x)
		      (when (string-match
			     (format "^%s" base) (nth 0 x))
			x))
		    entries)
		 ;; We just need the only and only entry FILENAME.
		 (list (assoc base entries)))))
832

Michael Albinus's avatar
Michael Albinus committed
833
	;; Sort entries.
834 835 836 837 838
	(setq entries
	      (sort
	       entries
	       (lambda (x y)
		 (if (string-match "t" switches)
839 840 841
		     ;; Sort by date.
		     (tramp-time-less-p (nth 3 y) (nth 3 x))
		   ;; Sort by name.
842 843
		   (string-lessp (nth 0 x) (nth 0 y))))))

Michael Albinus's avatar
Michael Albinus committed
844 845
	;; Handle "-F" switch.
	(when (string-match "F" switches)
846
	  (mapc
Michael Albinus's avatar
Michael Albinus committed
847 848 849 850 851 852 853 854 855
	   (lambda (x)
	     (when (not (zerop (length (car x))))
	       (cond
		((char-equal ?d (string-to-char (nth 1 x)))
		 (setcar x (concat (car x) "/")))
		((char-equal ?x (string-to-char (nth 1 x)))
		 (setcar x (concat (car x) "*"))))))
	   entries))

856
	;; Print entries.
857
	(mapc
858
	 (lambda (x)
859
	   (when (not (zerop (length (nth 0 x))))
860
	     (let ((attr
861
		    (when (tramp-smb-get-stat-capability v)
862
		      (ignore-errors
863
			(file-attributes filename 'string)))))
864 865
	       (insert
		(format
866
		 "%10s %3d %-8s %-8s %8s %s "
867
		 (or (nth 8 attr) (nth 1 x)) ; mode
868
		 (or (nth 1 attr) 1) ; inode
869 870
		 (or (nth 2 attr) "nobody") ; uid
		 (or (nth 3 attr) "nogroup") ; gid
871
		 (or (nth 7 attr) (nth 2 x)) ; size
872 873 874 875 876 877
		 (format-time-string
		  (if (tramp-time-less-p
		       (tramp-time-subtract (current-time) (nth 3 x))
		       tramp-half-a-year)
		      "%b %e %R"
		    "%b %e  %Y")
878
		  (nth 3 x)))) ; date
879 880 881
	       ;; We mark the file name.  The inserted name could be
	       ;; from somewhere else, so we use the relative file
	       ;; name of `default-directory'.
882
	       (let ((start (point)))
883 884 885
		 (insert
		  (format
		   "%s\n"
886 887 888
		   (file-relative-name
		    (expand-file-name
		     (nth 0 x) (file-name-directory filename)))))
889
		 (put-text-property start (1- (point)) 'dired-filename t))
890 891 892
	       (forward-line)
	       (beginning-of-line))))
	 entries)))))
893 894

(defun tramp-smb-handle-make-directory (dir &optional parents)
895
  "Like `make-directory' for Tramp files."
896 897
  (setq dir (directory-file-name (expand-file-name dir)))
  (unless (file-name-absolute-p dir)
898
    (setq dir (expand-file-name dir default-directory)))
Michael Albinus's avatar
Michael Albinus committed
899
  (with-parsed-tramp-file-name dir nil
900
    (save-match-data
901
      (let* ((ldir (file-name-directory dir)))
902
	;; Make missing directory parts.
903 904 905
	(when (and parents
		   (tramp-smb-get-share v)
		   (not (file-directory-p ldir)))
906
	  (make-directory ldir parents))
907
	;; Just do it.
908
	(when (file-directory-p ldir)
909
	  (make-directory-internal dir))
910
	(unless (file-directory-p dir)
911
	  (tramp-error v 'file-error "Couldn't make directory %s" dir))))))
912 913

(defun tramp-smb-handle-make-directory-internal (directory)
914
  "Like `make-directory-internal' for Tramp files."
915 916
  (setq directory (directory-file-name (expand-file-name directory)))
  (unless (file-name-absolute-p directory)
917
    (setq directory (expand-file-name directory default-directory)))
Michael Albinus's avatar
Michael Albinus committed
918
  (with-parsed-tramp-file-name directory nil
919
    (save-match-data
920
      (let* ((file (tramp-smb-get-localname v)))
921
	(when (file-directory-p (file-name-directory directory))
922 923
	  (tramp-smb-send-command
	   v
924
	   (if (tramp-smb-get-cifs-capabilities v)
925 926
	       (format
		"posix_mkdir \"%s\" %s"
927
		file (tramp-compat-decimal-to-octal (default-file-modes)))
928
	     (format "mkdir \"%s\"" file)))
929
	  ;; We must also flush the cache of the directory, because
930 931 932
	  ;; `file-attributes' reads the values from there.
	  (tramp-flush-file-property v (file-name-directory localname))
	  (tramp-flush-file-property v localname))
933
	(unless (file-directory-p directory)
934 935
	  (tramp-error
	   v 'file-error "Couldn't make directory %s" directory))))))
936

937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981
(defun tramp-smb-handle-make-symbolic-link
  (filename linkname &optional ok-if-already-exists)
  "Like `make-symbolic-link' for Tramp files.
If LINKNAME is a non-Tramp file, it is used verbatim as the target of
the symlink.  If LINKNAME is a Tramp file, only the localname component is
used as the target of the symlink.

If LINKNAME is a Tramp file and the localname component is relative, then
it is expanded first, before the localname component is taken.  Note that
this can give surprising results if the user/host for the source and
target of the symlink differ."
  (unless (tramp-equal-remote filename linkname)
    (with-parsed-tramp-file-name
	(if (tramp-tramp-file-p filename) filename linkname) nil
      (tramp-error
       v 'file-error
       "make-symbolic-link: %s"
       "only implemented for same method, same user, same host")))
  (with-parsed-tramp-file-name filename v1
    (with-parsed-tramp-file-name linkname v2
      (when (file-directory-p filename)
	(tramp-error
	 v2 'file-error
	 "make-symbolic-link: %s must not be a directory" filename))
      (when (and (not ok-if-already-exists)
		 (file-exists-p linkname)
		 (not (numberp ok-if-already-exists))
		 (y-or-n-p
		  (format
		   "File %s already exists; make it a new name anyway? "
		   linkname)))
	(tramp-error
	 v2 'file-error
	 "make-symbolic-link: file %s already exists" linkname))
      (unless (tramp-smb-get-cifs-capabilities v1)
	(tramp-error v2 'file-error "make-symbolic-link not supported"))
      ;; We must also flush the cache of the directory, because
      ;; `file-attributes' reads the values from there.
      (tramp-flush-file-property v2 (file-name-directory v2-localname))
      (tramp-flush-file-property v2 v2-localname)
      (unless
	  (tramp-smb-send-command
	   v1
	   (format
	    "symlink \"%s\" \"%s\""
982 983
	    (tramp-smb-get-localname v1)
	    (tramp-smb-get-localname v2)))
984 985 986 987 988
	(tramp-error
	 v2 'file-error
	 "error with make-symbolic-link, see buffer `%s' for details"
	 (buffer-name))))))

Michael Albinus's avatar
Michael Albinus committed
989 990 991 992 993 994 995 996 997 998 999 1000 1001 1002 1003 1004 1005 1006 1007 1008 1009 1010 1011 1012 1013 1014 1015 1016 1017 1018 1019 1020 1021 1022 1023 1024 1025 1026 1027 1028 1029 1030 1031 1032 1033 1034 1035 1036 1037 1038 1039 1040 1041 1042 1043 1044 1045 1046 1047 1048 1049 1050 1051 1052 1053 1054 1055 1056 1057 1058 1059 1060 1061 1062 1063 1064 1065 1066 1067 1068 1069 1070 1071 1072 1073 1074 1075 1076 1077 1078 1079 1080 1081 1082 1083 1084 1085 1086 1087 1088 1089 1090 1091 1092 1093 1094 1095 1096 1097 1098 1099 1100 1101 1102 1103 1104 1105 1106 1107 1108 1109
(defun tramp-smb-handle-process-file
  (program &optional infile destination display &rest args)
  "Like `process-file' for Tramp files."
  ;; The implementation is not complete yet.
  (when (and (numberp destination) (zerop destination))
    (error "Implementation does not handle immediate return"))

  (with-parsed-tramp-file-name default-directory nil
    (let* ((name (file-name-nondirectory program))
	   (name1 name)
	   (i 0)
	   input tmpinput outbuf command ret)

      ;; Determine input.
      (when infile
	(setq infile (expand-file-name infile))
	(if (tramp-equal-remote default-directory infile)
	    ;; INFILE is on the same remote host.
	    (setq input (with-parsed-tramp-file-name infile nil localname))
	  ;; INFILE must be copied to remote host.
	  (setq input (tramp-make-tramp-temp-file v)
		tmpinput (tramp-make-tramp-file-name method user host input))
	  (copy-file infile tmpinput t))
	;; Transform input into a filename powershell does understand.
	(setq input (format "//%s%s" host input)))

      ;; Determine output.
      (cond
       ;; Just a buffer.
       ((bufferp destination)
	(setq outbuf destination))
       ;; A buffer name.
       ((stringp destination)
	(setq outbuf (get-buffer-create destination)))
       ;; (REAL-DESTINATION ERROR-DESTINATION)
       ((consp destination)
	;; output.
	(cond
	 ((bufferp (car destination))
	  (setq outbuf (car destination)))
	 ((stringp (car destination))
	  (setq outbuf (get-buffer-create (car destination))))
	 ((car destination)
	  (setq outbuf (current-buffer))))
	;; stderr.
	(tramp-message v 2 "%s" "STDERR not supported"))
       ;; 't
       (destination
	(setq outbuf (current-buffer))))

      ;; Construct command.
      (setq command (mapconcat 'identity (cons program args) " ")
	    command (if input
			(format
			 "get-content %s | & %s"
			 (tramp-smb-shell-quote-argument input) command)
		      (format "& %s" command)))

      (while (get-process name1)
	;; NAME must be unique as process name.
	(setq i (1+ i)
	      name1 (format "%s<%d>" name i)))

      ;; Set the new process properties.
      (tramp-set-connection-property v "process-name" name1)
      (tramp-set-connection-property
       v "process-buffer"
       (or outbuf (generate-new-buffer tramp-temp-buffer-name)))

      ;; Call it.
      (condition-case nil
	  (with-current-buffer (tramp-get-connection-buffer v)
	    ;; Preserve buffer contents.
	    (narrow-to-region (point-max) (point-max))
	    (tramp-smb-call-winexe v)
	    (when (tramp-smb-get-share v)
	      (tramp-smb-send-command
	       v (format "cd \"//%s%s\"" host (file-name-directory localname))))
	    (tramp-smb-send-command v command)
	    ;; Preserve command output.
	    (narrow-to-region (point-max) (point-max))
	    (let ((p (tramp-get-connection-process v)))
	      (tramp-smb-send-command v "exit $lasterrorcode")
	      (while (memq (process-status p) '(run open))
		(sleep-for 0.1)
		(setq ret (process-exit-status p))))
	    (delete-region (point-min) (point-max))
	    (widen))

	;; When the user did interrupt, we should do it also.  We use
	;; return code -1 as marker.
	(quit
	 (setq ret -1))
	;; Handle errors.
	(error
	 (setq ret 1)))

      ;; We should show the output anyway.
      (when (and outbuf display) (display-buffer outbuf))

      ;; Cleanup.  We remove all file cache values for the connection,
      ;; because the remote process could have changed them.
      (tramp-set-connection-property v "process-name" nil)
      (tramp-set-connection-property v "process-buffer" nil)
      (when tmpinput (delete-file tmpinput))
      (unless outbuf
	(kill-buffer (tramp-get-connection-property v "process-buffer" nil)))

      ;; `process-file-side-effects' has been introduced with GNU
      ;; Emacs 23.2.  If set to `nil', no remote file will be changed
      ;; by `program'.  If it doesn't exist, we assume its default
      ;; value `t'.
      (unless (and (boundp