configure.ac 175 KB
Newer Older
1 2 3 4 5 6
dnl  Autoconf script for GNU Emacs
dnl To rebuild the `configure' script from this, execute the command
dnl 	autoconf
dnl in the directory containing this script.
dnl If you changed any AC_DEFINES, also run autoheader.
dnl
7
dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24
dnl
dnl  This file is part of GNU Emacs.
dnl
dnl  GNU Emacs is free software: you can redistribute it and/or modify
dnl  it under the terms of the GNU General Public License as published by
dnl  the Free Software Foundation, either version 3 of the License, or
dnl  (at your option) any later version.
dnl
dnl  GNU Emacs is distributed in the hope that it will be useful,
dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl  GNU General Public License for more details.
dnl
dnl  You should have received a copy of the GNU General Public License
dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

AC_PREREQ(2.65)
Glenn Morris's avatar
Glenn Morris committed
25
dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
26
AC_INIT(GNU Emacs, 25.0.50, bug-gnu-emacs@gnu.org)
27

28 29 30 31 32 33
dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
dnl and then quoted again for a C string.  Separate options with spaces.
dnl Add some environment variables, if they were passed via the environment
dnl rather than on the command-line.
emacs_config_options=
optsep=
34 35
dnl This is the documented way to record the args passed to configure,
dnl rather than $ac_configure_args.
36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64
for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  case $opt in
    -n | --no-create | --no-recursion)
      continue ;;
    CFLAGS | CPPFLAGS | LDFLAGS)
      eval 'test "${'$opt'+set}" = set' || continue
      case " $*" in
	*" $opt="*) continue ;;
      esac
      eval opt=$opt=\$$opt ;;
  esac

  emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  case $opt in
    *[["$emacs_shell_specials"]]*)
      case $opt in
	*\'*)
	  emacs_quote_apostrophes="s/'/'\\\\''/g"
	  opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
      esac
      opt="'$opt'"
      case $opt in
	*[['"\\']]*)
	  emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
	  opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
      esac ;;
  esac
  AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  optsep=' '
65 66
done

67
AC_CONFIG_HEADERS(src/config.h:src/config.in)
68
AC_CONFIG_SRCDIR(src/lisp.h)
69
AC_CONFIG_AUX_DIR(build-aux)
70
dnl automake 1.13 and later understand this, making -I m4 unnecessary.
Glenn Morris's avatar
Glenn Morris committed
71
dnl With older versions this is a no-op.
72
AC_CONFIG_MACRO_DIR(m4)
73 74 75 76

xcsdkdir=
AC_CHECK_PROGS(XCRUN, [xcrun])
if test -n "$XCRUN"; then
77 78
  if test -z "$MAKE"; then
    dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
79
    dnl the usual MAKE variable that 'make' itself uses.
80 81 82 83
    AC_CHECK_PROG([MAKE_PROG], [make], [yes])
    if test -z "$MAKE_PROG"; then
      MAKE="$XCRUN MAKE"
      export MAKE
84
      xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
85 86
    fi
  fi
87 88
fi

89 90 91 92 93 94 95
dnl GNU Make is required, so don't test for its individual features.
am_cv_make_support_nested_variables=yes
AC_DEFUN([AC_PROG_MAKE_SET],
  [SET_MAKE=
   AC_SUBST([SET_MAKE])])

dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
96 97 98 99 100 101 102 103 104
[emacs_check_gnu_make ()
{
  emacs_makeout=`($1 --version) 2>/dev/null` &&
  case $emacs_makeout in
    'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
    'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
       ac_path_MAKE_found=:;;
  esac
}]
105 106 107
AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
  [ac_path_MAKE_found=false
   if test -n "$MAKE"; then
108
     emacs_check_gnu_make "$MAKE"
109 110 111 112 113 114
     ac_cv_path_MAKE=$MAKE
   else
     emacs_tried_make=false
     emacs_tried_gmake=false
     emacs_tried_gnumake=false
     AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
115 116 117 118 119 120 121 122 123 124
       [[emacs_check_gnu_make "$ac_path_MAKE"
	 if $ac_path_MAKE_found; then
	   # Use the fully-qualified program name only if the basename
	   # would not resolve to it.
	   if eval \$emacs_tried_$ac_prog; then
	     ac_cv_path_MAKE=$ac_path_MAKE
	   else
	     ac_cv_path_MAKE=$ac_prog
	   fi
	 fi
125 126
	 eval emacs_tried_$ac_prog=:]])
   fi])
127 128
$ac_path_MAKE_found || {
AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
129 130 131 132
If you have it installed under another name, configure with 'MAKE=...'.
For example, run '$0 MAKE=gnu-make'.]])
}
MAKE=$ac_cv_path_MAKE
133
export MAKE
134

Glenn Morris's avatar
Glenn Morris committed
135 136
dnl Fairly arbitrary, older versions might work too.
AM_INIT_AUTOMAKE(1.11)
137

138 139 140
dnl Canonicalize the configuration name.
AC_CANONICAL_HOST

141
case $host in
142 143
 *-mingw*)

144 145 146 147 148 149 150 151 152
  if test -z "$host_alias"; then

      # No --host argument was given to 'configure'; therefore $host
      # was set to a default value based on the build platform.  But
      # this default value may be wrong if we are building from a
      # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
      # Therefore, we'll try to get the right host platform from the
      # compiler's target.

153
      AC_MSG_CHECKING([the compiler's target])
154
      if test -z "$CC"; then
155 156 157 158
	  cc=gcc
      else
	  cc=$CC
      fi
159 160 161
      cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
      case "$cc_target" in
          *-*) host=$cc_target
162 163
	      ;;
          "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
164
Please explicitly provide --host.])
165 166
              ;;
	  *) AC_MSG_WARN([Compiler reported non-standard target.
167
Defaulting to $host.])
168 169
              ;;
      esac
170
      AC_MSG_RESULT([$host])
171 172
  fi

173 174
  . $srcdir/nt/mingw-cfg.site

175 176 177 178 179 180
  case $srcdir in
    /* | ?:*)
      # srcdir is an absolute path.  In this case, force the format
      # "/c/foo/bar", to simplify later conversions to native Windows
      # format ("c:/foo/bar").
      srcdir=`cd "${srcdir}" && pwd -W`
181 182
      # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
      eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
183 184 185 186
      ;;
  esac;;
esac

187 188 189
canonical=$host
configuration=${host_alias-${build_alias-$host}}

190 191 192 193 194 195 196 197 198
dnl Support for --program-prefix, --program-suffix and
dnl --program-transform-name options
AC_ARG_PROGRAM

dnl It is important that variables on the RHS not be expanded here,
dnl hence the single quotes.  This is per the GNU coding standards, see
dnl (autoconf) Installation Directory Variables
dnl See also epaths.h below.
lispdir='${datadir}/emacs/${version}/lisp'
199
standardlisppath='${lispdir}'
200 201
locallisppath='${datadir}/emacs/${version}/site-lisp:'\
'${datadir}/emacs/site-lisp'
202
lisppath='${locallisppath}:${standardlisppath}'
203 204
etcdir='${datadir}/emacs/${version}/etc'
archlibdir='${libexecdir}/emacs/${version}/${configuration}'
205
etcdocdir='${datadir}/emacs/${version}/etc'
206 207
gamedir='${localstatedir}/games/emacs'

208 209 210
dnl Special option to disable the most of other options.
AC_ARG_WITH(all,
[AS_HELP_STRING([--without-all],
211 212
		[omit almost all features and build
		small executable with minimal dependencies])],
213
  [with_features=$withval],
214
  [with_features=yes])
215

216 217 218 219 220 221 222 223 224 225 226 227 228 229 230
dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
dnl Create a new --with option that defaults to being disabled.
dnl NAME is the base name of the option.  The shell variable with_NAME
dnl   will be set to either the user's value (if the option is
dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
dnl   option is not specified).  Note that the shell variable name is
dnl   constructed as autoconf does, by replacing non-alphanumeric
dnl   characters with "_".
dnl HELP-STRING is the help text for the option.
AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
])dnl

dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
Michael Albinus's avatar
Michael Albinus committed
231
dnl Create a new --with option that defaults to $with_features.
232
dnl NAME is the base name of the option.  The shell variable with_NAME
233 234 235 236 237 238 239
dnl   will be set either to 'no' (for a plain --without-NAME) or to
dnl   'yes' (if the option is not specified).  Note that the shell
dnl   variable name is constructed as autoconf does, by replacing
dnl   non-alphanumeric characters with "_".
dnl HELP-STRING is the help text for the option.
AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
240
   m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285
])dnl

OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
if test "$with_pop" = yes; then
   AC_DEFINE(MAIL_USE_POP)
fi
AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl

OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
if test "$with_kerberos" != no; then
   AC_DEFINE(KERBEROS)
fi
AH_TEMPLATE(KERBEROS,
	    [Define to support Kerberos-authenticated POP mail retrieval.])dnl

OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
if test "${with_kerberos5}" != no; then
  if test "${with_kerberos}" = no; then
    with_kerberos=yes
    AC_DEFINE(KERBEROS)
  fi
  AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
fi

OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
dnl FIXME hesiod support may not be present, so it seems like an error
dnl to define, or at least use, this unconditionally.
if test "$with_hesiod" != no; then
  AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
fi

OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
if test "$with_mmdf" != no; then
   AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
fi

OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
if test "$with_mail_unlink" != no; then
   AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
fi

AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
    [string giving default POP mail host])],
    AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))

286
AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
287
  [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
288
default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
289
  [ case "${withval}" in
290
      yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
291
      *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
292
this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
293 294 295 296 297
      ;;
    esac
    with_sound=$val
  ],
  [with_sound=$with_features])
298 299 300

dnl FIXME currently it is not the last.
dnl This should be the last --with option, because --with-x is
301
dnl added later on when we find the file name of X, and it's best to
302 303
dnl keep them together visually.
AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
304
 [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
305 306 307 308 309 310 311
[	  case "${withval}" in
	    y | ye | yes )	val=gtk ;;
	    n | no )		val=no  ;;
	    l | lu | luc | luci | lucid )	val=lucid ;;
	    a | at | ath | athe | athen | athena )	val=athena ;;
	    m | mo | mot | moti | motif )	val=motif ;;
	    g | gt | gtk  )	val=gtk ;;
312
	    gtk2  )	val=gtk2 ;;
313 314 315
	    gtk3  )	val=gtk3 ;;
	    * )
AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
316 317 318
this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
`gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
`athena' and `lucid' are synonyms.])
319 320 321 322 323
	    ;;
	  esac
	  with_x_toolkit=$val
])

