tramp-smb.el 72.7 KB
Newer Older
Michael Albinus's avatar
Michael Albinus committed
1
;;; tramp-smb.el --- Tramp access functions for SMB servers
2

3
;; Copyright (C) 2002-2013 Free Software Foundation, Inc.
4

Michael Albinus's avatar
Michael Albinus committed
5
;; Author: Michael Albinus <michael.albinus@gmx.de>
6
;; Keywords: comm, processes
7
;; Package: tramp
8 9 10

;; This file is part of GNU Emacs.

11
;; GNU Emacs is free software: you can redistribute it and/or modify
12
;; it under the terms of the GNU General Public License as published by
13 14
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
15 16 17 18 19 20 21

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
23 24 25 26 27 28 29 30 31

;;; Commentary:

;; Access functions for SMB servers like SAMBA or M$ Windows from Tramp.

;;; Code:

(require 'tramp)

Michael Albinus's avatar
Michael Albinus committed
32 33 34 35
;; Pacify byte-compiler.
(eval-when-compile
  (require 'cl))

36
;; Define SMB method ...
37 38
;;;###tramp-autoload
(defconst tramp-smb-method "smb"
39
  "Method to connect SAMBA and M$ SMB servers.")
40 41

;; ... and add it to the method list.
42 43
;;;###tramp-autoload
(unless (memq system-type '(cygwin windows-nt))
44 45 46 47 48
  (add-to-list 'tramp-methods
    `(,tramp-smb-method
      ;; We define an empty command, because `tramp-smb-call-winexe'
      ;; opens already the powershell.  Used in `tramp-handle-shell-command'.
      (tramp-remote-shell "")
Michael Albinus's avatar
Michael Albinus committed
49
      ;; This is just a guess.  We don't know whether the share "C$"
50 51 52
      ;; is available for public use, and whether the user has write
      ;; access.
      (tramp-tmpdir "/C$/Temp"))))
53 54 55

;; Add a default for `tramp-default-method-alist'. Rule: If there is
;; a domain in USER, it must be the SMB method.
56
;;;###tramp-autoload
57
(add-to-list 'tramp-default-method-alist
58
	     `(nil ,tramp-prefix-domain-regexp ,tramp-smb-method))
59 60 61

;; Add a default for `tramp-default-user-alist'. Rule: For the SMB method,
;; the anonymous user is chosen.
62
;;;###tramp-autoload
63
(add-to-list 'tramp-default-user-alist
64
	     `(,(concat "\\`" tramp-smb-method "\\'") nil nil))
65 66

;; Add completion function for SMB method.
67 68 69 70 71
;;;###tramp-autoload
(eval-after-load 'tramp
  '(tramp-set-completion-function
    tramp-smb-method
    '((tramp-parse-netrc "~/.netrc"))))
72 73

(defcustom tramp-smb-program "smbclient"
74
  "Name of SMB client to run."
75 76 77
  :group 'tramp
  :type 'string)

78 79 80 81 82 83
(defcustom tramp-smb-acl-program "smbcacls"
  "Name of SMB acls to run."
  :group 'tramp
  :type 'string
  :version "24.4")

84
(defcustom tramp-smb-conf "/dev/null"
85
  "Path of the smb.conf file.
86 87 88 89 90
If it is nil, no smb.conf will be added to the `tramp-smb-program'
call, letting the SMB client use the default one."
  :group 'tramp
  :type '(choice (const nil) (file :must-match t)))

91
(defvar tramp-smb-version nil
92
  "Version string of the SMB client.")
93

Michael Albinus's avatar
Michael Albinus committed
94 95 96 97 98 99 100 101 102 103 104 105
(defconst tramp-smb-server-version
  "Domain=\\[[^]]*\\] OS=\\[[^]]*\\] Server=\\[[^]]*\\]"
  "Regexp of SMB server identification.")

(defconst tramp-smb-prompt "^\\(smb:\\|PS\\) .+> \\|^\\s-+Server\\s-+Comment$"
  "Regexp used as prompt in smbclient or powershell.")

(defconst tramp-smb-wrong-passwd-regexp
  (regexp-opt
   '("NT_STATUS_LOGON_FAILURE"
     "NT_STATUS_WRONG_PASSWORD"))
  "Regexp for login error strings of SMB servers.")
106 107 108 109

(defconst tramp-smb-errors
  (mapconcat
   'identity
110 111
   `(;; Connection error / timeout / unknown command.
     "Connection\\( to \\S-+\\)? failed"
112
     "Read from server failed, maybe it closed the connection"
113
     "Call timed out: server did not respond"
114 115
     "\\S-+: command not found"
     "Server doesn't support UNIX CIFS calls"
116 117 118 119 120 121 122 123 124 125 126 127
     ,(regexp-opt
       '(;; Samba.
	 "ERRDOS"
	 "ERRHRD"
	 "ERRSRV"
	 "ERRbadfile"
	 "ERRbadpw"
	 "ERRfilexists"
	 "ERRnoaccess"
	 "ERRnomem"
	 "ERRnosuchshare"
	 ;; Windows 4.0 (Windows NT), Windows 5.0 (Windows 2000),
128 129
	 ;; Windows 5.1 (Windows XP), Windows 5.2 (Windows Server 2003),
	 ;; Windows 6.0 (Windows Vista), Windows 6.1 (Windows 7).
130 131 132 133 134 135 136 137
	 "NT_STATUS_ACCESS_DENIED"
	 "NT_STATUS_ACCOUNT_LOCKED_OUT"
	 "NT_STATUS_BAD_NETWORK_NAME"
	 "NT_STATUS_CANNOT_DELETE"
	 "NT_STATUS_CONNECTION_REFUSED"
	 "NT_STATUS_DIRECTORY_NOT_EMPTY"
	 "NT_STATUS_DUPLICATE_NAME"
	 "NT_STATUS_FILE_IS_A_DIRECTORY"
138
	 "NT_STATUS_HOST_UNREACHABLE"
139
	 "NT_STATUS_IMAGE_ALREADY_LOADED"
140
	 "NT_STATUS_INVALID_LEVEL"
141 142 143 144
	 "NT_STATUS_IO_TIMEOUT"
	 "NT_STATUS_LOGON_FAILURE"
	 "NT_STATUS_NETWORK_ACCESS_DENIED"
	 "NT_STATUS_NOT_IMPLEMENTED"
145
	 "NT_STATUS_NO_LOGON_SERVERS"
146 147 148 149 150 151 152 153 154
	 "NT_STATUS_NO_SUCH_FILE"
	 "NT_STATUS_NO_SUCH_USER"
	 "NT_STATUS_OBJECT_NAME_COLLISION"
	 "NT_STATUS_OBJECT_NAME_INVALID"
	 "NT_STATUS_OBJECT_NAME_NOT_FOUND"
	 "NT_STATUS_SHARING_VIOLATION"
	 "NT_STATUS_TRUSTED_RELATIONSHIP_FAILURE"
	 "NT_STATUS_UNSUCCESSFUL"
	 "NT_STATUS_WRONG_PASSWORD")))
155 156 157 158
   "\\|")
  "Regexp for possible error strings of SMB servers.
Used instead of analyzing error codes of commands.")

159 160 161 162 163 164 165 166 167 168
(defconst tramp-smb-actions-with-share
  '((tramp-smb-prompt tramp-action-succeed)
    (tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-process-alive))
  "List of pattern/action pairs.
This list is used for login to SMB servers.

See `tramp-actions-before-shell' for more info.")
169

170 171 172 173 174 175 176
(defconst tramp-smb-actions-without-share
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-out-of-band))
  "List of pattern/action pairs.
This list is used for login to SMB servers.
177

178
See `tramp-actions-before-shell' for more info.")
179

Michael Albinus's avatar
Michael Albinus committed
180 181 182 183 184 185 186 187 188 189
(defconst tramp-smb-actions-with-tar
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-smb-action-with-tar))
  "List of pattern/action pairs.
This list is used for tar-like copy of directories.

See `tramp-actions-before-shell' for more info.")

Michael Albinus's avatar
Michael Albinus committed
190
(defconst tramp-smb-actions-get-acl
191 192 193
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
Michael Albinus's avatar
Michael Albinus committed
194 195 196 197 198 199 200 201 202 203 204
    (tramp-process-alive-regexp tramp-smb-action-get-acl))
  "List of pattern/action pairs.
This list is used for smbcacls actions.

See `tramp-actions-before-shell' for more info.")

(defconst tramp-smb-actions-set-acl
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-smb-action-set-acl))
205 206 207 208 209
  "List of pattern/action pairs.
This list is used for smbcacls actions.

See `tramp-actions-before-shell' for more info.")

210 211
;; New handlers should be added here.
(defconst tramp-smb-file-name-handler-alist
Michael Albinus's avatar
Michael Albinus committed
212
  '(;; `access-file' performed by default handler.
213
    (add-name-to-file . tramp-smb-handle-add-name-to-file)
214 215
    ;; `byte-compiler-base-file-name' performed by default handler.
    (copy-directory . tramp-smb-handle-copy-directory)
216 217 218
    (copy-file . tramp-smb-handle-copy-file)
    (delete-directory . tramp-smb-handle-delete-directory)
    (delete-file . tramp-smb-handle-delete-file)
219
    ;; `diff-latest-backup-file' performed by default handler.
220
    (directory-file-name . tramp-handle-directory-file-name)
221
    (directory-files . tramp-smb-handle-directory-files)
222
    (directory-files-and-attributes
223
     . tramp-handle-directory-files-and-attributes)
224 225
    (dired-call-process . ignore)
    (dired-compress-file . ignore)
226
    (dired-uncache . tramp-handle-dired-uncache)
227
    (expand-file-name . tramp-smb-handle-expand-file-name)
228
    (file-accessible-directory-p . tramp-smb-handle-file-directory-p)
229
    (file-acl . tramp-smb-handle-file-acl)
230 231
    (file-attributes . tramp-smb-handle-file-attributes)
    (file-directory-p .  tramp-smb-handle-file-directory-p)
Michael Albinus's avatar
Michael Albinus committed
232
    ;; `file-equal-p' performed by default handler.
233 234
    (file-executable-p . tramp-handle-file-exists-p)
    (file-exists-p . tramp-handle-file-exists-p)
Michael Albinus's avatar
Michael Albinus committed
235
    ;; `file-in-directory-p' performed by default handler.
236 237 238
    (file-local-copy . tramp-smb-handle-file-local-copy)
    (file-modes . tramp-handle-file-modes)
    (file-name-all-completions . tramp-smb-handle-file-name-all-completions)
239
    (file-name-as-directory . tramp-handle-file-name-as-directory)
240 241 242
    (file-name-completion . tramp-handle-file-name-completion)
    (file-name-directory . tramp-handle-file-name-directory)
    (file-name-nondirectory . tramp-handle-file-name-nondirectory)
243
    ;; `file-name-sans-versions' performed by default handler.
244
    (file-newer-than-file-p . tramp-handle-file-newer-than-file-p)
245
    (file-notify-add-watch . tramp-handle-file-notify-add-watch)
Michael Albinus's avatar
Michael Albinus committed
246
    (file-notify-rm-watch . tramp-handle-file-notify-rm-watch)
247
    (file-ownership-preserved-p . ignore)
248
    (file-readable-p . tramp-handle-file-exists-p)
249
    (file-regular-p . tramp-handle-file-regular-p)
Michael Albinus's avatar
Michael Albinus committed
250 251
    (file-remote-p . tramp-handle-file-remote-p)
    ;; `file-selinux-context' performed by default handler.
252
    (file-symlink-p . tramp-handle-file-symlink-p)
253
    ;; `file-truename' performed by default handler.
254
    (file-writable-p . tramp-smb-handle-file-writable-p)
255
    (find-backup-file-name . tramp-handle-find-backup-file-name)
256 257
    ;; `find-file-noselect' performed by default handler.
    ;; `get-file-buffer' performed by default handler.
258 259 260
    (insert-directory . tramp-smb-handle-insert-directory)
    (insert-file-contents . tramp-handle-insert-file-contents)
    (load . tramp-handle-load)
261
    (make-auto-save-file-name . tramp-handle-make-auto-save-file-name)
262 263
    (make-directory . tramp-smb-handle-make-directory)
    (make-directory-internal . tramp-smb-handle-make-directory-internal)
264
    (make-symbolic-link . tramp-smb-handle-make-symbolic-link)
Michael Albinus's avatar
Michael Albinus committed
265
    (process-file . tramp-smb-handle-process-file)
266
    (rename-file . tramp-smb-handle-rename-file)
267
    (set-file-acl . tramp-smb-handle-set-file-acl)
268
    (set-file-modes . tramp-smb-handle-set-file-modes)
269
    (set-file-selinux-context . ignore)
270
    (set-file-times . ignore)
Michael Albinus's avatar
Michael Albinus committed
271
    (set-visited-file-modtime . tramp-handle-set-visited-file-modtime)
Michael Albinus's avatar
Michael Albinus committed
272 273
    (shell-command . tramp-handle-shell-command)
    (start-file-process . tramp-smb-handle-start-file-process)
Michael Albinus's avatar
Michael Albinus committed
274
    (substitute-in-file-name . tramp-smb-handle-substitute-in-file-name)
275
    (unhandled-file-name-directory . tramp-handle-unhandled-file-name-directory)
276
    (vc-registered . ignore)
Michael Albinus's avatar
Michael Albinus committed
277 278
    (verify-visited-file-modtime . tramp-handle-verify-visited-file-modtime)
    (write-region . tramp-smb-handle-write-region))
279 280 281
  "Alist of handler functions for Tramp SMB method.
Operations not mentioned here will be handled by the default Emacs primitives.")

Michael Albinus's avatar
Michael Albinus committed
282 283 284 285 286 287 288
;; Options for remote processes via winexe.
(defcustom tramp-smb-winexe-program "winexe"
  "Name of winexe client to run.
If it isn't found in the local $PATH, the absolute path of winexe
shall be given.  This is needed for remote processes."
  :group 'tramp
  :type 'string
289
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
290 291 292 293 294 295

(defcustom tramp-smb-winexe-shell-command "powershell.exe"
  "Shell to be used for processes on remote machines.
This must be Powershell V2 compatible."
  :group 'tramp
  :type 'string
296
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
297 298 299 300 301 302

(defcustom tramp-smb-winexe-shell-command-switch "-file -"
  "Command switch used together with `tramp-smb-winexe-shell-command'.
This can be used to disable echo etc."
  :group 'tramp
  :type 'string
303
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
304

305 306
;; It must be a `defsubst' in order to push the whole code into
;; tramp-loaddefs.el.  Otherwise, there would be recursive autoloading.
307 308
;;;###tramp-autoload
(defsubst tramp-smb-file-name-p (filename)
309
  "Check if it's a filename for SMB servers."
Michael Albinus's avatar
Michael Albinus committed
310 311
  (string= (tramp-file-name-method (tramp-dissect-file-name filename))
	   tramp-smb-method))
312

313
;;;###tramp-autoload
314 315 316 317 318 319
(defun tramp-smb-file-name-handler (operation &rest args)
  "Invoke the SMB related OPERATION.
First arg specifies the OPERATION, second arg is a list of arguments to
pass to the OPERATION."
  (let ((fn (assoc operation tramp-smb-file-name-handler-alist)))
    (if fn
320
	(save-match-data (apply (cdr fn) args))
321 322
      (tramp-run-real-handler operation args))))

323 324 325 326
;;;###tramp-autoload
(unless (memq system-type '(cygwin windows-nt))
  (add-to-list 'tramp-foreign-file-name-handler-alist
	       (cons 'tramp-smb-file-name-p 'tramp-smb-file-name-handler)))
327 328


329 330
;; File name primitives.

331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360
(defun tramp-smb-handle-add-name-to-file
  (filename newname &optional ok-if-already-exists)
  "Like `add-name-to-file' for Tramp files."
  (unless (tramp-equal-remote filename newname)
    (with-parsed-tramp-file-name
	(if (tramp-tramp-file-p filename) filename newname) nil
      (tramp-error
       v 'file-error
       "add-name-to-file: %s"
       "only implemented for same method, same user, same host")))
  (with-parsed-tramp-file-name filename v1
    (with-parsed-tramp-file-name newname v2
      (when (file-directory-p filename)
	(tramp-error
	 v2 'file-error
	 "add-name-to-file: %s must not be a directory" filename))
      (when (and (not ok-if-already-exists)
		 (file-exists-p newname)
		 (not (numberp ok-if-already-exists))
		 (y-or-n-p
		  (format
		   "File %s already exists; make it a new name anyway? "
		   newname)))
	(tramp-error
	 v2 'file-error
	 "add-name-to-file: file %s already exists" newname))
      ;; We must also flush the cache of the directory, because
      ;; `file-attributes' reads the values from there.
      (tramp-flush-file-property v2 (file-name-directory v2-localname))
      (tramp-flush-file-property v2 v2-localname)
361 362 363 364 365 366 367 368 369 370 371 372
      (unless
	  (tramp-smb-send-command
	   v1
	   (format
	    "%s \"%s\" \"%s\""
	    (if (tramp-smb-get-cifs-capabilities v1) "link" "hardlink")
	    (tramp-smb-get-localname v1)
	    (tramp-smb-get-localname v2)))
	(tramp-error
	 v2 'file-error
	 "error with add-name-to-file, see buffer `%s' for details"
	 (buffer-name))))))
373

Michael Albinus's avatar
Michael Albinus committed
374 375 376 377 378 379 380 381 382 383 384 385 386 387 388
(defun tramp-smb-action-with-tar (proc vec)
  "Untar from connection buffer."
  (if (not (memq (process-status proc) '(run open)))
      (throw 'tramp-action 'process-died)

    (with-current-buffer (tramp-get-connection-buffer vec)
      (goto-char (point-min))
      (when (search-forward-regexp tramp-smb-server-version nil t)
	;; There might be a hidden password prompt.
	(widen)
	(forward-line)
	(tramp-message vec 6 (buffer-substring (point-min) (point)))
	(delete-region (point-min) (point))
	(throw 'tramp-action 'ok)))))

389
(defun tramp-smb-handle-copy-directory
390
  (dirname newname &optional keep-date parents _copy-contents)
Michael Albinus's avatar
Michael Albinus committed
391
  "Like `copy-directory' for Tramp files."
392 393 394 395 396
  (setq dirname (expand-file-name dirname)
	newname (expand-file-name newname))
  (let ((t1 (tramp-tramp-file-p dirname))
	(t2 (tramp-tramp-file-p newname)))
    (with-parsed-tramp-file-name (if t1 dirname newname) nil
397
      (with-tramp-progress-reporter
Michael Albinus's avatar
Michael Albinus committed
398
	  v 0 (format "Copying %s to %s" dirname newname)
399
      (cond
400
       ;; We must use a local temporary directory.
401 402 403 404 405 406 407 408
       ((and t1 t2)
	(let ((tmpdir
	       (make-temp-name
		(expand-file-name
		 tramp-temp-name-prefix
		 (tramp-compat-temporary-file-directory)))))
	  (unwind-protect
	      (progn
409 410 411
		(tramp-compat-copy-directory dirname tmpdir keep-date parents)
		(tramp-compat-copy-directory tmpdir newname keep-date parents))
	    (tramp-compat-delete-directory tmpdir 'recursive))))
412 413

       ;; We can copy recursively.
414
       ((or t1 t2)
Michael Albinus's avatar
Michael Albinus committed
415 416 417 418 419 420 421 422
	(when (and (file-directory-p newname)
		   (not (string-equal (file-name-nondirectory dirname)
				      (file-name-nondirectory newname))))
	  (setq newname
		(expand-file-name
		 (file-name-nondirectory dirname) newname))
	  (if t2 (setq v (tramp-dissect-file-name newname))))
	(if (not (file-directory-p newname))
423
	    (make-directory newname parents))
Michael Albinus's avatar
Michael Albinus committed
424 425 426 427 428 429 430 431 432 433 434

	(setq tramp-current-method (tramp-file-name-method v)
	      tramp-current-user (tramp-file-name-user v)
	      tramp-current-host (tramp-file-name-real-host v))

	(let* ((real-user (tramp-file-name-real-user v))
	       (real-host (tramp-file-name-real-host v))
	       (domain    (tramp-file-name-domain v))
	       (port      (tramp-file-name-port v))
	       (share     (tramp-smb-get-share v))
	       (localname (file-name-as-directory
435
			   (tramp-compat-replace-regexp-in-string
Michael Albinus's avatar
Michael Albinus committed
436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466
			    "\\\\" "/" (tramp-smb-get-localname v))))
	       (tmpdir    (make-temp-name
			   (expand-file-name
			    tramp-temp-name-prefix
			    (tramp-compat-temporary-file-directory))))
	       (args      (list tramp-smb-program
				(concat "//" real-host "/" share) "-E")))

	  (if (not (zerop (length real-user)))
	      (setq args (append args (list "-U" real-user)))
	    (setq args (append args (list "-N"))))

	  (when domain (setq args (append args (list "-W" domain))))
	  (when port   (setq args (append args (list "-p" port))))
	  (when tramp-smb-conf
	    (setq args (append args (list "-s" tramp-smb-conf))))
	  (setq args
		(if t1
		    ;; Source is remote.
		    (append args
			    (list "-D" (shell-quote-argument localname)
				  "-c" (shell-quote-argument "tar qc - *")
				  "|" "tar" "xfC" "-"
				  (shell-quote-argument tmpdir)))
		  ;; Target is remote.
		  (append (list "tar" "cfC" "-" (shell-quote-argument dirname)
				"." "|")
			  args
			  (list "-D" (shell-quote-argument localname)
				"-c" (shell-quote-argument "tar qx -")))))

467
	  (unwind-protect
Michael Albinus's avatar
Michael Albinus committed
468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493
	      (with-temp-buffer
		;; Set the transfer process properties.
		(tramp-set-connection-property
		 v "process-name" (buffer-name (current-buffer)))
		(tramp-set-connection-property
		 v "process-buffer" (current-buffer))

		(when t1
		  ;; The smbclient tar command creates always complete
		  ;; paths.  We must emulate the directory structure,
		  ;; and symlink to the real target.
		  (make-directory
		   (expand-file-name ".." (concat tmpdir localname)) 'parents)
		  (make-symbolic-link
		   newname (directory-file-name (concat tmpdir localname))))

		;; Use an asynchronous processes.  By this, password
		;; can be handled.
		(let* ((default-directory tmpdir)
		       (p (start-process-shell-command
			   (tramp-get-connection-name v)
			   (tramp-get-connection-buffer v)
			   (mapconcat 'identity args " "))))

		  (tramp-message
		   v 6 "%s" (mapconcat 'identity (process-command p) " "))
Michael Albinus's avatar
Michael Albinus committed
494
		  (tramp-set-connection-property p "vector" v)
Michael Albinus's avatar
Michael Albinus committed
495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519
		  (tramp-compat-set-process-query-on-exit-flag p nil)
		  (tramp-process-actions p v nil tramp-smb-actions-with-tar)

		  (while (memq (process-status p) '(run open))
		    (sit-for 0.1))
		  (tramp-message v 6 "\n%s" (buffer-string))))

	    ;; Reset the transfer process properties.
	    (tramp-set-connection-property v "process-name" nil)
	    (tramp-set-connection-property v "process-buffer" nil)
	    (when t1 (delete-directory tmpdir 'recurse))))

	;; Handle KEEP-DATE argument.
	(when keep-date
	  (set-file-times newname (nth 5 (file-attributes dirname))))

	;; Set the mode.
	(unless keep-date
	  (set-file-modes newname (tramp-default-file-modes dirname)))

	;; When newname did exist, we have wrong cached values.
	(when t2
	  (with-parsed-tramp-file-name newname nil
	    (tramp-flush-file-property v (file-name-directory localname))
	    (tramp-flush-file-property v localname))))
520 521

       ;; We must do it file-wise.
522
       (t
523
	(tramp-run-real-handler
Michael Albinus's avatar
Michael Albinus committed
524
	 'copy-directory (list dirname newname keep-date parents))))))))
525 526

(defun tramp-smb-handle-copy-file
Michael Albinus's avatar
Michael Albinus committed
527
  (filename newname &optional ok-if-already-exists keep-date
528
	    _preserve-uid-gid _preserve-extended-attributes)
529
  "Like `copy-file' for Tramp files.
Michael Albinus's avatar
Michael Albinus committed
530
KEEP-DATE has no effect in case NEWNAME resides on an SMB server.
531
PRESERVE-UID-GID and PRESERVE-EXTENDED-ATTRIBUTES are completely ignored."
532 533
  (setq filename (expand-file-name filename)
	newname (expand-file-name newname))
534
  (with-tramp-progress-reporter
Michael Albinus's avatar
Michael Albinus committed
535 536
      (tramp-dissect-file-name
       (if (tramp-tramp-file-p filename) filename newname))
537 538
      0 (format "Copying %s to %s" filename newname)

Michael Albinus's avatar
Michael Albinus committed
539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570
    (if (file-directory-p filename)
	(tramp-compat-copy-directory filename newname keep-date t t)

      (let ((tmpfile (file-local-copy filename)))
	(if tmpfile
	    ;; Remote filename.
	    (condition-case err
		(rename-file tmpfile newname ok-if-already-exists)
	      ((error quit)
	       (delete-file tmpfile)
	       (signal (car err) (cdr err))))

	  ;; Remote newname.
	  (when (file-directory-p newname)
	    (setq newname
		  (expand-file-name (file-name-nondirectory filename) newname)))

	  (with-parsed-tramp-file-name newname nil
	    (when (and (not ok-if-already-exists)
		       (file-exists-p newname))
	      (tramp-error v 'file-already-exists newname))

	    ;; We must also flush the cache of the directory, because
	    ;; `file-attributes' reads the values from there.
	    (tramp-flush-file-property v (file-name-directory localname))
	    (tramp-flush-file-property v localname)
	    (unless (tramp-smb-get-share v)
	      (tramp-error
	       v 'file-error "Target `%s' must contain a share name" newname))
	    (unless (tramp-smb-send-command
		     v (format "put \"%s\" \"%s\""
			       filename (tramp-smb-get-localname v)))
571 572
	      (tramp-error
	       v 'file-error "Cannot copy `%s' to `%s'" filename newname))))))
573

Michael Albinus's avatar
Michael Albinus committed
574 575 576
    ;; KEEP-DATE handling.
    (when keep-date
      (set-file-times newname (nth 5 (file-attributes filename))))))
577

578
(defun tramp-smb-handle-delete-directory (directory &optional recursive)
579
  "Like `delete-directory' for Tramp files."
580
  (setq directory (directory-file-name (expand-file-name directory)))
Michael Albinus's avatar
Michael Albinus committed
581
  (when (file-exists-p directory)
582 583 584 585
    (if recursive
	(mapc
	 (lambda (file)
	   (if (file-directory-p file)
586
	       (tramp-compat-delete-directory file recursive)
587
	     (delete-file file)))
588 589 590
	 ;; We do not want to delete "." and "..".
	 (directory-files
	  directory 'full "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*")))
591

Michael Albinus's avatar
Michael Albinus committed
592
    (with-parsed-tramp-file-name directory nil
593
      ;; We must also flush the cache of the directory, because
594
      ;; `file-attributes' reads the values from there.
595 596
      (tramp-flush-file-property v (file-name-directory localname))
      (tramp-flush-directory-property v localname)
597 598 599 600 601 602 603 604 605 606 607
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_rmdir" "rmdir")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
	   v 'file-error "%s `%s'" (match-string 0) directory))))))
608

609
(defun tramp-smb-handle-delete-file (filename &optional _trash)
610
  "Like `delete-file' for Tramp files."
611
  (setq filename (expand-file-name filename))
Michael Albinus's avatar
Michael Albinus committed
612 613
  (when (file-exists-p filename)
    (with-parsed-tramp-file-name filename nil
614
      ;; We must also flush the cache of the directory, because
615
      ;; `file-attributes' reads the values from there.
616 617
      (tramp-flush-file-property v (file-name-directory localname))
      (tramp-flush-file-property v localname)
618 619 620 621 622 623 624 625 626 627 628
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_unlink" "rm")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
	   v 'file-error "%s `%s'" (match-string 0) filename))))))
629 630 631

(defun tramp-smb-handle-directory-files
  (directory &optional full match nosort)
632 633 634
  "Like `directory-files' for Tramp files."
  (let ((result (mapcar 'directory-file-name
			(file-name-all-completions "" directory))))
635
    ;; Discriminate with regexp.
636 637 638 639 640
    (when match
      (setq result
	    (delete nil
		    (mapcar (lambda (x) (when (string-match match x) x))
			    result))))
641
    ;; Append directory.
642 643 644 645 646
    (when full
      (setq result
	    (mapcar
	     (lambda (x) (expand-file-name x directory))
	     result)))
647
    ;; Sort them if necessary.
648
    (unless nosort (setq result (sort result 'string-lessp)))
649
    ;; That's it.
650
    result))
651

652 653 654 655 656 657 658 659 660 661 662 663 664
(defun tramp-smb-handle-expand-file-name (name &optional dir)
  "Like `expand-file-name' for Tramp files."
  ;; If DIR is not given, use DEFAULT-DIRECTORY or "/".
  (setq dir (or dir default-directory "/"))
  ;; Unless NAME is absolute, concat DIR and NAME.
  (unless (file-name-absolute-p name)
    (setq name (concat (file-name-as-directory dir) name)))
  ;; If NAME is not a Tramp file, run the real handler.
  (if (not (tramp-tramp-file-p name))
      (tramp-run-real-handler 'expand-file-name (list name nil))
    ;; Dissect NAME.
    (with-parsed-tramp-file-name name nil
      ;; Tilde expansion if necessary.  We use the user name as share,
Paul Eggert's avatar
Paul Eggert committed
665
      ;; which is often the case in domains.
666
      (when (string-match "\\`/?~\\([^/]*\\)" localname)
667 668
	(setq localname
	      (replace-match
669
	       (if (zerop (length (match-string 1 localname)))
670
		   (tramp-file-name-real-user v)
671
		 (match-string 1 localname))
672
	       nil nil localname)))
673 674 675
      ;; Make the file name absolute.
      (unless (tramp-run-real-handler 'file-name-absolute-p (list localname))
	(setq localname (concat "/" localname)))
676 677 678 679 680 681
      ;; No tilde characters in file name, do normal
      ;; `expand-file-name' (this does "/./" and "/../").
      (tramp-make-tramp-file-name
       method user host
       (tramp-run-real-handler 'expand-file-name (list localname))))))

Michael Albinus's avatar
Michael Albinus committed
682
(defun tramp-smb-action-get-acl (proc vec)
683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699
  "Read ACL data from connection buffer."
  (when (not (memq (process-status proc) '(run open)))
    ;; Accept pending output.
    (while (tramp-accept-process-output proc 0.1))
    (with-current-buffer (tramp-get-connection-buffer vec)
      ;; There might be a hidden password prompt.
      (widen)
      (tramp-message vec 10 "\n%s" (buffer-string))
      (goto-char (point-min))
      (while (and (not (eobp)) (not (looking-at "^REVISION:")))
	(forward-line)
	(delete-region (point-min) (point)))
      (while (and (not (eobp)) (looking-at "^.+:.+"))
 	(forward-line))
      (delete-region (point) (point-max))
      (throw 'tramp-action 'ok))))

700 701 702 703
(defun tramp-smb-handle-file-acl (filename)
  "Like `file-acl' for Tramp files."
  (with-parsed-tramp-file-name filename nil
    (with-tramp-file-property v localname "file-acl"
704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748
      (when (executable-find tramp-smb-acl-program)

	(setq tramp-current-method (tramp-file-name-method v)
	      tramp-current-user (tramp-file-name-user v)
	      tramp-current-host (tramp-file-name-real-host v))

	(let* ((real-user (tramp-file-name-real-user v))
	       (real-host (tramp-file-name-real-host v))
	       (domain    (tramp-file-name-domain v))
	       (port      (tramp-file-name-port v))
	       (share     (tramp-smb-get-share v))
	       (localname (tramp-compat-replace-regexp-in-string
			   "\\\\" "/" (tramp-smb-get-localname v)))
	       (args      (list (concat "//" real-host "/" share) "-E")))

	  (if (not (zerop (length real-user)))
	      (setq args (append args (list "-U" real-user)))
	    (setq args (append args (list "-N"))))

	  (when domain (setq args (append args (list "-W" domain))))
	  (when port   (setq args (append args (list "-p" port))))
	  (when tramp-smb-conf
	    (setq args (append args (list "-s" tramp-smb-conf))))
	  (setq
	   args
	   (append args (list (shell-quote-argument localname) "2>/dev/null")))

	  (unwind-protect
	      (with-temp-buffer
		;; Set the transfer process properties.
		(tramp-set-connection-property
		 v "process-name" (buffer-name (current-buffer)))
		(tramp-set-connection-property
		 v "process-buffer" (current-buffer))

		;; Use an asynchronous processes.  By this, password
		;; can be handled.
		(let ((p (apply
			  'start-process
			  (tramp-get-connection-name v)
			  (tramp-get-connection-buffer v)
			  tramp-smb-acl-program args)))

		  (tramp-message
		   v 6 "%s" (mapconcat 'identity (process-command p) " "))
Michael Albinus's avatar
Michael Albinus committed
749
		  (tramp-set-connection-property p "vector" v)
750
		  (tramp-compat-set-process-query-on-exit-flag p nil)
Michael Albinus's avatar
Michael Albinus committed
751
		  (tramp-process-actions p v nil tramp-smb-actions-get-acl)
752 753 754 755 756 757 758
		  (when (> (point-max) (point-min))
		    (tramp-compat-funcall
		     'substring-no-properties (buffer-string)))))

	    ;; Reset the transfer process properties.
	    (tramp-set-connection-property v "process-name" nil)
	    (tramp-set-connection-property v "process-buffer" nil)))))))
759

760
(defun tramp-smb-handle-file-attributes (filename &optional id-format)
761
  "Like `file-attributes' for Tramp files."
762
  (unless id-format (setq id-format 'integer))
763 764
  (ignore-errors
    (with-parsed-tramp-file-name filename nil
765 766
      (with-tramp-file-property
	  v localname (format "file-attributes-%s" id-format)
767
	(if (tramp-smb-get-stat-capability v)
768 769 770 771 772 773 774 775 776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797
	    (tramp-smb-do-file-attributes-with-stat v id-format)
	  ;; Reading just the filename entry via "dir localname" is not
	  ;; possible, because when filename is a directory, some
	  ;; smbclient versions return the content of the directory, and
	  ;; other versions don't.  Therefore, the whole content of the
	  ;; upper directory is retrieved, and the entry of the filename
	  ;; is extracted from.
	  (let* ((entries (tramp-smb-get-file-entries
			   (file-name-directory filename)))
		 (entry (assoc (file-name-nondirectory filename) entries))
		 (uid (if (equal id-format 'string) "nobody" -1))
		 (gid (if (equal id-format 'string) "nogroup" -1))
		 (inode (tramp-get-inode v))
		 (device (tramp-get-device v)))

	    ;; Check result.
	    (when entry
	      (list (and (string-match "d" (nth 1 entry))
			 t)        ;0 file type
		    -1	           ;1 link count
		    uid	           ;2 uid
		    gid	           ;3 gid
		    '(0 0)	   ;4 atime
		    (nth 3 entry)  ;5 mtime
		    '(0 0)	   ;6 ctime
		    (nth 2 entry)  ;7 size
		    (nth 1 entry)  ;8 mode
		    nil	           ;9 gid weird
		    inode	   ;10 inode number
		    device)))))))) ;11 file system number
798

799
(defun tramp-smb-do-file-attributes-with-stat (vec &optional id-format)
800
  "Implement `file-attributes' for Tramp files using stat command."
801 802
  (tramp-message
   vec 5 "file attributes with stat: %s" (tramp-file-name-localname vec))
Michael Albinus's avatar
Michael Albinus committed
803
  (with-current-buffer (tramp-get-connection-buffer vec)
804
    (let* (size id link uid gid atime mtime ctime mode inode)
805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862
      (when (tramp-smb-send-command
	     vec (format "stat \"%s\"" (tramp-smb-get-localname vec)))

	;; Loop the listing.
	(goto-char (point-min))
	(unless (re-search-forward tramp-smb-errors nil t)
	  (while (not (eobp))
	    (cond
	     ((looking-at
	       "Size:\\s-+\\([0-9]+\\)\\s-+Blocks:\\s-+[0-9]+\\s-+\\(\\w+\\)")
	      (setq size (string-to-number (match-string 1))
		    id (if (string-equal "directory" (match-string 2)) t
			 (if (string-equal "symbolic" (match-string 2)) ""))))
	     ((looking-at
	       "Inode:\\s-+\\([0-9]+\\)\\s-+Links:\\s-+\\([0-9]+\\)")
	      (setq inode (string-to-number (match-string 1))
		    link (string-to-number (match-string 2))))
	     ((looking-at
	       "Access:\\s-+([0-9]+/\\(\\S-+\\))\\s-+Uid:\\s-+\\([0-9]+\\)\\s-+Gid:\\s-+\\([0-9]+\\)")
	      (setq mode (match-string 1)
		    uid (if (equal id-format 'string) (match-string 2)
			  (string-to-number (match-string 2)))
		    gid (if (equal id-format 'string) (match-string 3)
			  (string-to-number (match-string 3)))))
	     ((looking-at
	       "Access:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq atime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Modify:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq mtime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Change:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq ctime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1)))))) ;; year
	    (forward-line))
	  ;; Return the result.
	  (list id link uid gid atime mtime ctime size mode nil inode
		(tramp-get-device vec)))))))
863 864

(defun tramp-smb-handle-file-directory-p (filename)
865 866 867
  "Like `file-directory-p' for Tramp files."
  (and (file-exists-p filename)
       (eq ?d (aref (nth 8 (file-attributes filename)) 0))))
868 869

(defun tramp-smb-handle-file-local-copy (filename)
870
  "Like `file-local-copy' for Tramp files."
871
  (with-parsed-tramp-file-name filename nil
872 873 874 875
    (unless (file-exists-p filename)
      (tramp-error
       v 'file-error
       "Cannot make local copy of non-existing file `%s'" filename))
876
    (let ((tmpfile (tramp-compat-make-temp-file filename)))
877
      (with-tramp-progress-reporter
878 879 880 881 882
	  v 3 (format "Fetching %s to tmp file %s" filename tmpfile)
	(unless (tramp-smb-send-command
		 v (format "get \"%s\" \"%s\""
			   (tramp-smb-get-localname v) tmpfile))
	  ;; Oops, an error.  We shall cleanup.
883
	  (delete-file tmpfile)
884 885
	  (tramp-error
	   v 'file-error "Cannot make local copy of file `%s'" filename)))
886
      tmpfile)))
887 888 889 890

;; This function should return "foo/" for directories and "bar" for
;; files.
(defun tramp-smb-handle-file-name-all-completions (filename directory)
891 892 893 894
  "Like `file-name-all-completions' for Tramp files."
  (all-completions
   filename
   (with-parsed-tramp-file-name directory nil
895
     (with-tramp-file-property v localname "file-name-all-completions"
896 897
       (save-match-data
	 (let ((entries (tramp-smb-get-file-entries directory)))
898 899 900 901 902 903 904 905 906
	   (mapcar
	    (lambda (x)
	      (list
	       (if (string-match "d" (nth 1 x))
		   (file-name-as-directory (nth 0 x))
		 (nth 0 x))))
	    entries)))))))

(defun tramp-smb-handle-file-writable-p (filename)
907 908 909 910 911 912
  "Like `file-writable-p' for Tramp files."
  (if (file-exists-p filename)
      (string-match "w" (or (nth 8 (file-attributes filename)) ""))
    (let ((dir (file-name-directory filename)))
      (and (file-exists-p dir)
	   (file-writable-p dir)))))
913 914 915

(defun tramp-smb-handle-insert-directory
  (filename switches &optional wildcard full-directory-p)
916
  "Like `insert-directory' for Tramp files."
917
  (setq filename (expand-file-name filename))
918 919 920 921
  (if full-directory-p
      ;; Called from `dired-add-entry'.
      (setq filename (file-name-as-directory filename))
    (setq filename (directory-file-name filename)))
Michael Albinus's avatar
Michael Albinus committed
922
  (with-parsed-tramp-file-name filename nil
923
    (save-match-data
924
      (let ((base (file-name-nondirectory filename))
925 926 927 928 929 930 931 932 933 934 935 936 937 938
	    ;; We should not destroy the cache entry.
	    (entries (copy-sequence
		      (tramp-smb-get-file-entries
		       (file-name-directory filename)))))

	(when wildcard
	  (string-match "\\." base)
	  (setq base (replace-match "\\\\." nil nil base))
	  (string-match "\\*" base)
	  (setq base (replace-match ".*" nil nil base))
	  (string-match "\\?" base)
	  (setq base (replace-match ".?" nil nil base)))

	;; Filter entries.
939
	(setq entries
940 941 942 943 944 945 946 947 948 949 950 951
	      (delq
	       nil
	       (if (or wildcard (zerop (length base)))
		   ;; Check for matching entries.
		   (mapcar
		    (lambda (x)
		      (when (string-match
			     (format "^%s" base) (nth 0 x))
			x))
		    entries)
		 ;; We just need the only and only entry FILENAME.
		 (list (assoc base entries)))))
952

Michael Albinus's avatar
Michael Albinus committed
953
	;; Sort entries.
954 955 956 957 958
	(setq entries
	      (sort
	       entries
	       (lambda (x y)
		 (if (string-match "t" switches)
959 960 961
		     ;; Sort by date.
		     (tramp-time-less-p (nth 3 y) (nth 3 x))
		   ;; Sort by name.
962 963
		   (string-lessp (nth 0 x) (nth 0 y))))))

Michael Albinus's avatar
Michael Albinus committed
964 965
	;; Handle "-F" switch.
	(when (string-match "F" switches)
966
	  (mapc
Michael Albinus's avatar
Michael Albinus committed
967 968 969 970 971 972 973 974 975
	   (lambda (x)
	     (when (not (zerop (length (car x))))
	       (cond
		((char-equal ?d (string-to-char (nth 1 x)))
		 (setcar x (concat (car x) "/")))
		((char-equal ?x (string-to-char (nth 1 x)))
		 (setcar x (concat (car x) "*"))))))
	   entries))

976
	;; Print entries.
977
	(mapc
978
	 (lambda (x)
979
	   (when (not (zerop (length (nth 0 x))))
980
	     (let ((attr
981
		    (when (tramp-smb-get-stat-capability v)
982
		      (ignore-errors
983
			(file-attributes filename 'string)))))
984 985
	       (insert
		(format
986
		 "%10s %3d %-8s %-8s %8s %s "
987
		 (or (nth 8 attr) (nth 1 x)) ; mode
988
		 (or (nth 1 attr) 1) ; inode
989 990
		 (or (nth 2 attr) "nobody") ; uid
		 (or (nth 3 attr) "nogroup") ; gid
991
		 (or (nth 7 attr) (nth 2 x)) ; size
992 993 994 995 996 997
		 (format-time-string
		  (if (tramp-time-less-p
		       (tramp-time-subtract (current-time) (nth 3 x))
		       tramp-half-a-year)
		      "%b %e %R"
		    "%b %e  %Y")
998
		  (nth 3 x)))) ; date
999 1000 1001
	       ;; We mark the file name.  The inserted name could be
	       ;; from somewhere else, so we use the relative file
	       ;; name of `default-directory'.
1002
	       (let ((start (point)))
1003 1004 1005
		 (insert
		  (format
		   "%s\n"
1006 1007 1008
		   (file-relative-name
		    (expand-file-name
		     (nth 0 x) (file-name-directory filename)))))
1009
		 (put-text-property start (1- (point)) 'dired-filename t))
1010 1011 1012
	       (forward-line)
	       (beginning-of-line))))
	 entries)))))
1013 1014

(defun tramp-smb-handle-make-directory (dir &optional parents)
1015
  "Like `make-directory' for Tramp files."
1016 1017
  (setq dir (directory-file-name (expand-file-name dir)))
  (unless (file-name-absolute-p dir)
1018
    (setq dir (expand-file-name dir default-directory)))
Michael Albinus's avatar
Michael Albinus committed
1019
  (with-parsed-tramp-file-name dir nil
1020
    (save-match-data
1021
      (let* ((ldir (file-name-directory dir)))
1022
	;; Make missing directory parts.
1023 1024 1025
	(when (and parents
		   (tramp-smb-get-share v)
		   (not (file-directory-p ldir)))
1026
	  (make-directory ldir parents))
1027
	;; Just do it.
1028
	(when (file-directory-p ldir)
1029
	  (make-directory-internal dir))
1030
	(unless (file-directory-p dir)
1031
	  (tramp-error v 'file-error "Couldn't make directory %s" dir))))))
1032 1033

(defun tramp-smb-handle-make-directory-internal (directory)
1034
  "Like `make-directory-internal' for Tramp files."
1035 1036
  (setq directory (directory-file-name (expand-file-name directory)))
  (unless (file-name-absolute-p directory)
1037
    (setq directory (expand-file-name directory default-directory)))
Michael Albinus's avatar
Michael Albinus committed
1038
  (with-parsed-tramp-file-name directory nil