subr.el 32.9 KB
Newer Older
Eric S. Raymond's avatar
Eric S. Raymond committed
1
;;; subr.el --- basic lisp subroutines for Emacs
Eric S. Raymond's avatar
Eric S. Raymond committed
2

Erik Naggum's avatar
Erik Naggum committed
3
;; Copyright (C) 1985, 1986, 1992, 1994, 1995 Free Software Foundation, Inc.
David Lawrence's avatar
David Lawrence committed
4 5 6 7 8

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
Jim Blandy's avatar
Jim Blandy committed
9
;; the Free Software Foundation; either version 2, or (at your option)
David Lawrence's avatar
David Lawrence committed
10 11 12 13 14 15 16 17
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
Erik Naggum's avatar
Erik Naggum committed
18 19 20
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.
David Lawrence's avatar
David Lawrence committed
21

Eric S. Raymond's avatar
Eric S. Raymond committed
22
;;; Code:
David Lawrence's avatar
David Lawrence committed
23

24 25 26 27 28 29 30 31

;;;; Lisp language features.

(defmacro lambda (&rest cdr)
  "Return a lambda expression.
A call of the form (lambda ARGS DOCSTRING INTERACTIVE BODY) is
self-quoting; the result of evaluating the lambda expression is the
expression itself.  The lambda expression may then be treated as a
Richard M. Stallman's avatar
Richard M. Stallman committed
32 33 34
function, i.e., stored as the function value of a symbol, passed to
funcall or mapcar, etc.

35
ARGS should take the same form as an argument list for a `defun'.
Richard M. Stallman's avatar
Richard M. Stallman committed
36 37 38
DOCSTRING is an optional documentation string.
 If present, it should describe how to call the function.
 But documentation strings are usually not useful in nameless functions.
39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58
INTERACTIVE should be a call to the function `interactive', which see.
It may also be omitted.
BODY should be a list of lisp expressions."
  ;; Note that this definition should not use backquotes; subr.el should not
  ;; depend on backquote.el.
  (list 'function (cons 'lambda cdr)))

