eldoc.el 21.1 KB
Newer Older
Noah Friedman's avatar
Noah Friedman committed
1 2
;;; eldoc.el --- show function arglist or variable docstring in echo area

3
;; Copyright (C) 1996-2011 Free Software Foundation, Inc.
Noah Friedman's avatar
Noah Friedman committed
4

5 6
;; Author: Noah Friedman <friedman@splode.com>
;; Maintainer: friedman@splode.com
Noah Friedman's avatar
Noah Friedman committed
7 8 9
;; Keywords: extensions
;; Created: 1995-10-06

10
;; This file is part of GNU Emacs.
Noah Friedman's avatar
Noah Friedman committed
11

12
;; GNU Emacs is free software: you can redistribute it and/or modify
Noah Friedman's avatar
Noah Friedman committed
13
;; it under the terms of the GNU General Public License as published by
14 15
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
16 17

;; GNU Emacs is distributed in the hope that it will be useful,
Noah Friedman's avatar
Noah Friedman committed
18 19 20
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.
21

Noah Friedman's avatar
Noah Friedman committed
22
;; You should have received a copy of the GNU General Public License
23
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
Noah Friedman's avatar
Noah Friedman committed
24 25 26

;;; Commentary:

27 28 29 30 31 32 33 34
;; This program was inspired by the behavior of the "mouse documentation
;; window" on many Lisp Machine systems; as you type a function's symbol
;; name as part of a sexp, it will print the argument list for that
;; function.  Behavior is not identical; for example, you need not actually
;; type the function name, you need only move point around in a sexp that
;; calls it.  Also, if point is over a documented variable, it will print
;; the one-line documentation for that variable instead, to remind you of
;; that variable's meaning.
Noah Friedman's avatar
Noah Friedman committed
35 36 37 38 39 40

;; One useful way to enable this minor mode is to put the following in your
;; .emacs:
;;
;;      (add-hook 'emacs-lisp-mode-hook 'turn-on-eldoc-mode)
;;      (add-hook 'lisp-interaction-mode-hook 'turn-on-eldoc-mode)
41
;;      (add-hook 'ielm-mode-hook 'turn-on-eldoc-mode)
Noah Friedman's avatar
Noah Friedman committed
42

43
;; Major modes for other languages may use ElDoc by defining an
44
;; appropriate function as the buffer-local value of
Richard M. Stallman's avatar
Richard M. Stallman committed
45
;; `eldoc-documentation-function'.
46

Noah Friedman's avatar
Noah Friedman committed
47 48
;;; Code:

49 50
(require 'help-fns)		       ;For fundoc-usage handling functions.

51 52
(defgroup eldoc nil
  "Show function arglist or variable docstring in echo area."
53
  :group 'lisp
54 55 56
  :group 'extensions)

(defcustom eldoc-idle-delay 0.50
57
  "Number of seconds of idle time to wait before printing.
Noah Friedman's avatar
Noah Friedman committed
58 59 60
If user input arrives before this interval of time has elapsed after the
last input, no documentation will be printed.

61 62 63
If this variable is set to 0, no idle time is required."
  :type 'number
  :group 'eldoc)
Noah Friedman's avatar
Noah Friedman committed
64

65
;;;###autoload
66
(defcustom eldoc-minor-mode-string (purecopy " ElDoc")
67
  "String to display in mode line when ElDoc Mode is enabled; nil for none."
68
  :type '(choice string (const :tag "None" nil))
69
  :group 'eldoc)
70

71
(defcustom eldoc-argument-case 'upcase
Noah Friedman's avatar
Noah Friedman committed
72 73 74
  "Case to display argument names of functions, as a symbol.
This has two preferred values: `upcase' or `downcase'.
Actually, any name of a function which takes a string as an argument and
75 76 77 78
returns another string is acceptable.

