desktop.el 44.5 KB
Newer Older
Richard M. Stallman's avatar
Richard M. Stallman committed
1 2
;;; desktop.el --- save partial status of Emacs when killed

3
;; Copyright (C) 1993, 1994, 1995, 1997, 2000, 2001, 2002, 2003,
4
;;   2004, 2005, 2006 Free Software Foundation, Inc.
Richard M. Stallman's avatar
Richard M. Stallman committed
5 6

;; Author: Morten Welinder <terra@diku.dk>
Lars Hansen's avatar
Lars Hansen committed
7
;; Maintainter: Lars Hansen <larsh@soem.dk>
Dave Love's avatar
Dave Love committed
8
;; Keywords: convenience
Richard M. Stallman's avatar
Richard M. Stallman committed
9
;; Favourite-brand-of-beer: None, I hate beer.
Richard M. Stallman's avatar
Richard M. Stallman committed
10 11 12 13 14 15 16 17 18 19 20 21 22 23

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
Erik Naggum's avatar
Erik Naggum committed
24
;; along with GNU Emacs; see the file COPYING.  If not, write to the
Lute Kamstra's avatar
Lute Kamstra committed
25 26
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.
Richard M. Stallman's avatar
Richard M. Stallman committed
27 28 29

;;; Commentary:

30 31 32 33 34 35 36 37
;; Save the Desktop, i.e.,
;;	- some global variables
;; 	- the list of buffers with associated files.  For each buffer also
;;		- the major mode
;;		- the default directory
;;		- the point
;;		- the mark & mark-active
;;		- buffer-read-only
38
;;		- some local variables
Richard M. Stallman's avatar
Richard M. Stallman committed
39

Kenichi Handa's avatar
Kenichi Handa committed
40 41
;; To use this, use customize to turn on desktop-save-mode or add the
;; following line somewhere in your .emacs file:
42
;;
Kenichi Handa's avatar
Kenichi Handa committed
43
;;	(desktop-save-mode 1)
44
;;
Kenichi Handa's avatar
Kenichi Handa committed
45 46 47 48 49 50 51 52
;; For further usage information, look at the section
;; "Saving Emacs Sessions" in the GNU Emacs Manual.

;; When the desktop module is loaded, the function `desktop-kill' is
;; added to the `kill-emacs-hook'. This function is responsible for
;; saving the desktop when Emacs is killed.  Furthermore an anonymous
;; function is added to the `after-init-hook'. This function is
;; responsible for loading the desktop when Emacs is started.
53

54 55 56 57 58 59
;; Special handling.
;; -----------------
;; Variables `desktop-buffer-mode-handlers' and `desktop-minor-mode-handlers'
;; are supplied to handle special major and minor modes respectively.
;; `desktop-buffer-mode-handlers' is an alist of major mode specific functions
;; to restore a desktop buffer. Elements must have the form
60
;;
61
;;    (MAJOR-MODE . RESTORE-BUFFER-FUNCTION).
62
;;
63 64 65 66 67
;; Functions listed are called by `desktop-create-buffer' when `desktop-read'
;; evaluates the desktop file. Buffers with a major mode not specified here,
;; are restored by the default handler `desktop-restore-file-buffer'.
;; `desktop-minor-mode-handlers' is an alist of functions to restore
;; non-standard minor modes.  Elements must have the form
68
;;
69
;;    (MINOR-MODE . RESTORE-FUNCTION).
70
;;
71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113
;; Functions are called by `desktop-create-buffer' to restore minor modes.
;; Minor modes not specified here, are restored by the standard minor mode
;; function.  If you write a module that defines a major or minor mode that
;; needs a special handler, then place code like

;;    (defun foo-restore-desktop-buffer
;;    ...
;;    (add-to-list 'desktop-buffer-mode-handlers
;;                 '(foo-mode . foo-restore-desktop-buffer))

;; or

;;    (defun bar-desktop-restore
;;    ...
;;    (add-to-list 'desktop-minor-mode-handlers
;;                 '(bar-mode . bar-desktop-restore))

;; in the module itself, and make shure that the mode function is
;; autoloaded. See the docstrings of `desktop-buffer-mode-handlers' and
;; `desktop-minor-mode-handlers' for more info.

;; Minor modes.
;; ------------
;; Conventional minor modes (see node "Minor Mode Conventions" in the elisp
;; manual) are handled in the following way:
;; When `desktop-save' saves the state of a buffer to the desktop file, it
;; saves as `desktop-minor-modes' the list of names of those variables in
;; `minor-mode-alist' that have a non-nil value.
;; When `desktop-create' restores the buffer, each of the symbols in
;; `desktop-minor-modes' is called as function with parameter 1.
;; The variables `desktop-minor-mode-table' and `desktop-minor-mode-handlers'
;; are used to handle non-conventional minor modes.  `desktop-save' uses
;; `desktop-minor-mode-table' to map minor mode variables to minor mode
;; functions before writing `desktop-minor-modes'. If a minor mode has a
;; variable name that is different form its function name, an entry

;;    (NAME RESTORE-FUNCTION)

;; should be added to `desktop-minor-mode-table'.  If a minor mode should not
;; be restored, RESTORE-FUNCTION should be set to nil.  `desktop-create' uses
;; `desktop-minor-mode-handlers' to lookup minor modes that needs a restore
;; function different from the usual minor mode function.
;; ---------------------------------------------------------------------------
114

115 116 117 118
;; By the way: don't use desktop.el to customize Emacs -- the file .emacs
;; in your home directory is used for that.  Saving global default values
;; for buffers is an example of misuse.