Paul Eggert's avatar
Paul Eggert committed
324 325 326 327 328
OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
if test "$with_wide_int" = yes; then
  AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
fi

329 330
dnl _ON results in a '--without' option in the --help output, so
dnl the help text should refer to "don't compile", etc.
Paul Eggert's avatar
Paul Eggert committed
331
with_xpm_set=${with_xpm+set}
332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347
OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])

OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])

OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
348
OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
349
OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
350 351 352 353

OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
354
OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
355 356
OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
Paul Eggert's avatar
Paul Eggert committed
357
OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
358 359 360 361 362 363 364 365 366 367 368

AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 [ case "${withval}" in
    y | ye | yes )	val=yes ;;
    n | no )		val=no  ;;
    g | gf | gfi | gfil | gfile )	val=gfile ;;
    i | in | ino | inot | inoti | inotif | inotify )	val=inotify ;;
    w | w3 | w32 )	val=w32 ;;
    * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
369 370
`yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
otherwise for the first of `gfile' or `inotify' that is usable.])
371 372 373 374
    ;;
   esac
   with_file_notification=$val
 ],
375
 [with_file_notification=$with_features])
376 377 378 379 380 381

## For the times when you want to build Emacs but don't have
## a suitable makeinfo, and can live without the manuals.
dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])

