register.el 19.4 KB
Newer Older
1
;;; register.el --- register commands for Emacs      -*- lexical-binding: t; -*-
Eric S. Raymond's avatar
Eric S. Raymond committed
2

3 4
;; Copyright (C) 1985, 1993-1994, 2001-2014 Free Software Foundation,
;; Inc.
Eric S. Raymond's avatar
Eric S. Raymond committed
5

Eric S. Raymond's avatar
Eric S. Raymond committed
6
;; Maintainer: FSF
Eric S. Raymond's avatar
Eric S. Raymond committed
7
;; Keywords: internal
8
;; Package: emacs
Eric S. Raymond's avatar
Eric S. Raymond committed
9

Richard M. Stallman's avatar
Richard M. Stallman committed
10 11
;; This file is part of GNU Emacs.

12
;; GNU Emacs is free software: you can redistribute it and/or modify
Richard M. Stallman's avatar
Richard M. Stallman committed
13
;; it under the terms of the GNU General Public License as published by
14 15
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Richard M. Stallman's avatar
Richard M. Stallman committed
16 17 18 19 20 21 22

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
23
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
Richard M. Stallman's avatar
Richard M. Stallman committed
24

25 26 27 28 29 30 31
;;; Commentary:

;; This package of functions emulates and somewhat extends the venerable
;; TECO's `register' feature, which permits you to save various useful
;; pieces of buffer state to named variables.  The entry points are
;; documented in the Emacs user's manual.

Stefan Monnier's avatar
Stefan Monnier committed
32
(eval-when-compile (require 'cl-lib))
33

Eric S. Raymond's avatar
Eric S. Raymond committed
34
;;; Code:
Richard M. Stallman's avatar
Richard M. Stallman committed
35

Stefan Monnier's avatar
Stefan Monnier committed
36
(cl-defstruct
37 38 39 40 41 42 43 44 45 46 47
  (registerv (:constructor nil)
	     (:constructor registerv--make (&optional data print-func
						      jump-func insert-func))
	     (:copier nil)
	     (:type vector)
	     :named)
  (data        nil :read-only t)
  (print-func  nil :read-only t)
  (jump-func   nil :read-only t)
  (insert-func nil :read-only t))

Stefan Monnier's avatar
Stefan Monnier committed
48
(cl-defun registerv-make (data &key print-func jump-func insert-func)
49 50 51 52 53
  "Create a register value object.

DATA can be any value.
PRINT-FUNC if provided controls how `list-registers' and
`view-register' print the register.  It should be a function
Juanma Barranquero's avatar
Juanma Barranquero committed
54
receiving one argument DATA and print text that completes
55 56 57 58 59 60 61
this sentence:
  Register X contains [TEXT PRINTED BY PRINT-FUNC]
JUMP-FUNC if provided, controls how `jump-to-register' jumps to the register.
INSERT-FUNC if provided, controls how `insert-register' insert the register.
They both receive DATA as argument."
  (registerv--make data print-func jump-func insert-func))

Richard M. Stallman's avatar
Richard M. Stallman committed
62 63
(defvar register-alist nil
  "Alist of elements (NAME . CONTENTS), one for each Emacs register.
64 65
NAME is a character (a number).  CONTENTS is a string, number, marker, list
or a struct returned by `registerv-make'.
66
A list of strings represents a rectangle.
67 68 69 70
A list of the form (file . FILE-NAME) represents the file named FILE-NAME.
A list of the form (file-query FILE-NAME POSITION) represents
 position POSITION in the file named FILE-NAME, but query before
 visiting it.
Karl Heuer's avatar
Karl Heuer committed
71 72 73
A list of the form (WINDOW-CONFIGURATION POSITION)
 represents a saved window configuration plus a saved value of point.
A list of the form (FRAME-CONFIGURATION POSITION)
74
 represents a saved frame configuration plus a saved value of point.")
Richard M. Stallman's avatar
Richard M. Stallman committed
75

76 77 78
(defgroup register nil
  "Register commands."
  :group 'convenience
79
  :version "24.3")
80

81 82
(defcustom register-separator nil
  "Register containing the text to put between collected texts, or nil if none.
83 84 85 86 87 88 89 90 91

When collecting text with
`append-to-register' (resp. `prepend-to-register') contents of
this register is added to the beginning (resp. end) of the marked
text."
  :group 'register
  :type '(choice (const :tag "None" nil)
		 (character :tag "Use register" :value ?+)))