Note that if `eldoc-documentation-function' is non-nil, this variable
has no effect, unless the function handles it explicitly."
79 80 81
  :type '(radio (function-item upcase)
		(function-item downcase)
                function)
82
  :group 'eldoc)
Noah Friedman's avatar
Noah Friedman committed
83

84
(defcustom eldoc-echo-area-use-multiline-p 'truncate-sym-name-if-fit
85
  "Allow long ElDoc messages to resize echo area display.
86
If value is t, never attempt to truncate messages; complete symbol name
87 88 89
and function arglist or 1-line variable documentation will be displayed
even if echo area must be resized to fit.

90
If value is any non-nil value other than t, symbol name may be truncated
91 92 93 94 95 96
if it will enable the function arglist or documentation string to fit on a
single line without resizing window.  Otherwise, behavior is just like
former case.

If value is nil, messages are always truncated to fit in a single line of
display in the echo area.  Function or variable symbol name may be
97 98 99 100
truncated to make more of the arglist or documentation string visible.

Note that if `eldoc-documentation-function' is non-nil, this variable
has no effect, unless the function handles it explicitly."
101 102 103 104 105 106
  :type '(radio (const :tag "Always" t)
                (const :tag "Never" nil)
                (const :tag "Yes, but truncate symbol names if it will\
 enable argument list to fit on one line" truncate-sym-name-if-fit))
  :group 'eldoc)