382
## This might be a 'configure' arg.
383 384
AC_SUBST([ACLOCAL_PATH])

385 386 387
## Makefile.in needs the cache file name.
AC_SUBST(cache_file)

388 389
## This is an option because I do not know if all info/man support
## compressed files, nor how to test if they do so.
390 391 392
OPTION_DEFAULT_ON([compress-install],
  [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
make GZIP_PROG= install])
393

394 395 396 397 398 399
AC_ARG_WITH(gameuser,dnl
[AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
  && gameuser="${with_gameuser}"
test "X$gameuser" = X && gameuser=games

400
AC_ARG_WITH([gnustep-conf],dnl
401 402
[AS_HELP_STRING([--with-gnustep-conf=FILENAME],
   [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429
test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
  GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
test "X$GNUSTEP_CONFIG_FILE" = "X" && \
     GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf

AC_ARG_ENABLE(ns-self-contained,
[AS_HELP_STRING([--disable-ns-self-contained],
                [disable self contained build under NeXTstep])],
   EN_NS_SELF_CONTAINED=$enableval,
   EN_NS_SELF_CONTAINED=yes)

AC_ARG_ENABLE(locallisppath,
[AS_HELP_STRING([--enable-locallisppath=PATH],
                [directories Emacs should search for lisp files specific
		 to this site])],
if test "${enableval}" = "no"; then
  locallisppath=
elif test "${enableval}" != "yes"; then
  locallisppath=${enableval}
fi)

AC_ARG_ENABLE(checking,
[AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
		[enable expensive run-time checks.  With LIST,
		 enable only specific categories of checks.
		 Categories are: all,yes,no.
		 Flags are: stringbytes, stringoverrun, stringfreelist,
430
		 xmallocoverrun, conslist, glyphs])],
431 432 433 434 435 436 437 438 439 440 441 442
[ac_checking_flags="${enableval}"],[])
IFS="${IFS= 	}"; ac_save_IFS="$IFS"; IFS="$IFS,"
for check in $ac_checking_flags
do
	case $check in
	# these set all the flags to specific states
	yes)		ac_enable_checking=1 ;;
	no)		ac_enable_checking= ;
			ac_gc_check_stringbytes= ;
	                ac_gc_check_string_overrun= ;
	                ac_gc_check_string_free_list= ;
	                ac_xmalloc_overrun= ;
443
	                ac_gc_check_cons_list= ;
444
			ac_glyphs_debug= ;;
445 446 447 448 449
	all)		ac_enable_checking=1 ;
			ac_gc_check_stringbytes=1 ;
	                ac_gc_check_string_overrun=1 ;
	                ac_gc_check_string_free_list=1 ;
	                ac_xmalloc_overrun=1 ;
450
	                ac_gc_check_cons_list=1 ;
451
			ac_glyphs_debug=1 ;;
452 453 454 455 456 457
	# these enable particular checks
	stringbytes) 	ac_gc_check_stringbytes=1 ;;
	stringoverrun) 	ac_gc_check_string_overrun=1 ;;
	stringfreelist) ac_gc_check_string_free_list=1 ;;
	xmallocoverrun)	ac_xmalloc_overrun=1 ;;
	conslist)	ac_gc_check_cons_list=1 ;;
458
	glyphs)		ac_glyphs_debug=1 ;;
459 460 461 462 463 464 465
	*)	AC_MSG_ERROR(unknown check category $check) ;;
	esac
done
IFS="$ac_save_IFS"

if test x$ac_enable_checking != x ; then
  AC_DEFINE(ENABLE_CHECKING, 1,
466
[Define to 1 if expensive run-time data type and consistency checks are enabled.])
467 468 469 470 471 472 473
fi
if test x$ac_gc_check_stringbytes != x ; then
  AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
[Define this temporarily to hunt a bug.  If defined, the size of
   strings is redundantly recorded in sdata structures so that it can
   be compared to the sizes recorded in Lisp strings.])
fi
474
if test x$ac_gc_check_string_overrun != x ; then
475 476 477 478 479 480 481 482 483 484 485 486 487 488 489
  AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
[Define this to check for short string overrun.])
fi
if test x$ac_gc_check_string_free_list != x ; then
  AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
[Define this to check the string free list.])
fi
if test x$ac_xmalloc_overrun != x ; then
  AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
[Define this to check for malloc buffer overrun.])
fi
if test x$ac_gc_check_cons_list != x ; then
  AC_DEFINE(GC_CHECK_CONS_LIST, 1,
[Define this to check for errors in cons list.])
fi
490
if test x$ac_glyphs_debug != x ; then
491 492 493
  AC_DEFINE(GLYPH_DEBUG, 1,
[Define this to enable glyphs debugging code.])
fi
494

