reveal.el 9.7 KB
Newer Older
Stefan Monnier's avatar
Stefan Monnier committed
1 2
;;; reveal.el --- Automatically reveal hidden text at point

3
;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
Glenn Morris's avatar
Glenn Morris committed
4
;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
Stefan Monnier's avatar
Stefan Monnier committed
5

Stefan Monnier's avatar
Stefan Monnier committed
6
;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
Stefan Monnier's avatar
Stefan Monnier committed
7 8
;; Keywords: outlines

Pavel Janík's avatar
Pavel Janík committed
9 10
;; This file is part of GNU Emacs.

Eli Zaretskii's avatar
Eli Zaretskii committed
11
;; GNU Emacs is free software; you can redistribute it and/or modify
Stefan Monnier's avatar
Stefan Monnier committed
12
;; it under the terms of the GNU General Public License as published by
13
;; the Free Software Foundation; either version 3, or (at your option)
Stefan Monnier's avatar
Stefan Monnier committed
14 15
;; any later version.

Eli Zaretskii's avatar
Eli Zaretskii committed
16
;; GNU Emacs is distributed in the hope that it will be useful,
Stefan Monnier's avatar
Stefan Monnier committed
17 18 19 20 21 22
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to
Lute Kamstra's avatar
Lute Kamstra committed
23 24
;; the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.
Stefan Monnier's avatar
Stefan Monnier committed
25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46

;;; Commentary:

;; Reveal mode is a minor mode that makes sure that text around point
;; is always visible.  When point enters a region of hidden text,
;; `reveal-mode' temporarily makes it visible.
;;
;; This is normally used in conjunction with `outline-minor-mode',
;; `hs-minor-mode', `hide-ifdef-mode', ...
;;
;; It only works with packages that hide text using overlays.
;; Packages can provide special support for it by placing
;; a function in the `reveal-toggle-invisible' property on the symbol
;; used as the value of the `invisible' overlay property.
;; The function is called right after revealing (or re-hiding) the
;; text with two arguments: the overlay and a boolean that's non-nil
;; if we have just revealed the text.  When revealing, that function
;; may re-hide some of the text.

;;; Todo:

;; - find other hysteresis features.
47 48
;; - don't hide after a scroll command
;; - delay hiding by a couple seconds (i.e. hide in the background)
Stefan Monnier's avatar
Stefan Monnier committed
49 50 51 52 53 54 55 56 57

;;; Code:

(defgroup reveal nil
  "Reveal hidden text on the fly."
  :group 'editing)

(defcustom reveal-around-mark t
  "Reveal text around the mark, if active."
58 59
  :type 'boolean
  :group 'reveal)
Stefan Monnier's avatar
Stefan Monnier committed
60

61 62 63
(defvar reveal-open-spots nil
  "List of spots in the buffer which are open.
Each element has the form (WINDOW . OVERLAY).")
Stefan Monnier's avatar
Stefan Monnier committed
64 65
(make-variable-buffer-local 'reveal-open-spots)

Stefan Monnier's avatar
Stefan Monnier committed
66 67 68
(defvar reveal-last-tick nil)
(make-variable-buffer-local 'reveal-last-tick)

Stefan Monnier's avatar
Stefan Monnier committed
69 70 71 72 73 74 75 76 77
;; Actual code

(defun reveal-post-command ()
  ;; Refresh the spots that might have changed.
  ;; `Refreshing' here means to try and re-hide the corresponding text.
  ;; We don't refresh everything correctly:
  ;; - we only refresh spots in the current window.
  ;; FIXME: do we actually know that (current-buffer) = (window-buffer) ?
  (with-local-quit
78 79 80 81 82 83 84 85 86 87
    (condition-case err
        (let ((old-ols
               (delq nil
                     (mapcar
                      (lambda (x)
                        ;; We refresh any spot in the current window as well
                        ;; as any spots associated with a dead window or
                        ;; a window which does not show this buffer any more.
                        (cond
                         ((eq (car x) (selected-window)) (cdr x))
88 89
                         ((not (and (window-live-p (car x))
                                    (eq (window-buffer (car x)) (current-buffer))))
90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107
                          ;; Adopt this since it's owned by a window that's
                          ;; either not live or at least not showing this
                          ;; buffer any more.
                          (setcar x (selected-window))
                          (cdr x))))
                      reveal-open-spots))))
          (setq old-ols (reveal-open-new-overlays old-ols))
          (reveal-close-old-overlays old-ols))
      (error (message "Reveal: %s" err)))))

(defun reveal-open-new-overlays (old-ols)
  (let ((repeat t))
    (while repeat
      (setq repeat nil)
      (dolist (ol (nconc (when (and reveal-around-mark mark-active)
                           (overlays-at (mark)))
                         (overlays-at (point))))
        (setq old-ols (delq ol old-ols))
108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138
        (when (overlay-start ol)        ;Check it's still live.
          (let ((inv (overlay-get ol 'invisible)) open)
            (when (and inv
                       ;; There's an `invisible' property.  Make sure it's
                       ;; actually invisible, and ellipsised.
                       (and (consp buffer-invisibility-spec)
                            (cdr (assq inv buffer-invisibility-spec)))
                       (or (setq open
                                 (or (overlay-get ol 'reveal-toggle-invisible)
                                     (and (symbolp inv)
                                          (get inv 'reveal-toggle-invisible))
                                     (overlay-get ol 'isearch-open-invisible-temporary)))
                           (overlay-get ol 'isearch-open-invisible)
                           (and (consp buffer-invisibility-spec)
                                (cdr (assq inv buffer-invisibility-spec))))
                       (overlay-put ol 'reveal-invisible inv))
              (push (cons (selected-window) ol) reveal-open-spots)
              (if (null open)
                  (overlay-put ol 'invisible nil)
                ;; Use the provided opening function and repeat (since the
                ;; opening function might have hidden a subpart around point
                ;; or moved/killed some of the overlays).
                (setq repeat t)
                (condition-case err
                    (funcall open ol nil)
                  (error (message "!!Reveal-show (funcall %s %s nil): %s !!"
                                  open ol err)
                         ;; Let's default to a meaningful behavior to avoid
                         ;; getting stuck in an infinite loop.
                         (setq repeat nil)
                         (overlay-put ol 'invisible nil))))))))))
139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183
  old-ols)

(defun reveal-close-old-overlays (old-ols)
  (if (not (eq reveal-last-tick
               (setq reveal-last-tick (buffer-modified-tick))))
      ;; The buffer was modified since last command: let's refrain from
      ;; closing any overlay because it tends to behave poorly when
      ;; inserting text at the end of an overlay (basically the overlay
      ;; should be rear-advance when it's open, but things like
      ;; outline-minor-mode make it non-rear-advance because it's
      ;; a better choice when it's closed).
      nil
    ;; The last command was only a point motion or some such
    ;; non-buffer-modifying command.  Let's close whatever can be closed.
    (dolist (ol old-ols)
      (if (and (overlay-start ol)       ;Check it's still live.
               (>= (point) (save-excursion
                             (goto-char (overlay-start ol))
                             (line-beginning-position 1)))
               (<= (point) (save-excursion
                             (goto-char (overlay-end ol))
                             (line-beginning-position 2)))
               ;; If the application has moved the overlay to some other
               ;; buffer, we'd better reset the buffer to its
               ;; original state.
               (eq (current-buffer) (overlay-buffer ol)))
          ;; Still near the overlay: keep it open.
          nil
        ;; Really close it.
        (let* ((inv (overlay-get ol 'reveal-invisible))
               (open (or (overlay-get ol 'reveal-toggle-invisible)
                         (get inv 'reveal-toggle-invisible)
                         (overlay-get ol 'isearch-open-invisible-temporary))))
          (if (and (overlay-start ol)   ;Check it's still live.
                   open)
              (condition-case err
                  (funcall open ol t)
                (error (message "!!Reveal-hide (funcall %s %s t): %s !!"
                                open ol err)))
            (overlay-put ol 'invisible inv))
          ;; Remove the overlay from the list of open spots.
          (overlay-put ol 'reveal-invisible nil)
          (setq reveal-open-spots
                (delq (rassoc ol reveal-open-spots)
                      reveal-open-spots)))))))
Stefan Monnier's avatar
Stefan Monnier committed
184

Stefan Monnier's avatar
Stefan Monnier committed
185 186
(defvar reveal-mode-map
  (let ((map (make-sparse-keymap)))
187 188
    ;; Override the default move-beginning-of-line and move-end-of-line
    ;; which skips valuable invisible text.
189 190
    (define-key map [remap move-beginning-of-line] 'beginning-of-line)
    (define-key map [remap move-end-of-line] 'end-of-line)
Stefan Monnier's avatar
Stefan Monnier committed
191 192
    map))

Stefan Monnier's avatar
Stefan Monnier committed
193 194 195 196 197 198 199 200
;;;###autoload
(define-minor-mode reveal-mode
  "Toggle Reveal mode on or off.
Reveal mode renders invisible text around point visible again.

Interactively, with no prefix argument, toggle the mode.
With universal prefix ARG (or if ARG is nil) turn mode on.
With zero or negative ARG turn mode off."
Lute Kamstra's avatar
Lute Kamstra committed
201
  :group 'reveal
202
  :lighter (global-reveal-mode nil " Reveal")
Stefan Monnier's avatar
Stefan Monnier committed
203
  :keymap reveal-mode-map
Stefan Monnier's avatar
Stefan Monnier committed
204 205 206 207 208 209 210 211 212 213 214 215 216 217 218
  (if reveal-mode
      (progn
	(set (make-local-variable 'search-invisible) t)
	(add-hook 'post-command-hook 'reveal-post-command nil t))
    (kill-local-variable 'search-invisible)
    (remove-hook 'post-command-hook 'reveal-post-command t)))

;;;###autoload
(define-minor-mode global-reveal-mode
  "Toggle Reveal mode in all buffers on or off.
Reveal mode renders invisible text around point visible again.

Interactively, with no prefix argument, toggle the mode.
With universal prefix ARG (or if ARG is nil) turn mode on.
With zero or negative ARG turn mode off."
Markus Rost's avatar
Markus Rost committed
219
  :global t :group 'reveal
Stefan Monnier's avatar
Stefan Monnier committed
220 221 222 223 224 225 226 227 228
  (setq-default reveal-mode global-reveal-mode)
  (if global-reveal-mode
      (progn
	(setq search-invisible t)
	(add-hook 'post-command-hook 'reveal-post-command))
    (setq search-invisible 'open)	;FIXME
    (remove-hook 'post-command-hook 'reveal-post-command)))

(provide 'reveal)
Markus Rost's avatar
Markus Rost committed
229

Stefan Monnier's avatar
Stefan Monnier committed
230
;; arch-tag: 96ba0242-2274-4ed7-8e10-26bc0707b4d8
Stefan Monnier's avatar
Stefan Monnier committed
231
;;; reveal.el ends here