desktop.el 19.5 KB
Newer Older
Richard M. Stallman's avatar
Richard M. Stallman committed
1 2
;;; desktop.el --- save partial status of Emacs when killed

3
;; Copyright (C) 1993, 1994, 1995 Free Software Foundation, Inc.
Richard M. Stallman's avatar
Richard M. Stallman committed
4 5

;; Author: Morten Welinder <terra@diku.dk>
Richard M. Stallman's avatar
Richard M. Stallman committed
6 7
;; Keywords: customization
;; Favourite-brand-of-beer: None, I hate beer.
Richard M. Stallman's avatar
Richard M. Stallman committed
8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to
;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.

;;; Commentary:

27 28 29 30 31 32 33 34
;; Save the Desktop, i.e.,
;;	- some global variables
;; 	- the list of buffers with associated files.  For each buffer also
;;		- the major mode
;;		- the default directory
;;		- the point
;;		- the mark & mark-active
;;		- buffer-read-only
35
;;		- some local variables
Richard M. Stallman's avatar
Richard M. Stallman committed
36

37 38 39 40 41 42 43
;; To use this, first put these three lines in the bottom of your .emacs
;; file (the later the better):
;;
;;	(load "desktop")
;;	(desktop-load-default)
;;	(desktop-read)
;;
44
;; Between the second and the third line you may wish to add something that
45
;; updates the variables `desktop-globals-to-save' and/or
46 47 48 49 50 51
;; `desktop-locals-to-save'.  If for instance you want to save the local
;; variable `foobar' for every buffer in which it is local, you could add
;; the line
;;
;;	(setq desktop-locals-to-save (cons 'foobar desktop-locals-to-save))
;;
52
;; To avoid saving excessive amounts of data you may also wish to add
53 54 55
;; something like the following
;;
;;	(add-hook 'kill-emacs-hook
56
;;		  '(lambda ()
57 58 59 60
;;		     (desktop-truncate search-ring 3)
;;		     (desktop-truncate regexp-search-ring 3)))
;;
;; which will make sure that no more than three search items are saved.  You
61 62
;; must place this line *after* the (load "desktop") line.  See also the
;; variable desktop-save-hook.
Richard M. Stallman's avatar
Richard M. Stallman committed
63

64 65 66 67 68
;; Start Emacs in the root directory of your "project". The desktop saver
;; is inactive by default.  You activate it by M-x desktop-save RET.  When
;; you exit the next time the above data will be saved.  This ensures that
;; all the files you were editing will be reloaded the next time you start
;; Emacs from the same directory and that points will be set where you
69
;; left them.  If you save a desktop file in your home directory it will
70
;; act as a default desktop when you start Emacs from a directory that
71 72 73 74 75 76
;; doesn't have its own.  I never do this, but you may want to.

;; By the way: don't use desktop.el to customize Emacs -- the file .emacs
;; in your home directory is used for that.  Saving global default values
;; for buffers is an example of misuse.

77 78 79
;; PLEASE NOTE: The kill ring can be saved as specified by the variable
;; `desktop-globals-to-save' (by default it isn't).  This may result in saving
;; things you did not mean to keep.  Use M-x desktop-clear RET.
80

81 82 83 84 85
;; Thanks to  hetrick@phys.uva.nl (Jim Hetrick)      for useful ideas.
;;            avk@rtsg.mot.com (Andrew V. Klein)     for a dired tip.
;;            chris@tecc.co.uk (Chris Boucher)       for a mark tip.
;;            f89-kam@nada.kth.se (Klas Mellbourn)   for a mh-e tip.
;;            kifer@sbkifer.cs.sunysb.edu (M. Kifer) for a bug hunt.
86
;;            treese@lcs.mit.edu (Win Treese)        for ange-ftp tips.
87 88 89 90 91 92 93
;; ---------------------------------------------------------------------------
;; TODO:
;;
;; Save window configuration.
;; Recognize more minor modes.
;; Save mark rings.
;; Start-up with buffer-menu???
Richard M. Stallman's avatar
Richard M. Stallman committed
94 95 96

;;; Code:

97 98 99
;; Make the compilation more silent
(eval-when-compile
  ;; We use functions from these modules
100 101
  ;; We can't (require 'mh-e) since that wants to load something.
  (mapcar 'require '(info dired reporter)))
