tramp-smb.el 76.7 KB
Newer Older
Michael Albinus's avatar
Michael Albinus committed
1
;;; tramp-smb.el --- Tramp access functions for SMB servers  -*- lexical-binding:t -*-
2

Paul Eggert's avatar
Paul Eggert committed
3
;; Copyright (C) 2002-2018 Free Software Foundation, Inc.
4

Michael Albinus's avatar
Michael Albinus committed
5
;; Author: Michael Albinus <michael.albinus@gmx.de>
6
;; Keywords: comm, processes
7
;; Package: tramp
8 9 10

;; This file is part of GNU Emacs.

11
;; GNU Emacs is free software: you can redistribute it and/or modify
12
;; it under the terms of the GNU General Public License as published by
13 14
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
15 16 17 18 19 20 21

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
23 24 25 26 27 28 29

;;; Commentary:

;; Access functions for SMB servers like SAMBA or M$ Windows from Tramp.

;;; Code:

30
(eval-when-compile (require 'cl-lib))
31 32 33
(require 'tramp)

;; Define SMB method ...
34 35
;;;###tramp-autoload
(defconst tramp-smb-method "smb"
36
  "Method to connect SAMBA and M$ SMB servers.")
37 38

;; ... and add it to the method list.
39 40
;;;###tramp-autoload
(unless (memq system-type '(cygwin windows-nt))
41 42 43 44 45
  (add-to-list 'tramp-methods
    `(,tramp-smb-method
      ;; We define an empty command, because `tramp-smb-call-winexe'
      ;; opens already the powershell.  Used in `tramp-handle-shell-command'.
      (tramp-remote-shell "")
Michael Albinus's avatar
Michael Albinus committed
46
      ;; This is just a guess.  We don't know whether the share "C$"
47 48
      ;; is available for public use, and whether the user has write
      ;; access.
49 50 51
      (tramp-tmpdir "/C$/Temp")
      ;; Another guess.  We might implement a better check later on.
      (tramp-case-insensitive t))))
52

53 54
;; Add a default for `tramp-default-user-alist'. Rule: For the SMB method,
;; the anonymous user is chosen.
55
;;;###tramp-autoload
56
(add-to-list 'tramp-default-user-alist
57
	     `(,(concat "\\`" tramp-smb-method "\\'") nil nil))
58 59

;; Add completion function for SMB method.
60 61 62 63 64
;;;###tramp-autoload
(eval-after-load 'tramp
  '(tramp-set-completion-function
    tramp-smb-method
    '((tramp-parse-netrc "~/.netrc"))))
65

66
;;;###tramp-autoload
67
(defcustom tramp-smb-program "smbclient"
68
  "Name of SMB client to run."
69
  :group 'tramp
Michael Albinus's avatar
Michael Albinus committed
70
  :type 'string)
71

72
;;;###tramp-autoload
73 74 75 76
(defcustom tramp-smb-acl-program "smbcacls"
  "Name of SMB acls to run."
  :group 'tramp
  :type 'string
Michael Albinus's avatar
Michael Albinus committed
77
  :version "24.4")
78

79
;;;###tramp-autoload
80
(defcustom tramp-smb-conf "/dev/null"
81
  "Path of the smb.conf file.
82 83 84
If it is nil, no smb.conf will be added to the `tramp-smb-program'
call, letting the SMB client use the default one."
  :group 'tramp
Michael Albinus's avatar
Michael Albinus committed
85
  :type '(choice (const nil) (file :must-match t)))
86

87
(defvar tramp-smb-version nil
88
  "Version string of the SMB client.")
89

Michael Albinus's avatar
Michael Albinus committed
90 91 92 93 94 95 96 97 98 99 100 101
(defconst tramp-smb-server-version
  "Domain=\\[[^]]*\\] OS=\\[[^]]*\\] Server=\\[[^]]*\\]"
  "Regexp of SMB server identification.")

(defconst tramp-smb-prompt "^\\(smb:\\|PS\\) .+> \\|^\\s-+Server\\s-+Comment$"
  "Regexp used as prompt in smbclient or powershell.")

(defconst tramp-smb-wrong-passwd-regexp
  (regexp-opt
   '("NT_STATUS_LOGON_FAILURE"
     "NT_STATUS_WRONG_PASSWORD"))
  "Regexp for login error strings of SMB servers.")
102 103 104 105

(defconst tramp-smb-errors
  (mapconcat
   'identity
106 107
   `(;; Connection error / timeout / unknown command.
     "Connection\\( to \\S-+\\)? failed"
108
     "Read from server failed, maybe it closed the connection"
109
     "Call timed out: server did not respond"
110
     "\\S-+: command not found"
111
     "Server doesn't support UNIX CIFS calls"
112 113 114 115 116 117 118 119 120 121 122
     ,(regexp-opt
       '(;; Samba.
	 "ERRDOS"
	 "ERRHRD"
	 "ERRSRV"
	 "ERRbadfile"
	 "ERRbadpw"
	 "ERRfilexists"
	 "ERRnoaccess"
	 "ERRnomem"
	 "ERRnosuchshare"
123
	 ;; See /usr/include/samba-4.0/core/ntstatus.h.
124
	 ;; Windows 4.0 (Windows NT), Windows 5.0 (Windows 2000),
125
	 ;; Windows 5.1 (Windows XP), Windows 5.2 (Windows Server 2003),
126
	 ;; Windows 6.0 (Windows Vista), Windows 6.1 (Windows 7),
127
	 ;; Windows 6.3 (Windows Server 2012, Windows 10).
128 129 130 131
	 "NT_STATUS_ACCESS_DENIED"
	 "NT_STATUS_ACCOUNT_LOCKED_OUT"
	 "NT_STATUS_BAD_NETWORK_NAME"
	 "NT_STATUS_CANNOT_DELETE"
132
	 "NT_STATUS_CONNECTION_DISCONNECTED"
133
	 "NT_STATUS_CONNECTION_REFUSED"
Michael Albinus's avatar
Michael Albinus committed
134
	 "NT_STATUS_CONNECTION_RESET"
135 136 137
	 "NT_STATUS_DIRECTORY_NOT_EMPTY"
	 "NT_STATUS_DUPLICATE_NAME"
	 "NT_STATUS_FILE_IS_A_DIRECTORY"
138
	 "NT_STATUS_HOST_UNREACHABLE"
139
	 "NT_STATUS_IMAGE_ALREADY_LOADED"
140
	 "NT_STATUS_INVALID_LEVEL"
141
	 "NT_STATUS_INVALID_PARAMETER_MIX"
142 143 144 145
	 "NT_STATUS_IO_TIMEOUT"
	 "NT_STATUS_LOGON_FAILURE"
	 "NT_STATUS_NETWORK_ACCESS_DENIED"
	 "NT_STATUS_NOT_IMPLEMENTED"
146
	 "NT_STATUS_NO_LOGON_SERVERS"
147 148 149 150 151
	 "NT_STATUS_NO_SUCH_FILE"
	 "NT_STATUS_NO_SUCH_USER"
	 "NT_STATUS_OBJECT_NAME_COLLISION"
	 "NT_STATUS_OBJECT_NAME_INVALID"
	 "NT_STATUS_OBJECT_NAME_NOT_FOUND"
152
	 "NT_STATUS_OBJECT_PATH_SYNTAX_BAD"
153
	 "NT_STATUS_PASSWORD_MUST_CHANGE"
154
	 "NT_STATUS_RESOURCE_NAME_NOT_FOUND"
155
	 "NT_STATUS_REVISION_MISMATCH"
156 157 158 159
	 "NT_STATUS_SHARING_VIOLATION"
	 "NT_STATUS_TRUSTED_RELATIONSHIP_FAILURE"
	 "NT_STATUS_UNSUCCESSFUL"
	 "NT_STATUS_WRONG_PASSWORD")))
160 161 162 163
   "\\|")
  "Regexp for possible error strings of SMB servers.
Used instead of analyzing error codes of commands.")

164 165 166 167 168 169 170 171 172 173
(defconst tramp-smb-actions-with-share
  '((tramp-smb-prompt tramp-action-succeed)
    (tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-process-alive))
  "List of pattern/action pairs.
This list is used for login to SMB servers.

See `tramp-actions-before-shell' for more info.")
174

175 176 177 178 179 180 181
(defconst tramp-smb-actions-without-share
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-out-of-band))
  "List of pattern/action pairs.
This list is used for login to SMB servers.
182

183
See `tramp-actions-before-shell' for more info.")
184

Michael Albinus's avatar
Michael Albinus committed
185 186 187 188 189 190 191 192 193 194
(defconst tramp-smb-actions-with-tar
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-smb-action-with-tar))
  "List of pattern/action pairs.
This list is used for tar-like copy of directories.

See `tramp-actions-before-shell' for more info.")

Michael Albinus's avatar
Michael Albinus committed
195
(defconst tramp-smb-actions-get-acl
196 197 198
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
Michael Albinus's avatar
Michael Albinus committed
199 200 201 202 203 204 205 206 207 208 209
    (tramp-process-alive-regexp tramp-smb-action-get-acl))
  "List of pattern/action pairs.
This list is used for smbcacls actions.

See `tramp-actions-before-shell' for more info.")

(defconst tramp-smb-actions-set-acl
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-smb-action-set-acl))
210 211 212 213 214
  "List of pattern/action pairs.
This list is used for smbcacls actions.

See `tramp-actions-before-shell' for more info.")

215
;; New handlers should be added here.
Michael Albinus's avatar
Michael Albinus committed
216
;;;###tramp-autoload
217
(defconst tramp-smb-file-name-handler-alist
Michael Albinus's avatar
Michael Albinus committed
218
  '(;; `access-file' performed by default handler.
219
    (add-name-to-file . tramp-smb-handle-add-name-to-file)
220 221
    ;; `byte-compiler-base-file-name' performed by default handler.
    (copy-directory . tramp-smb-handle-copy-directory)
222 223 224
    (copy-file . tramp-smb-handle-copy-file)
    (delete-directory . tramp-smb-handle-delete-directory)
    (delete-file . tramp-smb-handle-delete-file)
225
    ;; `diff-latest-backup-file' performed by default handler.
226
    (directory-file-name . tramp-handle-directory-file-name)
227
    (directory-files . tramp-smb-handle-directory-files)
228
    (directory-files-and-attributes
229
     . tramp-handle-directory-files-and-attributes)
230
    (dired-compress-file . ignore)
231
    (dired-uncache . tramp-handle-dired-uncache)
232
    (exec-path . ignore)
233
    (expand-file-name . tramp-smb-handle-expand-file-name)
Michael Albinus's avatar
Michael Albinus committed
234
    (file-accessible-directory-p . tramp-handle-file-accessible-directory-p)
235
    (file-acl . tramp-smb-handle-file-acl)
236
    (file-attributes . tramp-smb-handle-file-attributes)
Michael Albinus's avatar
Michael Albinus committed
237
    (file-directory-p .  tramp-handle-file-directory-p)
238
    (file-file-equal-p . tramp-handle-file-equal-p)
239 240
    (file-executable-p . tramp-handle-file-exists-p)
    (file-exists-p . tramp-handle-file-exists-p)
241
    (file-in-directory-p . tramp-handle-file-in-directory-p)
242 243 244
    (file-local-copy . tramp-smb-handle-file-local-copy)
    (file-modes . tramp-handle-file-modes)
    (file-name-all-completions . tramp-smb-handle-file-name-all-completions)
245
    (file-name-as-directory . tramp-handle-file-name-as-directory)
246
    (file-name-case-insensitive-p . tramp-handle-file-name-case-insensitive-p)
247 248 249
    (file-name-completion . tramp-handle-file-name-completion)
    (file-name-directory . tramp-handle-file-name-directory)
    (file-name-nondirectory . tramp-handle-file-name-nondirectory)
250
    ;; `file-name-sans-versions' performed by default handler.
251
    (file-newer-than-file-p . tramp-handle-file-newer-than-file-p)
252
    (file-notify-add-watch . tramp-handle-file-notify-add-watch)
Michael Albinus's avatar
Michael Albinus committed
253
    (file-notify-rm-watch . tramp-handle-file-notify-rm-watch)
254
    (file-notify-valid-p . tramp-handle-file-notify-valid-p)
255
    (file-ownership-preserved-p . ignore)
256
    (file-readable-p . tramp-handle-file-exists-p)
257
    (file-regular-p . tramp-handle-file-regular-p)
Michael Albinus's avatar
Michael Albinus committed
258
    (file-remote-p . tramp-handle-file-remote-p)
Michael Albinus's avatar
Michael Albinus committed
259
    (file-selinux-context . tramp-handle-file-selinux-context)
260
    (file-symlink-p . tramp-handle-file-symlink-p)
261
    (file-system-info . tramp-smb-handle-file-system-info)
262
    (file-truename . tramp-handle-file-truename)
263
    (file-writable-p . tramp-smb-handle-file-writable-p)
264
    (find-backup-file-name . tramp-handle-find-backup-file-name)
265 266
    ;; `find-file-noselect' performed by default handler.
    ;; `get-file-buffer' performed by default handler.
267 268 269
    (insert-directory . tramp-smb-handle-insert-directory)
    (insert-file-contents . tramp-handle-insert-file-contents)
    (load . tramp-handle-load)
270
    (make-auto-save-file-name . tramp-handle-make-auto-save-file-name)
271 272
    (make-directory . tramp-smb-handle-make-directory)
    (make-directory-internal . tramp-smb-handle-make-directory-internal)
273
    (make-nearby-temp-file . tramp-handle-make-nearby-temp-file)
274
    (make-symbolic-link . tramp-smb-handle-make-symbolic-link)
Michael Albinus's avatar
Michael Albinus committed
275
    (process-file . tramp-smb-handle-process-file)
276
    (rename-file . tramp-smb-handle-rename-file)
277
    (set-file-acl . tramp-smb-handle-set-file-acl)
278
    (set-file-modes . tramp-smb-handle-set-file-modes)
279
    (set-file-selinux-context . ignore)
280
    (set-file-times . ignore)
Michael Albinus's avatar
Michael Albinus committed
281
    (set-visited-file-modtime . tramp-handle-set-visited-file-modtime)
Michael Albinus's avatar
Michael Albinus committed
282 283
    (shell-command . tramp-handle-shell-command)
    (start-file-process . tramp-smb-handle-start-file-process)
Michael Albinus's avatar
Michael Albinus committed
284
    (substitute-in-file-name . tramp-smb-handle-substitute-in-file-name)
285
    (temporary-file-directory . tramp-handle-temporary-file-directory)
286
    (unhandled-file-name-directory . ignore)
287
    (vc-registered . ignore)
Michael Albinus's avatar
Michael Albinus committed
288 289
    (verify-visited-file-modtime . tramp-handle-verify-visited-file-modtime)
    (write-region . tramp-smb-handle-write-region))
290 291 292
  "Alist of handler functions for Tramp SMB method.
Operations not mentioned here will be handled by the default Emacs primitives.")

Michael Albinus's avatar
Michael Albinus committed
293
;; Options for remote processes via winexe.
294
;;;###tramp-autoload
Michael Albinus's avatar
Michael Albinus committed
295 296 297 298 299 300
(defcustom tramp-smb-winexe-program "winexe"
  "Name of winexe client to run.
If it isn't found in the local $PATH, the absolute path of winexe
shall be given.  This is needed for remote processes."
  :group 'tramp
  :type 'string
Michael Albinus's avatar
Michael Albinus committed
301
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
302

303
;;;###tramp-autoload
Michael Albinus's avatar
Michael Albinus committed
304 305 306 307 308
(defcustom tramp-smb-winexe-shell-command "powershell.exe"
  "Shell to be used for processes on remote machines.
This must be Powershell V2 compatible."
  :group 'tramp
  :type 'string
Michael Albinus's avatar
Michael Albinus committed
309
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
310

311
;;;###tramp-autoload
Michael Albinus's avatar
Michael Albinus committed
312 313 314 315 316
(defcustom tramp-smb-winexe-shell-command-switch "-file -"
  "Command switch used together with `tramp-smb-winexe-shell-command'.
This can be used to disable echo etc."
  :group 'tramp
  :type 'string
Michael Albinus's avatar
Michael Albinus committed
317
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
318

319 320
;; It must be a `defsubst' in order to push the whole code into
;; tramp-loaddefs.el.  Otherwise, there would be recursive autoloading.
321 322
;;;###tramp-autoload
(defsubst tramp-smb-file-name-p (filename)
323
  "Check if it's a filename for SMB servers."
Michael Albinus's avatar
Michael Albinus committed
324 325
  (string= (tramp-file-name-method (tramp-dissect-file-name filename))
	   tramp-smb-method))
326

327
;;;###tramp-autoload
328 329 330 331 332 333
(defun tramp-smb-file-name-handler (operation &rest args)
  "Invoke the SMB related OPERATION.
First arg specifies the OPERATION, second arg is a list of arguments to
pass to the OPERATION."
  (let ((fn (assoc operation tramp-smb-file-name-handler-alist)))
    (if fn
334
	(save-match-data (apply (cdr fn) args))
335 336
      (tramp-run-real-handler operation args))))

337 338
;;;###tramp-autoload
(unless (memq system-type '(cygwin windows-nt))
Michael Albinus's avatar
Michael Albinus committed
339 340
  (tramp-register-foreign-file-name-handler
   'tramp-smb-file-name-p 'tramp-smb-file-name-handler))
341

342 343
;; File name primitives.

344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359
(defun tramp-smb-handle-add-name-to-file
  (filename newname &optional ok-if-already-exists)
  "Like `add-name-to-file' for Tramp files."
  (unless (tramp-equal-remote filename newname)
    (with-parsed-tramp-file-name
	(if (tramp-tramp-file-p filename) filename newname) nil
      (tramp-error
       v 'file-error
       "add-name-to-file: %s"
       "only implemented for same method, same user, same host")))
  (with-parsed-tramp-file-name filename v1
    (with-parsed-tramp-file-name newname v2
      (when (file-directory-p filename)
	(tramp-error
	 v2 'file-error
	 "add-name-to-file: %s must not be a directory" filename))
Michael Albinus's avatar
Michael Albinus committed
360 361 362 363 364 365 366 367 368 369 370
	;; Do the 'confirm if exists' thing.
	(when (file-exists-p newname)
	  ;; What to do?
	  (if (or (null ok-if-already-exists) ; not allowed to exist
		  (and (numberp ok-if-already-exists)
		       (not (yes-or-no-p
			     (format
			      "File %s already exists; make it a link anyway? "
			      v2-localname)))))
	      (tramp-error v2 'file-already-exists newname)
	    (delete-file newname)))
371 372
      ;; We must also flush the cache of the directory, because
      ;; `file-attributes' reads the values from there.
373 374
      (tramp-flush-file-properties v2 (file-name-directory v2-localname))
      (tramp-flush-file-properties v2 v2-localname)
375 376 377 378 379 380 381 382 383 384
      (unless
	  (tramp-smb-send-command
	   v1
	   (format
	    "%s \"%s\" \"%s\""
	    (if (tramp-smb-get-cifs-capabilities v1) "link" "hardlink")
	    (tramp-smb-get-localname v1)
	    (tramp-smb-get-localname v2)))
	(tramp-error
	 v2 'file-error
385
	 "error with add-name-to-file, see buffer `%s' for details"
386
	 (buffer-name))))))
387

Michael Albinus's avatar
Michael Albinus committed
388 389
(defun tramp-smb-action-with-tar (proc vec)
  "Untar from connection buffer."
390
  (if (not (process-live-p proc))
Michael Albinus's avatar
Michael Albinus committed
391 392 393 394 395 396 397 398 399 400 401 402
      (throw 'tramp-action 'process-died)

    (with-current-buffer (tramp-get-connection-buffer vec)
      (goto-char (point-min))
      (when (search-forward-regexp tramp-smb-server-version nil t)
	;; There might be a hidden password prompt.
	(widen)
	(forward-line)
	(tramp-message vec 6 (buffer-substring (point-min) (point)))
	(delete-region (point-min) (point))
	(throw 'tramp-action 'ok)))))

403
(defun tramp-smb-handle-copy-directory
404
  (dirname newname &optional keep-date parents copy-contents)
Michael Albinus's avatar
Michael Albinus committed
405
  "Like `copy-directory' for Tramp files."
406 407 408 409 410 411 412 413 414 415 416 417
  (if copy-contents
      ;; We must do it file-wise.
      (tramp-run-real-handler
       'copy-directory (list dirname newname keep-date parents copy-contents))

    (setq dirname (expand-file-name dirname)
	  newname (expand-file-name newname))
    (let ((t1 (tramp-tramp-file-p dirname))
	  (t2 (tramp-tramp-file-p newname)))
      (with-parsed-tramp-file-name (if t1 dirname newname) nil
	(with-tramp-progress-reporter
	    v 0 (format "Copying %s to %s" dirname newname)
418
	  (when (and (file-directory-p newname)
419
		     (not (tramp-compat-directory-name-p newname)))
420
	    (tramp-error v 'file-already-exists newname))
421 422 423 424 425 426 427 428 429 430
	  (cond
	   ;; We must use a local temporary directory.
	   ((and t1 t2)
	    (let ((tmpdir
		   (make-temp-name
		    (expand-file-name
		     tramp-temp-name-prefix
		     (tramp-compat-temporary-file-directory)))))
	      (unwind-protect
		  (progn
431
		    (make-directory tmpdir)
432 433
		    (copy-directory
		     dirname (file-name-as-directory tmpdir) keep-date 'parents)
434
		    (copy-directory
435 436
		     (expand-file-name (file-name-nondirectory dirname) tmpdir)
		     newname keep-date parents))
437
		(delete-directory tmpdir 'recursive))))
438 439

	   ;; We can copy recursively.
Michael Albinus's avatar
Michael Albinus committed
440
	   ;; TODO: Does not work reliably.
Michael Albinus's avatar
Michael Albinus committed
441
	   (nil ;(and (or t1 t2) (tramp-smb-get-cifs-capabilities v))
442 443 444 445 446 447 448 449 450 451
	    (when (and (file-directory-p newname)
		       (not (string-equal (file-name-nondirectory dirname)
					  (file-name-nondirectory newname))))
	      (setq newname
		    (expand-file-name
		     (file-name-nondirectory dirname) newname))
	      (if t2 (setq v (tramp-dissect-file-name newname))))
	    (if (not (file-directory-p newname))
		(make-directory newname parents))

452
	    (let* ((share (tramp-smb-get-share v))
453
		   (localname (file-name-as-directory
454
			       (replace-regexp-in-string
455 456 457 458 459
				"\\\\" "/" (tramp-smb-get-localname v))))
		   (tmpdir    (make-temp-name
			       (expand-file-name
				tramp-temp-name-prefix
				(tramp-compat-temporary-file-directory))))
460 461 462
		   (args      (list (concat "//" host "/" share) "-E"))
		   ;; We do not want to run timers.
		   timer-list timer-idle-list)
463

464 465
	      (if (not (zerop (length user)))
		  (setq args (append args (list "-U" user)))
466 467 468 469 470 471 472 473 474 475
		(setq args (append args (list "-N"))))

	      (when domain (setq args (append args (list "-W" domain))))
	      (when port   (setq args (append args (list "-p" port))))
	      (when tramp-smb-conf
		(setq args (append args (list "-s" tramp-smb-conf))))
	      (setq args
		    (if t1
			;; Source is remote.
			(append args
476 477
				(list "-D" (tramp-unquote-shell-quote-argument
					    localname)
478 479
				      "-c" (shell-quote-argument "tar qc - *")
				      "|" "tar" "xfC" "-"
480 481
				      (tramp-unquote-shell-quote-argument
				       tmpdir)))
482 483
		      ;; Target is remote.
		      (append (list "tar" "cfC" "-"
484 485
				    (tramp-unquote-shell-quote-argument dirname)
				    "." "|")
486
			      args
487 488
			      (list "-D" (tramp-unquote-shell-quote-argument
					  localname)
489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505
				    "-c" (shell-quote-argument "tar qx -")))))

	      (unwind-protect
		  (with-temp-buffer
		    ;; Set the transfer process properties.
		    (tramp-set-connection-property
		     v "process-name" (buffer-name (current-buffer)))
		    (tramp-set-connection-property
		     v "process-buffer" (current-buffer))

		    (when t1
		      ;; The smbclient tar command creates always
		      ;; complete paths.  We must emulate the
		      ;; directory structure, and symlink to the real
		      ;; target.
		      (make-directory
		       (expand-file-name
506 507
			".." (concat tmpdir localname))
		       'parents)
508 509 510 511 512 513
		      (make-symbolic-link
		       newname (directory-file-name (concat tmpdir localname))))

		    ;; Use an asynchronous processes.  By this,
		    ;; password can be handled.
		    (let* ((default-directory tmpdir)
514 515
			   (p (apply
			       'start-process
516 517
			       (tramp-get-connection-name v)
			       (tramp-get-connection-buffer v)
518
			       tramp-smb-program args)))
519 520 521

		      (tramp-message
		       v 6 "%s" (mapconcat 'identity (process-command p) " "))
Michael Albinus's avatar
Michael Albinus committed
522
		      (process-put p 'vector v)
523
		      (process-put p 'adjust-window-size-function 'ignore)
524
		      (set-process-query-on-exit-flag p nil)
525 526
		      (tramp-process-actions p v nil tramp-smb-actions-with-tar)

527
		      (while (process-live-p p)
528 529 530 531
			(sit-for 0.1))
		      (tramp-message v 6 "\n%s" (buffer-string))))

		;; Reset the transfer process properties.
532 533
		(tramp-flush-connection-property v "process-name")
		(tramp-flush-connection-property v "process-buffer")
534
		(when t1 (delete-directory tmpdir 'recursive))))
535 536 537

	    ;; Handle KEEP-DATE argument.
	    (when keep-date
538 539 540 541
	      (set-file-times
	       newname
	       (tramp-compat-file-attribute-modification-time
		(file-attributes dirname))))
542 543 544 545 546 547 548 549

	    ;; Set the mode.
	    (unless keep-date
	      (set-file-modes newname (tramp-default-file-modes dirname)))

	    ;; When newname did exist, we have wrong cached values.
	    (when t2
	      (with-parsed-tramp-file-name newname nil
550 551
		(tramp-flush-file-properties v (file-name-directory localname))
		(tramp-flush-file-properties v localname))))
552 553 554 555 556

	   ;; We must do it file-wise.
	   (t
	    (tramp-run-real-handler
	     'copy-directory (list dirname newname keep-date parents)))))))))
557 558

(defun tramp-smb-handle-copy-file
Michael Albinus's avatar
Michael Albinus committed
559
  (filename newname &optional ok-if-already-exists keep-date
560
   _preserve-uid-gid _preserve-extended-attributes)
561
  "Like `copy-file' for Tramp files.
Michael Albinus's avatar
Michael Albinus committed
562
KEEP-DATE has no effect in case NEWNAME resides on an SMB server.
563
PRESERVE-UID-GID and PRESERVE-EXTENDED-ATTRIBUTES are completely ignored."
564 565
  (setq filename (expand-file-name filename)
	newname (expand-file-name newname))
566
  (with-tramp-progress-reporter
Michael Albinus's avatar
Michael Albinus committed
567 568
      (tramp-dissect-file-name
       (if (tramp-tramp-file-p filename) filename newname))
569 570
      0 (format "Copying %s to %s" filename newname)

Michael Albinus's avatar
Michael Albinus committed
571
    (if (file-directory-p filename)
572
	(copy-directory filename newname keep-date 'parents 'copy-contents)
Michael Albinus's avatar
Michael Albinus committed
573 574 575 576 577 578 579 580 581 582 583

      (let ((tmpfile (file-local-copy filename)))
	(if tmpfile
	    ;; Remote filename.
	    (condition-case err
		(rename-file tmpfile newname ok-if-already-exists)
	      ((error quit)
	       (delete-file tmpfile)
	       (signal (car err) (cdr err))))

	  ;; Remote newname.
584
	  (when (and (file-directory-p newname)
585
		     (tramp-compat-directory-name-p newname))
Michael Albinus's avatar
Michael Albinus committed
586 587 588 589 590 591 592 593 594 595
	    (setq newname
		  (expand-file-name (file-name-nondirectory filename) newname)))

	  (with-parsed-tramp-file-name newname nil
	    (when (and (not ok-if-already-exists)
		       (file-exists-p newname))
	      (tramp-error v 'file-already-exists newname))

	    ;; We must also flush the cache of the directory, because
	    ;; `file-attributes' reads the values from there.
596 597
	    (tramp-flush-file-properties v (file-name-directory localname))
	    (tramp-flush-file-properties v localname)
Michael Albinus's avatar
Michael Albinus committed
598 599
	    (unless (tramp-smb-get-share v)
	      (tramp-error
600
	       v 'file-error "Target `%s' must contain a share name" newname))
Michael Albinus's avatar
Michael Albinus committed
601 602
	    (unless (tramp-smb-send-command
		     v (format "put \"%s\" \"%s\""
603 604
			       (tramp-compat-file-name-unquote filename)
			       (tramp-smb-get-localname v)))
605
	      (tramp-error
606
	       v 'file-error "Cannot copy `%s' to `%s'" filename newname))))))
607

Michael Albinus's avatar
Michael Albinus committed
608 609
    ;; KEEP-DATE handling.
    (when keep-date
610 611 612 613
      (set-file-times
       newname
       (tramp-compat-file-attribute-modification-time
	(file-attributes filename))))))
614

Michael Albinus's avatar
Michael Albinus committed
615
(defun tramp-smb-handle-delete-directory (directory &optional recursive _trash)
616
  "Like `delete-directory' for Tramp files."
617
  (setq directory (directory-file-name (expand-file-name directory)))
Michael Albinus's avatar
Michael Albinus committed
618
  (when (file-exists-p directory)
619 620 621 622 623 624 625 626
    (when recursive
      (mapc
       (lambda (file)
	 (if (file-directory-p file)
	     (delete-directory file recursive)
	   (delete-file file)))
       ;; We do not want to delete "." and "..".
       (directory-files directory 'full directory-files-no-dot-files-regexp)))
627

Michael Albinus's avatar
Michael Albinus committed
628
    (with-parsed-tramp-file-name directory nil
629
      ;; We must also flush the cache of the directory, because
630
      ;; `file-attributes' reads the values from there.
631 632
      (tramp-flush-file-properties v (file-name-directory localname))
      (tramp-flush-directory-properties v localname)
633 634 635 636 637 638 639 640 641 642
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_rmdir" "rmdir")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
643 644 645 646 647 648
	   v 'file-error "%s `%s'" (match-string 0) directory)))

      ;; "rmdir" does not report an error.  So we check ourselves.
      (when (file-exists-p directory)
	(tramp-error
	 v 'file-error "`%s' not removed." directory)))))
649

650
(defun tramp-smb-handle-delete-file (filename &optional _trash)
651
  "Like `delete-file' for Tramp files."
652
  (setq filename (expand-file-name filename))
Michael Albinus's avatar
Michael Albinus committed
653 654
  (when (file-exists-p filename)
    (with-parsed-tramp-file-name filename nil
655
      ;; We must also flush the cache of the directory, because
656
      ;; `file-attributes' reads the values from there.
657 658
      (tramp-flush-file-properties v (file-name-directory localname))
      (tramp-flush-file-properties v localname)
659 660 661 662 663 664 665 666 667 668
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_unlink" "rm")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
669
	   v 'file-error "%s `%s'" (match-string 0) filename))))))
670 671 672

(defun tramp-smb-handle-directory-files
  (directory &optional full match nosort)
673 674
  "Like `directory-files' for Tramp files."
  (let ((result (mapcar 'directory-file-name
675
			(file-name-all-completions "" directory))))
676
    ;; Discriminate with regexp.
677 678 679 680 681
    (when match
      (setq result
	    (delete nil
		    (mapcar (lambda (x) (when (string-match match x) x))
			    result))))
682
    ;; Append directory.
683 684 685
    (when full
      (setq result
	    (mapcar
686
	     (lambda (x) (format "%s/%s" directory x))
687
	     result)))
688
    ;; Sort them if necessary.
689
    (unless nosort (setq result (sort result 'string-lessp)))
Michael Albinus's avatar
Michael Albinus committed
690
    result))
691

692 693 694 695 696 697 698 699 700 701 702 703 704
(defun tramp-smb-handle-expand-file-name (name &optional dir)
  "Like `expand-file-name' for Tramp files."
  ;; If DIR is not given, use DEFAULT-DIRECTORY or "/".
  (setq dir (or dir default-directory "/"))
  ;; Unless NAME is absolute, concat DIR and NAME.
  (unless (file-name-absolute-p name)
    (setq name (concat (file-name-as-directory dir) name)))
  ;; If NAME is not a Tramp file, run the real handler.
  (if (not (tramp-tramp-file-p name))
      (tramp-run-real-handler 'expand-file-name (list name nil))
    ;; Dissect NAME.
    (with-parsed-tramp-file-name name nil
      ;; Tilde expansion if necessary.  We use the user name as share,
Paul Eggert's avatar
Paul Eggert committed
705
      ;; which is often the case in domains.
706
      (when (string-match "\\`/?~\\([^/]*\\)" localname)
707 708
	(setq localname
	      (replace-match
709
	       (if (zerop (length (match-string 1 localname)))
710
		   user
711
		 (match-string 1 localname))
712
	       nil nil localname)))
713 714 715
      ;; Make the file name absolute.
      (unless (tramp-run-real-handler 'file-name-absolute-p (list localname))
	(setq localname (concat "/" localname)))
716 717 718
      ;; No tilde characters in file name, do normal
      ;; `expand-file-name' (this does "/./" and "/../").
      (tramp-make-tramp-file-name
719
       v (tramp-run-real-handler 'expand-file-name (list localname))))))
720

Michael Albinus's avatar
Michael Albinus committed
721
(defun tramp-smb-action-get-acl (proc vec)
722
  "Read ACL data from connection buffer."
723
  (unless (process-live-p proc)
724 725 726 727 728 729 730 731 732 733 734 735 736 737 738
    ;; Accept pending output.
    (while (tramp-accept-process-output proc 0.1))
    (with-current-buffer (tramp-get-connection-buffer vec)
      ;; There might be a hidden password prompt.
      (widen)
      (tramp-message vec 10 "\n%s" (buffer-string))
      (goto-char (point-min))
      (while (and (not (eobp)) (not (looking-at "^REVISION:")))
	(forward-line)
	(delete-region (point-min) (point)))
      (while (and (not (eobp)) (looking-at "^.+:.+"))
 	(forward-line))
      (delete-region (point) (point-max))
      (throw 'tramp-action 'ok))))

739 740
(defun tramp-smb-handle-file-acl (filename)
  "Like `file-acl' for Tramp files."
Michael Albinus's avatar
Michael Albinus committed
741 742 743 744 745 746 747
  (ignore-errors
    (with-parsed-tramp-file-name filename nil
      (with-tramp-file-property v localname "file-acl"
	(when (executable-find tramp-smb-acl-program)
	  (let* ((share     (tramp-smb-get-share v))
		 (localname (replace-regexp-in-string
			     "\\\\" "/" (tramp-smb-get-localname v)))
748 749 750
		 (args      (list (concat "//" host "/" share) "-E"))
		 ;; We do not want to run timers.
		 timer-list timer-idle-list)
Michael Albinus's avatar
Michael Albinus committed
751 752 753 754 755 756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782

	    (if (not (zerop (length user)))
		(setq args (append args (list "-U" user)))
	      (setq args (append args (list "-N"))))

	    (when domain (setq args (append args (list "-W" domain))))
	    (when port   (setq args (append args (list "-p" port))))
	    (when tramp-smb-conf
	      (setq args (append args (list "-s" tramp-smb-conf))))
	    (setq
	     args
	     (append args (list (tramp-unquote-shell-quote-argument localname)
				"2>/dev/null")))

	    (unwind-protect
		(with-temp-buffer
		  ;; Set the transfer process properties.
		  (tramp-set-connection-property
		   v "process-name" (buffer-name (current-buffer)))
		  (tramp-set-connection-property
		   v "process-buffer" (current-buffer))

		  ;; Use an asynchronous process.  By this, password can
		  ;; be handled.
		  (let ((p (apply
			    'start-process
			    (tramp-get-connection-name v)
			    (tramp-get-connection-buffer v)
			    tramp-smb-acl-program args)))

		    (tramp-message
		     v 6 "%s" (mapconcat 'identity (process-command p) " "))
Michael Albinus's avatar
Michael Albinus committed
783
		    (process-put p 'vector v)
Michael Albinus's avatar
Michael Albinus committed
784 785 786 787 788 789 790
		    (process-put p 'adjust-window-size-function 'ignore)
		    (set-process-query-on-exit-flag p nil)
		    (tramp-process-actions p v nil tramp-smb-actions-get-acl)
		    (when (> (point-max) (point-min))
		      (substring-no-properties (buffer-string)))))

	      ;; Reset the transfer process properties.
791 792
	      (tramp-flush-connection-property v "process-name")
	      (tramp-flush-connection-property v "process-buffer"))))))))
793

794
(defun tramp-smb-handle-file-attributes (filename &optional id-format)
795
  "Like `file-attributes' for Tramp files."
796
  (unless id-format (setq id-format 'integer))
797 798
  (ignore-errors
    (with-parsed-tramp-file-name filename nil
799 800
      (with-tramp-file-property
	  v localname (format "file-attributes-%s" id-format)
801
	(if (tramp-smb-get-stat-capability v)
802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831
	    (tramp-smb-do-file-attributes-with-stat v id-format)
	  ;; Reading just the filename entry via "dir localname" is not
	  ;; possible, because when filename is a directory, some
	  ;; smbclient versions return the content of the directory, and
	  ;; other versions don't.  Therefore, the whole content of the
	  ;; upper directory is retrieved, and the entry of the filename
	  ;; is extracted from.
	  (let* ((entries (tramp-smb-get-file-entries
			   (file-name-directory filename)))
		 (entry (assoc (file-name-nondirectory filename) entries))
		 (uid (if (equal id-format 'string) "nobody" -1))
		 (gid (if (equal id-format 'string) "nogroup" -1))
		 (inode (tramp-get-inode v))
		 (device (tramp-get-device v)))

	    ;; Check result.
	    (when entry
	      (list (and (string-match "d" (nth 1 entry))
			 t)        ;0 file type
		    -1	           ;1 link count
		    uid	           ;2 uid
		    gid	           ;3 gid
		    '(0 0)	   ;4 atime
		    (nth 3 entry)  ;5 mtime
		    '(0 0)	   ;6 ctime
		    (nth 2 entry)  ;7 size
		    (nth 1 entry)  ;8 mode
		    nil	           ;9 gid weird
		    inode	   ;10 inode number
		    device)))))))) ;11 file system number
832

833
(defun tramp-smb-do-file-attributes-with-stat (vec &optional id-format)
834
  "Implement `file-attributes' for Tramp files using stat command."
835 836
  (tramp-message
   vec 5 "file attributes with stat: %s" (tramp-file-name-localname vec))
Michael Albinus's avatar
Michael Albinus committed
837
  (with-current-buffer (tramp-get-connection-buffer vec)
838
    (let* (size id link uid gid atime mtime ctime mode inode)
839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893
      (when (tramp-smb-send-command
	     vec (format "stat \"%s\"" (tramp-smb-get-localname vec)))

	;; Loop the listing.
	(goto-char (point-min))
	(unless (re-search-forward tramp-smb-errors nil t)
	  (while (not (eobp))
	    (cond
	     ((looking-at
	       "Size:\\s-+\\([0-9]+\\)\\s-+Blocks:\\s-+[0-9]+\\s-+\\(\\w+\\)")
	      (setq size (string-to-number (match-string 1))
		    id (if (string-equal "directory" (match-string 2)) t
			 (if (string-equal "symbolic" (match-string 2)) ""))))
	     ((looking-at
	       "Inode:\\s-+\\([0-9]+\\)\\s-+Links:\\s-+\\([0-9]+\\)")
	      (setq inode (string-to-number (match-string 1))
		    link (string-to-number (match-string 2))))
	     ((looking-at
	       "Access:\\s-+([0-9]+/\\(\\S-+\\))\\s-+Uid:\\s-+\\([0-9]+\\)\\s-+Gid:\\s-+\\([0-9]+\\)")
	      (setq mode (match-string 1)
		    uid (if (equal id-format 'string) (match-string 2)
			  (string-to-number (match-string 2)))
		    gid (if (equal id-format 'string) (match-string 3)
			  (string-to-number (match-string 3)))))
	     ((looking-at
	       "Access:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq atime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Modify:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq mtime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Change:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq ctime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1)))))) ;; year
	    (forward-line))
Michael Albinus's avatar
Michael Albinus committed
894 895 896 897 898 899 900 901 902 903

	  ;; Resolve symlink.
	  (when (and (stringp id)
		     (tramp-smb-send-command
		      vec
		      (format "readlink \"%s\"" (tramp-smb-get-localname vec))))
	    (goto-char (point-min))
	    (and (looking-at ".+ -> \\(.+\\)")
		 (setq id (match-string 1))))

904
	  ;; Return the result.
905 906 907
	  (when (or id link uid gid atime mtime ctime size mode inode)
	    (list id link uid gid atime mtime ctime size mode nil inode
		  (tramp-get-device vec))))))))
908 909

(defun tramp-smb-handle-file-local-copy (filename)
910
  "Like `file-local-copy' for Tramp files."
911 912
  (with-parsed-tramp-file-name (file-truename filename) nil
    (unless (file-exists-p (file-truename filename))
913
      (tramp-error
Michael Albinus's avatar
Michael Albinus committed
914
       v tramp-file-missing
915
       "Cannot make local copy of non-existing file `%s'" filename))
916
    (let ((tmpfile (tramp-compat-make-temp-file filename)))
917
      (with-tramp-progress-reporter
918 919 920 921 922
	  v 3 (format "Fetching %s to tmp file %s" filename tmpfile)
	(unless (tramp-smb-send-command
		 v (format "get \"%s\" \"%s\""
			   (tramp-smb-get-localname v) tmpfile))
	  ;; Oops, an error.  We shall cleanup.
923
	  (delete-file tmpfile)
924
	  (tramp-error
925
	   v 'file-error "Cannot make local copy of file `%s'" filename)))
926
      tmpfile)))
927 928 929 930

;; This function should return "foo/" for directories and "bar" for
;; files.
(defun tramp-smb-handle-file-name-all-completions (filename directory)
931 932 933
  "Like `file-name-all-completions' for Tramp files."
  (all-completions
   filename
Michael Albinus's avatar
Michael Albinus committed
934
   (with-parsed-tramp-file-name (expand-file-name directory) nil
935
     (with-tramp-file-property v localname "file-name-all-completions"
936
       (save-match-data
Michael Albinus's avatar
Michael Albinus committed
937 938 939 940 941 942 943 944
	 (delete-dups
	  (mapcar
	   (lambda (x)