;;(defmacro defun-inline (name args &rest body)
;;  "Create an \"inline defun\" (actually a macro).
;;Use just like `defun'."
;;  (nconc (list 'defmacro name '(&rest args))
;;	 (if (stringp (car body))
;;	     (prog1 (list (car body))
;;	       (setq body (or (cdr body) body))))
;;	 (list (list 'cons (list 'quote
;;				 (cons 'lambda (cons args body)))
;;		     'args))))


;;;; Keymap support.
David Lawrence's avatar
David Lawrence committed
59 60 61 62 63 64 65 66 67 68 69 70 71

(defun undefined ()
  (interactive)
  (ding))

;Prevent the \{...} documentation construct
;from mentioning keys that run this command.
(put 'undefined 'suppress-keymap t)

(defun suppress-keymap (map &optional nodigits)
  "Make MAP override all normally self-inserting keys to be undefined.
Normally, as an exception, digits and minus-sign are set to make prefix args,
but optional second arg NODIGITS non-nil treats them like other chars."
72
  (substitute-key-definition 'self-insert-command 'undefined map global-map)
David Lawrence's avatar
David Lawrence committed
73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90
  (or nodigits
      (let (loop)
	(define-key map "-" 'negative-argument)
	;; Make plain numbers do numeric args.
	(setq loop ?0)
	(while (<= loop ?9)
	  (define-key map (char-to-string loop) 'digit-argument)
	  (setq loop (1+ loop))))))

;Moved to keymap.c
;(defun copy-keymap (keymap)
;  "Return a copy of KEYMAP"  
;  (while (not (keymapp keymap))
;    (setq keymap (signal 'wrong-type-argument (list 'keymapp keymap))))
;  (if (vectorp keymap)
;      (copy-sequence keymap)
;      (copy-alist keymap)))

91 92 93
(defvar key-substitution-in-progress nil
 "Used internally by substitute-key-definition.")

Richard M. Stallman's avatar
Richard M. Stallman committed
94
(defun substitute-key-definition (olddef newdef keymap &optional oldmap prefix)
David Lawrence's avatar
David Lawrence committed
95 96
  "Replace OLDDEF with NEWDEF for any keys in KEYMAP now defined as OLDDEF.
In other words, OLDDEF is replaced with NEWDEF where ever it appears.
Richard M. Stallman's avatar
Richard M. Stallman committed
97 98 99 100 101
If optional fourth argument OLDMAP is specified, we redefine
in KEYMAP as NEWDEF those chars which are defined as OLDDEF in OLDMAP."
  (or prefix (setq prefix ""))
  (let* ((scan (or oldmap keymap))
	 (vec1 (vector nil))
102 103 104
	 (prefix1 (vconcat prefix vec1))
	 (key-substitution-in-progress
	  (cons scan key-substitution-in-progress)))
Richard M. Stallman's avatar
Richard M. Stallman committed
105 106 107 108 109 110 111 112 113 114
    ;; Scan OLDMAP, finding each char or event-symbol that
    ;; has any definition, and act on it with hack-key.
    (while (consp scan)
      (if (consp (car scan))
	  (let ((char (car (car scan)))
		(defn (cdr (car scan))))
	    ;; The inside of this let duplicates exactly
	    ;; the inside of the following let that handles array elements.
	    (aset vec1 0 char)
	    (aset prefix1 (length prefix) char)
115
	    (let (inner-def skipped)
Richard M. Stallman's avatar
Richard M. Stallman committed
116 117
	      ;; Skip past menu-prompt.
	      (while (stringp (car-safe defn))
118
		(setq skipped (cons (car defn) skipped))
Richard M. Stallman's avatar
Richard M. Stallman committed
119
		(setq defn (cdr defn)))
120 121 122
	      ;; Skip past cached key-equivalence data for menu items.
	      (and (consp defn) (consp (car defn))
		   (setq defn (cdr defn)))
Richard M. Stallman's avatar
Richard M. Stallman committed
123
	      (setq inner-def defn)
124
	      ;; Look past a symbol that names a keymap.
Richard M. Stallman's avatar
Richard M. Stallman committed
125 126 127 128
	      (while (and (symbolp inner-def)
			  (fboundp inner-def))
		(setq inner-def (symbol-function inner-def)))
	      (if (eq defn olddef)
129
		  (define-key keymap prefix1 (nconc (nreverse skipped) newdef))
130
		(if (and (keymapp defn)
131 132
			 ;; Avoid recursively scanning
			 ;; where KEYMAP does not have a submap.
133 134 135
			 (let ((elt (lookup-key keymap prefix1)))
			   (or (null elt)
			       (keymapp elt)))
136
			 ;; Avoid recursively rescanning keymap being scanned.
137 138
			 (not (memq inner-def
				    key-substitution-in-progress)))
139 140
		    ;; If this one isn't being scanned already,
		    ;; scan it now.
Richard M. Stallman's avatar
Richard M. Stallman committed
141 142 143 144 145 146 147 148 149 150 151 152 153
		    (substitute-key-definition olddef newdef keymap
					       inner-def
					       prefix1)))))
	(if (arrayp (car scan))
	    (let* ((array (car scan))
		   (len (length array))
		   (i 0))
	      (while (< i len)
		(let ((char i) (defn (aref array i)))
		  ;; The inside of this let duplicates exactly
		  ;; the inside of the previous let.
		  (aset vec1 0 char)
		  (aset prefix1 (length prefix) char)
154
		  (let (inner-def skipped)
Richard M. Stallman's avatar
Richard M. Stallman committed
155 156
		    ;; Skip past menu-prompt.
		    (while (stringp (car-safe defn))
157
		      (setq skipped (cons (car defn) skipped))
Richard M. Stallman's avatar
Richard M. Stallman committed
158
		      (setq defn (cdr defn)))
159 160
		    (and (consp defn) (consp (car defn))
			 (setq defn (cdr defn)))
Richard M. Stallman's avatar
Richard M. Stallman committed
161 162 163 164 165
		    (setq inner-def defn)
		    (while (and (symbolp inner-def)
				(fboundp inner-def))
		      (setq inner-def (symbol-function inner-def)))
		    (if (eq defn olddef)
166 167
			(define-key keymap prefix1
			  (nconc (nreverse skipped) newdef))
168
		      (if (and (keymapp defn)
169 170 171
			       (let ((elt (lookup-key keymap prefix1)))
				 (or (null elt)
				     (keymapp elt)))
172 173
			       (not (memq inner-def
					  key-substitution-in-progress)))
Richard M. Stallman's avatar
Richard M. Stallman committed
174 175 176 177 178
			  (substitute-key-definition olddef newdef keymap
						     inner-def
						     prefix1)))))
		(setq i (1+ i))))))
      (setq scan (cdr scan)))))
179

180
(defun define-key-after (keymap key definition after)
181 182 183 184
  "Add binding in KEYMAP for KEY => DEFINITION, right after AFTER's binding.
This is like `define-key' except that the binding for KEY is placed
just after the binding for the event AFTER, instead of at the beginning
of the map.
185
The order matters when the keymap is used as a menu.
186 187
KEY must contain just one event type--that is to say, it must be
a string or vector of length 1."
188 189
  (or (keymapp keymap)
      (signal 'wrong-type-argument (list 'keymapp keymap)))
190
  (if (> (length key) 1)
191
      (error "multi-event key specified in `define-key-after'"))