119 120 121
;; PLEASE NOTE: The kill ring can be saved as specified by the variable
;; `desktop-globals-to-save' (by default it isn't).  This may result in saving
;; things you did not mean to keep.  Use M-x desktop-clear RET.
122

123 124 125 126 127
;; Thanks to  hetrick@phys.uva.nl (Jim Hetrick)      for useful ideas.
;;            avk@rtsg.mot.com (Andrew V. Klein)     for a dired tip.
;;            chris@tecc.co.uk (Chris Boucher)       for a mark tip.
;;            f89-kam@nada.kth.se (Klas Mellbourn)   for a mh-e tip.
;;            kifer@sbkifer.cs.sunysb.edu (M. Kifer) for a bug hunt.
128
;;            treese@lcs.mit.edu (Win Treese)        for ange-ftp tips.
129
;;            pot@cnuce.cnr.it (Francesco Potorti`)  for misc. tips.
130 131 132 133 134 135
;; ---------------------------------------------------------------------------
;; TODO:
;;
;; Save window configuration.
;; Recognize more minor modes.
;; Save mark rings.
Richard M. Stallman's avatar
Richard M. Stallman committed
136 137 138

;;; Code:

139
(defvar desktop-file-version "206"
Kenichi Handa's avatar
Kenichi Handa committed
140
  "Version number of desktop file format.
141 142 143
Written into the desktop file and used at desktop read to provide
backward compatibility.")

144
;; ----------------------------------------------------------------------------
145 146
;; USER OPTIONS -- settings you might want to play with.
;; ----------------------------------------------------------------------------
147 148 149 150 151

(defgroup desktop nil
  "Save status of Emacs when you exit."
  :group 'frames)

Kenichi Handa's avatar
Kenichi Handa committed
152 153 154 155 156 157 158 159 160 161
;;;###autoload
(define-minor-mode desktop-save-mode
  "Toggle desktop saving mode.
With numeric ARG, turn desktop saving on if ARG is positive, off
otherwise.  See variable `desktop-save' for a description of when the
desktop is saved."
  :global t
  :group 'desktop)

;; Maintained for backward compatibility
162 163
(define-obsolete-variable-alias 'desktop-enable
                                'desktop-save-mode "22.1")
164

165
(defcustom desktop-save 'ask-if-new
Kenichi Handa's avatar
Kenichi Handa committed
166 167 168
  "*Specifies whether the desktop should be saved when it is killed.
A desktop is killed when the user changes desktop or quits Emacs.
Possible values are:
169 170 171 172 173 174
   t             -- always save.
   ask           -- always ask.
   ask-if-new    -- ask if no desktop file exists, otherwise just save.
   ask-if-exists -- ask if desktop file exists, otherwise don't save.
   if-exists     -- save if desktop file exists, otherwise don't save.
   nil           -- never save.
Kenichi Handa's avatar
Kenichi Handa committed
175
The desktop is never saved when `desktop-save-mode' is nil.
176
The variables `desktop-dirname' and `desktop-base-file-name'
Kenichi Handa's avatar
Kenichi Handa committed
177
determine where the desktop is saved."
178 179 180 181 182 183 184
  :type '(choice
    (const :tag "Always save" t)
    (const :tag "Always ask" ask)
    (const :tag "Ask if desktop file is new, else do save" ask-if-new)
    (const :tag "Ask if desktop file exists, else don't save" ask-if-exists)
    (const :tag "Save if desktop file exists, else don't" if-exists)
    (const :tag "Never save" nil))
185
  :group 'desktop
186
  :version "22.1")
187 188

(defcustom desktop-base-file-name
189
  (convert-standard-filename ".emacs.desktop")
Kenichi Handa's avatar
Kenichi Handa committed
190
  "Name of file for Emacs desktop, excluding the directory part."
191 192
  :type 'file
  :group 'desktop)
193 194
(define-obsolete-variable-alias 'desktop-basefilename
                                'desktop-base-file-name "22.1")
Richard M. Stallman's avatar
Richard M. Stallman committed
195

196 197 198 199
(defcustom desktop-path '("." "~")
  "List of directories to search for the desktop file.
The base name of the file is specified in `desktop-base-file-name'."
  :type '(repeat directory)
200
  :group 'desktop
201
  :version "22.1")
202

203
(defcustom desktop-missing-file-warning nil
204 205 206 207 208
  "*If non-nil then `desktop-read' asks if a non-existent file should be recreated.
Also pause for a moment to display message about errors signaled in
`desktop-buffer-mode-handlers'.

If nil, just print error messages in the message buffer."
209
  :type 'boolean
210
  :group 'desktop
211
  :version "22.1")
Richard M. Stallman's avatar
Richard M. Stallman committed
212

213
(defcustom desktop-no-desktop-file-hook nil
Kenichi Handa's avatar
Kenichi Handa committed
214
  "Normal hook run when `desktop-read' can't find a desktop file.
215
May be used to show a dired buffer."
216
  :type 'hook
217
  :group 'desktop
218
  :version "22.1")
219 220

(defcustom desktop-after-read-hook nil
Kenichi Handa's avatar
Kenichi Handa committed
221
  "Normal hook run after a successful `desktop-read'.
222
May be used to show a buffer list."
223
  :type 'hook
224
  :group 'desktop
225
  :version "22.1")
226 227

(defcustom desktop-save-hook nil
Kenichi Handa's avatar
Kenichi Handa committed
228
  "Normal hook run before the desktop is saved in a desktop file.
229 230 231 232
This is useful for truncating history lists, for example."
  :type 'hook
  :group 'desktop)

233 234 235 236 237 238 239
(defcustom desktop-globals-to-save
  '(desktop-missing-file-warning
    tags-file-name
    tags-table-list
    search-ring
    regexp-search-ring
    register-alist)
Kenichi Handa's avatar
Kenichi Handa committed
240 241 242 243
  "List of global variables saved by `desktop-save'.
An element may be variable name (a symbol) or a cons cell of the form
\(VAR . MAX-SIZE), which means to truncate VAR's value to at most
MAX-SIZE elements (if the value is a list) before saving the value.
244 245 246 247
Feature: Saving `kill-ring' implies saving `kill-ring-yank-pointer'."
  :type '(repeat (restricted-sexp :match-alternatives (symbolp consp)))
  :group 'desktop)

248 249 250 251 252 253 254
(defcustom desktop-globals-to-clear
  '(kill-ring
    kill-ring-yank-pointer
    search-ring
    search-ring-yank-pointer
    regexp-search-ring
    regexp-search-ring-yank-pointer)
255
  "List of global variables that `desktop-clear' will clear.
256
An element may be variable name (a symbol) or a cons cell of the form
257 258
\(VAR . FORM).  Symbols are set to nil and for cons cells VAR is set
to the value obtained by evaluating FORM."
259
  :type '(repeat (restricted-sexp :match-alternatives (symbolp consp)))
260
  :group 'desktop
261
  :version "22.1")
262

263 264 265 266 267
(defcustom desktop-clear-preserve-buffers
  '("\\*scratch\\*" "\\*Messages\\*" "\\*server\\*" "\\*tramp/.+\\*")
  "*List of buffers that `desktop-clear' should not delete.
Each element is a regular expression.  Buffers with a name matched by any of
these won't be deleted."
268 269
  :type '(repeat string)
  :group 'desktop)
270

271
;;;###autoload
272 273 274 275 276 277 278 279 280
(defcustom desktop-locals-to-save
  '(desktop-locals-to-save  ; Itself!  Think it over.
    truncate-lines
    case-fold-search
    case-replace
    fill-column
    overwrite-mode
    change-log-default-name
    line-number-mode
281 282 283 284 285 286 287
    column-number-mode
    size-indication-mode
    buffer-file-coding-system
    indent-tabs-mode
    indicate-buffer-boundaries
    indicate-empty-lines
    show-trailing-whitespace)
Richard M. Stallman's avatar
Richard M. Stallman committed
288
  "List of local variables to save for each buffer.
289 290
The variables are saved only when they really are local.  Conventional minor
modes are restored automatically; they should not be listed here."
Kenichi Handa's avatar
Kenichi Handa committed
291 292
  :type '(repeat symbol)
  :group 'desktop)
293

294
;; We skip .log files because they are normally temporary.
Karl Heuer's avatar
Karl Heuer committed
295
;;         (ftp) files because they require passwords and whatnot.
296
(defcustom desktop-buffers-not-to-save
297
  "\\(^nn\\.a[0-9]+\\|\\.log\\|(ftp)\\)$"
298 299 300
  "Regexp identifying buffers that are to be excluded from saving."
  :type 'regexp
  :group 'desktop)
Richard M. Stallman's avatar
Richard M. Stallman committed
301

Kenichi Handa's avatar
Kenichi Handa committed
302
;; Skip tramp and ange-ftp files
303
(defcustom desktop-files-not-to-save
304
  "^/[^/:]*:"
305 306 307
  "Regexp identifying files whose buffers are to be excluded from saving."
  :type 'regexp
  :group 'desktop)
308

309 310 311
;; We skip TAGS files to save time (tags-file-name is saved instead).
(defcustom desktop-modes-not-to-save
  '(tags-table-mode)
312 313 314 315
  "List of major modes whose buffers should not be saved."
  :type '(repeat symbol)
  :group 'desktop)

316 317 318 319 320 321 322
(defcustom desktop-file-name-format 'absolute
  "*Format in which desktop file names should be saved.
Possible values are:
   absolute -- Absolute file name.
   tilde    -- Relative to ~.
   local    -- Relative to directory of desktop file."
  :type '(choice (const absolute) (const tilde) (const local))
323
  :group 'desktop
324
  :version "22.1")
325

326 327 328 329
(defcustom desktop-restore-eager t
  "Number of buffers to restore immediately.
Remaining buffers are restored lazily (when Emacs is idle).
If value is t, all buffers are restored immediately."
330
  :type '(choice (const t) integer)
331
  :group 'desktop
332
  :version "22.1")
333 334 335 336 337

(defcustom desktop-lazy-verbose t
  "Verbose reporting of lazily created buffers."
  :type 'boolean
  :group 'desktop
338
  :version "22.1")
339 340 341 342 343 344

(defcustom desktop-lazy-idle-delay 5
  "Idle delay before starting to create buffers.
See `desktop-restore-eager'."
  :type 'integer
  :group 'desktop
345
  :version "22.1")
346

347
;;;###autoload
348 349
(defvar desktop-save-buffer nil
  "When non-nil, save buffer status in desktop file.
350
This variable becomes buffer local when set.
351

352 353
If the value is a function, it is called by `desktop-save' with argument
DESKTOP-DIRNAME to obtain auxiliary information to save in the desktop
354
file along with the state of the buffer for which it was called.
355

Kenichi Handa's avatar
Kenichi Handa committed
356
When file names are returned, they should be formatted using the call
357
\"(desktop-file-name FILE-NAME DESKTOP-DIRNAME)\".
358

359 360 361
Later, when `desktop-read' evaluates the desktop file, auxiliary information
is passed as the argument DESKTOP-BUFFER-MISC to functions in
`desktop-buffer-mode-handlers'.")
362 363
(make-variable-buffer-local 'desktop-save-buffer)
(make-obsolete-variable 'desktop-buffer-modes-to-save
364
                        'desktop-save-buffer "22.1")
365
(make-obsolete-variable 'desktop-buffer-misc-functions
366
                        'desktop-save-buffer "22.1")
367

368 369 370
;;;###autoload
(defvar desktop-buffer-mode-handlers
  nil
371
  "Alist of major mode specific functions to restore a desktop buffer.
372 373 374 375
Functions listed are called by `desktop-create-buffer' when `desktop-read'
evaluates the desktop file.  List elements must have the form

   (MAJOR-MODE . RESTORE-BUFFER-FUNCTION).
376 377 378 379

Buffers with a major mode not specified here, are restored by the default
handler `desktop-restore-file-buffer'.

380
Handlers are called with argument list
381

382
   (DESKTOP-BUFFER-FILE-NAME DESKTOP-BUFFER-NAME DESKTOP-BUFFER-MISC)
383 384

Furthermore, they may use the following variables:
385 386 387 388 389 390 391 392 393

   desktop-file-version
   desktop-buffer-major-mode
   desktop-buffer-minor-modes
   desktop-buffer-point
   desktop-buffer-mark
   desktop-buffer-read-only
   desktop-buffer-locals

394
If a handler returns a buffer, then the saved mode settings
395 396 397 398
and variable values for that buffer are copied into it.

Modules that define a major mode that needs a special handler should contain
code like
399

400 401 402 403 404 405
   (defun foo-restore-desktop-buffer
   ...
   (add-to-list 'desktop-buffer-mode-handlers
                '(foo-mode . foo-restore-desktop-buffer))

Furthermore the major mode function must be autoloaded.")
406

407
;;;###autoload
408 409
(put 'desktop-buffer-mode-handlers 'risky-local-variable t)
(make-obsolete-variable 'desktop-buffer-handlers
410
                        'desktop-buffer-mode-handlers "22.1")
411

412 413
(defcustom desktop-minor-mode-table
  '((auto-fill-function auto-fill-mode)
414 415
    (vc-mode nil)
    (vc-dired-mode nil))
416 417 418 419 420 421
  "Table mapping minor mode variables to minor mode functions.
Each entry has the form (NAME RESTORE-FUNCTION).
NAME is the name of the buffer-local variable indicating that the minor
mode is active.  RESTORE-FUNCTION is the function to activate the minor mode.
called.  RESTORE-FUNCTION nil means don't try to restore the minor mode.
Only minor modes for which the name of the buffer-local variable
422
and the name of the minor mode function are different have to be added to
423
this table.  See also `desktop-minor-mode-handlers'."
424 425 426
  :type 'sexp
  :group 'desktop)

427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470
;;;###autoload
(defvar desktop-minor-mode-handlers
  nil
  "Alist of functions to restore non-standard minor modes.
Functions are called by `desktop-create-buffer' to restore minor modes.
List elements must have the form

   (MINOR-MODE . RESTORE-FUNCTION).

Minor modes not specified here, are restored by the standard minor mode
function.

Handlers are called with argument list

   (DESKTOP-BUFFER-LOCALS)

Furthermore, they may use the following variables:

   desktop-file-version
   desktop-buffer-file-name
   desktop-buffer-name
   desktop-buffer-major-mode
   desktop-buffer-minor-modes
   desktop-buffer-point
   desktop-buffer-mark
   desktop-buffer-read-only
   desktop-buffer-misc

When a handler is called, the buffer has been created and the major mode has
been set, but local variables listed in desktop-buffer-locals has not yet been
created and set.

Modules that define a minor mode that needs a special handler should contain
code like

   (defun foo-desktop-restore
   ...
   (add-to-list 'desktop-minor-mode-handlers
                '(foo-mode . foo-desktop-restore))

Furthermore the minor mode function must be autoloaded.

See also `desktop-minor-mode-table'.")

471
;;;###autoload
472 473
(put 'desktop-minor-mode-handlers 'risky-local-variable t)

474 475
;; ----------------------------------------------------------------------------
(defvar desktop-dirname nil
Kenichi Handa's avatar
Kenichi Handa committed
476
  "The directory in which the desktop file should be saved.")
Richard M. Stallman's avatar
Richard M. Stallman committed
477 478

(defconst desktop-header
479 480 481
";; --------------------------------------------------------------------------
;; Desktop File for Emacs
;; --------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
482
" "*Header to place in Desktop file.")
483 484 485

(defvar desktop-delay-hook nil
  "Hooks run after all buffers are loaded; intended for internal use.")
486

487
;; ----------------------------------------------------------------------------
Kenichi Handa's avatar
Kenichi Handa committed
488
(defun desktop-truncate (list n)
489
  "Truncate LIST to at most N elements destructively."
Kenichi Handa's avatar
Kenichi Handa committed
490
  (let ((here (nthcdr (1- n) list)))
491
    (if (consp here)
492
	(setcdr here nil))))
493

494
;; ----------------------------------------------------------------------------
495 496
(defun desktop-clear ()
  "Empty the Desktop.
497 498 499
This kills all buffers except for internal ones and those with names matched by
a regular expression in the list `desktop-clear-preserve-buffers'.
Furthermore, it clears the variables listed in `desktop-globals-to-clear'."
Richard M. Stallman's avatar
Richard M. Stallman committed
500
  (interactive)
501
  (desktop-lazy-abort)
502 503 504 505
  (dolist (var desktop-globals-to-clear)
    (if (symbolp var)
      (eval `(setq-default ,var nil))
      (eval `(setq-default ,(car var) ,(cdr var)))))
506 507 508 509 510 511 512
  (let ((buffers (buffer-list))
        (preserve-regexp (concat "^\\("
                                 (mapconcat (lambda (regexp)
                                              (concat "\\(" regexp "\\)"))
                                            desktop-clear-preserve-buffers
                                            "\\|")
                                 "\\)$")))
513
    (while buffers
514 515 516
      (let ((bufname (buffer-name (car buffers))))
         (or
           (null bufname)
517
           (string-match preserve-regexp bufname)
518
           ;; Don't kill buffers made for internal purposes.
519
           (and (not (equal bufname "")) (eq (aref bufname 0) ?\s))
520
           (kill-buffer (car buffers))))
521
      (setq buffers (cdr buffers))))
Richard M. Stallman's avatar
Richard M. Stallman committed
522
  (delete-other-windows))
523

524
;; ----------------------------------------------------------------------------
525
(add-hook 'kill-emacs-hook 'desktop-kill)
526

Richard M. Stallman's avatar
Richard M. Stallman committed
527
(defun desktop-kill ()
Kenichi Handa's avatar
Kenichi Handa committed
528
  "If `desktop-save-mode' is non-nil, do what `desktop-save' says to do.
529 530 531 532
If the desktop should be saved and `desktop-dirname'
is nil, ask the user where to save the desktop."
  (when
    (and
Kenichi Handa's avatar
Kenichi Handa committed
533
      desktop-save-mode
534
      (let ((exists (file-exists-p (expand-file-name desktop-base-file-name desktop-dirname))))
535
        (or
Kenichi Handa's avatar
Kenichi Handa committed
536
          (eq desktop-save t)
537 538 539 540 541 542 543 544
          (and exists (memq desktop-save '(ask-if-new if-exists)))
          (and
            (or
              (memq desktop-save '(ask ask-if-new))
              (and exists (eq desktop-save 'ask-if-exists)))
            (y-or-n-p "Save desktop? ")))))
    (unless desktop-dirname
      (setq desktop-dirname
545 546 547 548
        (file-name-as-directory
          (expand-file-name
            (call-interactively
              (lambda (dir) (interactive "DDirectory for desktop file: ") dir))))))
549 550 551
    (condition-case err
      (desktop-save desktop-dirname)
      (file-error
552
        (unless (yes-or-no-p "Error while saving the desktop.  Ignore? ")
553 554
          (signal (car err) (cdr err)))))))

555
;; ----------------------------------------------------------------------------
556 557 558 559 560 561 562 563 564 565 566
(defun desktop-list* (&rest args)
  (if (null (cdr args))
      (car args)
    (setq args (nreverse args))
    (let ((value (cons (nth 1 args) (car args))))
      (setq args (cdr (cdr args)))
      (while args
	(setq value (cons (car args) value))
	(setq args (cdr args)))
      value)))

567
;; ----------------------------------------------------------------------------
Kenichi Handa's avatar
Kenichi Handa committed
568
(defun desktop-internal-v2s (value)
Richard M. Stallman's avatar
Richard M. Stallman committed
569 570 571 572
  "Convert VALUE to a pair (QUOTE . TXT); (eval (read TXT)) gives VALUE.
TXT is a string that when read and evaluated yields value.
QUOTE may be `may' (value may be quoted),
`must' (values must be quoted), or nil (value may not be quoted)."
573
  (cond
574
   ((or (numberp value) (null value) (eq t value) (keywordp value))
Kenichi Handa's avatar
Kenichi Handa committed
575 576 577
    (cons 'may (prin1-to-string value)))
   ((stringp value)
    (let ((copy (copy-sequence value)))
578 579 580
      (set-text-properties 0 (length copy) nil copy)
      ;; Get rid of text properties because we cannot read them
      (cons 'may (prin1-to-string copy))))
Kenichi Handa's avatar
Kenichi Handa committed
581 582 583
   ((symbolp value)
    (cons 'must (prin1-to-string value)))
   ((vectorp value)
584 585 586 587 588 589 590
    (let* ((special nil)
	   (pass1 (mapcar
		   (lambda (el)
		     (let ((res (desktop-internal-v2s el)))
		       (if (null (car res))
			   (setq special t))
		       res))
Kenichi Handa's avatar
Kenichi Handa committed
591
		   value)))
592 593 594 595 596 597 598 599 600 601
      (if special
	  (cons nil (concat "(vector "
			    (mapconcat (lambda (el)
					 (if (eq (car el) 'must)
					     (concat "'" (cdr el))
					   (cdr el)))
				       pass1
				       " ")
			    ")"))
	(cons 'may (concat "[" (mapconcat 'cdr pass1 " ") "]")))))
Kenichi Handa's avatar
Kenichi Handa committed
602 603
   ((consp value)
    (let ((p value)
604
	  newlist
605
	  use-list*
606 607 608 609 610 611 612 613 614
	  anynil)
      (while (consp p)
	(let ((q.txt (desktop-internal-v2s (car p))))
	  (or anynil (setq anynil (null (car q.txt))))
	  (setq newlist (cons q.txt newlist)))
	(setq p (cdr p)))
      (if p
	  (let ((last (desktop-internal-v2s p))
		(el (car newlist)))
615 616 617 618 619
	    (or anynil (setq anynil (null (car last))))
	    (or anynil
		(setq newlist (cons '(must . ".") newlist)))
	    (setq use-list* t)
	    (setq newlist (cons last newlist))))
620 621 622
      (setq newlist (nreverse newlist))
      (if anynil
	  (cons nil
623
		(concat (if use-list* "(desktop-list* "  "(list ")
624 625 626 627 628 629 630 631 632
			(mapconcat (lambda (el)
				     (if (eq (car el) 'must)
					 (concat "'" (cdr el))
				       (cdr el)))
				   newlist
				   " ")
			")"))
	(cons 'must
	      (concat "(" (mapconcat 'cdr newlist " ") ")")))))
Kenichi Handa's avatar
Kenichi Handa committed
633
   ((subrp value)
634
    (cons nil (concat "(symbol-function '"
Kenichi Handa's avatar
Kenichi Handa committed
635
		      (substring (prin1-to-string value) 7 -1)
636
		      ")")))
Kenichi Handa's avatar
Kenichi Handa committed
637 638 639
   ((markerp value)
    (let ((pos (prin1-to-string (marker-position value)))
	  (buf (prin1-to-string (buffer-name (marker-buffer value)))))
640 641 642 643 644
      (cons nil (concat "(let ((mk (make-marker)))"
			" (add-hook 'desktop-delay-hook"
			" (list 'lambda '() (list 'set-marker mk "
			pos " (get-buffer " buf ")))) mk)"))))
   (t					; save as text
645
    (cons 'may "\"Unprintable entity\""))))
646

647
;; ----------------------------------------------------------------------------
Kenichi Handa's avatar
Kenichi Handa committed
648
(defun desktop-value-to-string (value)
Richard M. Stallman's avatar
Richard M. Stallman committed
649 650
  "Convert VALUE to a string that when read evaluates to the same value.
Not all types of values are supported."
651 652
  (let* ((print-escape-newlines t)
	 (float-output-format nil)
Kenichi Handa's avatar
Kenichi Handa committed
653
	 (quote.txt (desktop-internal-v2s value))
654 655 656 657 658
	 (quote (car quote.txt))
	 (txt (cdr quote.txt)))
    (if (eq quote 'must)
	(concat "'" txt)
      txt)))
659

660
;; ----------------------------------------------------------------------------
661 662 663
(defun desktop-outvar (varspec)
  "Output a setq statement for variable VAR to the desktop file.
The argument VARSPEC may be the variable name VAR (a symbol),
664
or a cons cell of the form (VAR . MAX-SIZE),
665 666 667 668 669 670 671 672 673 674 675
which means to truncate VAR's value to at most MAX-SIZE elements
\(if the value is a list) before saving the value."
  (let (var size)
    (if (consp varspec)
	(setq var (car varspec) size (cdr varspec))
      (setq var varspec))
    (if (boundp var)
	(progn
	  (if (and (integerp size)
		   (> size 0)
		   (listp (eval var)))
676
	      (desktop-truncate (eval var) size))
677 678 679 680 681
	  (insert "(setq "
		  (symbol-name var)
		  " "
		  (desktop-value-to-string (symbol-value var))
		  ")\n")))))
682

683
;; ----------------------------------------------------------------------------
684
(defun desktop-save-buffer-p (filename bufname mode &rest dummy)
685
  "Return t if buffer should have its state saved in the desktop file.
686
FILENAME is the visited file name, BUFNAME is the buffer name, and
687 688
MODE is the major mode.
\n\(fn FILENAME BUFNAME MODE)"
689
  (let ((case-fold-search nil))
690
    (and (not (string-match desktop-buffers-not-to-save bufname))
691 692 693 694 695 696 697 698 699
         (not (memq mode desktop-modes-not-to-save))
         (or (and filename
                  (not (string-match desktop-files-not-to-save filename)))
             (and (eq mode 'dired-mode)
                  (with-current-buffer bufname
                    (not (string-match desktop-files-not-to-save
                                       default-directory))))
             (and (null filename)
		  (with-current-buffer bufname desktop-save-buffer))))))
700

701
;; ----------------------------------------------------------------------------
702 703 704 705 706 707 708 709 710 711 712 713 714 715
(defun desktop-file-name (filename dirname)
  "Convert FILENAME to format specified in `desktop-file-name-format'.
DIRNAME must be the directory in which the desktop file will be saved."
  (cond
    ((not filename) nil)
    ((eq desktop-file-name-format 'tilde)
     (let ((relative-name (file-relative-name (expand-file-name filename) "~")))
       (cond
         ((file-name-absolute-p relative-name) relative-name)
         ((string= "./" relative-name) "~/")
         ((string= "." relative-name) "~")
         (t (concat "~/" relative-name)))))
    ((eq desktop-file-name-format 'local) (file-relative-name filename dirname))
    (t (expand-file-name filename))))
716

717
;; ----------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
718
(defun desktop-save (dirname)
Kenichi Handa's avatar
Kenichi Handa committed
719 720 721
  "Save the desktop in a desktop file.
Parameter DIRNAME specifies where to save the desktop file.
See also `desktop-base-file-name'."
Richard M. Stallman's avatar
Richard M. Stallman committed
722
  (interactive "DDirectory to save desktop file in: ")
723
  (run-hooks 'desktop-save-hook)
724
  (setq dirname (file-name-as-directory (expand-file-name dirname)))
Richard M. Stallman's avatar
Richard M. Stallman committed
725
  (save-excursion
726
    (let ((filename (expand-file-name desktop-base-file-name dirname))
727 728
          (info
            (mapcar
729
              #'(lambda (b)
730 731 732 733 734 735 736
                  (set-buffer b)
                  (list
                    (desktop-file-name (buffer-file-name) dirname)
                    (buffer-name)
                    major-mode
                    ;; minor modes
                    (let (ret)
737 738
                      (mapc
                        #'(lambda (minor-mode)
739
                          (and
740 741
                            (boundp minor-mode)
                            (symbol-value minor-mode)
742 743 744 745
                            (let* ((special (assq minor-mode desktop-minor-mode-table))
                                   (value (cond (special (cadr special))
                                                ((functionp minor-mode) minor-mode))))
                              (when value (add-to-list 'ret value)))))
746 747 748 749 750
                        (mapcar #'car minor-mode-alist))
                      ret)
                    (point)
                    (list (mark t) mark-active)
                    buffer-read-only
751
                    ;; Auxiliary information
752 753
                    (when (functionp desktop-save-buffer)
                      (funcall desktop-save-buffer dirname))
754 755 756 757 758 759 760 761 762 763
                    (let ((locals desktop-locals-to-save)
                          (loclist (buffer-local-variables))
                          (ll))
                      (while locals
                        (let ((here (assq (car locals) loclist)))
                          (if here
                            (setq ll (cons here ll))
                            (when (member (car locals) loclist)
                              (setq ll (cons (car locals) ll)))))
                        (setq locals (cdr locals)))
764
                      ll)))
765
              (buffer-list)))
766
          (eager desktop-restore-eager)
767
          (buf (get-buffer-create "*desktop*")))
Richard M. Stallman's avatar
Richard M. Stallman committed
768 769
      (set-buffer buf)
      (erase-buffer)
770

771
      (insert
772
        ";; -*- mode: emacs-lisp; coding: utf-8-emacs; -*-\n"
773 774 775 776 777
        desktop-header
        ";; Created " (current-time-string) "\n"
        ";; Desktop file format version " desktop-file-version "\n"
        ";; Emacs version " emacs-version "\n\n"
        ";; Global section:\n")
778
      (mapc (function desktop-outvar) desktop-globals-to-save)
Richard M. Stallman's avatar
Richard M. Stallman committed
779
      (if (memq 'kill-ring desktop-globals-to-save)
780 781 782 783
        (insert
          "(setq kill-ring-yank-pointer (nthcdr "
          (int-to-string (- (length kill-ring) (length kill-ring-yank-pointer)))
          " kill-ring))\n"))
Richard M. Stallman's avatar
Richard M. Stallman committed
784

785
      (insert "\n;; Buffer section -- buffers listed in same order as in buffer list:\n")
786
      (mapc #'(lambda (l)
787 788 789 790 791 792 793 794 795 796 797 798 799 800 801
                (when (apply 'desktop-save-buffer-p l)
                  (insert "("
                          (if (or (not (integerp eager))
                                  (unless (zerop eager)
                                    (setq eager (1- eager))
                                    t))
                              "desktop-create-buffer"
                            "desktop-append-buffer-args")
                          " "
                          desktop-file-version)
                  (mapc #'(lambda (e)
                            (insert "\n  " (desktop-value-to-string e)))
                        l)
                  (insert ")\n\n")))
            info)
Richard M. Stallman's avatar
Richard M. Stallman committed
802
      (setq default-directory dirname)
803
      (let ((coding-system-for-write 'utf-8-emacs))
804
        (write-region (point-min) (point-max) filename nil 'nomessage))))
Richard M. Stallman's avatar
Richard M. Stallman committed
805
  (setq desktop-dirname dirname))
806

807
;; ----------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
808
(defun desktop-remove ()
Kenichi Handa's avatar
Kenichi Handa committed
809 810
  "Delete desktop file in `desktop-dirname'.
This function also sets `desktop-dirname' to nil."
Richard M. Stallman's avatar
Richard M. Stallman committed
811
  (interactive)
Kenichi Handa's avatar
Kenichi Handa committed
812 813 814 815
  (when desktop-dirname
    (let ((filename (expand-file-name desktop-base-file-name desktop-dirname)))
      (setq desktop-dirname nil)
      (when (file-exists-p filename)
816
        (delete-file filename)))))
Kenichi Handa's avatar
Kenichi Handa committed
817

818 819 820 821 822
(defvar desktop-buffer-args-list nil
  "List of args for `desktop-create-buffer'.")

(defvar desktop-lazy-timer nil)

823
;; ----------------------------------------------------------------------------
824
;;;###autoload
Kenichi Handa's avatar
Kenichi Handa committed
825 826 827 828
(defun desktop-read (&optional dirname)
  "Read and process the desktop file in directory DIRNAME.
Look for a desktop file in DIRNAME, or if DIRNAME is omitted, look in
directories listed in `desktop-path'.  If a desktop file is found, it
829
is processed and `desktop-after-read-hook' is run.  If no desktop file
Kenichi Handa's avatar
Kenichi Handa committed
830 831 832
is found, clear the desktop and run `desktop-no-desktop-file-hook'.
This function is a no-op when Emacs is running in batch mode.
It returns t if a desktop file was loaded, nil otherwise."
Richard M. Stallman's avatar
Richard M. Stallman committed
833
  (interactive)
834
  (unless noninteractive
Kenichi Handa's avatar
Kenichi Handa committed
835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855
    (setq desktop-dirname
      (file-name-as-directory
        (expand-file-name
          (or
            ;; If DIRNAME is specified, use it.
            (and (< 0 (length dirname)) dirname)
            ;; Otherwise search desktop file in desktop-path.
            (let ((dirs desktop-path))
              (while
                (and
                  dirs
                  (not
                    (file-exists-p (expand-file-name desktop-base-file-name (car dirs)))))
                (setq dirs (cdr dirs)))
              (and dirs (car dirs)))
            ;; If not found and `desktop-path' is non-nil, use its first element.
            (and desktop-path (car desktop-path))
            ;; Default: Home directory.
            "~"))))
    (if (file-exists-p (expand-file-name desktop-base-file-name desktop-dirname))
      ;; Desktop file found, process it.
856 857 858
      (let ((desktop-first-buffer nil)
            (desktop-buffer-ok-count 0)
            (desktop-buffer-fail-count 0))
859
        (setq desktop-lazy-timer nil)
Kenichi Handa's avatar
Kenichi Handa committed
860 861 862 863 864
        ;; Evaluate desktop buffer.
        (load (expand-file-name desktop-base-file-name desktop-dirname) t t t)
        ;; `desktop-create-buffer' puts buffers at end of the buffer list.
        ;; We want buffers existing prior to evaluating the desktop (and not reused)
        ;; to be placed at the end of the buffer list, so we move them here.
865 866
        (mapc 'bury-buffer
              (nreverse (cdr (memq desktop-first-buffer (nreverse (buffer-list))))))
Kenichi Handa's avatar
Kenichi Handa committed
867 868 869 870
        (switch-to-buffer (car (buffer-list)))
        (run-hooks 'desktop-delay-hook)
        (setq desktop-delay-hook nil)
        (run-hooks 'desktop-after-read-hook)
871
        (message "Desktop: %d buffer%s restored%s%s."
872 873 874 875
                 desktop-buffer-ok-count
                 (if (= 1 desktop-buffer-ok-count) "" "s")
                 (if (< 0 desktop-buffer-fail-count)
                     (format ", %d failed to restore" desktop-buffer-fail-count)
876 877 878 879
                   "")
                 (if desktop-buffer-args-list
                     (format ", %d to restore lazily"
                             (length desktop-buffer-args-list))
880
                   ""))
Kenichi Handa's avatar
Kenichi Handa committed
881 882 883 884 885 886 887
        t)
      ;; No desktop file found.
      (desktop-clear)
      (let ((default-directory desktop-dirname))
        (run-hooks 'desktop-no-desktop-file-hook))
      (message "No desktop file.")
      nil)))
888

889
;; ----------------------------------------------------------------------------
Kenichi Handa's avatar
Kenichi Handa committed
890
;; Maintained for backward compatibility
891
;;;###autoload
Richard M. Stallman's avatar
Richard M. Stallman committed
892
(defun desktop-load-default ()
Richard M. Stallman's avatar
Richard M. Stallman committed
893
  "Load the `default' start-up library manually.
Kenichi Handa's avatar
Kenichi Handa committed
894
Also inhibit further loading of it."
895 896 897 898 899
  (unless inhibit-default-init	        ; safety check
    (load "default" t t)
    (setq inhibit-default-init t)))
(make-obsolete 'desktop-load-default
               'desktop-save-mode "22.1")
900 901 902

;; ----------------------------------------------------------------------------
;;;###autoload
Kenichi Handa's avatar
Kenichi Handa committed
903 904 905 906 907 908 909
(defun desktop-change-dir (dirname)
  "Change to desktop saved in DIRNAME.
Kill the desktop as specified by variables `desktop-save-mode' and
`desktop-save', then clear the desktop and load the desktop file in
directory DIRNAME."
  (interactive "DChange to directory: ")
  (setq dirname (file-name-as-directory (expand-file-name dirname desktop-dirname)))
910 911
  (desktop-kill)
  (desktop-clear)
Kenichi Handa's avatar
Kenichi Handa committed
912
  (desktop-read dirname))
913

Kenichi Handa's avatar
Kenichi Handa committed
914
;; ----------------------------------------------------------------------------
915
;;;###autoload
Kenichi Handa's avatar
Kenichi Handa committed
916 917
(defun desktop-save-in-desktop-dir ()
  "Save the desktop in directory `desktop-dirname'."
918 919
  (interactive)
  (if desktop-dirname
920
      (desktop-save desktop-dirname)
921 922 923 924 925 926 927 928
    (call-interactively 'desktop-save))
  (message "Desktop saved in %s" desktop-dirname))

;; ----------------------------------------------------------------------------
;;;###autoload
(defun desktop-revert ()
  "Revert to the last loaded desktop."
  (interactive)
Kenichi Handa's avatar
Kenichi Handa committed
929 930 931 932 933 934
  (unless desktop-dirname
    (error "Unknown desktop directory"))
  (unless (file-exists-p (expand-file-name desktop-base-file-name desktop-dirname))
    (error "No desktop file found"))
  (desktop-clear)
  (desktop-read desktop-dirname))
935

936
;; ----------------------------------------------------------------------------
937 938 939 940 941 942 943
(defun desktop-restore-file-buffer (desktop-buffer-file-name
                                    desktop-buffer-name
                                    desktop-buffer-misc)
  "Restore a file buffer."
  (eval-when-compile ; Just to silence the byte compiler
    (defvar desktop-buffer-major-mode)
    (defvar desktop-buffer-locals))
944 945
  (if desktop-buffer-file-name
      (if (or (file-exists-p desktop-buffer-file-name)
946 947 948 949
              (let ((msg (format "Desktop: File \"%s\" no longer exists."
                                 desktop-buffer-file-name)))
                 (if desktop-missing-file-warning
		     (y-or-n-p (concat msg " Re-create? "))
Deepak Goel's avatar
Deepak Goel committed
950
                   (message "%s" msg)
951
                   nil)))
Kenichi Handa's avatar
Kenichi Handa committed
952 953 954 955 956 957
	  (let* ((auto-insert nil) ; Disable auto insertion
		 (coding-system-for-read
		  (or coding-system-for-read
		      (cdr (assq 'buffer-file-coding-system
				 desktop-buffer-locals))))
		 (buf (find-file-noselect desktop-buffer-file-name)))
958 959
	    (condition-case nil
		(switch-to-buffer buf)
960
	      (error (pop-to-buffer buf)))
961 962 963
	    (and (not (eq major-mode desktop-buffer-major-mode))
		 (functionp desktop-buffer-major-mode)
		 (funcall desktop-buffer-major-mode))
964
	    buf)
965
	nil)))
966

967 968
(defun desktop-load-file (function)
  "Load the file where auto loaded FUNCTION is defined."
969
  (when function
970
    (let ((fcell (and (fboundp function) (symbol-function function))))
971 972 973
      (when (and (listp fcell)
                 (eq 'autoload (car fcell)))
        (load (cadr fcell))))))
974

975
;; ----------------------------------------------------------------------------
Juri Linkov's avatar
Juri Linkov committed
976 977
;; Create a buffer, load its file, set its mode, ...;
;; called from Desktop file only.
978

979 980 981
;; Just to silence the byte compiler.
(eval-when-compile
  (defvar desktop-first-buffer)) ; Dynamically bound in `desktop-read'
982

983 984 985 986 987 988 989 990 991 992 993 994
(defun desktop-create-buffer
  (desktop-file-version
   desktop-buffer-file-name
   desktop-buffer-name
   desktop-buffer-major-mode
   desktop-buffer-minor-modes
   desktop-buffer-point
   desktop-buffer-mark
   desktop-buffer-read-only
   desktop-buffer-misc
   &optional
   desktop-buffer-locals)
995 996 997 998
  ;; Just to silence the byte compiler. Bound locally in `desktop-read'.
  (eval-when-compile
    (defvar desktop-buffer-ok-count)
    (defvar desktop-buffer-fail-count))
999 1000 1001
  ;; To make desktop files with relative file names possible, we cannot
  ;; allow `default-directory' to change. Therefore we save current buffer.
  (save-current-buffer
1002 1003
    ;; Give major mode module a chance to add a handler.
    (desktop-load-file desktop-buffer-major-mode)
1004 1005 1006 1007 1008 1009 1010 1011 1012 1013 1014 1015 1016 1017 1018
    (let ((buffer-list (buffer-list))
          (result
           (condition-case err
               (funcall (or (cdr (assq desktop-buffer-major-mode
                                       desktop-buffer-mode-handlers))
                            'desktop-restore-file-buffer)
                        desktop-buffer-file-name
                        desktop-buffer-name
                        desktop-buffer-misc)
             (error
              (message "Desktop: Can't load buffer %s: %s"
                       desktop-buffer-name
                       (error-message-string err))
              (when desktop-missing-file-warning (sit-for 1))
              nil))))
1019 1020 1021 1022
      (if (bufferp result)
          (setq desktop-buffer-ok-count (1+ desktop-buffer-ok-count))
        (setq desktop-buffer-fail-count (1+ desktop-buffer-fail-count))
        (setq result nil))
1023 1024
      ;; Restore buffer list order with new buffer at end. Don't change
      ;; the order for old desktop files (old desktop module behaviour).
1025
      (unless (< desktop-file-version 206)
1026
        (mapc 'bury-buffer buffer-list)
1027
        (when result (bury-buffer result)))
1028
      (when result
1029 1030
        (unless (or desktop-first-buffer (< desktop-file-version 206))
          (setq desktop-first-buffer result))
1031 1032 1033 1034
        (set-buffer result)
        (unless (equal (buffer-name) desktop-buffer-name)
          (rename-buffer desktop-buffer-name))
        ;; minor modes
1035 1036 1037 1038 1039
        (cond ((equal '(t) desktop-buffer-minor-modes) ; backwards compatible
               (auto-fill-mode 1))
              ((equal '(nil) desktop-buffer-minor-modes) ; backwards compatible
               (auto-fill-mode 0))
              (t
1040
               (mapc #'(lambda (minor-mode)
1041 1042 1043 1044 1045