107 108
(defface eldoc-highlight-function-argument
  '((t (:inherit bold)))
109 110 111
  "Face used for the argument at point in a function's argument list.
Note that if `eldoc-documentation-function' is non-nil, this face
has no effect, unless the function handles it explicitly."
112 113
  :group 'eldoc)

114 115
;;; No user options below here.

116
(defvar eldoc-message-commands-table-size 31
117
  "Used by `eldoc-add-command' to initialize `eldoc-message-commands' obarray.
118 119 120 121 122 123 124 125
It should probably never be necessary to do so, but if you
choose to increase the number of buckets, you must do so before loading
this file since the obarray is initialized at load time.
Remember to keep it a prime number to improve hash performance.")

(defconst eldoc-message-commands
  (make-vector eldoc-message-commands-table-size 0)
  "Commands after which it is appropriate to print in the echo area.
126
ElDoc does not try to print function arglists, etc., after just any command,
127
because some commands print their own messages in the echo area and these
128
functions would instantly overwrite them.  But `self-insert-command' as well
129 130 131 132
as most motion commands are good candidates.
This variable contains an obarray of symbols; do not manipulate it
directly.  Instead, use `eldoc-add-command' and `eldoc-remove-command'.")

133
;; Not a constant.
134 135 136
(defconst eldoc-last-data (make-vector 3 nil)
  "Bookkeeping; elements are as follows:
  0 - contains the last symbol read from the buffer.
137 138
  1 - contains the string last displayed in the echo area for variables,
      or argument string for functions.
139
  2 - 'function if function args, 'variable if variable documentation.")
140

141
(defvar eldoc-last-message nil)
Noah Friedman's avatar
Noah Friedman committed
142

143
(defvar eldoc-timer nil "ElDoc's timer object.")
144

145
(defvar eldoc-current-idle-delay eldoc-idle-delay
146
  "Idle time delay currently in use by timer.
147
This is used to determine if `eldoc-idle-delay' is changed by the user.")
Noah Friedman's avatar
Noah Friedman committed
148 149 150


;;;###autoload
151
(define-minor-mode eldoc-mode
Chong Yidong's avatar
Chong Yidong committed
152 153 154 155 156 157 158 159 160 161 162
  "Toggle echo area display of Lisp objects at point (ElDoc mode).
With a prefix argument ARG, enable ElDoc mode if ARG is positive,
and disable it otherwise.  If called from Lisp, enable ElDoc mode
if ARG is omitted or nil.

ElDoc mode is a buffer-local minor mode.  When enabled, the echo
area displays information about a function or variable in the
text where point is.  If point is on a documented variable, it
displays the first line of that variable's doc string.  Otherwise
it displays the argument list of the function called in the
expression point is on."
Lute Kamstra's avatar
Lute Kamstra committed
163
  :group 'eldoc :lighter eldoc-minor-mode-string
164
  (setq eldoc-last-message nil)
165 166 167 168 169 170
  (if eldoc-mode
      (progn
	(add-hook 'post-command-hook 'eldoc-schedule-timer nil t)
	(add-hook 'pre-command-hook 'eldoc-pre-command-refresh-echo-area t))
   (remove-hook 'post-command-hook 'eldoc-schedule-timer)
   (remove-hook 'pre-command-hook 'eldoc-pre-command-refresh-echo-area)))
Noah Friedman's avatar
Noah Friedman committed
171 172 173

;;;###autoload
(defun turn-on-eldoc-mode ()
174
  "Unequivocally turn on ElDoc mode (see command `eldoc-mode')."
Noah Friedman's avatar
Noah Friedman committed
175 176 177
  (interactive)
  (eldoc-mode 1))

178

179 180 181 182 183 184 185 186 187 188 189 190
(defun eldoc-schedule-timer ()
  (or (and eldoc-timer
           (memq eldoc-timer timer-idle-list))
      (setq eldoc-timer
            (run-with-idle-timer eldoc-idle-delay t
                                 'eldoc-print-current-symbol-info)))

  ;; If user has changed the idle delay, update the timer.
  (cond ((not (= eldoc-idle-delay eldoc-current-idle-delay))
         (setq eldoc-current-idle-delay eldoc-idle-delay)
         (timer-set-idle-time eldoc-timer eldoc-idle-delay t))))

191 192
(defun eldoc-message (&rest args)
  (let ((omessage eldoc-last-message))
193
    (setq eldoc-last-message
194 195 196 197 198 199 200
	  (cond ((eq (car args) eldoc-last-message) eldoc-last-message)
		((null (car args)) nil)
		;; If only one arg, no formatting to do, so put it in
		;; eldoc-last-message so eq test above might succeed on
		;; subsequent calls.
		((null (cdr args)) (car args))
		(t (apply 'format args))))
201 202 203
    ;; In emacs 19.29 and later, and XEmacs 19.13 and later, all messages
    ;; are recorded in a log.  Do not put eldoc messages in that log since
    ;; they are Legion.
204 205 206 207
    ;; Emacs way of preventing log messages.
    (let ((message-log-max nil))
      (cond (eldoc-last-message (message "%s" eldoc-last-message))
	    (omessage (message nil)))))
208 209
  eldoc-last-message)

210 211 212 213 214 215 216 217 218 219 220
;; This function goes on pre-command-hook for XEmacs or when using idle
;; timers in Emacs.  Motion commands clear the echo area for some reason,
;; which make eldoc messages flicker or disappear just before motion
;; begins.  This function reprints the last eldoc message immediately
;; before the next command executes, which does away with the flicker.
;; This doesn't seem to be required for Emacs 19.28 and earlier.
(defun eldoc-pre-command-refresh-echo-area ()
  (and eldoc-last-message
       (if (eldoc-display-message-no-interference-p)
           (eldoc-message eldoc-last-message)
         (setq eldoc-last-message nil))))
221 222 223

;; Decide whether now is a good time to display a message.
(defun eldoc-display-message-p ()
224
  (and (eldoc-display-message-no-interference-p)
225 226 227 228 229 230 231 232
       ;; If this-command is non-nil while running via an idle
       ;; timer, we're still in the middle of executing a command,
       ;; e.g. a query-replace where it would be annoying to
       ;; overwrite the echo area.
       (and (not this-command)
	    (symbolp last-command)
	    (intern-soft (symbol-name last-command)
			 eldoc-message-commands))))
Noah Friedman's avatar
Noah Friedman committed
233

234 235
;; Check various conditions about the current environment that might make
;; it undesirable to print eldoc messages right this instant.
236 237 238
(defun eldoc-display-message-no-interference-p ()
  (and eldoc-mode
       (not executing-kbd-macro)
239
       (not (and (boundp 'edebug-active) edebug-active))
240 241 242 243 244
       ;; Having this mode operate in an active minibuffer/echo area causes
       ;; interference with what's going on there.
       (not cursor-in-echo-area)
       (not (eq (selected-window) (minibuffer-window)))))

245

246
;;;###autoload
Richard M. Stallman's avatar
Richard M. Stallman committed
247
(defvar eldoc-documentation-function nil
248 249 250 251 252 253 254
  "If non-nil, function to call to return doc string.
The function of no args should return a one-line string for displaying
doc about a function etc. appropriate to the context around point.
It should return nil if there's no doc appropriate for the context.
Typically doc is returned if point is on a function-like name or in its
arg list.

255 256 257 258 259
The result is used as is, so the function must explicitly handle
the variables `eldoc-argument-case' and `eldoc-echo-area-use-multiline-p',
and the face `eldoc-highlight-function-argument', if they are to have any
effect.

260
This variable is expected to be made buffer-local by modes (other than
261
Emacs Lisp mode) that support ElDoc.")
262

263
(defun eldoc-print-current-symbol-info ()
264 265
  (condition-case err
      (and (eldoc-display-message-p)
Richard M. Stallman's avatar
Richard M. Stallman committed
266 267
	   (if eldoc-documentation-function
	       (eldoc-message (funcall eldoc-documentation-function))
268 269 270
	     (let* ((current-symbol (eldoc-current-symbol))
		    (current-fnsym  (eldoc-fnsym-in-current-sexp))
		    (doc (cond
271 272 273 274 275
			  ((null current-fnsym)
			   nil)
			  ((eq current-symbol (car current-fnsym))
			   (or (apply 'eldoc-get-fnsym-args-string
				      current-fnsym)
276 277 278
			       (eldoc-get-var-docstring current-symbol)))
			  (t
			   (or (eldoc-get-var-docstring current-symbol)
279 280
			       (apply 'eldoc-get-fnsym-args-string
				      current-fnsym))))))
281
	       (eldoc-message doc))))
282 283 284
    ;; This is run from post-command-hook or some idle timer thing,
    ;; so we need to be careful that errors aren't ignored.
    (error (message "eldoc error: %s" err))))
285

286
(defun eldoc-get-fnsym-args-string (sym &optional index)
287 288
  "Return a string containing the parameter list of the function SYM.
If SYM is a subr and no arglist is obtainable from the docstring
289 290 291 292 293
or elsewhere, return a 1-line docstring.  Calls the functions
`eldoc-function-argstring-format' and
`eldoc-highlight-function-argument' to format the result.  The
former calls `eldoc-argument-case'; the latter gives the
function name `font-lock-function-name-face', and optionally
294
highlights argument number INDEX."
295
  (let (args doc advertised)
296
    (cond ((not (and sym (symbolp sym) (fboundp sym))))
297 298 299
	  ((and (eq sym (aref eldoc-last-data 0))
		(eq 'function (aref eldoc-last-data 2)))
	   (setq doc (aref eldoc-last-data 1)))
300 301 302
	  ((listp (setq advertised (gethash (indirect-function sym)
					    advertised-signature-table t)))
	   (setq args advertised))
303 304
	  ((setq doc (help-split-fundoc (documentation sym t) sym))
	   (setq args (car doc))
305
	   ;; Remove any enclosing (), since e-function-argstring adds them.
306
	   (string-match "\\`[^ )]* ?" args)
307
	   (setq args (substring args (match-end 0)))
308
	   (if (string-match-p ")\\'" args)
309 310 311 312 313 314 315 316 317 318 319 320
	       (setq args (substring args 0 -1))))
	  (t
	   (setq args (help-function-arglist sym))))
    (if args
	;; Stringify, and store before highlighting, downcasing, etc.
	;; FIXME should truncate before storing.
	(eldoc-last-data-store sym (setq args (eldoc-function-argstring args))
			       'function)
      (setq args doc))		  ; use stored value
    ;; Change case, highlight, truncate.
    (if args
	(eldoc-highlight-function-argument
321
	 sym (eldoc-function-argstring-format args) index))))
322

323 324 325
(defun eldoc-highlight-function-argument (sym args index)
  "Highlight argument INDEX in ARGS list for function SYM.
In the absence of INDEX, just call `eldoc-docstring-format-sym-doc'."
326 327
  (let ((start          nil)
	(end            0)
328
	(argument-face  'eldoc-highlight-function-argument))
329 330 331 332 333 334 335
    ;; Find the current argument in the argument string.  We need to
    ;; handle `&rest' and informal `...' properly.
    ;;
    ;; FIXME: What to do with optional arguments, like in
    ;;        (defun NAME ARGLIST [DOCSTRING] BODY...) case?
    ;;        The problem is there is no robust way to determine if
    ;;        the current argument is indeed a docstring.
336
    (while (and index (>= index 1))
337 338 339 340 341 342 343 344 345
      (if (string-match "[^ ()]+" args end)
	  (progn
	    (setq start (match-beginning 0)
		  end   (match-end 0))
	    (let ((argument (match-string 0 args)))
	      (cond ((string= argument "&rest")
		     ;; All the rest arguments are the same.
		     (setq index 1))
		    ((string= argument "&optional"))
346
		    ((string-match-p "\\.\\.\\.$" argument)
347 348 349 350 351 352 353 354 355 356 357 358 359 360 361
		     (setq index 0))
		    (t
		     (setq index (1- index))))))
	(setq end           (length args)
	      start         (1- end)
	      argument-face 'font-lock-warning-face
	      index         0)))
    (let ((doc args))
      (when start
	(setq doc (copy-sequence args))
	(add-text-properties start end (list 'face argument-face) doc))
      (setq doc (eldoc-docstring-format-sym-doc
		 sym doc 'font-lock-function-name-face))
      doc)))

362 363 364
;; Return a string containing a brief (one-line) documentation string for
;; the variable.
(defun eldoc-get-var-docstring (sym)
365 366 367 368 369 370 371 372
  (when sym
    (cond ((and (eq sym (aref eldoc-last-data 0))
		(eq 'variable (aref eldoc-last-data 2)))
	   (aref eldoc-last-data 1))
	  (t
	   (let ((doc (documentation-property sym 'variable-documentation t)))
	     (cond (doc
		    (setq doc (eldoc-docstring-format-sym-doc
373 374
			       sym (eldoc-docstring-first-line doc)
			       'font-lock-variable-name-face))
375 376
		    (eldoc-last-data-store sym doc 'variable)))
	     doc)))))
377 378 379 380 381 382 383 384 385 386 387 388

(defun eldoc-last-data-store (symbol doc type)
  (aset eldoc-last-data 0 symbol)
  (aset eldoc-last-data 1 doc)
  (aset eldoc-last-data 2 type))

;; Note that any leading `*' in the docstring (which indicates the variable
;; is a user option) is removed.
(defun eldoc-docstring-first-line (doc)
  (and (stringp doc)
       (substitute-command-keys
        (save-match-data
389 390 391
	  ;; Don't use "^" in the regexp below since it may match
	  ;; anywhere in the doc-string.
	  (let ((start (if (string-match "\\`\\*" doc) (match-end 0) 0)))
392 393 394 395 396 397 398 399
            (cond ((string-match "\n" doc)
                   (substring doc start (match-beginning 0)))
                  ((zerop start) doc)
                  (t (substring doc start))))))))

;; If the entire line cannot fit in the echo area, the symbol name may be
;; truncated or eliminated entirely from the output to make room for the
;; description.
400
(defun eldoc-docstring-format-sym-doc (sym doc face)
401 402
  (save-match-data
    (let* ((name (symbol-name sym))
403
           (ea-multi eldoc-echo-area-use-multiline-p)
404 405 406 407 408 409 410 411
           ;; Subtract 1 from window width since emacs will not write
           ;; any chars to the last column, or in later versions, will
           ;; cause a wraparound and resize of the echo area.
           (ea-width (1- (window-width (minibuffer-window))))
           (strip (- (+ (length name) (length ": ") (length doc)) ea-width)))
      (cond ((or (<= strip 0)
                 (eq ea-multi t)
                 (and ea-multi (> (length doc) ea-width)))
412
             (format "%s: %s" (propertize name 'face face) doc))
413 414 415 416
            ((> (length doc) ea-width)
             (substring (format "%s" doc) 0 ea-width))
            ((>= strip (length name))
             (format "%s" doc))
417
            (t
418 419 420 421
             ;; Show the end of the partial symbol name, rather
             ;; than the beginning, since the former is more likely
             ;; to be unique given package namespace conventions.
             (setq name (substring name strip))
422
             (format "%s: %s" (propertize name 'face face) doc))))))
Noah Friedman's avatar
Noah Friedman committed
423

424

425
;; Return a list of current function name and argument index.
Noah Friedman's avatar
Noah Friedman committed
426
(defun eldoc-fnsym-in-current-sexp ()
427 428 429 430 431 432 433 434 435 436 437 438
  (save-excursion
    (let ((argument-index (1- (eldoc-beginning-of-sexp))))
      ;; If we are at the beginning of function name, this will be -1.
      (when (< argument-index 0)
	(setq argument-index 0))
      ;; Don't do anything if current word is inside a string.
      (if (= (or (char-after (1- (point))) 0) ?\")
	  nil
	(list (eldoc-current-symbol) argument-index)))))

;; Move to the beginnig of current sexp.  Return the number of nested
;; sexp the point was over or after.
439
(defun eldoc-beginning-of-sexp ()
440 441
  (let ((parse-sexp-ignore-comments t)
	(num-skipped-sexps 0))
442
    (condition-case err
443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459
	(progn
	  ;; First account for the case the point is directly over a
	  ;; beginning of a nested sexp.
	  (condition-case err
	      (let ((p (point)))
		(forward-sexp -1)
		(forward-sexp 1)
		(when (< (point) p)
		  (setq num-skipped-sexps 1)))
	    (error))
	  (while
	      (let ((p (point)))
		(forward-sexp -1)
		(when (< (point) p)
		  (setq num-skipped-sexps (1+ num-skipped-sexps))))))
      (error))
    num-skipped-sexps))
460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476

;; returns nil unless current word is an interned symbol.
(defun eldoc-current-symbol ()
  (let ((c (char-after (point))))
    (and c
         (memq (char-syntax c) '(?w ?_))
         (intern-soft (current-word)))))

;; Do indirect function resolution if possible.
(defun eldoc-symbol-function (fsym)
  (let ((defn (and (fboundp fsym)
                   (symbol-function fsym))))
    (and (symbolp defn)
         (condition-case err
             (setq defn (indirect-function fsym))
           (error (setq defn nil))))
    defn))
Noah Friedman's avatar
Noah Friedman committed
477

478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495
(defun eldoc-function-argstring (arglist)
  "Return ARGLIST as a string enclosed by ().
ARGLIST is either a string, or a list of strings or symbols."
  (cond ((stringp arglist))
	((not (listp arglist))
	 (setq arglist nil))
	((symbolp (car arglist))
	 (setq arglist
	       (mapconcat (lambda (s) (symbol-name s))
			  arglist " ")))
	((stringp (car arglist))
	 (setq arglist
	       (mapconcat (lambda (s) s)
			  arglist " "))))
  (if arglist
      (format "(%s)" arglist)))

(defun eldoc-function-argstring-format (argstring)
496
  "Apply `eldoc-argument-case' to each word in ARGSTRING.
497 498
The words \"&rest\", \"&optional\" are returned unchanged."
  (mapconcat (lambda (s)
499
	       (if (string-match-p "\\`(?&\\(?:optional\\|rest\\))?\\'" s)
500 501
		   s
		 (funcall eldoc-argument-case s)))
502
	     (split-string argstring) " "))
503

Noah Friedman's avatar
Noah Friedman committed
504

505 506 507 508 509 510 511
;; When point is in a sexp, the function args are not reprinted in the echo
;; area after every possible interactive command because some of them print
;; their own messages in the echo area; the eldoc functions would instantly
;; overwrite them unless it is more restrained.
;; These functions do display-command table management.

(defun eldoc-add-command (&rest cmds)
512 513 514 515
  (dolist (name cmds)
    (and (symbolp name)
         (setq name (symbol-name name)))
    (set (intern name eldoc-message-commands) t)))
516 517

(defun eldoc-add-command-completions (&rest names)
518 519
  (dolist (name names)
    (apply 'eldoc-add-command (all-completions name obarray 'commandp))))
520 521

(defun eldoc-remove-command (&rest cmds)
522 523 524 525
  (dolist (name cmds)
    (and (symbolp name)
         (setq name (symbol-name name)))
    (unintern name eldoc-message-commands)))
526 527

(defun eldoc-remove-command-completions (&rest names)
528
  (dolist (name names)
529
    (apply 'eldoc-remove-command
530
           (all-completions name eldoc-message-commands))))
531

532

533 534
;; Prime the command list.
(eldoc-add-command-completions
535 536 537 538 539 540 541
 "backward-" "beginning-of-" "delete-other-windows" "delete-window"
 "down-list" "end-of-" "exchange-point-and-mark" "forward-" "goto-"
 "handle-select-window" "indent-for-tab-command" "left-" "mark-page"
 "mark-paragraph" "mouse-set-point" "move-" "move-beginning-of-"
 "move-end-of-" "next-" "other-window" "pop-global-mark" "previous-"
 "recenter" "right-" "scroll-" "self-insert-command" "split-window-"
 "up-list")
Noah Friedman's avatar
Noah Friedman committed
542 543 544 545

(provide 'eldoc)

;;; eldoc.el ends here