192
  (let ((tail keymap) done inserted
193 194 195 196 197 198 199
	(first (aref key 0)))
    (while (and (not done) tail)
      ;; Delete any earlier bindings for the same key.
      (if (eq (car-safe (car (cdr tail))) first)
	  (setcdr tail (cdr (cdr tail))))
      ;; When we reach AFTER's binding, insert the new binding after.
      ;; If we reach an inherited keymap, insert just before that.
200
      ;; If we reach the end of this keymap, insert at the end.
201
      (if (or (eq (car-safe (car tail)) after)
202 203
	      (eq (car (cdr tail)) 'keymap)
	      (null (cdr tail)))
204
	  (progn
205 206 207 208 209 210 211 212 213
	    ;; Stop the scan only if we find a parent keymap.
	    ;; Keep going past the inserted element
	    ;; so we can delete any duplications that come later.
	    (if (eq (car (cdr tail)) 'keymap)
		(setq done t))
	    ;; Don't insert more than once.
	    (or inserted
		(setcdr tail (cons (cons (aref key 0) definition) (cdr tail))))
	    (setq inserted t)))
214 215
      (setq tail (cdr tail)))))

216 217
(put 'keyboard-translate-table 'char-table-extra-slots 0)

218 219 220 221
(defun keyboard-translate (from to)
  "Translate character FROM to TO at a low level.
This function creates a `keyboard-translate-table' if necessary
and then modifies one entry in it."
222 223 224
  (or (char-table-p keyboard-translate-table)
      (setq keyboard-translate-table
	    (make-char-table 'keyboard-translate-table nil)))
225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247
  (aset keyboard-translate-table from to))


;;;; The global keymap tree.  

;;; global-map, esc-map, and ctl-x-map have their values set up in
;;; keymap.c; we just give them docstrings here.

(defvar global-map nil
  "Default global keymap mapping Emacs keyboard input into commands.
The value is a keymap which is usually (but not necessarily) Emacs's
global map.")

(defvar esc-map nil
  "Default keymap for ESC (meta) commands.
The normal global definition of the character ESC indirects to this keymap.")

(defvar ctl-x-map nil
  "Default keymap for C-x commands.
The normal global definition of the character C-x indirects to this keymap.")

(defvar ctl-x-4-map (make-sparse-keymap)
  "Keymap for subcommands of C-x 4")
248
(defalias 'ctl-x-4-prefix ctl-x-4-map)
249 250 251 252
(define-key ctl-x-map "4" 'ctl-x-4-prefix)

(defvar ctl-x-5-map (make-sparse-keymap)
  "Keymap for frame commands.")
253
(defalias 'ctl-x-5-prefix ctl-x-5-map)
254 255
(define-key ctl-x-map "5" 'ctl-x-5-prefix)

256

257 258
;;;; Event manipulation functions.

259 260 261 262
;; The call to `read' is to ensure that the value is computed at load time
;; and not compiled into the .elc file.  The value is negative on most
;; machines, but not on all!
(defconst listify-key-sequence-1 (logior 128 (read "?\\M-\\^@")))
263

264 265 266 267 268 269
(defun listify-key-sequence (key)
  "Convert a key sequence to a list of events."
  (if (vectorp key)
      (append key nil)
    (mapcar (function (lambda (c)
			(if (> c 127)
270
			    (logxor c listify-key-sequence-1)
271 272 273
			  c)))
	    (append key nil))))

274 275 276 277 278 279 280 281 282 283 284 285
(defsubst eventp (obj)
  "True if the argument is an event object."
  (or (integerp obj)
      (and (symbolp obj)
	   (get obj 'event-symbol-elements))
      (and (consp obj)
	   (symbolp (car obj))
	   (get (car obj) 'event-symbol-elements))))

(defun event-modifiers (event)
  "Returns a list of symbols representing the modifier keys in event EVENT.
The elements of the list may include `meta', `control',
286 287
`shift', `hyper', `super', `alt', `click', `double', `triple', `drag',
and `down'."
288 289 290 291 292 293
  (let ((type event))
    (if (listp type)
	(setq type (car type)))
    (if (symbolp type)
	(cdr (get type 'event-symbol-elements))
      (let ((list nil))
294
	(or (zerop (logand type ?\M-\^@))
295
	    (setq list (cons 'meta list)))
296
	(or (and (zerop (logand type ?\C-\^@))
297 298
		 (>= (logand type 127) 32))
	    (setq list (cons 'control list)))
299
	(or (and (zerop (logand type ?\S-\^@))
300 301
		 (= (logand type 255) (downcase (logand type 255))))
	    (setq list (cons 'shift list)))
302
	(or (zerop (logand type ?\H-\^@))
303
	    (setq list (cons 'hyper list)))
304
	(or (zerop (logand type ?\s-\^@))
305
	    (setq list (cons 'super list)))
306
	(or (zerop (logand type ?\A-\^@))
307 308 309
	    (setq list (cons 'alt list)))
	list))))

310 311 312
(defun event-basic-type (event)
  "Returns the basic type of the given event (all modifiers removed).
The value is an ASCII printing character (not upper case) or a symbol."
313 314
  (if (consp event)
      (setq event (car event)))
315 316 317 318 319
  (if (symbolp event)
      (car (get event 'event-symbol-elements))
    (let ((base (logand event (1- (lsh 1 18)))))
      (downcase (if (< base 32) (logior base 64) base)))))

320 321 322 323 324 325 326 327 328 329 330
(defsubst mouse-movement-p (object)
  "Return non-nil if OBJECT is a mouse movement event."
  (and (consp object)
       (eq (car object) 'mouse-movement)))

(defsubst event-start (event)
  "Return the starting position of EVENT.
If EVENT is a mouse press or a mouse click, this returns the location
of the event.
If EVENT is a drag, this returns the drag's starting position.
The return value is of the form
331
   (WINDOW BUFFER-POSITION (X . Y) TIMESTAMP)
332 333 334 335 336 337 338
The `posn-' functions access elements of such lists."
  (nth 1 event))

(defsubst event-end (event)
  "Return the ending location of EVENT.  EVENT should be a click or drag event.
If EVENT is a click event, this function is the same as `event-start'.
The return value is of the form
339
   (WINDOW BUFFER-POSITION (X . Y) TIMESTAMP)
340
The `posn-' functions access elements of such lists."
341
  (nth (if (consp (nth 2 event)) 2 1) event))
342

343 344 345 346 347
(defsubst event-click-count (event)
  "Return the multi-click count of EVENT, a click or drag event.
The return value is a positive integer."
  (if (integerp (nth 2 event)) (nth 2 event) 1))

348 349 350
(defsubst posn-window (position)
  "Return the window in POSITION.
POSITION should be a list of the form
351
   (WINDOW BUFFER-POSITION (X . Y) TIMESTAMP)
352 353 354 355 356 357
as returned by the `event-start' and `event-end' functions."
  (nth 0 position))

(defsubst posn-point (position)
  "Return the buffer location in POSITION.
POSITION should be a list of the form
358
   (WINDOW BUFFER-POSITION (X . Y) TIMESTAMP)
359
as returned by the `event-start' and `event-end' functions."
360 361 362
  (if (consp (nth 1 position))
      (car (nth 1 position))
    (nth 1 position)))
363

364 365
(defsubst posn-x-y (position)
  "Return the x and y coordinates in POSITION.
366
POSITION should be a list of the form
367
   (WINDOW BUFFER-POSITION (X . Y) TIMESTAMP)
368 369 370
as returned by the `event-start' and `event-end' functions."
  (nth 2 position))

371
(defun posn-col-row (position)
372
  "Return the column and row in POSITION, measured in characters.
373 374
POSITION should be a list of the form
   (WINDOW BUFFER-POSITION (X . Y) TIMESTAMP)
375 376 377 378 379
as returned by the `event-start' and `event-end' functions.
For a scroll-bar event, the result column is 0, and the row
corresponds to the vertical position of the click in the scroll bar."
  (let ((pair   (nth 2 position))
	(window (posn-window position)))
380 381 382
    (if (eq (if (consp (nth 1 position))
		(car (nth 1 position))
	      (nth 1 position))
383 384
	    'vertical-scroll-bar)
	(cons 0 (scroll-bar-scale pair (1- (window-height window))))
385 386 387
      (if (eq (if (consp (nth 1 position))
		  (car (nth 1 position))
		(nth 1 position))
388 389
	      'horizontal-scroll-bar)
	  (cons (scroll-bar-scale pair (window-width window)) 0)
390 391 392
	(let* ((frame (if (framep window) window (window-frame window)))
	       (x (/ (car pair) (frame-char-width frame)))
	       (y (/ (cdr pair) (frame-char-height frame))))
393
	  (cons x y))))))
394

395 396 397
(defsubst posn-timestamp (position)
  "Return the timestamp of POSITION.
POSITION should be a list of the form
398
   (WINDOW BUFFER-POSITION (X . Y) TIMESTAMP)
399
as returned by the `event-start' and `event-end' functions."
400
  (nth 3 position))
401

David Lawrence's avatar
David Lawrence committed
402

403 404
;;;; Obsolescent names for functions.

405 406 407 408 409 410 411 412 413 414 415 416 417
(defalias 'dot 'point)
(defalias 'dot-marker 'point-marker)
(defalias 'dot-min 'point-min)
(defalias 'dot-max 'point-max)
(defalias 'window-dot 'window-point)
(defalias 'set-window-dot 'set-window-point)
(defalias 'read-input 'read-string)
(defalias 'send-string 'process-send-string)
(defalias 'send-region 'process-send-region)
(defalias 'show-buffer 'set-window-buffer)
(defalias 'buffer-flush-undo 'buffer-disable-undo)
(defalias 'eval-current-buffer 'eval-buffer)
(defalias 'compiled-function-p 'byte-code-function-p)
David Lawrence's avatar
David Lawrence committed
418

419 420
;; Some programs still use this as a function.
(defun baud-rate ()
Richard M. Stallman's avatar
Richard M. Stallman committed
421 422
  "Obsolete function returning the value of the `baud-rate' variable.
Please convert your programs to use the variable `baud-rate' directly."
423 424
  baud-rate)

425 426
(defalias 'focus-frame 'ignore)
(defalias 'unfocus-frame 'ignore)
427 428 429

;;;; Alternate names for functions - these are not being phased out.

430 431 432 433 434 435 436
(defalias 'string= 'string-equal)
(defalias 'string< 'string-lessp)
(defalias 'move-marker 'set-marker)
(defalias 'eql 'eq)
(defalias 'not 'null)
(defalias 'rplaca 'setcar)
(defalias 'rplacd 'setcdr)
437
(defalias 'beep 'ding) ;preserve lingual purity
438 439 440 441 442
(defalias 'indent-to-column 'indent-to)
(defalias 'backward-delete-char 'delete-backward-char)
(defalias 'search-forward-regexp (symbol-function 're-search-forward))
(defalias 'search-backward-regexp (symbol-function 're-search-backward))
(defalias 'int-to-string 'number-to-string)
443
(defalias 'set-match-data 'store-match-data)
444 445 446

;;; Should this be an obsolete name?  If you decide it should, you get
;;; to go through all the sources and change them.
447
(defalias 'string-to-int 'string-to-number)
David Lawrence's avatar
David Lawrence committed
448

449
;;;; Hook manipulation functions.
David Lawrence's avatar
David Lawrence committed
450

451 452
;; We used to have this variable so that C code knew how to run hooks.  That
;; calling convention is made obsolete now the hook running functions are in C.
David Lawrence's avatar
David Lawrence committed
453 454
(defconst run-hooks 'run-hooks
  "Variable by which C primitives find the function `run-hooks'.
455
Don't change it.  Don't use it either; use the hook running C primitives.")
David Lawrence's avatar
David Lawrence committed
456

457 458 459 460 461 462 463
(defun make-local-hook (hook)
  "Make the hook HOOK local to the current buffer.
When a hook is local, its local and global values
work in concert: running the hook actually runs all the hook
functions listed in *either* the local value *or* the global value
of the hook variable.

464 465 466 467 468 469 470 471 472
This function works by making `t' a member of the buffer-local value,
which acts as a flag to run the hook functions in the default value as
well.  This works for all normal hooks, but does not work for most
non-normal hooks yet.  We will be changing the callers of non-normal
hooks so that they can handle localness; this has to be done one by
one.

This function does nothing if HOOK is already local in the current
buffer.
473 474 475 476 477 478 479 480 481

Do not use `make-local-variable' to make a hook variable buffer-local."
  (if (local-variable-p hook)
      nil
    (or (boundp hook) (set hook nil))
    (make-local-variable hook)
    (set hook (list t))))

(defun add-hook (hook function &optional append local)
482 483 484 485 486 487
  "Add to the value of HOOK the function FUNCTION.
FUNCTION is not added if already present.
FUNCTION is added (if necessary) at the beginning of the hook list
unless the optional argument APPEND is non-nil, in which case
FUNCTION is added at the end.

488 489 490 491 492 493
The optional fourth argument, LOCAL, if non-nil, says to modify
the hook's buffer-local value rather than its default value.
This makes no difference if the hook is not buffer-local.
To make a hook variable buffer-local, always use
`make-local-hook', not `make-local-variable'.

494 495
HOOK should be a symbol, and FUNCTION may be any valid function.  If
HOOK is void, it is first set to nil.  If HOOK's value is a single
496
function, it is changed to a list of functions."
David Lawrence's avatar
David Lawrence committed
497
  (or (boundp hook) (set hook nil))
498
  (or (default-boundp hook) (set-default hook nil))
499 500 501 502
  ;; If the hook value is a single function, turn it into a list.
  (let ((old (symbol-value hook)))
    (if (or (not (listp old)) (eq (car old) 'lambda))
	(set hook (list old))))
503 504 505
  (if (or local
	  ;; Detect the case where make-local-variable was used on a hook
	  ;; and do what we used to do.
506
	  (and (local-variable-if-set-p hook)
507
	       (not (memq t (symbol-value hook)))))
508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526
      ;; Alter the local value only.
      (or (if (consp function)
	      (member function (symbol-value hook))
	    (memq function (symbol-value hook)))
	  (set hook 
	       (if append
		   (append (symbol-value hook) (list function))
		 (cons function (symbol-value hook)))))
    ;; Alter the global value (which is also the only value,
    ;; if the hook doesn't have a local value).
    (or (if (consp function)
	    (member function (default-value hook))
	  (memq function (default-value hook)))
	(set-default hook 
		     (if append
			 (append (default-value hook) (list function))
		       (cons function (default-value hook)))))))

(defun remove-hook (hook function &optional local)
527 528 529
  "Remove from the value of HOOK the function FUNCTION.
HOOK should be a symbol, and FUNCTION may be any valid function.  If
FUNCTION isn't the value of HOOK, or, if FUNCTION doesn't appear in the
530 531 532 533 534 535 536
list of hooks to run in HOOK, then nothing is done.  See `add-hook'.

The optional third argument, LOCAL, if non-nil, says to modify
the hook's buffer-local value rather than its default value.
This makes no difference if the hook is not buffer-local.
To make a hook variable buffer-local, always use
`make-local-hook', not `make-local-variable'."
537
  (if (or (not (boundp hook))		;unbound symbol, or
538
	  (not (default-boundp 'hook))
539 540 541
	  (null (symbol-value hook))	;value is nil, or
	  (null function))		;function is nil, then
      nil				;Do nothing.
542 543 544 545 546
    (if (or local
	    ;; Detect the case where make-local-variable was used on a hook
	    ;; and do what we used to do.
	    (and (local-variable-p hook)
		 (not (memq t (symbol-value hook)))))
547 548 549 550 551 552 553 554 555 556 557 558 559 560
	(let ((hook-value (symbol-value hook)))
	  (if (consp hook-value)
	      (if (member function hook-value)
		  (setq hook-value (delete function (copy-sequence hook-value))))
	    (if (equal hook-value function)
		(setq hook-value nil)))
	  (set hook hook-value))
      (let ((hook-value (default-value hook)))
	(if (consp hook-value)
	    (if (member function hook-value)
		(setq hook-value (delete function (copy-sequence hook-value))))
	  (if (equal hook-value function)
	      (setq hook-value nil)))
	(set-default hook hook-value)))))
561 562

(defun add-to-list (list-var element)
Richard M. Stallman's avatar
Richard M. Stallman committed
563
  "Add to the value of LIST-VAR the element ELEMENT if it isn't there yet.
Karl Heuer's avatar
Karl Heuer committed
564
The test for presence of ELEMENT is done with `equal'.
Richard M. Stallman's avatar
Richard M. Stallman committed
565 566 567 568 569
If you want to use `add-to-list' on a variable that is not defined
until a certain package is loaded, you should put the call to `add-to-list'
into a hook function that will be run only after loading the package.
`eval-after-load' provides one way to do this.  In some cases
other hooks, such as major mode hooks, can do the job."
570 571
  (or (member element (symbol-value list-var))
      (set list-var (cons element (symbol-value list-var)))))
David Lawrence's avatar
David Lawrence committed
572

573 574 575 576 577
;;;; Specifying things to do after certain files are loaded.

(defun eval-after-load (file form)
  "Arrange that, if FILE is ever loaded, FORM will be run at that time.
This makes or adds to an entry on `after-load-alist'.
578
If FILE is already loaded, evaluate FORM right now.
579
It does nothing if FORM is already on the list for FILE.
580
FILE should be the name of a library, with no directory name."
581
  ;; Make sure there is an element for FILE.
582 583
  (or (assoc file after-load-alist)
      (setq after-load-alist (cons (list file) after-load-alist)))
584
  ;; Add FORM to the element if it isn't there.
585 586
  (let ((elt (assoc file after-load-alist)))
    (or (member form (cdr elt))
587 588 589 590 591
	(progn
	  (nconc elt (list form))
	  ;; If the file has been loaded already, run FORM right away.
	  (and (assoc file load-history)
	       (eval form)))))
592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607
  form)

(defun eval-next-after-load (file)
  "Read the following input sexp, and run it whenever FILE is loaded.
This makes or adds to an entry on `after-load-alist'.
FILE should be the name of a library, with no directory name."
  (eval-after-load file (read)))


;;;; Input and display facilities.

(defun read-quoted-char (&optional prompt)
  "Like `read-char', except that if the first character read is an octal
digit, we read up to two more octal digits and return the character
represented by the octal number consisting of those digits.
Optional argument PROMPT specifies a string to use to prompt the user."
608
  (let ((message-log-max nil) (count 0) (code 0) char)
609 610
    (while (< count 3)
      (let ((inhibit-quit (zerop count))
611 612 613 614 615
	    ;; Don't let C-h get the help message--only help function keys.
	    (help-char nil)
	    (help-form
	     "Type the special character you want to use,
or three octal digits representing its character code."))
616 617 618 619 620 621 622
	(and prompt (message "%s-" prompt))
	(setq char (read-char))
	(if inhibit-quit (setq quit-flag nil)))
      (cond ((null char))
	    ((and (<= ?0 char) (<= char ?7))
	     (setq code (+ (* code 8) (- char ?0))
		   count (1+ count))
623
	     (and prompt (setq prompt (message "%s %c" prompt char))))
624 625 626
	    ((> count 0)
	     (setq unread-command-events (list char) count 259))
	    (t (setq code char count 259))))
627
    ;; Turn a meta-character into a character with the 0200 bit set.
628
    (logior (if (/= (logand code ?\M-\^@) 0) 128 0)
629
	    (logand 255 code))))
630 631 632

(defun force-mode-line-update (&optional all)
  "Force the mode-line of the current buffer to be redisplayed.
633
With optional non-nil ALL, force redisplay of all mode-lines."
634 635 636
  (if all (save-excursion (set-buffer (other-buffer))))
  (set-buffer-modified-p (buffer-modified-p)))

David Lawrence's avatar
David Lawrence committed
637 638 639 640 641 642 643 644 645
(defun momentary-string-display (string pos &optional exit-char message) 
  "Momentarily display STRING in the buffer at POS.
Display remains until next character is typed.
If the char is EXIT-CHAR (optional third arg, default is SPC) it is swallowed;
otherwise it is then available as input (as a command if nothing else).
Display MESSAGE (optional fourth arg) in the echo area.
If MESSAGE is nil, instructions to type EXIT-CHAR are displayed there."
  (or exit-char (setq exit-char ?\ ))
  (let ((buffer-read-only nil)
646 647
	;; Don't modify the undo list at all.
	(buffer-undo-list t)
David Lawrence's avatar
David Lawrence committed
648 649 650 651 652 653 654 655 656 657
	(modified (buffer-modified-p))
	(name buffer-file-name)
	insert-end)
    (unwind-protect
	(progn
	  (save-excursion
	    (goto-char pos)
	    ;; defeat file locking... don't try this at home, kids!
	    (setq buffer-file-name nil)
	    (insert-before-markers string)
658 659 660 661 662 663 664 665 666 667 668
	    (setq insert-end (point))
	    ;; If the message end is off screen, recenter now.
	    (if (> (window-end) insert-end)
		(recenter (/ (window-height) 2)))
	    ;; If that pushed message start off the screen,
	    ;; scroll to start it at the top of the screen.
	    (move-to-window-line 0)
	    (if (> (point) pos)
		(progn
		  (goto-char pos)
		  (recenter 0))))
David Lawrence's avatar
David Lawrence committed
669 670
	  (message (or message "Type %s to continue editing.")
		   (single-key-description exit-char))
671
	  (let ((char (read-event)))
David Lawrence's avatar
David Lawrence committed
672
	    (or (eq char exit-char)
Jim Blandy's avatar
Jim Blandy committed
673
		(setq unread-command-events (list char)))))
David Lawrence's avatar
David Lawrence committed
674 675 676 677 678 679
      (if insert-end
	  (save-excursion
	    (delete-region pos insert-end)))
      (setq buffer-file-name name)
      (set-buffer-modified-p modified))))

680 681 682

;;;; Miscellanea.

683 684 685 686 687 688 689 690 691 692 693 694
;; A number of major modes set this locally.
;; Give it a global value to avoid compiler warnings.
(defvar font-lock-defaults nil)

;; Avoid compiler warnings about this variable,
;; which has a special meaning on certain system types.
(defvar buffer-file-type nil
  "Non-nil if the visited file is a binary file.
This variable is meaningful on MS-DOG and Windows NT.
On those systems, it is automatically local in every buffer.
On other systems, this variable is normally always nil.")

Simon Marshall's avatar
Simon Marshall committed
695
;; This should probably be written in C (i.e., without using `walk-windows').
696
(defun get-buffer-window-list (buffer &optional minibuf frame)
Simon Marshall's avatar
Simon Marshall committed
697
  "Return windows currently displaying BUFFER, or nil if none.
698
See `walk-windows' for the meaning of MINIBUF and FRAME."
699
  (let ((buffer (if (bufferp buffer) buffer (get-buffer buffer))) windows)
Simon Marshall's avatar
Simon Marshall committed
700 701 702
    (walk-windows (function (lambda (window)
			      (if (eq (window-buffer window) buffer)
				  (setq windows (cons window windows)))))
703
		  minibuf frame)
Simon Marshall's avatar
Simon Marshall committed
704 705
    windows))

706 707 708
(defun ignore (&rest ignore)
  "Do nothing and return nil.
This function accepts any number of arguments, but ignores them."
709
  (interactive)
710 711 712
  nil)

(defun error (&rest args)
Richard M. Stallman's avatar
Richard M. Stallman committed
713 714 715 716
  "Signal an error, making error message by passing all args to `format'.
In Emacs, the convention is that error messages start with a capital
letter but *do not* end with a period.  Please follow this convention
for the sake of consistency."
717 718 719
  (while t
    (signal 'error (list (apply 'format args)))))

720
(defalias 'user-original-login-name 'user-login-name)
721

David Lawrence's avatar
David Lawrence committed
722 723 724 725 726 727 728 729 730 731 732
(defun start-process-shell-command (name buffer &rest args)
  "Start a program in a subprocess.  Return the process object for it.
Args are NAME BUFFER COMMAND &rest COMMAND-ARGS.
NAME is name for process.  It is modified if necessary to make it unique.
BUFFER is the buffer or (buffer-name) to associate with the process.
 Process output goes at end of that buffer, unless you specify
 an output stream or filter function to handle the output.
 BUFFER may be also nil, meaning that this process is not associated
 with any buffer
Third arg is command name, the name of a shell command.
Remaining arguments are the arguments for the command.
733
Wildcards and redirection are handled as usual in the shell."
734 735 736
  (cond
   ((eq system-type 'vax-vms)
    (apply 'start-process name buffer args))
737 738
   ;; We used to use `exec' to replace the shell with the command,
   ;; but that failed to handle (...) and semicolon, etc.
739 740
   (t
    (start-process name buffer shell-file-name shell-command-switch
741
		   (mapconcat 'identity args " ")))))
David Lawrence's avatar
David Lawrence committed
742

743 744 745 746 747 748
(defvar save-match-data-internal)

;; We use save-match-data-internal as the local variable because
;; that works ok in practice (people should not use that variable elsewhere).
;; We used to use an uninterned symbol; the compiler handles that properly
;; now, but it generates slower code.
749 750
(defmacro save-match-data (&rest body)
  "Execute the BODY forms, restoring the global value of the match data."
751
  `(let ((save-match-data-internal (match-data)))
752 753
       (unwind-protect
	   (progn ,@body)
754
	 (store-match-data save-match-data-internal))))
755

756
(defun match-string (num &optional string)
757 758 759 760 761
  "Return string of text matched by last search.
NUM specifies which parenthesized expression in the last regexp.
 Value is nil if NUMth pair didn't match, or there were less than NUM pairs.
Zero means the entire text matched by the whole regexp or whole string.
STRING should be given if the last search was by `string-match' on STRING."
762 763 764 765
  (if (match-beginning num)
      (if string
	  (substring string (match-beginning num) (match-end num))
	(buffer-substring (match-beginning num) (match-end num)))))
766

767 768
(defun shell-quote-argument (argument)
  "Quote an argument for passing as argument to an inferior shell."
769 770 771 772 773 774 775 776 777 778 779 780 781 782
  (if (eq system-type 'ms-dos)
      ;; MS-DOS shells don't have quoting, so don't do any.
      argument
    (if (eq system-type 'windows-nt)
	(concat "\"" argument "\"")
      ;; Quote everything except POSIX filename characters.
      ;; This should be safe enough even for really weird shells.
      (let ((result "") (start 0) end)
	(while (string-match "[^-0-9a-zA-Z_./]" argument start)
	  (setq end (match-beginning 0)
		result (concat result (substring argument start end)
			       "\\" (substring argument end (1+ end)))
		start (1+ end)))
	(concat result (substring argument start))))))
783

784
(defun make-syntax-table (&optional oldtable)
785 786 787
  "Return a new syntax table.
It inherits all letters and control characters from the standard
syntax table; other characters are copied from the standard syntax table."
788 789 790 791 792 793
  (if oldtable
      (copy-syntax-table oldtable)
    (let ((table (copy-syntax-table))
	  i)
      (setq i 0)
      (while (<= i 31)
794
	(aset table i nil)
795 796 797
	(setq i (1+ i)))
      (setq i ?A)
      (while (<= i ?Z)
798
	(aset table i nil)
799 800 801
	(setq i (1+ i)))
      (setq i ?a)
      (while (<= i ?z)
802
	(aset table i nil)
803 804 805
	(setq i (1+ i)))
      (setq i 128)
      (while (<= i 255)
806
	(aset table i nil)
807 808
	(setq i (1+ i)))
      table)))
809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839

(defun global-set-key (key command)
  "Give KEY a global binding as COMMAND.
COMMAND is a symbol naming an interactively-callable function.
KEY is a key sequence (a string or vector of characters or event types).
Non-ASCII characters with codes above 127 (such as ISO Latin-1)
can be included if you use a vector.
Note that if KEY has a local binding in the current buffer
that local binding will continue to shadow any global binding."
  (interactive "KSet key globally: \nCSet key %s to command: ")
  (or (vectorp key) (stringp key)
      (signal 'wrong-type-argument (list 'arrayp key)))
  (define-key (current-global-map) key command)
  nil)

(defun local-set-key (key command)
  "Give KEY a local binding as COMMAND.
COMMAND is a symbol naming an interactively-callable function.
KEY is a key sequence (a string or vector of characters or event types).
Non-ASCII characters with codes above 127 (such as ISO Latin-1)
can be included if you use a vector.
The binding goes in the current buffer's local map,
which in most cases is shared with all other buffers in the same major mode."
  (interactive "KSet key locally: \nCSet key %s locally to command: ")
  (let ((map (current-local-map)))
    (or map
	(use-local-map (setq map (make-sparse-keymap))))
    (or (vectorp key) (stringp key)
	(signal 'wrong-type-argument (list 'arrayp key)))
    (define-key map key command))
  nil)
840

841 842 843 844 845 846
(defun global-unset-key (key)
  "Remove global binding of KEY.
KEY is a string representing a sequence of keystrokes."
  (interactive "kUnset key globally: ")
  (global-set-key key nil))

847
(defun local-unset-key (key)
848 849 850 851
  "Remove local binding of KEY.
KEY is a string representing a sequence of keystrokes."
  (interactive "kUnset key locally: ")
  (if (current-local-map)
852
      (local-set-key key nil))
853 854
  nil)

855 856 857 858 859 860 861 862 863
;; We put this here instead of in frame.el so that it's defined even on
;; systems where frame.el isn't loaded.
(defun frame-configuration-p (object)
  "Return non-nil if OBJECT seems to be a frame configuration.
Any list whose car is `frame-configuration' is assumed to be a frame
configuration."
  (and (consp object)
       (eq (car object) 'frame-configuration)))

864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882
;; now in fns.c
;(defun nth (n list)
;  "Returns the Nth element of LIST.
;N counts from zero.  If LIST is not that long, nil is returned."
;  (car (nthcdr n list)))
;
;(defun copy-alist (alist)
;  "Return a copy of ALIST.
;This is a new alist which represents the same mapping
;from objects to objects, but does not share the alist structure with ALIST.
;The objects mapped (cars and cdrs of elements of the alist)
;are shared, however."
;  (setq alist (copy-sequence alist))
;  (let ((tail alist))
;    (while tail
;      (if (consp (car tail))
;	  (setcar tail (cons (car (car tail)) (cdr (car tail)))))
;      (setq tail (cdr tail))))
;  alist)
Eric S. Raymond's avatar
Eric S. Raymond committed
883 884

;;; subr.el ends here
885