102
;; ----------------------------------------------------------------------------
103 104 105
;; USER OPTIONS -- settings you might want to play with.
;; ----------------------------------------------------------------------------
(defconst desktop-basefilename
106
  (if (or (eq system-type 'ms-dos) (eq system-type 'windows-nt))
Richard M. Stallman's avatar
Richard M. Stallman committed
107 108
      "emacs.dsk" ; Ms-Dos does not support multiple dots in file name
    ".emacs.desktop")
Richard M. Stallman's avatar
Richard M. Stallman committed
109
  "File for Emacs desktop, not including the directory name.")
Richard M. Stallman's avatar
Richard M. Stallman committed
110

111
(defvar desktop-missing-file-warning t
Richard M. Stallman's avatar
Richard M. Stallman committed
112 113
  "*If non-nil then desktop warns when a file no longer exists.
Otherwise it simply ignores that file.")
Richard M. Stallman's avatar
Richard M. Stallman committed
114

115
(defvar desktop-globals-to-save
Richard M. Stallman's avatar
Richard M. Stallman committed
116
  (list 'desktop-missing-file-warning
117
	;; Feature: saving kill-ring implies saving kill-ring-yank-pointer
118
	;; 'kill-ring
119 120
	'tags-file-name
	'tags-table-list
121 122
	'search-ring
	'regexp-search-ring
123
	'register-alist
124
	;; 'desktop-globals-to-save	; Itself!
Richard M. Stallman's avatar
Richard M. Stallman committed
125
	)
126 127 128 129 130
  "List of global variables to save when killing Emacs.
An element may be variable name (a symbol)
or a cons cell of the form  (VAR . MAX-SIZE),
which means to truncate VAR's value to at most MAX-SIZE elements
\(if the value is a list) before saving the value.")
Richard M. Stallman's avatar
Richard M. Stallman committed
131

132 133 134 135 136 137 138 139
(defvar desktop-locals-to-save
  (list 'desktop-locals-to-save		; Itself!  Think it over.
        'truncate-lines
	'case-fold-search
	'case-replace
	'fill-column
	'overwrite-mode
	'change-log-default-name
140
	'line-number-mode
141
	)
Richard M. Stallman's avatar
Richard M. Stallman committed
142 143
  "List of local variables to save for each buffer.
The variables are saved only when they really are local.")
144
(make-variable-buffer-local 'desktop-locals-to-save)
145

146
;; We skip .log files because they are normally temporary.
Karl Heuer's avatar
Karl Heuer committed
147
;;         (ftp) files because they require passwords and whatnot.
148
;;         TAGS files to save time (tags-file-name is saved instead).
Richard M. Stallman's avatar
Richard M. Stallman committed
149
(defvar desktop-buffers-not-to-save
150
 "\\(^nn\\.a[0-9]+\\|\\.log\\|(ftp)\\|^tags\\|^TAGS\\)$"
Richard M. Stallman's avatar
Richard M. Stallman committed
151 152
 "Regexp identifying buffers that are to be excluded from saving.")

153 154 155 156 157
;; Skip ange-ftp files
(defvar desktop-files-not-to-save
  "^/[^/:]*:"
  "Regexp identifying files whose buffers are to be excluded from saving.")

Richard M. Stallman's avatar
Richard M. Stallman committed
158
(defvar desktop-buffer-handlers
159
  '(desktop-buffer-dired
Richard M. Stallman's avatar
Richard M. Stallman committed
160
    desktop-buffer-rmail
161
    desktop-buffer-mh
Richard M. Stallman's avatar
Richard M. Stallman committed
162 163
    desktop-buffer-info
    desktop-buffer-file)
Richard M. Stallman's avatar
Richard M. Stallman committed
164 165 166 167 168 169
  "*List of functions to call in order to create a buffer.
The functions are called without explicit parameters but may access
the the major mode as `mam', the file name as `fn', the buffer name as
`bn', the default directory as `dd'.  If some function returns non-nil
no further functions are called.  If the function returns t then the
buffer is considered created.")
170 171 172

(defvar desktop-create-buffer-form "(desktop-create-buffer 205"
  "Opening of form for creation of new buffers.")
173 174 175 176

(defvar desktop-save-hook nil
  "Hook run before saving the desktop to allow you to cut history lists and
the like shorter.")
177 178
;; ----------------------------------------------------------------------------
(defvar desktop-dirname nil
Richard M. Stallman's avatar
Richard M. Stallman committed
179 180 181
  "The directory in which the current desktop file resides.")

(defconst desktop-header
182 183 184
";; --------------------------------------------------------------------------
;; Desktop File for Emacs
;; --------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
185
" "*Header to place in Desktop file.")
186 187 188

(defvar desktop-delay-hook nil
  "Hooks run after all buffers are loaded; intended for internal use.")
189
;; ----------------------------------------------------------------------------
190 191 192 193
(defun desktop-truncate (l n)
  "Truncate LIST to at most N elements destructively."
  (let ((here (nthcdr (1- n) l)))
    (if (consp here)
194
	(setcdr here nil))))
195
;; ----------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
196 197
(defun desktop-clear () "Empty the Desktop."
  (interactive)
198 199 200 201 202 203
  (setq kill-ring nil
	kill-ring-yank-pointer nil
	search-ring nil
	search-ring-yank-pointer nil
	regexp-search-ring nil
	regexp-search-ring-yank-pointer nil)
Richard M. Stallman's avatar
Richard M. Stallman committed
204 205
  (mapcar (function kill-buffer) (buffer-list))
  (delete-other-windows))
206
;; ----------------------------------------------------------------------------
207
(add-hook 'kill-emacs-hook 'desktop-kill)
208

Richard M. Stallman's avatar
Richard M. Stallman committed
209
(defun desktop-kill ()
210
  (if desktop-dirname
211 212 213 214 215 216
      (condition-case err
	  (desktop-save desktop-dirname)
	(file-error
	 (if (yes-or-no-p "Error while saving the desktop.  Quit anyway? ")
	     nil
	   (signal (car err) (cdr err)))))))
217
;; ----------------------------------------------------------------------------
218
(defun desktop-internal-v2s (val)
Richard M. Stallman's avatar
Richard M. Stallman committed
219 220 221 222
  "Convert VALUE to a pair (QUOTE . TXT); (eval (read TXT)) gives VALUE.
TXT is a string that when read and evaluated yields value.
QUOTE may be `may' (value may be quoted),
`must' (values must be quoted), or nil (value may not be quoted)."
223
  (cond
224
   ((or (numberp val) (null val) (eq t val))
225
    (cons 'may (prin1-to-string val)))
226
   ((stringp val)
227 228 229 230
    (let ((copy (copy-sequence val)))
      (set-text-properties 0 (length copy) nil copy)
      ;; Get rid of text properties because we cannot read them
      (cons 'may (prin1-to-string copy))))
231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252
   ((symbolp val)
    (cons 'must (prin1-to-string val)))
   ((vectorp val)
    (let* ((special nil)
	   (pass1 (mapcar
		   (lambda (el)
		     (let ((res (desktop-internal-v2s el)))
		       (if (null (car res))
			   (setq special t))
		       res))
		   val)))
      (if special
	  (cons nil (concat "(vector "
			    (mapconcat (lambda (el)
					 (if (eq (car el) 'must)
					     (concat "'" (cdr el))
					   (cdr el)))
				       pass1
				       " ")
			    ")"))
	(cons 'may (concat "[" (mapconcat 'cdr pass1 " ") "]")))))
   ((consp val)
253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288
    (let ((p val)
	  newlist
	  anynil)
      (while (consp p)
	(let ((q.txt (desktop-internal-v2s (car p))))
	  (or anynil (setq anynil (null (car q.txt))))
	  (setq newlist (cons q.txt newlist)))
	(setq p (cdr p)))
      (if p
	  (let ((last (desktop-internal-v2s p))
		(el (car newlist)))
	    (setcar newlist
		    (if (or anynil (setq anynil (null (car last))))
			(cons nil
			      (concat "(cons "
				      (if (eq (car el) 'must) "'" "")
				      (cdr el)
				      " "
				      (if (eq (car last) 'must) "'" "")
				      (cdr last)
				      ")"))
		      (cons 'must
			    (concat (cdr el) " . " (cdr last)))))))
      (setq newlist (nreverse newlist))
      (if anynil
	  (cons nil
		(concat "(list "
			(mapconcat (lambda (el)
				     (if (eq (car el) 'must)
					 (concat "'" (cdr el))
				       (cdr el)))
				   newlist
				   " ")
			")"))
	(cons 'must
	      (concat "(" (mapconcat 'cdr newlist " ") ")")))))
289 290 291 292 293 294 295 296 297 298 299 300
   ((subrp val)
    (cons nil (concat "(symbol-function '"
		      (substring (prin1-to-string val) 7 -1)
		      ")")))
   ((markerp val)
    (let ((pos (prin1-to-string (marker-position val)))
	  (buf (prin1-to-string (buffer-name (marker-buffer val)))))
      (cons nil (concat "(let ((mk (make-marker)))"
			" (add-hook 'desktop-delay-hook"
			" (list 'lambda '() (list 'set-marker mk "
			pos " (get-buffer " buf ")))) mk)"))))
   (t					; save as text
301
    (cons 'may "\"Unprintable entity\""))))
302

303
(defun desktop-value-to-string (val)
Richard M. Stallman's avatar
Richard M. Stallman committed
304 305
  "Convert VALUE to a string that when read evaluates to the same value.
Not all types of values are supported."
306 307 308 309 310 311 312 313
  (let* ((print-escape-newlines t)
	 (float-output-format nil)
	 (quote.txt (desktop-internal-v2s val))
	 (quote (car quote.txt))
	 (txt (cdr quote.txt)))
    (if (eq quote 'must)
	(concat "'" txt)
      txt)))
314
;; ----------------------------------------------------------------------------
315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335
(defun desktop-outvar (varspec)
  "Output a setq statement for variable VAR to the desktop file.
The argument VARSPEC may be the variable name VAR (a symbol),
or a cons cell of the form  (VAR . MAX-SIZE),
which means to truncate VAR's value to at most MAX-SIZE elements
\(if the value is a list) before saving the value."
  (let (var size)
    (if (consp varspec)
	(setq var (car varspec) size (cdr varspec))
      (setq var varspec))
    (if (boundp var)
	(progn
	  (if (and (integerp size)
		   (> size 0)
		   (listp (eval var)))
	      (desktop-truncate (eval var) size)) 
	  (insert "(setq "
		  (symbol-name var)
		  " "
		  (desktop-value-to-string (symbol-value var))
		  ")\n")))))
336
;; ----------------------------------------------------------------------------
337
(defun desktop-save-buffer-p (filename bufname mode &rest dummy)
Richard M. Stallman's avatar
Richard M. Stallman committed
338
  "Return t if the desktop should record a particular buffer for next startup.
339
FILENAME is the visited file name, BUFNAME is the buffer name, and
Richard M. Stallman's avatar
Richard M. Stallman committed
340
MODE is the major mode."
341 342 343 344 345 346 347 348 349 350 351
  (let ((case-fold-search nil))
    (or (and filename
	     (not (string-match desktop-buffers-not-to-save bufname))
	     (not (string-match desktop-files-not-to-save filename)))
	(and (eq mode 'dired-mode)
	     (save-excursion
	       (set-buffer (get-buffer bufname))
	       (not (string-match desktop-files-not-to-save
				  default-directory))))
	(and (null filename)
	     (memq mode '(Info-mode rmail-mode))))))
352
;; ----------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
353 354 355
(defun desktop-save (dirname)
  "Save the Desktop file.  Parameter DIRNAME specifies where to save desktop."
  (interactive "DDirectory to save desktop file in: ")
356
  (run-hooks 'desktop-save-hook)
Richard M. Stallman's avatar
Richard M. Stallman committed
357
  (save-excursion
358
    (let ((filename (expand-file-name
Richard M. Stallman's avatar
Richard M. Stallman committed
359
		     (concat dirname desktop-basefilename)))
360 361
	  (info (nreverse
		 (mapcar
Richard M. Stallman's avatar
Richard M. Stallman committed
362 363
		  (function (lambda (b)
			      (set-buffer b)
364
			      (list
Richard M. Stallman's avatar
Richard M. Stallman committed
365 366
			       (buffer-file-name)
			       (buffer-name)
367 368
			       major-mode
			       (list	; list explaining minor modes
369
				(not (null auto-fill-function)))
Richard M. Stallman's avatar
Richard M. Stallman committed
370
			       (point)
371
			       (list (mark t) mark-active)
Richard M. Stallman's avatar
Richard M. Stallman committed
372
			       buffer-read-only
373 374 375 376
			       (cond ((eq major-mode 'Info-mode)
				      (list Info-current-file
					    Info-current-node))
				     ((eq major-mode 'dired-mode)
377 378 379 380 381 382 383
				      (cons
				       (expand-file-name dired-directory)
				       (cdr
					(nreverse
					 (mapcar
					  (function car)
					  dired-subdir-alist))))))
384 385 386 387 388 389 390 391 392 393 394
			       (let ((locals desktop-locals-to-save)
				     (loclist (buffer-local-variables))
				     (ll))
				 (while locals
				   (let ((here (assq (car locals) loclist)))
				     (if here
					 (setq ll (cons here ll))
				       (if (member (car locals) loclist)
					   (setq ll (cons (car locals) ll)))))
				   (setq locals (cdr locals)))
				 ll)
Richard M. Stallman's avatar
Richard M. Stallman committed
395 396 397 398 399
			       )))
		  (buffer-list))))
	  (buf (get-buffer-create "*desktop*")))
      (set-buffer buf)
      (erase-buffer)
400

401 402
      (insert desktop-header
	      ";; Created " (current-time-string) "\n"
403 404
	      ";; Emacs version " emacs-version "\n\n"
	      ";; Global section:\n")
Richard M. Stallman's avatar
Richard M. Stallman committed
405 406
      (mapcar (function desktop-outvar) desktop-globals-to-save)
      (if (memq 'kill-ring desktop-globals-to-save)
407 408
	  (insert "(setq kill-ring-yank-pointer (nthcdr "
		  (int-to-string
Richard M. Stallman's avatar
Richard M. Stallman committed
409 410 411
		   (- (length kill-ring) (length kill-ring-yank-pointer)))
		  " kill-ring))\n"))

412
      (insert "\n;; Buffer section:\n")
413 414 415 416 417 418 419 420 421 422 423 424
      (mapcar
       (function (lambda (l)
		   (if (apply 'desktop-save-buffer-p l)
		       (progn
			 (insert desktop-create-buffer-form)
			 (mapcar
			  (function (lambda (e)
				      (insert "\n  "
					      (desktop-value-to-string e))))
			  l)
			 (insert ")\n\n")))))
       info)
Richard M. Stallman's avatar
Richard M. Stallman committed
425 426 427 428
      (setq default-directory dirname)
      (if (file-exists-p filename) (delete-file filename))
      (write-region (point-min) (point-max) filename nil 'nomessage)))
  (setq desktop-dirname dirname))
429
;; ----------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
430 431 432 433 434
(defun desktop-remove ()
  "Delete the Desktop file and inactivate the desktop system."
  (interactive)
  (if desktop-dirname
      (let ((filename (concat desktop-dirname desktop-basefilename)))
435 436 437
	(setq desktop-dirname nil)
	(if (file-exists-p filename)
	    (delete-file filename)))))
438
;; ----------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
439 440 441 442 443 444 445 446 447 448 449 450
(defun desktop-read ()
  "Read the Desktop file and the files it specifies."
  (interactive)
  (let ((filename))
    (if (file-exists-p (concat "./" desktop-basefilename))
	(setq desktop-dirname (expand-file-name "./"))
      (if (file-exists-p (concat "~/" desktop-basefilename))
	  (setq desktop-dirname (expand-file-name "~/"))
	(setq desktop-dirname nil)))
    (if desktop-dirname
	(progn
	  (load (concat desktop-dirname desktop-basefilename) t t t)
451
	  (run-hooks 'desktop-delay-hook)
Richard M. Stallman's avatar
Richard M. Stallman committed
452 453
	  (message "Desktop loaded."))
      (desktop-clear))))
454
;; ----------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
455
(defun desktop-load-default ()
Richard M. Stallman's avatar
Richard M. Stallman committed
456 457 458
  "Load the `default' start-up library manually.
Also inhibit further loading of it.  Call this from your `.emacs' file
to provide correct modes for autoloaded files."
459
  (if (not inhibit-default-init)	; safety check
Richard M. Stallman's avatar
Richard M. Stallman committed
460 461 462
      (progn
	(load "default" t t)
	(setq inhibit-default-init t))))
463 464 465
;; ----------------------------------------------------------------------------
;; Note: the following functions use the dynamic variable binding in Lisp.
;;
Richard M. Stallman's avatar
Richard M. Stallman committed
466
(defun desktop-buffer-info () "Load an info file."
467
  (if (eq 'Info-mode mam)
Richard M. Stallman's avatar
Richard M. Stallman committed
468 469 470 471
      (progn
	(require 'info)
	(Info-find-node (nth 0 misc) (nth 1 misc))
	t)))
472
;; ----------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
473 474
(defun desktop-buffer-rmail () "Load an RMAIL file."
  (if (eq 'rmail-mode mam)
475
      (condition-case error
476 477 478 479
	  (progn (rmail-input fn) t)
	(file-locked
	 (kill-buffer (current-buffer))
	 'ignored))))
480
;; ----------------------------------------------------------------------------
481 482 483 484 485 486 487 488
(defun desktop-buffer-mh () "Load a folder in the mh system."
  (if (eq 'mh-folder-mode mam)
      (progn
	(require 'mh-e)
	(mh-find-path)
	(mh-visit-folder bn)
	t)))
;; ----------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
489
(defun desktop-buffer-dired () "Load a directory using dired."
Richard M. Stallman's avatar
Richard M. Stallman committed
490
  (if (eq 'dired-mode mam)
491
      (if (file-directory-p (file-name-directory (car misc)))
492 493
	  (progn
	    (dired (car misc))
494
	    (mapcar 'dired-insert-subdir (cdr misc))
495 496 497 498
	    t)
	(message "Directory %s no longer exists." (car misc))
	(sit-for 1)
	'ignored)))
499
;; ----------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
500 501 502 503
(defun desktop-buffer-file () "Load a file."
  (if fn
      (if (or (file-exists-p fn)
	      (and desktop-missing-file-warning
504 505
		   (y-or-n-p (format
			      "File \"%s\" no longer exists. Re-create? "
Richard M. Stallman's avatar
Richard M. Stallman committed
506 507 508
			      fn))))
	  (progn (find-file fn) t)
	'ignored)))
509 510
;; ----------------------------------------------------------------------------
;; Create a buffer, load its file, set is mode, ...;  called from Desktop file
Richard M. Stallman's avatar
Richard M. Stallman committed
511
;; only.
512
(defun desktop-create-buffer (ver fn bn mam mim pt mk ro misc &optional locals)
Richard M. Stallman's avatar
Richard M. Stallman committed
513 514 515 516 517 518 519
  (let ((hlist desktop-buffer-handlers)
	(result)
	(handler))
    (while (and (not result) hlist)
      (setq handler (car hlist))
      (setq result (funcall handler))
      (setq hlist (cdr hlist)))
Richard M. Stallman's avatar
Richard M. Stallman committed
520
    (if (eq result t)
Richard M. Stallman's avatar
Richard M. Stallman committed
521 522 523
	(progn
	  (if (not (equal (buffer-name) bn))
	      (rename-buffer bn))
524
	  (auto-fill-mode (if (nth 0 mim) 1 0))
Richard M. Stallman's avatar
Richard M. Stallman committed
525
	  (goto-char pt)
526 527 528 529 530 531 532
	  (if (consp mk)
	      (progn
		(set-mark (car mk))
		(setq mark-active (car (cdr mk))))
	    (set-mark mk))
	  ;; Never override file system if the file really is read-only marked.
	  (if ro (setq buffer-read-only ro))
533 534 535 536 537 538 539 540 541 542 543
	  (while locals
	    (let ((this (car locals)))
	      (if (consp this)
		  ;; an entry of this form `(symbol . value)'
		  (progn
		    (make-local-variable (car this))
		    (set (car this) (cdr this)))
		;; an entry of the form `symbol'
		(make-local-variable this)
		(makunbound this)))
	    (setq locals (cdr locals)))
Richard M. Stallman's avatar
Richard M. Stallman committed
544
	  ))))
545 546 547 548 549 550 551 552 553

;; Backward compatibility -- update parameters to 205 standards.
(defun desktop-buffer (fn bn mam mim pt mk ro tl fc cfs cr misc)
  (desktop-create-buffer 205 fn bn mam (cdr mim) pt mk ro misc
			 (list (cons 'truncate-lines tl)
			       (cons 'fill-column fc)
			       (cons 'case-fold-search cfs)
			       (cons 'case-replace cr)
			       (cons 'overwrite-mode (car mim)))))
554
;; ----------------------------------------------------------------------------
Richard M. Stallman's avatar
Richard M. Stallman committed
555
(provide 'desktop)
Richard M. Stallman's avatar
Richard M. Stallman committed
556 557

;; desktop.el ends here.