info.el 162 KB
Newer Older
1
;;; info.el --- info package for Emacs
Eric S. Raymond's avatar
Eric S. Raymond committed
2

3
;; Copyright (C) 1985, 1986, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
4
;;   2000, 2001, 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
Eric S. Raymond's avatar
Eric S. Raymond committed
5

Eric S. Raymond's avatar
Eric S. Raymond committed
6
;; Maintainer: FSF
Eric S. Raymond's avatar
Eric S. Raymond committed
7
;; Keywords: help
Eric S. Raymond's avatar
Eric S. Raymond committed
8

Jim Blandy's avatar
Jim Blandy committed
9 10 11 12
;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
Eric S. Raymond's avatar
Eric S. Raymond committed
13
;; the Free Software Foundation; either version 2, or (at your option)
Jim Blandy's avatar
Jim Blandy committed
14 15 16 17 18 19 20 21
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
Erik Naggum's avatar
Erik Naggum committed
22
;; along with GNU Emacs; see the file COPYING.  If not, write to the
Lute Kamstra's avatar
Lute Kamstra committed
23 24
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.
Jim Blandy's avatar
Jim Blandy committed
25

Eric S. Raymond's avatar
Eric S. Raymond committed
26 27
;;; Commentary:

28
;; Note that nowadays we expect Info files to be made using makeinfo.
29 30 31 32
;; In particular we make these assumptions:
;;  - a menu item MAY contain colons but not colon-space ": "
;;  - a menu item ending with ": " (but not ":: ") is an index entry
;;  - a node name MAY NOT contain a colon
33 34
;; This distinction is to support indexing of computer programming
;; language terms that may contain ":" but not ": ".
Eric S. Raymond's avatar
Eric S. Raymond committed
35 36 37

;;; Code:

Dave Love's avatar
Dave Love committed
38 39
(eval-when-compile (require 'jka-compr))

40
(defgroup info nil
41
  "Info subsystem."
42 43 44 45
  :group 'help
  :group 'docs)


Jim Blandy's avatar
Jim Blandy committed
46
(defvar Info-history nil
47
  "Stack of Info nodes user has visited.
48
Each element of the stack is a list (FILENAME NODENAME BUFFERPOS).")
Jim Blandy's avatar
Jim Blandy committed
49

50
(defvar Info-history-forward nil
51
  "Stack of Info nodes user has visited with `Info-history-back' command.
52
Each element of the stack is a list (FILENAME NODENAME BUFFERPOS).")
53

Juri Linkov's avatar
Juri Linkov committed
54
(defvar Info-history-list nil
55
  "List of all Info nodes user has visited.
56
Each element of the list is a list (FILENAME NODENAME).")
Juri Linkov's avatar
Juri Linkov committed
57

58
(defcustom Info-enable-edit nil
59
  "*Non-nil means the \\<Info-mode-map>\\[Info-edit] command in Info can edit the current node.
60
This is convenient if you want to write Info files by hand.
61 62
However, we recommend that you not do this.
It is better to write a Texinfo file and generate the Info file from that,
63 64 65
because that gives you a printed manual as well."
  :type 'boolean
  :group 'info)
Jim Blandy's avatar
Jim Blandy committed
66

67
(defvar Info-enable-active-nodes nil
Jim Blandy's avatar
Jim Blandy committed
68 69
  "Non-nil allows Info to execute Lisp code associated with nodes.
The Lisp code is executed when the node is selected.")
70
(put 'Info-enable-active-nodes 'risky-local-variable t)
Jim Blandy's avatar
Jim Blandy committed
71

72
(defface info-node
73 74 75
  '((((class color) (background light)) :foreground "brown" :weight bold :slant italic)
    (((class color) (background dark)) :foreground "white" :weight bold :slant italic)
    (t :weight bold :slant italic))
76 77 78
  "Face for Info node names."
  :group 'info)

79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124
(defface info-title-1
  '((((type tty pc) (class color) (background light))
     :foreground "green" :weight bold)
    (((type tty pc) (class color) (background dark))
     :foreground "yellow" :weight bold)
    (t :height 1.2 :inherit info-title-2))
  "Face for info titles at level 1."
  :group 'info)
;; backward-compatibility alias
(put 'Info-title-1-face 'face-alias 'info-title-1)

(defface info-title-2
  '((((type tty pc) (class color)) :foreground "lightblue" :weight bold)
    (t :height 1.2 :inherit info-title-3))
  "Face for info titles at level 2."
  :group 'info)
;; backward-compatibility alias
(put 'Info-title-2-face 'face-alias 'info-title-2)

(defface info-title-3
  '((((type tty pc) (class color)) :weight bold)
    (t :height 1.2 :inherit info-title-4))
  "Face for info titles at level 3."
  :group 'info)
;; backward-compatibility alias
(put 'Info-title-3-face 'face-alias 'info-title-3)

(defface info-title-4
  '((((type tty pc) (class color)) :weight bold)
    (t :weight bold :inherit variable-pitch))
  "Face for info titles at level 4."
  :group 'info)
;; backward-compatibility alias
(put 'Info-title-4-face 'face-alias 'info-title-4)

(defface info-menu-header
  '((((type tty pc))
     :underline t
     :weight bold)
    (t
     :inherit variable-pitch
     :weight bold))
  "Face for headers in Info menus."
  :group 'info)

(defface info-menu-star
125 126
  '((((class color)) :foreground "red1")
    (t :underline t))
127
  "Face for every third `*' in an Info menu."
128
  :group 'info)
129
(put 'info-menu-5 'face-alias 'info-menu-star)
130 131

(defface info-xref
132 133
  '((t :inherit link))
  "Face for unvisited Info cross-references."
134 135
  :group 'info)

Juri Linkov's avatar
Juri Linkov committed
136
(defface info-xref-visited
137
  '((t :inherit link-visited))
Juri Linkov's avatar
Juri Linkov committed
138
  "Face for visited Info cross-references."
139
  :version "22.1"
Juri Linkov's avatar
Juri Linkov committed
140 141 142
  :group 'info)

(defcustom Info-fontify-visited-nodes t
143
  "*Non-nil to fontify references to visited nodes in `info-xref-visited' face."
144
  :version "22.1"
Juri Linkov's avatar
Juri Linkov committed
145 146 147
  :type 'boolean
  :group 'info)

148
(defcustom Info-fontify-maximum-menu-size 100000
149
  "*Maximum size of menu to fontify if `font-lock-mode' is non-nil."
150 151
  :type 'integer
  :group 'info)
152

Miles Bader's avatar
Miles Bader committed
153
(defcustom Info-use-header-line t
154
  "*Non-nil means to put the beginning-of-node links in an Emacs header-line.
Miles Bader's avatar
Miles Bader committed
155 156 157 158 159
A header-line does not scroll with the rest of the buffer."
  :type 'boolean
  :group 'info)

(defface info-header-xref
160
  '((t :inherit info-xref))
Miles Bader's avatar
Miles Bader committed
161 162 163 164
  "Face for Info cross-references in a node header."
  :group 'info)

(defface info-header-node
165
  '((t :inherit info-node))
Miles Bader's avatar
Miles Bader committed
166 167 168
  "Face for Info nodes in a node header."
  :group 'info)

169
(defvar Info-directory-list nil
Jim Blandy's avatar
Jim Blandy committed
170
  "List of directories to search for Info documentation files.
171
If nil, meaning not yet initialized, Info uses the environment
172
variable INFOPATH to initialize it, or `Info-default-directory-list'
173 174
if there is no INFOPATH variable in the environment, or the
concatenation of the two if INFOPATH ends with a colon.
175 176

When `Info-directory-list' is initialized from the value of
177 178 179 180 181 182 183
`Info-default-directory-list', and Emacs is installed in one of the
standard directories, the directory of Info files that come with Emacs
is put last (so that local Info files override standard ones).

When `Info-directory-list' is initialized from the value of
`Info-default-directory-list', and Emacs is not installed in one
of the standard directories, the first element of the resulting
184 185
list is the directory where Emacs installs the Info files that
come with it.  This is so that Emacs's own manual, which suits the
186 187 188 189 190 191
version of Emacs you are using, will always be found first.  This
is useful when you install an experimental version of Emacs without
removing the standard installation.

If you want to override the order of directories in
`Info-default-directory-list', set INFOPATH in the environment.
192 193

If you run the Emacs executable from the `src' directory in the Emacs
194 195 196 197
source tree, and INFOPATH is not defined, the `info' directory in the
source tree is used as the first element of `Info-directory-list', in
place of the installation Info directory.  This is useful when you run
a version of Emacs without installing it.")
Jim Blandy's avatar
Jim Blandy committed
198

199
(defcustom Info-additional-directory-list nil
200
  "List of additional directories to search for Info documentation files.
201
These directories are searched after those in `Info-directory-list'."
202 203
  :type '(repeat directory)
  :group 'info)
204

205
(defcustom Info-scroll-prefer-subnodes nil
206
  "*If non-nil, \\<Info-mode-map>\\[Info-scroll-up] in a menu visits subnodes.
207

208 209 210 211 212 213 214 215
If this is non-nil, and you scroll far enough in a node that its menu
appears on the screen, the next \\<Info-mode-map>\\[Info-scroll-up]
moves to a subnode indicated by the following menu item.  This means
that you visit a subnode before getting to the end of the menu.

Setting this option to nil results in behavior similar to the stand-alone
Info reader program, which visits the first subnode from the menu only
when you hit the end of the current node."
216
  :version "22.1"
217 218 219
  :type 'boolean
  :group 'info)

220
(defcustom Info-hide-note-references t
221
  "*If non-nil, hide the tag and section reference in *note and * menu items.
Juri Linkov's avatar
Juri Linkov committed
222
If value is non-nil but not `hide', also replaces the \"*note\" with \"see\".
223 224
If value is non-nil but not t or `hide', the reference section is still shown.
`nil' completely disables this feature."
225
  :version "22.1"
Juri Linkov's avatar
Juri Linkov committed
226
  :type '(choice (const :tag "No hiding" nil)
227
		 (const :tag "Replace tag and hide reference" t)
Juri Linkov's avatar
Juri Linkov committed
228 229
		 (const :tag "Hide tag and reference" hide)
		 (other :tag "Only replace tag" tag))
230 231
  :group 'info)

Kim F. Storm's avatar
Kim F. Storm committed
232 233
(defcustom Info-refill-paragraphs nil
  "*If non-nil, attempt to refill paragraphs with hidden references.
234
This refilling may accidentally remove explicit line breaks in the Info
Kim F. Storm's avatar
Kim F. Storm committed
235
file, so be prepared for a few surprises if you enable this feature."
236
  :version "22.1"
Kim F. Storm's avatar
Kim F. Storm committed
237 238 239
  :type 'boolean
  :group 'info)

240
(defcustom Info-search-whitespace-regexp "\\s-+"
Juri Linkov's avatar
Juri Linkov committed
241 242 243 244 245 246 247 248
  "*If non-nil, regular expression to match a sequence of whitespace chars.
This applies to Info search for regular expressions.
You might want to use something like \"[ \\t\\r\\n]+\" instead.
In the Customization buffer, that is `[' followed by a space,
a tab, a carriage return (control-M), a newline, and `]+'."
  :type 'regexp
  :group 'info)

249
(defcustom Info-isearch-search t
250 251 252 253 254 255 256 257 258 259 260
  "*If non-nil, isearch in Info searches through multiple nodes.
Before leaving the initial Info node, where isearch was started,
it fails once with the error message [initial node], and with
subsequent C-s/C-r continues through other nodes without failing
with this error message in other nodes.  When isearch fails for
the rest of the manual, it wraps aroung the whole manual and
restarts the search from the top/final node depending on
search direction.

Setting this option to nil restores the default isearch behavior
with wrapping around the current Info node."
261 262 263 264
  :version "22.1"
  :type 'boolean
  :group 'info)

265 266
(defvar Info-isearch-initial-node nil)

267 268 269 270
(defcustom Info-mode-hook
  ;; Try to obey obsolete Info-fontify settings.
  (unless (and (boundp 'Info-fontify) (null Info-fontify))
    '(turn-on-font-lock))
Juri Linkov's avatar
Juri Linkov committed
271 272 273 274 275 276
  "Hooks run when `Info-mode' is called."
  :type 'hook
  :group 'info)

(defcustom Info-selection-hook nil
  "Hooks run when `Info-select-node' is called."
Colin Walters's avatar
Colin Walters committed
277 278 279
  :type 'hook
  :group 'info)

Juri Linkov's avatar
Juri Linkov committed
280 281 282
(defvar Info-edit-mode-hook nil
  "Hooks run when `Info-edit-mode' is called.")

Jim Blandy's avatar
Jim Blandy committed
283
(defvar Info-current-file nil
284 285
  "Info file that Info is now looking at, or nil.
This is the name that was specified in Info, not the actual file name.
286
It doesn't contain directory names or file name extensions added by Info.")
Jim Blandy's avatar
Jim Blandy committed
287 288

(defvar Info-current-subfile nil
Dave Love's avatar
Dave Love committed
289
  "Info subfile that is actually in the *info* buffer now.
290
nil if current Info file is not split into subfiles.")
Jim Blandy's avatar
Jim Blandy committed
291 292 293 294

(defvar Info-current-node nil
  "Name of node that Info is now looking at, or nil.")

295
(defvar Info-tag-table-marker nil
Jim Blandy's avatar
Jim Blandy committed
296 297 298
  "Marker pointing at beginning of current Info file's tag table.
Marker points nowhere if file has no tag table.")

299 300 301
(defvar Info-tag-table-buffer nil
  "Buffer used for indirect tag tables.")

302 303 304
(defvar Info-current-file-completions nil
  "Cached completion list for current Info file.")

305 306 307
(defvar Info-file-supports-index-cookies nil
  "Non-nil if current Info file supports index cookies.")

308
(defvar Info-index-alternatives nil
Dave Love's avatar
Dave Love committed
309
  "List of possible matches for last `Info-index' command.")
310

311 312 313 314 315
(defvar Info-point-loc nil
  "Point location within a selected node.
If string, the point is moved to the proper occurrence of the
name of the followed cross reference within a selected node.
If number, the point is moved to the corresponding line.")
Juri Linkov's avatar
Juri Linkov committed
316

317 318
(defvar Info-standalone nil
  "Non-nil if Emacs was started solely as an Info browser.")
319

320
(defvar Info-suffix-list
321 322
  ;; The MS-DOS list should work both when long file names are
  ;; supported (Windows 9X), and when only 8+3 file names are available.
323 324 325
  (if (eq system-type 'ms-dos)
      '( (".gz"      . "gunzip")
	 (".z"       . "gunzip")
326
	 (".bz2"     . ("bzip2" "-dc"))
327 328 329 330 331 332 333 334
	 (".inz"     . "gunzip")
	 (".igz"     . "gunzip")
	 (".info.Z"  . "gunzip")
	 (".info.gz" . "gunzip")
	 ("-info.Z"  . "gunzip")
	 ("-info.gz" . "gunzip")
	 ("/index.gz". "gunzip")
	 ("/index.z" . "gunzip")
335
	 (".inf"     . nil)
336 337 338
	 (".info"    . nil)
	 ("-info"    . nil)
	 ("/index"   . nil)
339
	 (""         . nil))
340 341 342 343
    '( (".info.Z".    "uncompress")
       (".info.Y".    "unyabba")
       (".info.gz".   "gunzip")
       (".info.z".    "gunzip")
344
       (".info.bz2" . ("bzip2" "-dc"))
345 346 347 348
       (".info".      nil)
       ("-info.Z".   "uncompress")
       ("-info.Y".   "unyabba")
       ("-info.gz".  "gunzip")
349
       ("-info.bz2" . ("bzip2" "-dc"))
350 351 352 353 354 355
       ("-info.z".   "gunzip")
       ("-info".     nil)
       ("/index.Z".   "uncompress")
       ("/index.Y".   "unyabba")
       ("/index.gz".  "gunzip")
       ("/index.z".   "gunzip")
356
       ("/index.bz2". ("bzip2" "-dc"))
357 358 359 360 361
       ("/index".     nil)
       (".Z".         "uncompress")
       (".Y".         "unyabba")
       (".gz".        "gunzip")
       (".z".         "gunzip")
362
       (".bz2" .      ("bzip2" "-dc"))
363
       ("".           nil)))
364 365
  "List of file name suffixes and associated decoding commands.
Each entry should be (SUFFIX . STRING); the file is given to
366 367 368 369 370 371
the command as standard input.

STRING may be a list of strings.  In that case, the first element is
the command name, and the rest are arguments to that command.

If STRING is nil, no decoding is done.
372 373
Because the SUFFIXes are tried in order, the empty string should
be last in the list.")
374

375
;; Concatenate SUFFIX onto FILENAME.  SUFFIX should start with a dot.
376 377 378 379
;; First, on MS-DOS with no long file names support, delete some of
;; the extension in FILENAME to make room.
(defun info-insert-file-contents-1 (filename suffix lfn)
  (if lfn	; long file names are supported
380 381
      (concat filename suffix)
    (let* ((sans-exts (file-name-sans-extension filename))
382 383 384
	   ;; How long is the extension in FILENAME (not counting the dot).
	   (ext-len (max 0 (- (length filename) (length sans-exts) 1)))
	   ext-left)
385
      ;; SUFFIX starts with a dot.  If FILENAME already has one,
386
      ;; get rid of the one in SUFFIX (unless suffix is empty).
387
      (or (and (<= ext-len 0)
388
	       (not (eq (aref filename (1- (length filename))) ?.)))
389
	  (= (length suffix) 0)
390
	  (setq suffix (substring suffix 1)))
391 392
      ;; How many chars of that extension should we keep?
      (setq ext-left (min ext-len (max 0 (- 3 (length suffix)))))
393 394 395 396 397
      ;; Get rid of the rest of the extension, and add SUFFIX.
      (concat (substring filename 0 (- (length filename)
				       (- ext-len ext-left)))
	      suffix))))

398 399 400 401
(defun info-file-exists-p (filename)
  (and (file-exists-p filename)
       (not (file-directory-p filename))))

402
(defun info-insert-file-contents (filename &optional visit)
403
  "Insert the contents of an Info file in the current buffer.
404
Do the right thing if the file has been compressed or zipped."
405
  (let* ((tail Info-suffix-list)
406 407 408
	 (lfn (if (fboundp 'msdos-long-file-names)
		  (msdos-long-file-names)
		t))
409 410 411
	 (check-short (and (fboundp 'msdos-long-file-names)
			   lfn))
	 fullname decoder done)
412
    (if (info-file-exists-p filename)
413 414
	;; FILENAME exists--see if that name contains a suffix.
	;; If so, set DECODE accordingly.
415 416 417 418 419 420 421 422
	(progn
	  (while (and tail
		      (not (string-match
			    (concat (regexp-quote (car (car tail))) "$")
			    filename)))
	    (setq tail (cdr tail)))
	  (setq fullname filename
		decoder (cdr (car tail))))
423
      ;; Try adding suffixes to FILENAME and see if we can find something.
424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439
      (while (and tail (not done))
	(setq fullname (info-insert-file-contents-1 filename
						    (car (car tail)) lfn))
	(if (info-file-exists-p fullname)
	    (setq done t
		  ;; If we found a file with a suffix, set DECODER
		  ;; according to the suffix.
		  decoder (cdr (car tail)))
	  ;; When the MS-DOS port runs on Windows, we need to check
	  ;; the short variant of a long file name as well.
	  (when check-short
	    (setq fullname (info-insert-file-contents-1 filename
							(car (car tail)) nil))
	    (if (info-file-exists-p fullname)
		(setq done t
		      decoder (cdr (car tail))))))
440 441
	(setq tail (cdr tail)))
      (or tail
442
	  (error "Can't find %s or any compressed version of it" filename)))
443
    ;; check for conflict with jka-compr
444
    (if (and (jka-compr-installed-p)
445 446
	     (jka-compr-get-compression-info fullname))
	(setq decoder nil))
447
    (if decoder
448 449 450 451 452 453
	(progn
	  (insert-file-contents-literally fullname visit)
	  (let ((buffer-read-only nil)
		(coding-system-for-write 'no-conversion)
		(default-directory (or (file-name-directory fullname)
				       default-directory)))
454 455 456 457
	    (or (consp decoder)
		(setq decoder (list decoder)))
	    (apply 'call-process-region (point-min) (point-max)
		   (car decoder) t t nil (cdr decoder))))
458
      (insert-file-contents fullname visit))))
459

460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497
(defun Info-default-dirs ()
  (let ((source (expand-file-name "info/" source-directory))
	(sibling (if installation-directory
		     (expand-file-name "info/" installation-directory)
		   (if invocation-directory
		       (let ((infodir (expand-file-name
				       "../info/"
				       invocation-directory)))
			 (if (file-exists-p infodir)
			     infodir
			   (setq infodir (expand-file-name
					  "../../../info/"
					  invocation-directory))
			   (and (file-exists-p infodir)
				infodir))))))
	alternative)
    (setq alternative
	  (if (and sibling (file-exists-p sibling))
	      ;; Uninstalled, Emacs builddir != srcdir.
	      sibling
	    ;; Uninstalled, builddir == srcdir
	    source))
    (if (or (member alternative Info-default-directory-list)
	    ;; On DOS/NT, we use movable executables always,
	    ;; and we must always find the Info dir at run time.
	    (if (memq system-type '(ms-dos windows-nt))
		nil
	      ;; Use invocation-directory for Info
	      ;; only if we used it for exec-directory also.
	      (not (string= exec-directory
			    (expand-file-name "lib-src/"
					      installation-directory))))
	    (not (file-exists-p alternative)))
	Info-default-directory-list
      ;; `alternative' contains the Info files that came with this
      ;; version, so we should look there first.  `Info-insert-dir'
      ;; currently expects to find `alternative' first on the list.
      (cons alternative
498 499 500
	    ;; Don't drop the last part, it might contain non-Emacs stuff.
	    ;; (reverse (cdr (reverse
	    Info-default-directory-list)))) ;; )))
501

502
(defun info-initialize ()
Dave Love's avatar
Dave Love committed
503
  "Initialize `Info-directory-list', if that hasn't been done yet."
504
  (unless Info-directory-list
505
    (let ((path (getenv "INFOPATH")))
506
      (setq Info-directory-list
507 508
	    (prune-directory-list
	     (if path
509 510 511 512 513 514
		 (if (string-match ":\\'" path)
		     (append (split-string (substring path 0 -1)
					   (regexp-quote path-separator))
			     (Info-default-dirs))
		   (split-string path (regexp-quote path-separator)))
	       (Info-default-dirs)))))))
515

516
;;;###autoload
517
(defun info-other-window (&optional file-or-node)
518 519 520
  "Like `info' but show the Info buffer in another window."
  (interactive (if current-prefix-arg
		   (list (read-file-name "Info file name: " nil nil t))))
521
  (let (same-window-buffer-names same-window-regexps)
522
    (info file-or-node)))
523

524
;;;###autoload (add-hook 'same-window-regexps "\\*info\\*\\(\\|<[0-9]+>\\)")
525

526
;;;###autoload (put 'info 'info-file "emacs")
Jim Blandy's avatar
Jim Blandy committed
527
;;;###autoload
528
(defun info (&optional file-or-node buffer)
Jim Blandy's avatar
Jim Blandy committed
529
  "Enter Info, the documentation browser.
530
Optional argument FILE-OR-NODE specifies the file to examine;
Jim Blandy's avatar
Jim Blandy committed
531
the default is the top-level directory of Info.
532
Called from a program, FILE-OR-NODE may specify an Info node of the form
Dave Love's avatar
Dave Love committed
533
`(FILENAME)NODENAME'.
534 535 536 537
Optional argument BUFFER specifies the Info buffer name;
the default buffer name is *info*.  If BUFFER exists,
just switch to BUFFER.  Otherwise, create a new buffer
with the top-level Info directory.
Jim Blandy's avatar
Jim Blandy committed
538

539 540
In interactive use, a non-numeric prefix argument directs
this command to read a file name from the minibuffer.
Juri Linkov's avatar
Juri Linkov committed
541 542
A numeric prefix argument selects an Info buffer with the prefix number
appended to the Info buffer name.
Richard M. Stallman's avatar
Richard M. Stallman committed
543 544

The search path for Info files is in the variable `Info-directory-list'.
545
The top-level Info directory is made by combining all the files named `dir'
Richard M. Stallman's avatar
Richard M. Stallman committed
546
in all the directories in that path."
547 548 549 550 551 552 553 554
  (interactive (list
                (if (and current-prefix-arg (not (numberp current-prefix-arg)))
                    (read-file-name "Info file name: " nil nil t))
                (if (numberp current-prefix-arg)
                    (format "*info*<%s>" current-prefix-arg))))
  (pop-to-buffer (or buffer "*info*"))
  (if (and buffer (not (eq major-mode 'Info-mode)))
      (Info-mode))
555
  (if file-or-node
556 557 558 559
      ;; If argument already contains parentheses, don't add another set
      ;; since the argument will then be parsed improperly.  This also
      ;; has the added benefit of allowing node names to be included
      ;; following the parenthesized filename.
560
      (Info-goto-node
561 562 563
       (if (and (stringp file-or-node) (string-match "(.*)" file-or-node))
           file-or-node
         (concat "(" file-or-node ")")))
564 565 566 567
    (if (and (zerop (buffer-size))
	     (null Info-history))
	;; If we just created the Info buffer, go to the directory.
	(Info-directory))))
Jim Blandy's avatar
Jim Blandy committed
568

569 570
;;;###autoload
(defun info-emacs-manual ()
571
  "Display the Emacs manual in Info mode."
572 573 574
  (interactive)
  (info "emacs"))

575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591
;;;###autoload
(defun info-standalone ()
  "Run Emacs as a standalone Info reader.
Usage:  emacs -f info-standalone [filename]
In standalone mode, \\<Info-mode-map>\\[Info-exit] exits Emacs itself."
  (setq Info-standalone t)
  (if (and command-line-args-left
	   (not (string-match "^-" (car command-line-args-left))))
      (condition-case err
	  (progn
	    (info (car command-line-args-left))
	    (setq command-line-args-left (cdr command-line-args-left)))
	(error (send-string-to-terminal
		(format "%s\n" (if (eq (car-safe err) 'error)
				   (nth 1 err) err)))
	       (save-buffers-kill-emacs)))
    (info)))
592

Stefan Monnier's avatar
Stefan Monnier committed
593
;; See if the accessible portion of the buffer begins with a node
594 595 596 597 598 599 600 601 602
;; delimiter, and the node header line which follows matches REGEXP.
;; Typically, this test will be followed by a loop that examines the
;; rest of the buffer with (search-forward "\n\^_"), and it's a pity
;; to have the overhead of this special test inside the loop.

;; This function changes match-data, but supposedly the caller might
;; want to use the results of re-search-backward.

;; The return value is the value of point at the beginning of matching
Stefan Monnier's avatar
Stefan Monnier committed
603
;; REGEXP, if the function succeeds, nil otherwise.
604
(defun Info-node-at-bob-matching (regexp)
605 606
  (and (bobp)				; are we at beginning of buffer?
       (looking-at "\^_")		; does it begin with node delimiter?
607 608 609
       (let (beg)
	 (forward-line 1)
	 (setq beg (point))
610
	 (forward-line 1)		; does the line after delimiter match REGEXP?
611 612
	 (re-search-backward regexp beg t))))

Juri Linkov's avatar
Juri Linkov committed
613 614 615 616
(defun Info-find-file (filename &optional noerror)
  "Return expanded FILENAME, or t, if FILENAME is \"dir\".
Optional second argument NOERROR, if t, means if file is not found
just return nil (no error)."
Jim Blandy's avatar
Jim Blandy committed
617 618
  ;; Convert filename to lower case if not found as specified.
  ;; Expand it.
619
  (if (stringp filename)
Jim Blandy's avatar
Jim Blandy committed
620
      (let (temp temp-downcase found)
621
        (setq filename (substitute-in-file-name filename))
Juri Linkov's avatar
Juri Linkov committed
622
	(cond
Jesper Harder's avatar
Jesper Harder committed
623 624 625 626
	 ((string= (downcase filename) "dir")
	  (setq found t))
	 ((string= filename "apropos")
	  (setq found 'apropos))
Juri Linkov's avatar
Juri Linkov committed
627 628 629 630
	 ((string= filename "history")
	  (setq found 'history))
	 ((string= filename "toc")
	  (setq found 'toc))
Jesper Harder's avatar
Jesper Harder committed
631 632
	 (t
	  (let ((dirs (if (string-match "^\\./" filename)
633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649
                          ;; If specified name starts with `./'
                          ;; then just try current directory.
                          '("./")
                        (if (file-name-absolute-p filename)
                            ;; No point in searching for an
                            ;; absolute file name
                            '(nil)
                          (if Info-additional-directory-list
                              (append Info-directory-list
                                      Info-additional-directory-list)
                            Info-directory-list)))))
            ;; Search the directory list for file FILENAME.
            (while (and dirs (not found))
              (setq temp (expand-file-name filename (car dirs)))
              (setq temp-downcase
                    (expand-file-name (downcase filename) (car dirs)))
              ;; Try several variants of specified name.
650
              (let ((suffix-list Info-suffix-list)
651 652 653
		    (lfn (if (fboundp 'msdos-long-file-names)
			     (msdos-long-file-names)
			   t)))
654 655 656
                (while (and suffix-list (not found))
                  (cond ((info-file-exists-p
                          (info-insert-file-contents-1
657
                           temp (car (car suffix-list)) lfn))
658 659 660
                         (setq found temp))
                        ((info-file-exists-p
                          (info-insert-file-contents-1
661 662 663 664 665 666 667 668
                           temp-downcase (car (car suffix-list)) lfn))
                         (setq found temp-downcase))
			((and (fboundp 'msdos-long-file-names)
			      lfn
			      (info-file-exists-p
			       (info-insert-file-contents-1
				temp (car (car suffix-list)) nil)))
			 (setq found temp)))
669
                  (setq suffix-list (cdr suffix-list))))
Jesper Harder's avatar
Jesper Harder committed
670
              (setq dirs (cdr dirs))))))
671 672
        (if found
            (setq filename found)
Juri Linkov's avatar
Juri Linkov committed
673 674 675 676 677 678
          (if noerror
              (setq filename nil)
            (error "Info file %s does not exist" filename)))
        filename)))

(defun Info-find-node (filename nodename &optional no-going-back)
679
  "Go to an Info node specified as separate FILENAME and NODENAME.
Juri Linkov's avatar
Juri Linkov committed
680 681 682 683
NO-GOING-BACK is non-nil if recovering from an error in this function;
it says do not attempt further (recursive) error recovery."
  (info-initialize)
  (setq filename (Info-find-file filename))
684
  ;; Go into Info buffer.
685
  (or (eq major-mode 'Info-mode) (pop-to-buffer "*info*"))
686 687 688 689 690 691
  ;; Record the node we are leaving, if we were in one.
  (and (not no-going-back)
       Info-current-file
       (setq Info-history
	     (cons (list Info-current-file Info-current-node (point))
		   Info-history)))
692 693
  (Info-find-node-2 filename nodename no-going-back))

694
;;;###autoload
695
(defun Info-on-current-buffer (&optional nodename)
696 697 698
  "Use Info mode to browse the current Info buffer.
With a prefix arg, this queries for the node name to visit first;
otherwise, that defaults to `Top'."
699 700 701
  (interactive
   (list (if current-prefix-arg
	     (completing-read "Node name: " (Info-build-node-completions)
702 703
			      nil t "Top"))))
  (unless nodename (setq nodename "Top"))
704
  (info-initialize)
705
  (Info-mode)
706 707 708 709
  (set (make-local-variable 'Info-current-file)
       (or buffer-file-name
	   ;; If called on a non-file buffer, make a fake file name.
	   (concat default-directory (buffer-name))))
710 711
  (Info-find-node-2 nil nodename))

712 713 714 715 716
;; It's perhaps a bit nasty to kill the *info* buffer to force a re-read,
;; but at least it keeps this routine (which is only for the benefit of
;; makeinfo-buffer) out of the way of normal operations.
;;
(defun Info-revert-find-node (filename nodename)
717
  "Go to an Info node FILENAME and NODENAME, re-reading disk contents.
718 719 720 721 722 723 724 725 726
When *info* is already displaying FILENAME and NODENAME, the window position
is preserved, if possible."
  (pop-to-buffer "*info*")
  (let ((old-filename Info-current-file)
	(old-nodename Info-current-node)
	(pcolumn      (current-column))
	(pline        (count-lines (point-min) (line-beginning-position)))
	(wline        (count-lines (point-min) (window-start)))
	(old-history  Info-history)
727 728
	(new-history  (and Info-current-file
			   (list Info-current-file Info-current-node (point)))))
729 730 731 732 733 734 735
    (kill-buffer (current-buffer))
    (Info-find-node filename nodename)
    (setq Info-history old-history)
    (if (and (equal old-filename Info-current-file)
	     (equal old-nodename Info-current-node))
	(progn
	  ;; note goto-line is no good, we want to measure from point-min
736
	  (goto-char (point-min))
737 738
	  (forward-line wline)
	  (set-window-start (selected-window) (point))
739
	  (goto-char (point-min))
740 741 742 743 744 745
	  (forward-line pline)
	  (move-to-column pcolumn))
      ;; only add to the history when coming from a different file+node
      (if new-history
	  (setq Info-history (cons new-history Info-history))))))

746 747 748 749 750 751 752 753 754 755
(defun Info-find-in-tag-table-1 (marker regexp case-fold)
  "Find a node in a tag table.
MARKER specifies the buffer and position to start searching at.
REGEXP is a regular expression matching nodes or references.  Its first
group should match `Node:' or `Ref:'.
CASE-FOLD t means search for a case-insensitive match.
If a match was found, value is a list (FOUND-ANCHOR POS MODE), where
FOUND-ANCHOR is non-nil if a `Ref:' was matched, POS is the position
where the match was found, and MODE is `major-mode' of the buffer in
which the match was found."
756
  (let ((case-fold-search case-fold))
757 758 759
    (save-excursion
      (set-buffer (marker-buffer marker))
      (goto-char marker)
760

761 762 763 764
      ;; Search tag table
      (beginning-of-line)
      (when (re-search-forward regexp nil t)
	(list (string-equal "Ref:" (match-string 1))
765
	      (+ (point-min) (read (current-buffer)))
766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803
	      major-mode)))))

(defun Info-find-in-tag-table (marker regexp)
  "Find a node in a tag table.
MARKER specifies the buffer and position to start searching at.
REGEXP is a regular expression matching nodes or references.  Its first
group should match `Node:' or `Ref:'.
If a match was found, value is a list (FOUND-ANCHOR POS MODE), where
FOUND-ANCHOR is non-nil if a `Ref:' was matched, POS is the position
where the match was found, and MODE is `major-mode' of the buffer in
which the match was found.
This function tries to find a case-sensitive match first, then a
case-insensitive match is tried."
  (let ((result (Info-find-in-tag-table-1 marker regexp nil)))
    (when (null (car result))
      (setq result (Info-find-in-tag-table-1 marker regexp t)))
    result))

(defun Info-find-node-in-buffer-1 (regexp case-fold)
  "Find a node or anchor in the current buffer.
REGEXP is a regular expression matching nodes or references.  Its first
group should match `Node:' or `Ref:'.
CASE-FOLD t means search for a case-insensitive match.
Value is the position at which a match was found, or nil if not found."
  (let ((case-fold-search case-fold)
	found)
    (save-excursion
      (when (Info-node-at-bob-matching regexp)
	(setq found (point)))
      (while (and (not found)
		  (search-forward "\n\^_" nil t))
	(forward-line 1)
	(let ((beg (point)))
	  (forward-line 1)
	  (when (re-search-backward regexp beg t)
	    (beginning-of-line)
	    (setq found (point)))))
      found)))
804

805 806 807 808 809 810 811 812 813
(defun Info-find-node-in-buffer (regexp)
  "Find a node or anchor in the current buffer.
REGEXP is a regular expression matching nodes or references.  Its first
group should match `Node:' or `Ref:'.
Value is the position at which a match was found, or nil if not found.
This function looks for a case-sensitive match first.  If none is found,
a case-insensitive match is tried."
  (or (Info-find-node-in-buffer-1 regexp nil)
      (Info-find-node-in-buffer-1 regexp t)))
814

815
(defun Info-find-node-2 (filename nodename &optional no-going-back)
816
  (buffer-disable-undo (current-buffer))
Jim Blandy's avatar
Jim Blandy committed
817 818 819 820 821
  (or (eq major-mode 'Info-mode)
      (Info-mode))
  (widen)
  (setq Info-current-node nil)
  (unwind-protect
822 823
      (let ((case-fold-search t)
	    anchorpos)
824 825 826 827 828 829 830 831 832
        ;; Switch files if necessary
        (or (null filename)
            (equal Info-current-file filename)
            (let ((buffer-read-only nil))
              (setq Info-current-file nil
                    Info-current-subfile nil
                    Info-current-file-completions nil
                    buffer-file-name nil)
              (erase-buffer)
Jesper Harder's avatar
Jesper Harder committed
833 834 835 836 837
	      (cond
	       ((eq filename t)
		(Info-insert-dir))
	       ((eq filename 'apropos)
		(insert-buffer-substring " *info-apropos*"))
Juri Linkov's avatar
Juri Linkov committed
838 839 840 841
	       ((eq filename 'history)
		(insert-buffer-substring " *info-history*"))
	       ((eq filename 'toc)
		(insert-buffer-substring " *info-toc*"))
Jesper Harder's avatar
Jesper Harder committed
842
	       (t
843
                (info-insert-file-contents filename nil)
Jesper Harder's avatar
Jesper Harder committed
844
                (setq default-directory (file-name-directory filename))))
845
              (set-buffer-modified-p nil)
846 847 848 849 850 851 852 853 854 855 856 857 858

	      ;; Check makeinfo version for index cookie support
	      (let ((found nil))
		(goto-char (point-min))
		(condition-case ()
		    (if (and (re-search-forward
			      "makeinfo version \\([0-9]+.[0-9]+\\)"
			      (line-beginning-position 3) t)
			     (not (version< (match-string 1) "4.7")))
			(setq found t))
		  (error nil))
		(set (make-local-variable 'Info-file-supports-index-cookies) found))

859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882
              ;; See whether file has a tag table.  Record the location if yes.
              (goto-char (point-max))
              (forward-line -8)
              ;; Use string-equal, not equal, to ignore text props.
              (if (not (or (string-equal nodename "*")
                           (not
                            (search-forward "\^_\nEnd tag table\n" nil t))))
                  (let (pos)
                    ;; We have a tag table.  Find its beginning.
                    ;; Is this an indirect file?
                    (search-backward "\nTag table:\n")
                    (setq pos (point))
                    (if (save-excursion
                          (forward-line 2)
                          (looking-at "(Indirect)\n"))
                        ;; It is indirect.  Copy it to another buffer
                        ;; and record that the tag table is in that buffer.
                        (let ((buf (current-buffer))
                              (tagbuf
                               (or Info-tag-table-buffer
                                   (generate-new-buffer " *info tag table*"))))
                          (setq Info-tag-table-buffer tagbuf)
                          (save-excursion
                            (set-buffer tagbuf)
883
                            (buffer-disable-undo (current-buffer))
884 885 886 887 888 889 890 891
                            (setq case-fold-search t)
                            (erase-buffer)
                            (insert-buffer-substring buf))
                          (set-marker Info-tag-table-marker
                                      (match-end 0) tagbuf))
                      (set-marker Info-tag-table-marker pos)))
                (set-marker Info-tag-table-marker nil))
              (setq Info-current-file
Jesper Harder's avatar
Jesper Harder committed
892 893 894
		    (cond
		     ((eq filename t) "dir")
		     ((eq filename 'apropos) "apropos")
Juri Linkov's avatar
Juri Linkov committed
895 896
		     ((eq filename 'history) "history")
		     ((eq filename 'toc) "toc")
Jesper Harder's avatar
Jesper Harder committed
897 898
		     (t filename)))
	      ))
899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914
        ;; Use string-equal, not equal, to ignore text props.
        (if (string-equal nodename "*")
            (progn (setq Info-current-node nodename)
                   (Info-set-mode-line))
          ;; Possibilities:
          ;;
          ;; 1. Anchor found in tag table
          ;; 2. Anchor *not* in tag table
          ;;
          ;; 3. Node found in tag table
          ;; 4. Node *not* found in tag table, but found in file
          ;; 5. Node *not* in tag table, and *not* in file
          ;;
          ;; *Or* the same, but in an indirect subfile.

          ;; Search file for a suitable node.
915
	  (let ((guesspos (point-min))
916
		(regexp (concat "\\(Node:\\|Ref:\\) *\\("
917
				(if (stringp nodename)
918 919
				    (regexp-quote nodename)
				  "")
920
				"\\) *[,\t\n\177]")))
921

922
	    (catch 'foo
923

924
	      ;; First, search a tag table, if any
925 926 927
	      (when (marker-position Info-tag-table-marker)
		(let* ((m Info-tag-table-marker)
		       (found (Info-find-in-tag-table m regexp)))
928

929 930 931
		  (when found
		    ;; FOUND is (ANCHOR POS MODE).
		    (setq guesspos (nth 1 found))
932

933 934 935 936 937 938 939
		    ;; If this is an indirect file, determine which
		    ;; file really holds this node and read it in.
		    (unless (eq (nth 2 found) 'Info-mode)
		      ;; Note that the current buffer must be the
		      ;; *info* buffer on entry to
		      ;; Info-read-subfile.  Thus the hackery above.
		      (setq guesspos (Info-read-subfile guesspos)))
940 941

		    ;; Handle anchor
942 943 944
		    (when (nth 0 found)
		      (goto-char (setq anchorpos guesspos))
		      (throw 'foo t)))))
945 946 947 948

	      ;; Else we may have a node, which we search for:
	      (goto-char (max (point-min)
			      (- (byte-to-position guesspos) 1000)))
949

950 951 952 953 954 955 956
	      ;; Now search from our advised position (or from beg of
	      ;; buffer) to find the actual node.  First, check
	      ;; whether the node is right where we are, in case the
	      ;; buffer begins with a node.
	      (let ((pos (Info-find-node-in-buffer regexp)))
		(when pos
		  (goto-char pos)
957 958 959 960 961 962 963 964 965 966 967
		  (throw 'foo t)))

              (when (string-match "\\([^.]+\\)\\." nodename)
                (let (Info-point-loc)
                  (Info-find-node-2
                   filename (match-string 1 nodename) no-going-back))
                (widen)
                (throw 'foo t))

              ;; No such anchor in tag table or node in tag table or file
              (error "No such node or anchor: %s" nodename))
968 969

	    (Info-select-node)
Juri Linkov's avatar
Juri Linkov committed
970 971 972 973 974 975 976 977 978
	    (goto-char (point-min))
	    (cond (anchorpos
                   (let ((new-history (list Info-current-file
                                            (substring-no-properties nodename))))
                     ;; Add anchors to the history too
                     (setq Info-history-list
                           (cons new-history
                                 (delete new-history Info-history-list))))
                   (goto-char anchorpos))
979 980 981 982 983 984
                  ((numberp Info-point-loc)
                   (forward-line (1- Info-point-loc))
                   (setq Info-point-loc nil))
		  ((stringp Info-point-loc)
		   (Info-find-index-name Info-point-loc)
		   (setq Info-point-loc nil))))))
Jim Blandy's avatar
Jim Blandy committed
985 986
    ;; If we did not finish finding the specified node,
    ;; go back to the previous one.
987
    (or Info-current-node no-going-back (null Info-history)
988 989 990 991
        (let ((hist (car Info-history)))
          (setq Info-history (cdr Info-history))
          (Info-find-node (nth 0 hist) (nth 1 hist) t)
          (goto-char (nth 2 hist))))))
Jim Blandy's avatar
Jim Blandy committed
992

993 994
;; Cache the contents of the (virtual) dir file, once we have merged
;; it for the first time, so we can save time subsequently.
995 996
(defvar Info-dir-contents nil)

997 998 999 1000
;; Cache for the directory we decided to use for the default-directory
;; of the merged dir text.
(defvar Info-dir-contents-directory nil)

1001 1002 1003 1004
;; Record the file attributes of all the files from which we
;; constructed Info-dir-contents.
(defvar Info-dir-file-attributes nil)

1005 1006
(defvar Info-dir-file-name nil)

1007
;; Construct the Info directory node by merging the files named `dir'
1008 1009 1010
;; from various directories.  Set the *info* buffer's
;; default-directory to the first directory we actually get any text
;; from.
1011
(defun Info-insert-dir ()
1012 1013 1014 1015
  (if (and Info-dir-contents Info-dir-file-attributes
	   ;; Verify that none of the files we used has changed
	   ;; since we used it.
	   (eval (cons 'and
1016 1017 1018 1019 1020 1021 1022 1023 1024
		       (mapcar (lambda (elt)
				 (let ((curr (file-attributes
					      ;; Handle symlinks
					      (file-truename (car elt)))))

				   ;; Don't compare the access time.
				   (if curr (setcar (nthcdr 4 curr) 0))
				   (setcar (nthcdr 4 (cdr elt)) 0)
				   (equal (cdr elt) curr)))
1025
			       Info-dir-file-attributes))))
1026 1027 1028
      (progn
	(insert Info-dir-contents)
	(goto-char (point-min)))
1029
    (let ((dirs (if Info-additional-directory-list
Richard M. Stallman's avatar
Richard M. Stallman committed
1030 1031 1032
		    (append Info-directory-list
			    Info-additional-directory-list)
		  Info-directory-list))
1033
	  (dir-file-attrs nil)
1034 1035
	  ;; Bind this in case the user sets it to nil.
	  (case-fold-search t)
1036 1037
	  ;; This is set non-nil if we find a problem in some input files.
	  problems
1038
	  buffers buffer others nodes dirs-done)
1039 1040

      ;; Search the directory list for the directory file.
1041
      (while dirs
1042 1043 1044 1045 1046
	(let ((truename (file-truename (expand-file-name (car dirs)))))
	  (or (member truename dirs-done)
	      (member (directory-file-name truename) dirs-done)
	      ;; Try several variants of specified name.
	      ;; Try upcasing, appending `.info', or both.