92
(defcustom register-preview-delay 1
93 94 95
  "If non-nil, time to wait in seconds before popping up a preview window.
If nil, do not show register previews, unless `help-char' (or a member of
`help-event-list') is pressed."
96
  :version "24.4"
97
  :type '(choice number (const :tag "No preview unless requested" nil))
98 99
  :group 'register)

100 101 102
(defun get-register (register)
  "Return contents of Emacs register named REGISTER, or nil if none."
  (cdr (assq register register-alist)))
Richard M. Stallman's avatar
Richard M. Stallman committed
103

104 105
(defun set-register (register value)
  "Set contents of Emacs register named REGISTER to VALUE.  Returns VALUE.
106
See the documentation of the variable `register-alist' for possible VALUEs."
107
  (let ((aelt (assq register register-alist)))
Richard M. Stallman's avatar
Richard M. Stallman committed
108 109
    (if aelt
	(setcdr aelt value)
Stefan Monnier's avatar
Stefan Monnier committed
110
      (push (cons register value) register-alist))
Richard M. Stallman's avatar
Richard M. Stallman committed
111 112
    value))

113 114 115 116 117 118 119 120 121
(defun register-describe-oneline (c)
  "One-line description of register C."
  (let ((d (replace-regexp-in-string
            "\n[ \t]*" " "
            (with-output-to-string (describe-register-1 c)))))
    (if (string-match "Register.+? contains \\(?:an? \\|the \\)?" d)
        (substring d (match-end 0))
      d)))

Glenn Morris's avatar
Glenn Morris committed
122 123 124 125 126 127 128 129 130 131
(defun register-preview-default (r)
  "Default function for the variable `register-preview-function'."
  (format "%s %s\n"
	  (concat (single-key-description (car r)) ":")
	  (register-describe-oneline (car r))))

(defvar register-preview-function #'register-preview-default
  "Function to format a register for previewing.
Takes one argument, a cons (NAME . CONTENTS) as found in `register-alist'.
Returns a string.")
132 133 134

(defun register-preview (buffer &optional show-empty)
  "Pop up a window to show register preview in BUFFER.
Glenn Morris's avatar
Glenn Morris committed
135 136
If SHOW-EMPTY is non-nil show the window even if no registers.
Format of each entry is controlled by the variable `register-preview-function'."
137
  (when (or show-empty (consp register-alist))
138 139 140 141 142 143 144
    (with-temp-buffer-window
     buffer
     (cons 'display-buffer-below-selected
	   '((window-height . fit-window-to-buffer)))
     nil
     (with-current-buffer standard-output
       (setq cursor-in-non-selected-windows nil)
Glenn Morris's avatar
Glenn Morris committed
145
       (insert (mapconcat register-preview-function register-alist ""))))))
146 147

(defun register-read-with-preview (prompt)
148 149 150 151 152
  "Read and return an event, prompting with PROMPT, possibly showing a preview.
If `register-alist' and `register-preview-delay' are both non-nil,
display a window listing registers after `register-preview-delay' seconds.
If `help-char' (or a member of `help-event-list') is pressed, display
such a window regardless."
153 154 155 156 157 158 159 160 161 162 163 164 165 166 167
  (let* ((buffer "*Register Preview*")
	 (timer (when (numberp register-preview-delay)
		  (run-with-timer register-preview-delay nil
				  (lambda ()
				    (unless (get-buffer-window buffer)
				      (register-preview buffer))))))
	 (help-chars (cl-loop for c in (cons help-char help-event-list)
			      when (not (get-register c))
			      collect c)))
    (unwind-protect
	(progn
	  (while (memq (read-event (propertize prompt 'face 'minibuffer-prompt))
		       help-chars)
	    (unless (get-buffer-window buffer)
	      (register-preview buffer 'show-empty)))
Glenn Morris's avatar
Glenn Morris committed
168 169
	  (if (characterp last-input-event) last-input-event
	    (error "Non-character input-event")))
170 171 172 173 174
      (and (timerp timer) (cancel-timer timer))
      (let ((w (get-buffer-window buffer)))
        (and (window-live-p w) (delete-window w)))
      (and (get-buffer buffer) (kill-buffer buffer)))))

175
(defun point-to-register (register &optional arg)
176
  "Store current location of point in register REGISTER.
Jim Blandy's avatar
Jim Blandy committed
177
With prefix argument, store current frame configuration.
178
Use \\[jump-to-register] to go to that location or restore that configuration.
Richard M. Stallman's avatar
Richard M. Stallman committed
179
Argument is a character, naming the register."
180 181
  (interactive (list (register-read-with-preview "Point to register: ")
		     current-prefix-arg))
Stefan Monnier's avatar
Stefan Monnier committed
182 183
  ;; Turn the marker into a file-ref if the buffer is killed.
  (add-hook 'kill-buffer-hook 'register-swap-out nil t)
184
  (set-register register
Karl Heuer's avatar
Karl Heuer committed
185 186
		(if arg (list (current-frame-configuration) (point-marker))
		  (point-marker))))
Richard M. Stallman's avatar
Richard M. Stallman committed
187

188
(defun window-configuration-to-register (register &optional _arg)
189 190 191
  "Store the window configuration of the selected frame in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Argument is a character, naming the register."
192 193 194
  (interactive (list (register-read-with-preview
		      "Window configuration to register: ")
		     current-prefix-arg))
195 196
  ;; current-window-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
197
  (set-register register (list (current-window-configuration) (point-marker))))
198

199
(defun frame-configuration-to-register (register &optional _arg)
200 201 202
  "Store the window configuration of all frames in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Argument is a character, naming the register."
203 204 205
  (interactive (list (register-read-with-preview
		      "Frame configuration to register: ")
		     current-prefix-arg))
206 207
  ;; current-frame-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
208
  (set-register register (list (current-frame-configuration) (point-marker))))
209

210
(defalias 'register-to-point 'jump-to-register)
211
(defun jump-to-register (register &optional delete)
Richard M. Stallman's avatar
Richard M. Stallman committed
212
  "Move point to location stored in a register.
213
If the register contains a file name, find that file.
214
\(To put a file name in a register, you must use `set-register'.)
215 216
If the register contains a window configuration (one frame) or a frameset
\(all frames), restore that frame or all frames accordingly.
217
First argument is a character, naming the register.
218
Optional second arg non-nil (interactively, prefix argument) says to
219
delete any existing frames that the frameset doesn't mention.
220
\(Otherwise, these frames are iconified.)"
221 222
  (interactive (list (register-read-with-preview "Jump to register: ")
		     current-prefix-arg))
223
  (let ((val (get-register register)))
224
    (cond
225
     ((registerv-p val)
Stefan Monnier's avatar
Stefan Monnier committed
226
      (cl-assert (registerv-jump-func val) nil
227 228 229
              "Don't know how to jump to register %s"
              (single-key-description register))
      (funcall (registerv-jump-func val) (registerv-data val)))
230 231 232 233 234 235
     ((and (consp val) (frame-configuration-p (car val)))
      (set-frame-configuration (car val) (not delete))
      (goto-char (cadr val)))
     ((and (consp val) (window-configuration-p (car val)))
      (set-window-configuration (car val))
      (goto-char (cadr val)))
236
     ((markerp val)
237 238
      (or (marker-buffer val)
	  (error "That register's buffer no longer exists"))
239 240
      (switch-to-buffer (marker-buffer val))
      (goto-char val))
241 242
     ((and (consp val) (eq (car val) 'file))
      (find-file (cdr val)))
243 244 245 246 247 248
     ((and (consp val) (eq (car val) 'file-query))
      (or (find-buffer-visiting (nth 1 val))
	  (y-or-n-p (format "Visit file %s again? " (nth 1 val)))
	  (error "Register access aborted"))
      (find-file (nth 1 val))
      (goto-char (nth 2 val)))
249 250
     (t
      (error "Register doesn't contain a buffer position or configuration")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
251

252
(defun register-swap-out ()
Stefan Monnier's avatar
Stefan Monnier committed
253
  "Turn markers into file-query references when a buffer is killed."
254
  (and buffer-file-name
Stefan Monnier's avatar
Stefan Monnier committed
255 256 257 258 259 260 261
       (dolist (elem register-alist)
	 (and (markerp (cdr elem))
	      (eq (marker-buffer (cdr elem)) (current-buffer))
	      (setcdr elem
		      (list 'file-query
			    buffer-file-name
			    (marker-position (cdr elem))))))))
262

263
(defun number-to-register (number register)
Karl Heuer's avatar
Karl Heuer committed
264 265
  "Store a number in a register.
Two args, NUMBER and REGISTER (a character, naming the register).
266 267
If NUMBER is nil, a decimal number is read from the buffer starting
at point, and point moves to the end of that number.
Karl Heuer's avatar
Karl Heuer committed
268
Interactively, NUMBER is the prefix arg (none means nil)."
269 270
  (interactive (list current-prefix-arg
		     (register-read-with-preview "Number to register: ")))
271
  (set-register register
272 273
		(if number
		    (prefix-numeric-value number)
274 275 276
		  (if (looking-at "\\s-*-?[0-9]+")
		      (progn
			(goto-char (match-end 0))
277
			(string-to-number (match-string 0)))
Karl Heuer's avatar
Karl Heuer committed
278 279
		    0))))

280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297
(defun increment-register (prefix register)
  "Augment contents of REGISTER.
Interactively, PREFIX is in raw form.

If REGISTER contains a number, add `prefix-numeric-value' of
PREFIX to it.

If REGISTER is empty or if it contains text, call
`append-to-register' with `delete-flag' set to PREFIX."
  (interactive "P\ncIncrement register: ")
  (let ((register-val (get-register register)))
    (cond
     ((numberp register-val)
      (let ((number (prefix-numeric-value prefix)))
	(set-register register (+ number register-val))))
     ((or (not register-val) (stringp register-val))
      (append-to-register register (region-beginning) (region-end) prefix))
     (t (error "Register does not contain a number or text")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
298

299
(defun view-register (register)
Richard M. Stallman's avatar
Richard M. Stallman committed
300
  "Display what is contained in register named REGISTER.
301
The Lisp value REGISTER is a character."
302
  (interactive (list (register-read-with-preview "View register: ")))
303
  (let ((val (get-register register)))
Richard M. Stallman's avatar
Richard M. Stallman committed
304
    (if (null val)
305
	(message "Register %s is empty" (single-key-description register))
Richard M. Stallman's avatar
Richard M. Stallman committed
306
      (with-output-to-temp-buffer "*Output*"
307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323
	(describe-register-1 register t)))))

(defun list-registers ()
  "Display a list of nonempty registers saying briefly what they contain."
  (interactive)
  (let ((list (copy-sequence register-alist)))
    (setq list (sort list (lambda (a b) (< (car a) (car b)))))
    (with-output-to-temp-buffer "*Output*"
      (dolist (elt list)
	(when (get-register (car elt))
	  (describe-register-1 (car elt))
	  (terpri))))))

(defun describe-register-1 (register &optional verbose)
  (princ "Register ")
  (princ (single-key-description register))
  (princ " contains ")
324 325
  (let ((val (get-register register)))
    (cond
326 327 328 329 330
     ((registerv-p val)
      (if (registerv-print-func val)
          (funcall (registerv-print-func val) (registerv-data val))
        (princ "[UNPRINTABLE CONTENTS].")))

331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373
     ((numberp val)
      (princ val))

     ((markerp val)
      (let ((buf (marker-buffer val)))
	(if (null buf)
	    (princ "a marker in no buffer")
	  (princ "a buffer position:\n    buffer ")
	  (princ (buffer-name buf))
	  (princ ", position ")
	  (princ (marker-position val)))))

     ((and (consp val) (window-configuration-p (car val)))
      (princ "a window configuration."))

     ((and (consp val) (frame-configuration-p (car val)))
      (princ "a frame configuration."))

     ((and (consp val) (eq (car val) 'file))
      (princ "the file ")
      (prin1 (cdr val))
      (princ "."))

     ((and (consp val) (eq (car val) 'file-query))
      (princ "a file-query reference:\n    file ")
      (prin1 (car (cdr val)))
      (princ ",\n    position ")
      (princ (car (cdr (cdr val))))
      (princ "."))

     ((consp val)
      (if verbose
	  (progn
	    (princ "the rectangle:\n")
	    (while val
	      (princ "    ")
	      (princ (car val))
	      (terpri)
	      (setq val (cdr val))))
	(princ "a rectangle starting with ")
	(princ (car val))))

     ((stringp val)
374
      (setq val (copy-sequence val))
375 376 377 378
      (if (eq yank-excluded-properties t)
	  (set-text-properties 0 (length val) nil val)
	(remove-list-of-text-properties 0 (length val)
					yank-excluded-properties val))
379 380 381 382
      (if verbose
	  (progn
	    (princ "the text:\n")
	    (princ val))
383
	(cond
384 385 386 387 388 389 390 391 392 393 394
	 ;; Extract first N characters starting with first non-whitespace.
	 ((string-match (format "[^ \t\n].\\{,%d\\}"
				;; Deduct 6 for the spaces inserted below.
				(min 20 (max 0 (- (window-width) 6))))
			val)
	  (princ "text starting with\n    ")
	  (princ (match-string 0 val)))
	 ((string-match "^[ \t\n]+$" val)
	  (princ "whitespace"))
	 (t
	  (princ "the empty string")))))
395 396 397
     (t
      (princ "Garbage:\n")
      (if verbose (prin1 val))))))
Richard M. Stallman's avatar
Richard M. Stallman committed
398

399 400
(defun insert-register (register &optional arg)
  "Insert contents of register REGISTER.  (REGISTER is a character.)
Richard M. Stallman's avatar
Richard M. Stallman committed
401 402 403
Normally puts point before and mark after the inserted text.
If optional second arg is non-nil, puts mark before and point after.
Interactively, second arg is non-nil if prefix arg is supplied."
404 405
  (interactive (progn
		 (barf-if-buffer-read-only)
406 407
		 (list (register-read-with-preview "Insert register: ")
		       current-prefix-arg)))
Richard M. Stallman's avatar
Richard M. Stallman committed
408
  (push-mark)
409
  (let ((val (get-register register)))
410
    (cond
411
     ((registerv-p val)
Stefan Monnier's avatar
Stefan Monnier committed
412
      (cl-assert (registerv-insert-func val) nil
413 414 415
              "Don't know how to insert register %s"
              (single-key-description register))
      (funcall (registerv-insert-func val) (registerv-data val)))
416 417
     ((consp val)
      (insert-rectangle val))
418
     ((stringp val)
419
      (insert-for-yank val))
Karl Heuer's avatar
Karl Heuer committed
420
     ((numberp val)
421 422 423 424 425
      (princ val (current-buffer)))
     ((and (markerp val) (marker-position val))
      (princ (marker-position val) (current-buffer)))
     (t
      (error "Register does not contain text"))))
Richard M. Stallman's avatar
Richard M. Stallman committed
426 427
  (if (not arg) (exchange-point-and-mark)))

428
(defun copy-to-register (register start end &optional delete-flag region)
429 430
  "Copy region into register REGISTER.
With prefix arg, delete as well.
431
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
432 433 434
START and END are buffer positions indicating what to copy.
The optional argument REGION if non-nil, indicates that we're not just copying
some text between START and END, but we're copying the region."
435 436 437
  (interactive (list (register-read-with-preview "Copy to register: ")
		     (region-beginning)
		     (region-end)
438 439 440 441 442 443
		     current-prefix-arg
		     t))
  (set-register register (if region
			     (funcall region-extract-function delete-flag)
			   (prog1 (filter-buffer-substring start end)
			     (if delete-flag (delete-region start end)))))
444
  (setq deactivate-mark t)
445
  (cond (delete-flag)
446 447
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
448

449 450 451 452
(defun append-to-register (register start end &optional delete-flag)
  "Append region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
453
START and END are buffer positions indicating what to append."
454 455 456 457
  (interactive (list (register-read-with-preview "Append to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
458
  (let ((reg (get-register register))
459
        (text (filter-buffer-substring start end))
460
	(separator (and register-separator (get-register register-separator))))
461 462
    (set-register
     register (cond ((not reg) text)
463
                    ((stringp reg) (concat reg separator text))
464
                    (t (error "Register does not contain text")))))
465
  (setq deactivate-mark t)
466 467 468 469
  (cond (delete-flag
	 (delete-region start end))
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
470

471 472 473 474
(defun prepend-to-register (register start end &optional delete-flag)
  "Prepend region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
475
START and END are buffer positions indicating what to prepend."
476 477 478 479
  (interactive (list (register-read-with-preview "Prepend to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
480
  (let ((reg (get-register register))
481
        (text (filter-buffer-substring start end))
482
	(separator (and register-separator (get-register register-separator))))
483 484
    (set-register
     register (cond ((not reg) text)
485
                    ((stringp reg) (concat text separator reg))
486
                    (t (error "Register does not contain text")))))
487
  (setq deactivate-mark t)
488 489 490 491
  (cond (delete-flag
	 (delete-region start end))
	((called-interactively-p 'interactive)
	 (indicate-copied-region))))
Richard M. Stallman's avatar
Richard M. Stallman committed
492

493 494
(defun copy-rectangle-to-register (register start end &optional delete-flag)
  "Copy rectangular region into register REGISTER.
495 496
With prefix arg, delete as well.
To insert this register in the buffer, use \\[insert-register].
497 498

Called from a program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
499
START and END are buffer positions giving two corners of rectangle."
500 501 502 503 504
  (interactive (list (register-read-with-preview
		      "Copy rectangle to register: ")
		     (region-beginning)
		     (region-end)
		     current-prefix-arg))
505 506 507 508 509 510 511 512 513
  (let ((rectangle (if delete-flag
		       (delete-extract-rectangle start end)
		     (extract-rectangle start end))))
    (set-register register rectangle)
    (when (and (null delete-flag)
	       (called-interactively-p 'interactive))
      (setq deactivate-mark t)
      (indicate-copied-region (length (car rectangle))))))

Masatake YAMATO's avatar
Masatake YAMATO committed
514
(provide 'register)
Eric S. Raymond's avatar
Eric S. Raymond committed
515
;;; register.el ends here