tramp-smb.el 36.6 KB
Newer Older
Michael Albinus's avatar
Michael Albinus committed
1
;;; tramp-smb.el --- Tramp access functions for SMB servers
2

3 4
;; Copyright (C) 2002, 2003, 2004, 2005, 2006,
;;   2007 Free Software Foundation, Inc.
5

Michael Albinus's avatar
Michael Albinus committed
6
;; Author: Michael Albinus <michael.albinus@gmx.de>
7 8 9 10 11 12
;; Keywords: comm, processes

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
13
;; the Free Software Foundation; either version 3, or (at your option)
14 15 16 17 18 19 20 21
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22 23
;; along with GNU Emacs; see the file COPYING.  If not, see
;; <http://www.gnu.org/licenses/>.
24 25 26 27 28 29 30 31

;;; Commentary:

;; Access functions for SMB servers like SAMBA or M$ Windows from Tramp.

;;; Code:

(require 'tramp)
32
(require 'tramp-cache)
33
(require 'tramp-compat)
34 35 36 37 38 39 40 41 42 43 44 45 46

;; Define SMB method ...
(defcustom tramp-smb-method "smb"
  "*Method to connect SAMBA and M$ SMB servers."
  :group 'tramp
  :type 'string)

;; ... and add it to the method list.
(add-to-list 'tramp-methods (cons tramp-smb-method nil))

;; Add a default for `tramp-default-method-alist'. Rule: If there is
;; a domain in USER, it must be the SMB method.
(add-to-list 'tramp-default-method-alist
47 48 49 50 51 52
	     `(nil "%" ,tramp-smb-method))

;; Add a default for `tramp-default-user-alist'. Rule: For the SMB method,
;; the anonymous user is chosen.
(add-to-list 'tramp-default-user-alist
	     `(,tramp-smb-method nil ""))
53 54 55 56 57 58 59 60 61 62 63

;; Add completion function for SMB method.
(tramp-set-completion-function
 tramp-smb-method
 '((tramp-parse-netrc "~/.netrc")))

(defcustom tramp-smb-program "smbclient"
  "*Name of SMB client to run."
  :group 'tramp
  :type 'string)

Michael Albinus's avatar
Michael Albinus committed
64
(defconst tramp-smb-prompt "^smb: .+> \\|^\\s-+Server\\s-+Comment$"
65 66 67
  "Regexp used as prompt in smbclient.")

(defconst tramp-smb-errors
68
  ;; `regexp-opt' not possible because of first string.
69 70
  (mapconcat
   'identity
71
   '(;; Connection error / timeout
72
     "Connection to \\S-+ failed"
73
     "Read from server failed, maybe it closed the connection"
74
     "Call timed out: server did not respond"
75
     ;; Samba
76
     "ERRDOS"
77
     "ERRSRV"
78 79 80 81 82 83
     "ERRbadfile"
     "ERRbadpw"
     "ERRfilexists"
     "ERRnoaccess"
     "ERRnomem"
     "ERRnosuchshare"
84 85
     ;; Windows 4.0 (Windows NT), Windows 5.0 (Windows 2000),
     ;; Windows 5.1 (Windows XP), Windows 5.2 (Windows Server 2003)
86
     "NT_STATUS_ACCESS_DENIED"
87
     "NT_STATUS_ACCOUNT_LOCKED_OUT"
88 89
     "NT_STATUS_BAD_NETWORK_NAME"
     "NT_STATUS_CANNOT_DELETE"
90 91 92
     "NT_STATUS_DIRECTORY_NOT_EMPTY"
     "NT_STATUS_DUPLICATE_NAME"
     "NT_STATUS_FILE_IS_A_DIRECTORY"
93
     "NT_STATUS_LOGON_FAILURE"
94
     "NT_STATUS_NETWORK_ACCESS_DENIED"
95
     "NT_STATUS_NO_SUCH_FILE"
96
     "NT_STATUS_OBJECT_NAME_COLLISION"
97 98
     "NT_STATUS_OBJECT_NAME_INVALID"
     "NT_STATUS_OBJECT_NAME_NOT_FOUND"
99
     "NT_STATUS_SHARING_VIOLATION"
100
     "NT_STATUS_TRUSTED_RELATIONSHIP_FAILURE"
101
     "NT_STATUS_WRONG_PASSWORD")
102 103 104 105
   "\\|")
  "Regexp for possible error strings of SMB servers.
Used instead of analyzing error codes of commands.")

106 107 108 109 110 111 112 113 114 115
(defconst tramp-smb-actions-with-share
  '((tramp-smb-prompt tramp-action-succeed)
    (tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-process-alive))
  "List of pattern/action pairs.
This list is used for login to SMB servers.

See `tramp-actions-before-shell' for more info.")
116

117 118 119 120 121 122 123
(defconst tramp-smb-actions-without-share
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-out-of-band))
  "List of pattern/action pairs.
This list is used for login to SMB servers.
124

125
See `tramp-actions-before-shell' for more info.")
126

127 128 129 130 131 132 133 134 135 136
;; New handlers should be added here.
(defconst tramp-smb-file-name-handler-alist
  '(
    ;; `access-file' performed by default handler
    (add-name-to-file . tramp-smb-handle-copy-file) ;; we're on Windows, honey.
    ;; `byte-compiler-base-file-name' performed by default handler
    (copy-file . tramp-smb-handle-copy-file)
    (delete-directory . tramp-smb-handle-delete-directory)
    (delete-file . tramp-smb-handle-delete-file)
    ;; `diff-latest-backup-file' performed by default handler
137
    (directory-file-name . tramp-handle-directory-file-name)
138 139
    (directory-files . tramp-smb-handle-directory-files)
    (directory-files-and-attributes . tramp-smb-handle-directory-files-and-attributes)
140 141
    (dired-call-process . ignore)
    (dired-compress-file . ignore)
142 143 144 145 146 147 148 149
    ;; `dired-uncache' performed by default handler
    ;; `expand-file-name' not necessary because we cannot expand "~/"
    (file-accessible-directory-p . tramp-smb-handle-file-directory-p)
    (file-attributes . tramp-smb-handle-file-attributes)
    (file-directory-p .  tramp-smb-handle-file-directory-p)
    (file-executable-p . tramp-smb-handle-file-exists-p)
    (file-exists-p . tramp-smb-handle-file-exists-p)
    (file-local-copy . tramp-smb-handle-file-local-copy)
150
    (file-remote-p . tramp-handle-file-remote-p)
151 152 153 154 155 156 157 158
    (file-modes . tramp-handle-file-modes)
    (file-name-all-completions . tramp-smb-handle-file-name-all-completions)
    ;; `file-name-as-directory' performed by default handler
    (file-name-completion . tramp-handle-file-name-completion)
    (file-name-directory . tramp-handle-file-name-directory)
    (file-name-nondirectory . tramp-handle-file-name-nondirectory)
    ;; `file-name-sans-versions' performed by default handler
    (file-newer-than-file-p . tramp-smb-handle-file-newer-than-file-p)
159
    (file-ownership-preserved-p . ignore)
160 161
    (file-readable-p . tramp-smb-handle-file-exists-p)
    (file-regular-p . tramp-handle-file-regular-p)
162
    (file-symlink-p . tramp-handle-file-symlink-p)
163 164
    ;; `file-truename' performed by default handler
    (file-writable-p . tramp-smb-handle-file-writable-p)
165
    (find-backup-file-name . tramp-handle-find-backup-file-name)
166 167 168 169 170 171 172
    ;; `find-file-noselect' performed by default handler
    ;; `get-file-buffer' performed by default handler
    (insert-directory . tramp-smb-handle-insert-directory)
    (insert-file-contents . tramp-handle-insert-file-contents)
    (load . tramp-handle-load)
    (make-directory . tramp-smb-handle-make-directory)
    (make-directory-internal . tramp-smb-handle-make-directory-internal)
173
    (make-symbolic-link . ignore)
174
    (rename-file . tramp-smb-handle-rename-file)
175 176 177
    (set-file-modes . ignore)
    (set-visited-file-modtime . ignore)
    (shell-command . ignore)
Michael Albinus's avatar
Michael Albinus committed
178
    (substitute-in-file-name . tramp-smb-handle-substitute-in-file-name)
179
    (unhandled-file-name-directory . tramp-handle-unhandled-file-name-directory)
180 181
    (vc-registered . ignore)
    (verify-visited-file-modtime . ignore)
182 183 184 185 186 187 188 189
    (write-region . tramp-smb-handle-write-region)
)
  "Alist of handler functions for Tramp SMB method.
Operations not mentioned here will be handled by the default Emacs primitives.")

(defun tramp-smb-file-name-p (filename)
  "Check if it's a filename for SMB servers."
  (let ((v (tramp-dissect-file-name filename)))
190
    (string= (tramp-file-name-method v) tramp-smb-method)))
191 192 193 194 195 196 197

(defun tramp-smb-file-name-handler (operation &rest args)
  "Invoke the SMB related OPERATION.
First arg specifies the OPERATION, second arg is a list of arguments to
pass to the OPERATION."
  (let ((fn (assoc operation tramp-smb-file-name-handler-alist)))
    (if fn
198
	(save-match-data (apply (cdr fn) args))
199 200 201 202 203 204 205 206 207
      (tramp-run-real-handler operation args))))

(add-to-list 'tramp-foreign-file-name-handler-alist
	     (cons 'tramp-smb-file-name-p 'tramp-smb-file-name-handler))


;; File name primitives

(defun tramp-smb-handle-copy-file
208
  (filename newname &optional ok-if-already-exists keep-date preserve-uid-gid)
209
  "Like `copy-file' for Tramp files.
210 211
KEEP-DATE is not handled in case NEWNAME resides on an SMB server.
PRESERVE-UID-GID is completely ignored."
212 213 214 215 216 217
  (setq filename (expand-file-name filename)
	newname (expand-file-name newname))

  (let ((tmpfile (file-local-copy filename)))

    (if tmpfile
218
	;; Remote filename.
219 220
	(rename-file tmpfile newname ok-if-already-exists)

221
      ;; Remote newname.
222 223 224 225
      (when (file-directory-p newname)
	(setq newname (expand-file-name
		       (file-name-nondirectory filename) newname)))

Michael Albinus's avatar
Michael Albinus committed
226
      (with-parsed-tramp-file-name newname nil
227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245
	(when (and (not ok-if-already-exists)
		   (file-exists-p newname))
	  (tramp-error v 'file-already-exists newname))

	;; We must also flush the cache of the directory, because
	;; file-attributes reads the values from there.
	(tramp-flush-file-property v (file-name-directory localname))
	(tramp-flush-file-property v localname)
	(let ((share (tramp-smb-get-share localname))
	      (file (tramp-smb-get-localname localname t)))
	  (unless share
	    (tramp-error
	     v 'file-error "Target `%s' must contain a share name" newname))
	  (tramp-message v 0 "Copying file %s to file %s..." filename newname)
	  (if (tramp-smb-send-command
	       v (format "put %s \"%s\"" filename file))
	      (tramp-message
	       v 0 "Copying file %s to file %s...done" filename newname)
	    (tramp-error v 'file-error "Cannot copy `%s'" filename)))))))
246 247

(defun tramp-smb-handle-delete-directory (directory)
248
  "Like `delete-directory' for Tramp files."
249
  (setq directory (directory-file-name (expand-file-name directory)))
Michael Albinus's avatar
Michael Albinus committed
250 251
  (when (file-exists-p directory)
    (with-parsed-tramp-file-name directory nil
252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269
      ;; We must also flush the cache of the directory, because
      ;; file-attributes reads the values from there.
      (tramp-flush-file-property v (file-name-directory localname))
      (tramp-flush-directory-property v localname)
      (let ((dir (tramp-smb-get-localname (file-name-directory localname) t))
	    (file (file-name-nondirectory localname)))
	(unwind-protect
	    (unless (and
		     (tramp-smb-send-command v (format "cd \"%s\"" dir))
		     (tramp-smb-send-command v (format "rmdir \"%s\"" file)))
	      ;; Error
	      (with-current-buffer (tramp-get-connection-buffer v)
		(goto-char (point-min))
		(search-forward-regexp tramp-smb-errors nil t)
		(tramp-error
		 v 'file-error "%s `%s'" (match-string 0) directory)))
	  ;; Always go home
	  (tramp-smb-send-command v (format "cd \\")))))))
270 271

(defun tramp-smb-handle-delete-file (filename)
272
  "Like `delete-file' for Tramp files."
273
  (setq filename (expand-file-name filename))
Michael Albinus's avatar
Michael Albinus committed
274 275
  (when (file-exists-p filename)
    (with-parsed-tramp-file-name filename nil
276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293
      ;; We must also flush the cache of the directory, because
      ;; file-attributes reads the values from there.
      (tramp-flush-file-property v (file-name-directory localname))
      (tramp-flush-file-property v localname)
      (let ((dir (tramp-smb-get-localname (file-name-directory localname) t))
	    (file (file-name-nondirectory localname)))
	(unwind-protect
	    (unless (and
		     (tramp-smb-send-command v (format "cd \"%s\"" dir))
		     (tramp-smb-send-command v (format "rm \"%s\"" file)))
	      ;; Error
	      (with-current-buffer (tramp-get-connection-buffer v)
		(goto-char (point-min))
		(search-forward-regexp tramp-smb-errors nil t)
		(tramp-error
		 v 'file-error "%s `%s'" (match-string 0) filename)))
	  ;; Always go home
	  (tramp-smb-send-command v (format "cd \\")))))))
294 295 296

(defun tramp-smb-handle-directory-files
  (directory &optional full match nosort)
297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315
  "Like `directory-files' for Tramp files."
  (let ((result (mapcar 'directory-file-name
			(file-name-all-completions "" directory))))
    ;; Discriminate with regexp
    (when match
      (setq result
	    (delete nil
		    (mapcar (lambda (x) (when (string-match match x) x))
			    result))))
    ;; Append directory
    (when full
      (setq result
	    (mapcar
	     (lambda (x) (expand-file-name x directory))
	     result)))
    ;; Sort them if necessary
    (unless nosort (setq result (sort result 'string-lessp)))
    ;; That's it
    result))
316 317

(defun tramp-smb-handle-directory-files-and-attributes
318
  (directory &optional full match nosort id-format)
319
  "Like `directory-files-and-attributes' for Tramp files."
320 321
  (mapcar
   (lambda (x)
322
     ;; We cannot call `file-attributes' for backward compatibility reasons.
Michael Albinus's avatar
Michael Albinus committed
323
     ;; Its optional parameter ID-FORMAT is introduced with Emacs 22.
324
     (cons x (tramp-smb-handle-file-attributes
325
	(if full x (expand-file-name x directory)) id-format)))
326
   (directory-files directory full match nosort)))
327

328
(defun tramp-smb-handle-file-attributes (filename &optional id-format)
329 330 331 332 333 334
  "Like `file-attributes' for Tramp files."
  ;; Reading just the filename entry via "dir localname" is not
  ;; possible, because when filename is a directory, some smbclient
  ;; versions return the content of the directory, and other versions
  ;; don't.  Therefore, the whole content of the upper directory is
  ;; retrieved, and the entry of the filename is extracted from.
Michael Albinus's avatar
Michael Albinus committed
335
  (with-parsed-tramp-file-name filename nil
336 337 338
    (with-file-property v localname (format "file-attributes-%s" id-format)
      (let* ((entries (tramp-smb-get-file-entries
		       (file-name-directory filename)))
339
	     (entry (and entries
340
			 (assoc (file-name-nondirectory filename) entries)))
341 342
	     (uid (if (and id-format (equal id-format 'string)) "nobody" -1))
	     (gid (if (and id-format (equal id-format 'string)) "nogroup" -1))
343
	     (inode (tramp-get-inode v))
344
	     (device (tramp-get-device v)))
345

346
        ;; Check result.
347 348
	(when entry
	  (list (and (string-match "d" (nth 1 entry))
349 350 351 352 353 354 355 356 357 358 359 360
		     t)       ;0 file type
		-1	      ;1 link count
		uid	      ;2 uid
		gid	      ;3 gid
		'(0 0)	      ;4 atime
		(nth 3 entry) ;5 mtime
		'(0 0)	      ;6 ctime
		(nth 2 entry) ;7 size
		(nth 1 entry) ;8 mode
		nil	      ;9 gid weird
		inode	      ;10 inode number
		device))))))  ;11 file system number
361 362

(defun tramp-smb-handle-file-directory-p (filename)
363 364 365
  "Like `file-directory-p' for Tramp files."
  (and (file-exists-p filename)
       (eq ?d (aref (nth 8 (file-attributes filename)) 0))))
366 367

(defun tramp-smb-handle-file-exists-p (filename)
368 369
  "Like `file-exists-p' for Tramp files."
  (not (null (file-attributes filename))))
370 371

(defun tramp-smb-handle-file-local-copy (filename)
372
  "Like `file-local-copy' for Tramp files."
373
  (with-parsed-tramp-file-name filename nil
374
    (let ((file (tramp-smb-get-localname localname t))
375
	  (tmpfile (tramp-compat-make-temp-file filename)))
376 377 378 379
      (unless (file-exists-p filename)
	(tramp-error
	 v 'file-error
	 "Cannot make local copy of non-existing file `%s'" filename))
380 381
      (tramp-message v 4 "Fetching %s to tmp file %s..." filename tmpfile)
      (if (tramp-smb-send-command v (format "get \"%s\" %s" file tmpfile))
382
	  (tramp-message
383
	   v 4 "Fetching %s to tmp file %s...done" filename tmpfile)
384 385 386
	(tramp-error
	 v 'file-error
	 "Cannot make local copy of file `%s'" filename))
387
      tmpfile)))
388 389 390 391

;; This function should return "foo/" for directories and "bar" for
;; files.
(defun tramp-smb-handle-file-name-all-completions (filename directory)
392 393 394 395 396 397 398
  "Like `file-name-all-completions' for Tramp files."
  (all-completions
   filename
   (with-parsed-tramp-file-name directory nil
     (with-file-property v localname "file-name-all-completions"
       (save-match-data
	 (let ((entries (tramp-smb-get-file-entries directory)))
399 400 401 402 403 404 405 406 407
	   (mapcar
	    (lambda (x)
	      (list
	       (if (string-match "d" (nth 1 x))
		   (file-name-as-directory (nth 0 x))
		 (nth 0 x))))
	    entries)))))))

(defun tramp-smb-handle-file-newer-than-file-p (file1 file2)
408
  "Like `file-newer-than-file-p' for Tramp files."
409 410 411
  (cond
   ((not (file-exists-p file1)) nil)
   ((not (file-exists-p file2)) t)
412 413
   (t (tramp-time-less-p (nth 5 (file-attributes file2))
			 (nth 5 (file-attributes file1))))))
414 415

(defun tramp-smb-handle-file-writable-p (filename)
416 417 418 419 420 421
  "Like `file-writable-p' for Tramp files."
  (if (file-exists-p filename)
      (string-match "w" (or (nth 8 (file-attributes filename)) ""))
    (let ((dir (file-name-directory filename)))
      (and (file-exists-p dir)
	   (file-writable-p dir)))))
422 423 424

(defun tramp-smb-handle-insert-directory
  (filename switches &optional wildcard full-directory-p)
425
  "Like `insert-directory' for Tramp files."
426
  (setq filename (expand-file-name filename))
427 428
  (when full-directory-p
    ;; Called from `dired-add-entry'.
429
    (setq filename (file-name-as-directory filename)))
Michael Albinus's avatar
Michael Albinus committed
430
  (with-parsed-tramp-file-name filename nil
431
    (tramp-flush-file-property v (file-name-directory localname))
432
    (save-match-data
433 434 435 436 437 438 439 440 441 442 443 444 445 446 447
      (let ((base (file-name-nondirectory filename))
	    ;; We should not destroy the cache entry.
	    (entries (copy-sequence
		      (tramp-smb-get-file-entries
		       (file-name-directory filename)))))

	(when wildcard
	  (string-match "\\." base)
	  (setq base (replace-match "\\\\." nil nil base))
	  (string-match "\\*" base)
	  (setq base (replace-match ".*" nil nil base))
	  (string-match "\\?" base)
	  (setq base (replace-match ".?" nil nil base)))

	;; Filter entries.
448
	(setq entries
449 450 451 452 453 454 455 456 457 458 459 460
	      (delq
	       nil
	       (if (or wildcard (zerop (length base)))
		   ;; Check for matching entries.
		   (mapcar
		    (lambda (x)
		      (when (string-match
			     (format "^%s" base) (nth 0 x))
			x))
		    entries)
		 ;; We just need the only and only entry FILENAME.
		 (list (assoc base entries)))))
461 462 463 464 465 466 467

	;; Sort entries
	(setq entries
	      (sort
	       entries
	       (lambda (x y)
		 (if (string-match "t" switches)
468 469 470
		     ;; Sort by date.
		     (tramp-time-less-p (nth 3 y) (nth 3 x))
		   ;; Sort by name.
471 472
		   (string-lessp (nth 0 x) (nth 0 y))))))

473
	;; Print entries.
474 475
	(mapcar
	 (lambda (x)
476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493
	   (when (not (zerop (length (nth 0 x))))
	     (insert
	      (format
	       "%10s %3d %-8s %-8s %8s %s %s\n"
	       (nth 1 x) ; mode
	       1 "nobody" "nogroup"
	       (nth 2 x) ; size
	       (format-time-string
		(if (tramp-time-less-p
		     (tramp-time-subtract (current-time) (nth 3 x))
		     tramp-half-a-year)
		    "%b %e %R"
		  "%b %e  %Y")
		(nth 3 x)) ; date
	       (nth 0 x))) ; file name
	     (forward-line)
	     (beginning-of-line)))
	   entries)))))
494 495

(defun tramp-smb-handle-make-directory (dir &optional parents)
496
  "Like `make-directory' for Tramp files."
497 498
  (setq dir (directory-file-name (expand-file-name dir)))
  (unless (file-name-absolute-p dir)
499
    (setq dir (expand-file-name dir default-directory)))
Michael Albinus's avatar
Michael Albinus committed
500
  (with-parsed-tramp-file-name dir nil
501
    (save-match-data
Kai Großjohann's avatar
Kai Großjohann committed
502
      (let* ((share (tramp-smb-get-share localname))
503 504 505 506 507 508
	     (ldir (file-name-directory dir)))
	;; Make missing directory parts
	(when (and parents share (not (file-directory-p ldir)))
	  (make-directory ldir parents))
	;; Just do it
	(when (file-directory-p ldir)
509
	  (make-directory-internal dir))
510
	(unless (file-directory-p dir)
511
	  (tramp-error v 'file-error "Couldn't make directory %s" dir))))))
512 513

(defun tramp-smb-handle-make-directory-internal (directory)
514
  "Like `make-directory-internal' for Tramp files."
515 516
  (setq directory (directory-file-name (expand-file-name directory)))
  (unless (file-name-absolute-p directory)
517
    (setq directory (expand-file-name directory default-directory)))
Michael Albinus's avatar
Michael Albinus committed
518
  (with-parsed-tramp-file-name directory nil
519
    (save-match-data
520
      (let* ((file (tramp-smb-get-localname localname t)))
521
	(when (file-directory-p (file-name-directory directory))
522 523 524 525
	  (tramp-smb-send-command v (format "mkdir \"%s\"" file))
	  ;; We must also flush the cache of the directory, because
	  ;; file-attributes reads the values from there.
	  (tramp-flush-file-property v (file-name-directory localname)))
526
	(unless (file-directory-p directory)
527 528
	  (tramp-error
	   v 'file-error "Couldn't make directory %s" directory))))))
529 530 531

(defun tramp-smb-handle-rename-file
  (filename newname &optional ok-if-already-exists)
532
  "Like `rename-file' for Tramp files."
533 534 535 536 537 538 539 540 541 542 543 544 545 546
  (setq filename (expand-file-name filename)
	newname (expand-file-name newname))

  (let ((tmpfile (file-local-copy filename)))

    (if tmpfile
	;; remote filename
	(rename-file tmpfile newname ok-if-already-exists)

      ;; remote newname
      (when (file-directory-p newname)
	(setq newname (expand-file-name
		      (file-name-nondirectory filename) newname)))

Michael Albinus's avatar
Michael Albinus committed
547
      (with-parsed-tramp-file-name newname nil
548 549 550 551 552 553 554 555 556 557 558 559 560
	(when (and (not ok-if-already-exists)
		   (file-exists-p newname))
	  (tramp-error v 'file-already-exists newname))
	;; We must also flush the cache of the directory, because
	;; file-attributes reads the values from there.
	(tramp-flush-file-property v (file-name-directory localname))
	(tramp-flush-file-property v localname)
	(let ((file (tramp-smb-get-localname localname t)))
	  (tramp-message v 0 "Copying file %s to file %s..." filename newname)
	  (if (tramp-smb-send-command v (format "put %s \"%s\"" filename file))
	      (tramp-message
	       v 0 "Copying file %s to file %s...done" filename newname)
	    (tramp-error v 'file-error "Cannot rename `%s'" filename))))))
561 562 563

  (delete-file filename))

Michael Albinus's avatar
Michael Albinus committed
564
(defun tramp-smb-handle-substitute-in-file-name (filename)
565
  "Like `handle-substitute-in-file-name' for Tramp files.
566 567 568 569 570 571 572 573
\"//\" substitutes only in the local filename part.  Catches
errors for shares like \"C$/\", which are common in Microsoft Windows."
  (with-parsed-tramp-file-name filename nil
    ;; Ignore in LOCALNAME everything before "//".
    (when (and (stringp localname) (string-match ".+?/\\(/\\|~\\)" localname))
      (setq filename
	    (concat (file-remote-p filename)
		    (replace-match "\\1" nil nil localname)))))
Michael Albinus's avatar
Michael Albinus committed
574 575 576 577
  (condition-case nil
      (tramp-run-real-handler 'substitute-in-file-name (list filename))
    (error filename)))

578 579
(defun tramp-smb-handle-write-region
  (start end filename &optional append visit lockname confirm)
580
  "Like `write-region' for Tramp files."
581
  (setq filename (expand-file-name filename))
Michael Albinus's avatar
Michael Albinus committed
582
  (with-parsed-tramp-file-name filename nil
583 584
    (unless (eq append nil)
      (tramp-error
585
	 v 'file-error "Cannot append to file using Tramp (`%s')" filename))
586
    ;; XEmacs takes a coding system as the seventh argument, not `confirm'.
587 588 589 590 591 592
    (when (and (not (featurep 'xemacs))
	       confirm (file-exists-p filename))
      (unless (y-or-n-p (format "File %s exists; overwrite anyway? "
				filename))
	(tramp-error v 'file-error "File not overwritten")))
    ;; We must also flush the cache of the directory, because
593
    ;; `file-attributes' reads the values from there.
594 595 596 597
    (tramp-flush-file-property v (file-name-directory localname))
    (tramp-flush-file-property v localname)
    (let ((file (tramp-smb-get-localname localname t))
	  (curbuf (current-buffer))
598
	  (tmpfile (tramp-compat-make-temp-file filename)))
599 600 601 602 603 604
      ;; We say `no-message' here because we don't want the visited file
      ;; modtime data to be clobbered from the temp file.  We call
      ;; `set-visited-file-modtime' ourselves later on.
      (tramp-run-real-handler
       'write-region
       (if confirm ; don't pass this arg unless defined for backward compat.
605 606
	   (list start end tmpfile append 'no-message lockname confirm)
	 (list start end tmpfile append 'no-message lockname)))
607

608 609
      (tramp-message v 5 "Writing tmp file %s to file %s..." tmpfile filename)
      (if (tramp-smb-send-command v (format "put %s \"%s\"" tmpfile file))
610
	  (tramp-message
611
	   v 5 "Writing tmp file %s to file %s...done" tmpfile filename)
612 613
	(tramp-error v 'file-error "Cannot write `%s'" filename))

614
      (delete-file tmpfile)
615 616 617 618 619 620
      (unless (equal curbuf (current-buffer))
	(tramp-error
	 v 'file-error
	 "Buffer has changed from `%s' to `%s'" curbuf (current-buffer)))
      (when (eq visit t)
	(set-visited-file-modtime)))))
621 622 623 624


;; Internal file name functions

Kai Großjohann's avatar
Kai Großjohann committed
625 626
(defun tramp-smb-get-share (localname)
  "Returns the share name of LOCALNAME."
627
  (save-match-data
Kai Großjohann's avatar
Kai Großjohann committed
628 629
    (when (string-match "^/?\\([^/]+\\)/" localname)
      (match-string 1 localname))))
630

Kai Großjohann's avatar
Kai Großjohann committed
631 632
(defun tramp-smb-get-localname (localname convert)
  "Returns the file name of LOCALNAME.
633 634
If CONVERT is non-nil exchange \"/\" by \"\\\\\"."
  (save-match-data
Kai Großjohann's avatar
Kai Großjohann committed
635
    (let ((res localname))
636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655

      (setq
       res (if (string-match "^/?[^/]+/\\(.*\\)" res)
	       (if convert
		   (mapconcat
		    (lambda (x) (if (equal x ?/) "\\" (char-to-string x)))
		    (match-string 1 res) "")
		 (match-string 1 res))
	     (if (string-match "^/?\\([^/]+\\)$" res)
		 (match-string 1 res)
	       "")))

      ;; Sometimes we have discarded `substitute-in-file-name'
      (when (string-match "\\(\\$\\$\\)\\(/\\|$\\)" res)
	(setq res (replace-match "$" nil nil res 1)))

      res)))

;; Share names of a host are cached. It is very unlikely that the
;; shares do change during connection.
656 657
(defun tramp-smb-get-file-entries (directory)
  "Read entries which match DIRECTORY.
658
Either the shares are listed, or the `dir' command is executed.
Kai Großjohann's avatar
Kai Großjohann committed
659
Result is a list of (LOCALNAME MODE SIZE MONTH DAY TIME YEAR)."
660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689
  (with-parsed-tramp-file-name directory nil
    (setq localname (or localname "/"))
    (with-file-property v localname "file-entries"
      (with-current-buffer (tramp-get-buffer v)
	(let* ((share (tramp-smb-get-share localname))
	       (file (tramp-smb-get-localname localname nil))
	       (cache (tramp-get-connection-property v "share-cache" nil))
	       res entry)

	  (if (and (not share) cache)
	      ;; Return cached shares
	      (setq res cache)

	    ;; Read entries
	    (setq file (file-name-as-directory file))
	    (when (string-match "^\\./" file)
	      (setq file (substring file 1)))
	    (if share
		(tramp-smb-send-command v (format "dir \"%s*\"" file))
	      ;; `tramp-smb-maybe-open-connection' lists also the share names
	      (tramp-smb-maybe-open-connection v))

	    ;; Loop the listing
	    (goto-char (point-min))
	    (unless (re-search-forward tramp-smb-errors nil t)
	      (while (not (eobp))
		(setq entry (tramp-smb-read-file-entry share))
		(forward-line)
		(when entry (add-to-list 'res entry))))

690
	    ;; Cache share entries
691 692
	    (unless share
	      (tramp-set-connection-property v "share-cache" res)))
693

694 695
	  ;; Add directory itself
	  (add-to-list 'res '("" "drwxrwxrwx" 0 (0 0)))
696

697 698 699
	  ;; There's a very strange error (debugged with XEmacs 21.4.14)
	  ;; If there's no short delay, it returns nil.  No idea about.
	  (when (featurep 'xemacs) (sleep-for 0.01))
700

701 702
	  ;; Return entries
	  (delq nil res))))))
703 704 705 706 707 708 709 710 711 712 713 714 715 716 717

;; Return either a share name (if SHARE is nil), or a file name
;;
;; If shares are listed, the following format is expected
;;
;; \s-\{8,8}                              - leading spaces
;; \S-\(.*\S-\)\s-*                       - share name, 14 char
;; \s-                                    - space delimeter
;; \S-+\s-*                               - type, 8 char, "Disk    " expected
;; \(\s-\{2,2\}.*\)?                      - space delimeter, comment
;;
;; Entries provided by smbclient DIR aren't fully regular.
;; They should have the format
;;
;; \s-\{2,2}                              - leading spaces
718 719
;; \S-\(.*\S-\)\s-*                       - file name, 30 chars, left bound
;; \s-+[ADHRSV]*                          - permissions, 7 chars, right bound
720
;; \s-                                    - space delimeter
721
;; \s-+[0-9]+                             - size, 8 chars, right bound
722 723 724
;; \s-\{2,2\}                             - space delimeter
;; \w\{3,3\}                              - weekday
;; \s-                                    - space delimeter
725 726
;; \w\{3,3\}                              - month
;; \s-                                    - space delimeter
727
;; [ 12][0-9]                             - day
728 729 730 731 732
;; \s-                                    - space delimeter
;; [0-9]\{2,2\}:[0-9]\{2,2\}:[0-9]\{2,2\} - time
;; \s-                                    - space delimeter
;; [0-9]\{4,4\}                           - year
;;
733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749
;; samba/src/client.c (http://samba.org/doxygen/samba/client_8c-source.html)
;; has function display_finfo:
;;
;;   d_printf("  %-30s%7.7s %8.0f  %s",
;;            finfo->name,
;;            attrib_string(finfo->mode),
;;            (double)finfo->size,
;;            asctime(LocalTime(&t)));
;;
;; in Samba 1.9, there's the following code:
;;
;;   DEBUG(0,("  %-30s%7.7s%10d  %s",
;;  	   CNV_LANG(finfo->name),
;;	   attrib_string(finfo->mode),
;;	   finfo->size,
;;	   asctime(LocalTime(&t))));
;;
750 751 752 753 754 755 756 757 758 759 760
;; Problems:
;; * Modern regexp constructs, like spy groups and counted repetitions, aren't
;;   available in older Emacsen.
;; * The length of constructs (file name, size) might exceed the default.
;; * File names might contain spaces.
;; * Permissions might be empty.
;;
;; So we try to analyze backwards.
(defun tramp-smb-read-file-entry (share)
  "Parse entry in SMB output buffer.
If SHARE is result, entries are of type dir. Otherwise, shares are listed.
Kai Großjohann's avatar
Kai Großjohann committed
761
Result is the list (LOCALNAME MODE SIZE MTIME)."
762 763
;; We are called from `tramp-smb-get-file-entries', which sets the
;; current buffer.
764
  (let ((line (buffer-substring (point) (tramp-compat-line-end-position)))
Kai Großjohann's avatar
Kai Großjohann committed
765
	localname mode size month day hour min sec year mtime)
766 767 768

    (if (not share)

769 770
	;; Read share entries.
	(when (string-match "^\\s-+\\(\\S-\\(.*\\S-\\)?\\)\\s-+Disk" line)
Kai Großjohann's avatar
Kai Großjohann committed
771
	  (setq localname (match-string 1 line)
772 773 774
		mode "dr-xr-xr-x"
		size 0))

775
      ;; Real listing.
776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810
      (block nil

	;; year
	(if (string-match "\\([0-9]+\\)$" line)
	    (setq year (string-to-number (match-string 1 line))
		  line (substring line 0 -5))
	  (return))

	;; time
	(if (string-match "\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)$" line)
	    (setq hour (string-to-number (match-string 1 line))
		  min  (string-to-number (match-string 2 line))
		  sec  (string-to-number (match-string 3 line))
		  line (substring line 0 -9))
	  (return))

	;; day
	(if (string-match "\\([0-9]+\\)$" line)
	    (setq day  (string-to-number (match-string 1 line))
		  line (substring line 0 -3))
	  (return))

	;; month
	(if (string-match "\\(\\w+\\)$" line)
	    (setq month (match-string 1 line)
		  line  (substring line 0 -4))
	  (return))

	;; weekday
	(if (string-match "\\(\\w+\\)$" line)
	    (setq line (substring line 0 -5))
	  (return))

	;; size
	(if (string-match "\\([0-9]+\\)$" line)
811 812 813 814 815
	    (let ((length (- (max 10 (1+ (length (match-string 1 line)))))))
	      (setq size (string-to-number (match-string 1 line)))
	      (when (string-match "\\([ADHRSV]+\\)" (substring line length))
		(setq length (+ length (match-end 0))))
	      (setq line (substring line 0 length)))
816 817
	  (return))

818 819
	;; mode: ARCH, DIR, HIDDEN, RONLY, SYSTEM, VOLID
	(if (string-match "\\([ADHRSV]+\\)?$" line)
820
	    (setq
821
	     mode (or (match-string 1 line) "")
822 823 824 825 826 827
	     mode (save-match-data (format
		    "%s%s"
		    (if (string-match "D" mode) "d" "-")
		    (mapconcat
		     (lambda (x) "") "    "
		     (concat "r" (if (string-match "R" mode) "-" "w") "x"))))
828
	     line (substring line 0 -7))
829 830
	  (return))

Kai Großjohann's avatar
Kai Großjohann committed
831
	;; localname
832
	(if (string-match "^\\s-+\\(\\S-\\(.*\\S-\\)?\\)\\s-*$" line)
Kai Großjohann's avatar
Kai Großjohann committed
833
	    (setq localname (match-string 1 line))
834 835
	  (return))))

Kai Großjohann's avatar
Kai Großjohann committed
836
    (when (and localname mode size)
837 838 839 840
      (setq mtime
	    (if (and sec min hour day month year)
		(encode-time
		 sec min hour day
841
		 (cdr (assoc (downcase month) tramp-parse-time-months))
842 843
		 year)
	      '(0 0)))
Kai Großjohann's avatar
Kai Großjohann committed
844
      (list localname mode size mtime))))
845 846 847 848


;; Connection functions

849 850 851 852 853 854 855 856 857 858
(defun tramp-smb-send-command (vec command)
  "Send the COMMAND to connection VEC.
Returns nil if there has been an error message from smbclient."
  (tramp-smb-maybe-open-connection vec)
  (tramp-message vec 6 "%s" command)
  (tramp-send-string vec command)
  (tramp-smb-wait-for-output vec))

(defun tramp-smb-maybe-open-connection (vec)
  "Maybe open a connection to HOST, log in as USER, using `tramp-smb-program'.
859 860
Does not do anything if a connection is already open, but re-opens the
connection if a previous connection has died for some reason."
861 862 863
  (let* ((share (tramp-smb-get-share (tramp-file-name-localname vec)))
	 (buf (tramp-get-buffer vec))
	 (p (get-buffer-process buf)))
Michael Albinus's avatar
Michael Albinus committed
864

865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891
    ;; If too much time has passed since last command was sent, look
    ;; whether has been an error message; maybe due to connection timeout.
    (with-current-buffer buf
      (goto-char (point-min))
      (when (and (> (tramp-time-diff
		     (current-time)
		     (tramp-get-connection-property
		      p "last-cmd-time" '(0 0 0)))
		    60)
		 p (processp p) (memq (process-status p) '(run open))
		 (re-search-forward tramp-smb-errors nil t))
	(delete-process p)
	(setq p nil)))

    ;; Check whether it is still the same share.
    (unless
	(and p (processp p) (memq (process-status p) '(run open))
	     (string-equal
	      share
	      (tramp-get-connection-property p "smb-share" "")))

      (save-match-data
	;; There might be unread output from checking for share names.
	(when buf (with-current-buffer buf (erase-buffer)))
	(when (and p (processp p)) (delete-process p))

	(unless (let ((default-directory
892
			(tramp-compat-temporary-file-directory)))
893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925 926 927 928 929 930
		  (executable-find tramp-smb-program))
	  (error "Cannot find command %s in %s" tramp-smb-program exec-path))

	(let* ((user (tramp-file-name-user vec))
	       (host (tramp-file-name-host vec))
	       (real-user user)
	       (real-host host)
	       domain port args)

	  ;; Check for domain ("user%domain") and port ("host#port").
	  (when (and user (string-match "\\(.+\\)%\\(.+\\)" user))
	    (setq real-user (or (match-string 1 user) user)
		  domain (match-string 2 user)))

	  (when (and host (string-match "\\(.+\\)#\\(.+\\)" host))
	    (setq real-host (or (match-string 1 host) host)
		  port (match-string 2 host)))

	  (if share
	      (setq args (list (concat "//" real-host "/" share)))
	    (setq args (list "-L" real-host )))

	  (if (not (zerop (length real-user)))
	      (setq args (append args (list "-U" real-user)))
	    (setq args (append args (list "-N"))))

	  (when domain (setq args (append args (list "-W" domain))))
	  (when port   (setq args (append args (list "-p" port))))
	  (setq args (append args (list "-s" "/dev/null")))

	  ;; OK, let's go.
	  (tramp-message
	   vec 3 "Opening connection for //%s%s/%s..."
	   (if (not (zerop (length user))) (concat user "@") "")
	   host (or share ""))

	  (let* ((coding-system-for-read nil)
		 (process-connection-type tramp-process-connection-type)
931 932
		 (p (let ((default-directory
			    (tramp-compat-temporary-file-directory)))
933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962
		      (apply #'start-process
			     (tramp-buffer-name vec) (tramp-get-buffer vec)
			     tramp-smb-program args))))

	    (tramp-message
	     vec 6 "%s" (mapconcat 'identity (process-command p) " "))
	    (set-process-sentinel p 'tramp-flush-connection-property)
	    (tramp-set-process-query-on-exit-flag p nil)
	    (tramp-set-connection-property p "smb-share" share)

	    ;; Set variables for computing the prompt for reading password.
	    (setq tramp-current-method tramp-smb-method
		  tramp-current-user user
		  tramp-current-host host)

	    ;; Set chunksize.  Otherwise, `tramp-send-string' might
	    ;; try it itself.
	    (tramp-set-connection-property p "chunksize" tramp-chunksize)

	    ;; Play login scenario.
	    (tramp-process-actions
	     p vec
	     (if share
		 tramp-smb-actions-with-share
	       tramp-smb-actions-without-share))

	    (tramp-message
	     vec 3 "Opening connection for //%s%s/%s...done"
	     (if (not (zerop (length user))) (concat user "@") "")
	     host (or share ""))))))))
963 964

;; We don't use timeouts.  If needed, the caller shall wrap around.
965
(defun tramp-smb-wait-for-output (vec)
966 967
  "Wait for output from smbclient command.
Returns nil if an error message has appeared."
968 969 970 971 972 973
  (with-current-buffer (tramp-get-buffer vec)
    (let ((p (get-buffer-process (current-buffer)))
	  (found (progn (goto-char (point-min))
			(re-search-forward tramp-smb-prompt nil t)))
	  (err   (progn (goto-char (point-min))
			(re-search-forward tramp-smb-errors nil t))))
974

975 976 977 978
      ;; Algorithm: get waiting output.  See if last line contains
      ;; tramp-smb-prompt sentinel or tramp-smb-errors strings.
      ;; If not, wait a bit and again get waiting output.
      (while (and (not found) (not err))
979

980 981
	;; Accept pending output.
	(tramp-accept-process-output p)
982

983 984 985
	;; Search for prompt.
	(goto-char (point-min))
	(setq found (re-search-forward tramp-smb-prompt nil t))
986

987 988 989
	;; Search for errors.
	(goto-char (point-min))
	(setq err (re-search-forward tramp-smb-errors nil t)))
990

991 992
      ;; When the process is still alive, read pending output.
      (while (and (not found) (memq (process-status p) '(run open)))
993

994 995
	;; Accept pending output.
	(tramp-accept-process-output p)
996

997 998 999
	;; Search for prompt.
	(goto-char (point-min))
	(setq found (re-search-forward tramp-smb-prompt nil t)))
1000

1001 1002 1003
      ;; Return value is whether no error message has appeared.
      (tramp-message vec 6 "\n%s" (buffer-string))
      (not err))))
1004 1005 1006 1007 1008 1009 1010 1011 1012 1013 1014 1015 1016 1017 1018


(provide 'tramp-smb)

;;; TODO:

;; * Error handling in case password is wrong.
;; * Read password from "~/.netrc".
;; * Return more comprehensive file permission string.  Think whether it is
;;   possible to implement `set-file-modes'.
;; * Handle links (FILENAME.LNK).
;; * Try to remove the inclusion of dummy "" directory.  Seems to be at
;;   several places, especially in `tramp-smb-handle-insert-directory'.
;; * (RMS) Use unwind-protect to clean up the state so as to make the state
;;   regular again.
1019
;; * Make it multi-hop capable.
1020

Miles Bader's avatar
Miles Bader committed
1021
;;; arch-tag: fcc9dbec-7503-4d73-b638-3c8aa59575f5
1022
;;; tramp-smb.el ends here