495 496 497 498
AC_ARG_ENABLE(check-lisp-object-type,
[AS_HELP_STRING([--enable-check-lisp-object-type],
                [enable compile time checks for the Lisp_Object data type.
		This is useful for development for catching certain types of bugs.])],
499
if test "${enableval}" != "no"; then
500 501
   AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
   [Define this to enable compile time checks for the Lisp_Object data type.])
502 503 504
fi)


505 506 507 508
dnl The name of this option is unfortunate.  It predates, and has no
dnl relation to, the "sampling-based elisp profiler" added in 24.3.
dnl Actually, it stops it working.
dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
509 510
AC_ARG_ENABLE(profiling,
[AS_HELP_STRING([--enable-profiling],
511 512 513
		[build emacs with low-level, gprof profiling support.
                Mainly useful for debugging Emacs itself.  May not work on
                all platforms.  Stops profiler.el working.])],
514 515 516 517 518 519 520 521 522 523 524
[ac_enable_profiling="${enableval}"],[])
if test x$ac_enable_profiling != x ; then
   PROFILING_CFLAGS="-DPROFILING=1 -pg"
else
   PROFILING_CFLAGS=
fi
AC_SUBST(PROFILING_CFLAGS)

AC_ARG_ENABLE(autodepend,
[AS_HELP_STRING([--enable-autodepend],
		[automatically generate dependencies to .h-files.
Glenn Morris's avatar
Glenn Morris committed
525
 		 Requires gcc, enabled if found.])],
526 527
[ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])

528 529 530 531 532
AC_ARG_ENABLE(gtk-deprecation-warnings,
[AS_HELP_STRING([--enable-gtk-deprecation-warnings],
		[Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
[ac_enable_gtk_deprecation_warnings="${enableval}"],[])

533 534 535 536 537 538 539 540 541 542 543 544
dnl This used to use changequote, but, apart from `changequote is evil'
dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
dnl the great gob of text.  Thus it's not processed for possible expansion.
dnl Just make sure the brackets remain balanced.
dnl
dnl Since Emacs can't find matching pairs of quotes, boundaries are
dnl indicated by comments.
dnl quotation begins
[

### If you add support for a new configuration, add code to this
### switch statement to recognize your configuration name and select
Glenn Morris's avatar
Glenn Morris committed
545 546
### the appropriate opsys.

547 548 549 550 551 552
### As far as handling version numbers on operating systems is
### concerned, make sure things will fail in a fixable way.  If
### /etc/MACHINES doesn't say anything about version numbers, be
### prepared to handle anything reasonably.  If version numbers
### matter, be sure /etc/MACHINES says something about it.

Paul Eggert's avatar
Paul Eggert committed
553
opsys='' unported=no
554 555
case "${canonical}" in

556 557
  ## GNU/Linux and similar ports
  *-*-linux* )
558 559 560
    opsys=gnu-linux
  ;;

561 562 563 564 565
  ## FreeBSD ports
  *-*-freebsd* )
    opsys=freebsd
  ;;

566 567 568 569 570
  ## DragonFly ports
  *-*-dragonfly* )
    opsys=dragonfly
  ;;

571 572 573 574 575 576 577 578 579 580 581
  ## FreeBSD kernel + glibc based userland
  *-*-kfreebsd*gnu* )
    opsys=gnu-kfreebsd
  ;;

  ## NetBSD ports
  *-*-netbsd* )
    opsys=netbsd
  ;;

  ## OpenBSD ports
582
  *-*-openbsd* | *-*-mirbsd* )
583 584 585 586 587 588
    opsys=openbsd
  ;;

  ## Apple Darwin / Mac OS X
  *-apple-darwin* )
    case "${canonical}" in
589
      *-apple-darwin[0-9].*) unported=yes ;;
590 591
      i[3456]86-* | x86_64-* )  ;;
      * )            unported=yes ;;
592
    esac
593
    opsys=darwin
594 595 596 597 598 599
    ## Use fink packages if available.
    ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
##    if test -d /sw/include && test -d /sw/lib; then
##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
##    fi
600 601
  ;;

602 603 604 605 606
  ## Cygwin ports
  *-*-cygwin )
    opsys=cygwin
  ;;

607 608
  ## HP 9000 series 700 and 800, running HP/UX
  hppa*-hp-hpux10.2* )
609
    opsys=hpux10-20
610 611
  ;;
  hppa*-hp-hpux1[1-9]* )
612
    opsys=hpux11
613 614 615 616 617
    CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
  ;;

  ## IBM machines
  rs6000-ibm-aix4.[23]* )
Paul Eggert's avatar
Paul Eggert committed
618
    opsys=aix4-2
619 620
  ;;
  powerpc-ibm-aix4.[23]*  )
Paul Eggert's avatar
Paul Eggert committed
621
    opsys=aix4-2
622 623
  ;;
  rs6000-ibm-aix[56]* )
Paul Eggert's avatar
Paul Eggert committed
624
    opsys=aix4-2
625
  ;;
Paul Eggert's avatar
Paul Eggert committed
626
  powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
Paul Eggert's avatar
Paul Eggert committed
627
    opsys=aix4-2
628 629 630 631 632
  ;;

  ## Silicon Graphics machines
  ## Iris 4D
  mips-sgi-irix6.5 )
633
    opsys=irix6-5
634 635 636 637 638 639 640 641 642 643 644
    # Without defining _LANGUAGE_C, things get masked out in the headers
    # so that, for instance, grepping for `free' in stdlib.h fails and
    # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
    NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
  ;;

  ## Suns
  *-sun-solaris* \
    | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
    | x86_64-*-solaris2*    | x86_64-*-sunos5*)
    case "${canonical}" in
Paul Eggert's avatar
Paul Eggert committed
645 646 647
      i[3456]86-*-* )   ;;
      amd64-*-*|x86_64-*-*) ;;
      sparc* )		;;
648 649 650
      * )		unported=yes ;;
    esac
    case "${canonical}" in
651 652 653 654
      *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
		opsys=sol2-10
		emacs_check_sunpro_c=yes
		;;
655 656
      *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
      ## Note that Emacs 23.1's NEWS said the following would be dropped.
657 658 659 660
      *-sunos5.6* | *-solaris2.6* )
		opsys=sol2-6
		RANLIB="ar -ts"
		;;
661
      ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682
      *-sunos5.[7-9]* | *-solaris2.[7-9]* )
		opsys=sol2-6
		emacs_check_sunpro_c=yes
		;;
    esac
    ## Watch out for a compiler that we know will not work.
    case "${canonical}" in
     *-solaris* | *-sunos5* )
		if [ "x$CC" = x/usr/ucb/cc ]; then
		  ## /usr/ucb/cc doesn't work;
		  ## we should find some other compiler that does work.
		  unset CC
		fi
		;;
      *) ;;
    esac
  ;;

  ## Intel 386 machines where we don't care about the manufacturer.
  i[3456]86-*-* )
    case "${canonical}" in
683
      *-darwin* )               opsys=darwin ;;
684
      *-mingw* )
685
		opsys=mingw32
686
		# MinGW overrides and adds some system headers in nt/inc.
687
		GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
688
		;;
689 690 691
      *-sysv4.2uw* )	  	opsys=unixware ;;
      *-sysv5uw* )	  	opsys=unixware ;;
      *-sysv5OpenUNIX* )  	opsys=unixware ;;
692 693 694 695
      ## Otherwise, we'll fall through to the generic opsys code at the bottom.
    esac
  ;;

696 697 698
  # MinGW64
  x86_64-*-* )
    case "${canonical}" in
699
      *-mingw* )
700 701 702 703 704 705 706 707
		opsys=mingw32
		# MinGW overrides and adds some system headers in nt/inc.
		GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
		;;
      ## Otherwise, we'll fall through to the generic opsys code at the bottom.
    esac
  ;;

708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731
  * )
    unported=yes
  ;;
esac

### If the code above didn't choose an operating system, just choose
### an operating system based on the configuration name.  You really
### only want to use this when you have no idea what the right
### operating system is; if you know what operating systems a machine
### runs, it's cleaner to make it explicit in the case statement
### above.
if test x"${opsys}" = x; then
  case "${canonical}" in
    *-gnu* )				opsys=gnu ;;
    * )
      unported=yes
    ;;
  esac
fi

]
dnl quotation ends

if test $unported = yes; then
Glenn Morris's avatar
Glenn Morris committed
732
  AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
Glenn Morris's avatar
Glenn Morris committed
733
If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
734 735 736 737
Check `etc/MACHINES' for recognized configuration names.])
fi

#### Choose a compiler.
738

Paul Eggert's avatar
Paul Eggert committed
739 740 741
dnl Don't bother to test for C89.
AC_DEFUN([_AC_PROG_CC_C89], [$2])

742
dnl Sets GCC=yes if using gcc.
743
AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
744
if test -n "$XCRUN"; then
745
  AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
746
  test -n "$AR" && export AR
747
fi
748

Paul Eggert's avatar
Paul Eggert committed
749 750 751
dnl Emacs needs C99 or later.
gl_PROG_CC_C99

Paul Eggert's avatar
Paul Eggert committed
752 753
AM_PROG_CC_C_O

754 755 756 757 758 759
if test x$GCC = xyes; then
  test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
else
  test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
fi

760 761 762 763 764
dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
dnl alternative to lib/gnulib.mk, so as to avoid generating header files
dnl that clash with MinGW.
AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])

765 766
# Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
AC_DEFUN([gl_CRYPTO_CHECK])
767 768
# Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
# as we don't use them.
769
AC_DEFUN([gl_FCNTL_O_FLAGS])
770

771
# Initialize gnulib right after choosing the compiler.
Glenn Morris's avatar
Comment  
Glenn Morris committed
772
dnl Amongst other things, this sets AR and ARFLAGS.
773 774
gl_EARLY

775
if test "$ac_test_CFLAGS" != set; then
Paul Eggert's avatar
Paul Eggert committed
776 777 778
  # It's helpful to have C macros available to GDB, so prefer -g3 to -g
  # if -g3 works and the user does not specify CFLAGS.
  # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
779 780 781 782 783 784 785 786 787 788 789 790 791 792 793
  case $CFLAGS in
    '-g')
      emacs_g3_CFLAGS='-g3';;
    '-g -O2')
      emacs_g3_CFLAGS='-g3 -O2';;
    *)
      emacs_g3_CFLAGS='';;
  esac
  if test -n "$emacs_g3_CFLAGS"; then
    emacs_save_CFLAGS=$CFLAGS
    CFLAGS=$emacs_g3_CFLAGS
    AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
      [emacs_cv_prog_cc_g3],
      [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
	 [emacs_cv_prog_cc_g3=yes],
Paul Eggert's avatar
Paul Eggert committed
794 795
	 [emacs_cv_prog_cc_g3=no])])
    if test $emacs_cv_prog_cc_g3 != yes; then
796 797
      CFLAGS=$emacs_save_CFLAGS
    fi
798 799 800
    if test $opsys = mingw32; then
      CFLAGS="$CFLAGS -gdwarf-2"
    fi
801
  fi
Paul Eggert's avatar
Paul Eggert committed
802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819

  case $CFLAGS in
    *-O*) ;;
    *)
      # No optimization flag was inferred for this non-GCC compiler.
      # Try -O.  This is needed for xlc on AIX; see Bug#14258.
      emacs_save_CFLAGS=$CFLAGS
      test -z "$CFLAGS" || CFLAGS="$CFLAGS "
      CFLAGS=${CFLAGS}-O
      AC_CACHE_CHECK([whether $CC accepts -O],
        [emacs_cv_prog_cc_o],
	[AC_LINK_IFELSE([AC_LANG_PROGRAM()],
	   [emacs_cv_prog_cc_o=yes],
	   [emacs_cv_prog_cc_o=no])])
      if test $emacs_cv_prog_cc_o != yes; then
	CFLAGS=$emacs_save_CFLAGS
      fi ;;
  esac
820 821
fi

822 823
AC_ARG_ENABLE([gcc-warnings],
  [AS_HELP_STRING([--enable-gcc-warnings],
824
                  [turn on lots of GCC warnings/errors. This is intended for
825 826
		   developers, and may generate false alarms when used
		   with older or non-GNU development tools.])],
827 828 829 830 831 832 833 834
  [case $enableval in
     yes|no) ;;
     *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
   esac
   gl_gcc_warnings=$enableval],
  [gl_gcc_warnings=no]
)

835 836 837 838 839
# clang is unduly picky about some things.
AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
  [AC_COMPILE_IFELSE(
     [AC_LANG_PROGRAM([[
	  #ifndef __clang__
Paul Eggert's avatar
Paul Eggert committed
840
	    error "not clang";
841 842 843 844 845
	  #endif
        ]])],
     [emacs_cv_clang=yes],
     [emacs_cv_clang=no])])

846 847 848 849
# When compiling with GCC, prefer -isystem to -I when including system
# include files, to avoid generating useless diagnostics for the files.
if test "$gl_gcc_warnings" != yes; then
  isystem='-I'
850 851 852 853 854 855
  if test "$emacs_cv_clang" = yes
  then
     # Turn off some warnings if supported.
     gl_WARN_ADD([-Wno-switch])
     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
     gl_WARN_ADD([-Wno-pointer-sign])
856
     gl_WARN_ADD([-Wno-string-plus-int])
857
  fi
858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876
else
  isystem='-isystem '

  # This, $nw, is the list of warnings we disable.
  nw=

  case $with_x_toolkit in
    lucid | athena | motif)
       # Old toolkits mishandle 'const'.
       nw="$nw -Wwrite-strings"
       ;;
    *)
       gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
       ;;
  esac
  AC_SUBST([WERROR_CFLAGS])

  nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  nw="$nw -Woverlength-strings"     # Not a problem these days
877
  nw="$nw -Wformat-nonliteral"      # we do this a lot
Paul Eggert's avatar
Paul Eggert committed
878
  nw="$nw -Wvla"                    # Emacs uses <vla.h>.
879
  nw="$nw -Wswitch-default"         # Too many warnings for now
880
  nw="$nw -Winline"                 # OK to ignore 'inline'
881
  nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
882 883
  nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
                                    # signed overflow has undefined behavior
884 885
  nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
  nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
886
  nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
887 888 889 890 891

  # Emacs doesn't care about shadowing; see
  # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
  nw="$nw -Wshadow"

892 893 894
  # Emacs's use of alloca inhibits protecting the stack.
  nw="$nw -Wstack-protector"

Paul Eggert's avatar
Paul Eggert committed
895 896
  # Emacs's use of partly-pure functions such as CHECK_TYPE make this
  # option problematic.
897 898
  nw="$nw -Wsuggest-attribute=pure"

899 900 901 902 903 904 905
  # This part is merely for shortening the command line,
  # since -Wno-FOO needs to be added below regardless.
  nw="$nw -Wmissing-field-initializers"
  nw="$nw -Wswitch"
  nw="$nw -Wtype-limits"
  nw="$nw -Wunused-parameter"

906 907 908 909
  if test $emacs_cv_clang = yes; then
    nw="$nw -Wcast-align"
  fi

910 911 912 913 914
  gl_MANYWARN_ALL_GCC([ws])
  gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  for w in $ws; do
    gl_WARN_ADD([$w])
  done
Paul Eggert's avatar
Paul Eggert committed
915
  gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
916 917 918 919 920 921 922
  gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
  gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
  gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
  gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
  gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
  gl_WARN_ADD([-Wno-format-nonliteral])

923 924 925 926 927 928 929 930
  # More things that clang is unduly picky about.
  if test $emacs_cv_clang = yes; then
    gl_WARN_ADD([-Wno-format-extra-args])
    gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
    gl_WARN_ADD([-Wno-unused-command-line-argument])
    gl_WARN_ADD([-Wno-unused-value])
  fi

931
  AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
932 933
  AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
  AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
934 935
  [/* Enable compile-time and run-time bounds-checking, and some warnings,
      without upsetting glibc 2.15+. */
936 937
   #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
        && defined __OPTIMIZE__ && __OPTIMIZE__)
938 939 940
   # define _FORTIFY_SOURCE 2
   #endif
  ])
941 942 943 944 945 946 947 948

  # We use a slightly smaller set of warning options for lib/.
  # Remove the following and save the result in GNULIB_WARN_CFLAGS.
  nw=
  nw="$nw -Wunused-macros"

  gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
  AC_SUBST([GNULIB_WARN_CFLAGS])
949 950
fi

951 952 953 954 955 956 957
edit_cflags="
  s,///*,/,g
  s/^/ /
  s/ -I/ $isystem/g
  s/^ //
"

958 959 960
AC_ARG_ENABLE(link-time-optimization,
[AS_HELP_STRING([--enable-link-time-optimization],
                [build emacs with link-time optimization.
961 962 963 964 965
		 This requires GCC 4.5.0 or later, or clang.
		 (Note that clang support is experimental - see INSTALL.)
		 It also makes Emacs harder to debug, and when we tried it
		 with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
		 recommended for typical use.])],
966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000 1001 1002
if test "${enableval}" != "no"; then
   ac_lto_supported=no
   if test $emacs_cv_clang = yes; then
      AC_MSG_CHECKING([whether link-time optimization is supported by clang])
      GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
      if test -x "$GOLD_PLUGIN"; then
	 LTO="-flto"
      fi
   elif test x$GCC = xyes; then
      AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
      CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
      if test x$CPUS != x; then
	 LTO="-flto=$CPUS"
      else
	 LTO="-flto"
      fi
   else
      AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
   fi
   if test -z "$LTO"; then
      ac_lto_supported=no
   else
      old_CFLAGS=$CFLAGS
      CFLAGS="$CFLAGS $LTO"
      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
         [ac_lto_supported=yes], [ac_lto_supported=no])
         CFLAGS="$old_CFLAGS"
   fi
   AC_MSG_RESULT([$ac_lto_supported])
   if test "$ac_lto_supported" = "yes"; then
      CFLAGS="$CFLAGS $LTO"
      if test x$emacs_cv_clang = xyes; then
	 AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
	 # WARNING: 'ar --plugin ...' doesn't work without
	 # command, so plugin name is appended to ARFLAGS.
	 ARFLAGS="cru --plugin $GOLD_PLUGIN"
	 RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1003 1004 1005 1006 1007 1008 1009
      else
        dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
        dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
        dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
        dnl dump core on Fedora 20, so play it safe for now.
        gl_COMPILER_OPTION_IF([-ffat-lto-objects],
          [CFLAGS="$CFLAGS -ffat-lto-objects"])
1010 1011 1012
      fi
   fi
fi)
1013

1014 1015 1016 1017 1018 1019 1020 1021 1022 1023 1024
dnl Port to Automake 1.11.
dnl This section can be removed once we assume Automake 1.14 or later.
: ${AM_DEFAULT_VERBOSITY=1}
: ${AM_V=$AM_DEFAULT_VERBOSITY}
: ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
AC_SUBST([AM_V])
AM_SUBST_NOTMAKE([AM_V])
AC_SUBST([AM_DEFAULT_V])
AM_SUBST_NOTMAKE([AM_DEFAULT_V])
AC_SUBST([AM_DEFAULT_VERBOSITY])

1025 1026 1027 1028 1029 1030 1031
dnl Some other nice autoconf tests.
dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
dnl AC_PROG_INSTALL
dnl AC_PROG_MKDIR_P
dnl if test "x$RANLIB" = x; then
dnl   AC_PROG_RANLIB
dnl fi
1032 1033 1034 1035 1036 1037 1038 1039 1040 1041 1042 1043 1044 1045


dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
dnl can be made to directories.  This is not relevant for our usage, and
dnl excludes some cases that work fine for us.  Eg MS Windows or files
dnl hosted on AFS, both examples where simple links work, but links to
dnl directories fail.  We use a cut-down version instead.
dnl AC_PROG_LN_S

AC_MSG_CHECKING([whether ln -s works for files in the same directory])
rm -f conf$$ conf$$.file

LN_S_FILEONLY='cp -p'

1046 1047
dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
dnl random program in the current directory.
1048 1049
if (echo >conf$$.file) 2>/dev/null; then
  if ln -s conf$$.file conf$$ 2>/dev/null; then
1050 1051 1052 1053 1054
    if test "$opsys" = "mingw32"; then
      LN_S_FILEONLY='/bin/ln -s'
    else
      LN_S_FILEONLY='ln -s'
    fi
1055
  elif ln conf$$.file conf$$ 2>/dev/null; then
1056 1057 1058 1059 1060
    if test "$opsys" = "mingw32"; then
      LN_S_FILEONLY=/bin/ln
    else
      LN_S_FILEONLY=ln
    fi
1061 1062 1063 1064 1065 1066 1067 1068 1069 1070 1071 1072 1073
  fi
fi

rm -f conf$$ conf$$.file

if test "$LN_S_FILEONLY" = "ln -s"; then
   AC_MSG_RESULT([yes])
else
   AC_MSG_RESULT([no, using $LN_S_FILEONLY])
fi

AC_SUBST(LN_S_FILEONLY)

1074

1075 1076 1077 1078 1079 1080
dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
dnl doesn't support links to directories, as in "ln file dir".  But that
dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
dnl executables at "make install" time.
dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
dnl for more details.
1081
if test "$opsys" = "mingw32"; then
Eli Zaretskii's avatar
Eli Zaretskii committed
1082
  LN_S="/bin/ln"
1083 1084
fi

1085 1086 1087 1088
dnl On some Debian versions, "install-info" prints irritating messages
dnl "This is not dpkg install-info anymore, but GNU install-info"
dnl if called via an absolute file name.
dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1089 1090 1091 1092 1093
dnl Sadly some people may have an old ginstall-info installed on
dnl non-Debian systems, so we can't use this.
dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)

1094 1095
AC_PATH_PROG(INSTALL_INFO, install-info, :,
  $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1096 1097 1098
dnl Don't use GZIP, which is used by gzip for additional parameters.
AC_PATH_PROG(GZIP_PROG, gzip)

1099
test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1100 1101
   GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"

1102 1103 1104
if test $opsys = gnu-linux; then
  AC_PATH_PROG(PAXCTL, paxctl,,
    [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1105 1106 1107 1108 1109 1110
  if test "X$PAXCTL" != X; then
    AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
      [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
      else AC_MSG_RESULT(no); PAXCTL=""; fi])
  fi
1111 1112 1113 1114 1115 1116 1117 1118 1119 1120 1121 1122 1123

  if test "${SETFATTR+set}" != set; then
    AC_CACHE_CHECK([for setfattr],
      [emacs_cv_prog_setfattr],
      [touch conftest.tmp
       if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
	 emacs_cv_prog_setfattr=yes
       else
	 emacs_cv_prog_setfattr=no
       fi])
    if test "$emacs_cv_prog_setfattr" = yes; then
      SETFATTR=setfattr
    else
Paul Eggert's avatar
Paul Eggert committed
1124
      SETFATTR=
1125 1126 1127 1128
    fi
    rm -f conftest.tmp
    AC_SUBST([SETFATTR])
  fi
1129
fi
1130

1131
## Need makeinfo >= 4.7 (?) to build the manuals.
1132
if test "$MAKEINFO" != "no"; then
1133 1134 1135 1136
  if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
    MAKEINFO=makeinfo
  fi
  case `($MAKEINFO --version) 2>/dev/null` in
1137 1138 1139 1140
    *' (GNU texinfo) '4.[[7-9]]* | \
    *' (GNU texinfo) '4.[[1-9][0-9]]* | \
    *' (GNU texinfo) '[[5-9]]* | \
    *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1141
    *) MAKEINFO=no;;
1142
  esac
1143 1144 1145 1146 1147 1148
fi

## Makeinfo is unusual.  For a released Emacs, the manuals are
## pre-built, and not deleted by the normal clean rules.  makeinfo is
## therefore in the category of "special tools" not normally required, which
## configure does not have to check for (eg autoconf itself).
1149 1150
## In a repository checkout on the other hand, the manuals are not included.
## So makeinfo is a requirement to build from the repository, and configure
1151 1152
## should test for it as it does for any other build requirement.
## We use the presence of $srcdir/info/emacs to distinguish a release,
1153
## with pre-built manuals, from a repository checkout.
1154 1155
HAVE_MAKEINFO=yes

1156
if test "$MAKEINFO" = "no"; then
1157
  MAKEINFO=makeinfo
1158
  if test "x${with_makeinfo}" = "xno"; then
1159
    HAVE_MAKEINFO=no
1160
  elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1161
    AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1162 1163 1164 1165 1166
source tree does not seem to have pre-built manuals in the `info' directory.
Either install a suitable version of makeinfo, or re-run configure
with the `--without-makeinfo' option to build without the manuals.] )
  fi
fi
1167
AC_SUBST(HAVE_MAKEINFO)
1168

1169
if test $opsys = mingw32; then
1170
   DOCMISC_W32=efaq-w32
1171
else
1172
   DOCMISC_W32=
1173
fi
1174
AC_SUBST(DOCMISC_W32)
1175

1176 1177 1178 1179 1180 1181 1182 1183 1184 1185 1186 1187 1188 1189 1190 1191
dnl Add our options to ac_link now, after it is set up.

if test x$GCC = xyes; then
  test "x$GCC_LINK_TEST_OPTIONS" != x && \
    ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
else
  test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
    ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
fi

dnl We need -znocombreloc if we're using a relatively recent GNU ld.
dnl If we can link with the flag, it shouldn't do any harm anyhow.
dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
dnl if not built to support GNU ld.

1192 1193 1194 1195
dnl For a long time, -znocombreloc was added to LDFLAGS rather than
dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
dnl * inappropriate, as LDFLAGS is a user option but this is essential.
dnl   Eg "make LDFLAGS=... all" could run into problems,
1196
dnl   http://bugs.debian.org/684788
1197 1198
dnl * unnecessary, since temacs is the only thing that actually needs it.
dnl   Indeed this is where it was originally, prior to:
1199
dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1200
late_LDFLAGS="$LDFLAGS"
1201
if test x$GCC = xyes; then
1202
  LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1203
else
1204
  LDFLAGS_NOCOMBRELOC="-znocombreloc"
1205 1206
fi

1207 1208
LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"

1209 1210 1211
AC_MSG_CHECKING([for -znocombreloc])
AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  [AC_MSG_RESULT(yes)],
1212
  LDFLAGS_NOCOMBRELOC=
1213 1214
  [AC_MSG_RESULT(no)])

1215
LDFLAGS="$late_LDFLAGS"
1216

1217 1218 1219 1220 1221 1222 1223 1224 1225
AC_CACHE_CHECK([whether addresses are sanitized],
  [emacs_cv_sanitize_address],
  [AC_COMPILE_IFELSE(
     [AC_LANG_PROGRAM(
	[[#ifndef __has_feature
	  #define __has_feature(f) 0
	  #endif
	  #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
	  #else
Paul Eggert's avatar
Paul Eggert committed
1226
	   error "Addresses are not sanitized.";
1227 1228 1229 1230 1231
	  #endif
	]])],
     [emacs_cv_sanitize_address=yes],
     [emacs_cv_sanitize_address=no])])

1232 1233
dnl The function dump-emacs will not be defined and temacs will do
dnl (load "loadup") automatically unless told otherwise.
1234
test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no