tramp-smb.el 76.7 KB
Newer Older
Michael Albinus's avatar
Michael Albinus committed
1
;;; tramp-smb.el --- Tramp access functions for SMB servers  -*- lexical-binding:t -*-
2

Paul Eggert's avatar
Paul Eggert committed
3
;; Copyright (C) 2002-2019 Free Software Foundation, Inc.
4

Michael Albinus's avatar
Michael Albinus committed
5
;; Author: Michael Albinus <michael.albinus@gmx.de>
6
;; Keywords: comm, processes
7
;; Package: tramp
8 9 10

;; This file is part of GNU Emacs.

11
;; GNU Emacs is free software: you can redistribute it and/or modify
12
;; it under the terms of the GNU General Public License as published by
13 14
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
15 16 17 18 19 20 21

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
23 24 25 26 27 28 29

;;; Commentary:

;; Access functions for SMB servers like SAMBA or M$ Windows from Tramp.

;;; Code:

30
(eval-when-compile (require 'cl-lib))
31 32 33
(require 'tramp)

;; Define SMB method ...
34 35
;;;###tramp-autoload
(defconst tramp-smb-method "smb"
36
  "Method to connect SAMBA and M$ SMB servers.")
37 38

;; ... and add it to the method list.
39 40
;;;###tramp-autoload
(unless (memq system-type '(cygwin windows-nt))
41 42 43 44 45 46 47 48 49 50 51 52 53
  (tramp--with-startup
   (add-to-list 'tramp-methods
                `(,tramp-smb-method
                  ;; We define an empty command, because
                  ;; `tramp-smb-call-winexe' opens already the powershell.
                  ;; Used in `tramp-handle-shell-command'.
                  (tramp-remote-shell "")
                  ;; This is just a guess.  We don't know whether the share "C$"
                  ;; is available for public use, and whether the user has write
                  ;; access.
                  (tramp-tmpdir "/C$/Temp")
                  ;; Another guess.  We might implement a better check later on.
                  (tramp-case-insensitive t)))))
54

55 56
;; Add a default for `tramp-default-user-alist'. Rule: For the SMB method,
;; the anonymous user is chosen.
57
;;;###tramp-autoload
58 59 60
(tramp--with-startup
 (add-to-list 'tramp-default-user-alist
	      `(,(concat "\\`" tramp-smb-method "\\'") nil nil))
61

62 63 64 65
 ;; Add completion function for SMB method.
 (tramp-set-completion-function
  tramp-smb-method
  '((tramp-parse-netrc "~/.netrc"))))
66 67

(defcustom tramp-smb-program "smbclient"
68
  "Name of SMB client to run."
69
  :group 'tramp
Michael Albinus's avatar
Michael Albinus committed
70
  :type 'string)
71

72 73 74 75
(defcustom tramp-smb-acl-program "smbcacls"
  "Name of SMB acls to run."
  :group 'tramp
  :type 'string
Michael Albinus's avatar
Michael Albinus committed
76
  :version "24.4")
77

78
(defcustom tramp-smb-conf "/dev/null"
79
  "Path of the smb.conf file.
80 81 82
If it is nil, no smb.conf will be added to the `tramp-smb-program'
call, letting the SMB client use the default one."
  :group 'tramp
Michael Albinus's avatar
Michael Albinus committed
83
  :type '(choice (const nil) (file :must-match t)))
84

85
(defvar tramp-smb-version nil
86
  "Version string of the SMB client.")
87

Michael Albinus's avatar
Michael Albinus committed
88 89 90 91 92 93 94 95 96 97 98 99
(defconst tramp-smb-server-version
  "Domain=\\[[^]]*\\] OS=\\[[^]]*\\] Server=\\[[^]]*\\]"
  "Regexp of SMB server identification.")

(defconst tramp-smb-prompt "^\\(smb:\\|PS\\) .+> \\|^\\s-+Server\\s-+Comment$"
  "Regexp used as prompt in smbclient or powershell.")

(defconst tramp-smb-wrong-passwd-regexp
  (regexp-opt
   '("NT_STATUS_LOGON_FAILURE"
     "NT_STATUS_WRONG_PASSWORD"))
  "Regexp for login error strings of SMB servers.")
100 101 102 103

(defconst tramp-smb-errors
  (mapconcat
   'identity
104 105
   `(;; Connection error / timeout / unknown command.
     "Connection\\( to \\S-+\\)? failed"
106
     "Read from server failed, maybe it closed the connection"
107
     "Call timed out: server did not respond"
108
     "\\S-+: command not found"
109
     "Server doesn't support UNIX CIFS calls"
110 111 112 113 114 115 116 117 118 119 120
     ,(regexp-opt
       '(;; Samba.
	 "ERRDOS"
	 "ERRHRD"
	 "ERRSRV"
	 "ERRbadfile"
	 "ERRbadpw"
	 "ERRfilexists"
	 "ERRnoaccess"
	 "ERRnomem"
	 "ERRnosuchshare"
121
	 ;; See /usr/include/samba-4.0/core/ntstatus.h.
122
	 ;; Windows 4.0 (Windows NT), Windows 5.0 (Windows 2000),
123
	 ;; Windows 5.1 (Windows XP), Windows 5.2 (Windows Server 2003),
124
	 ;; Windows 6.0 (Windows Vista), Windows 6.1 (Windows 7),
125
	 ;; Windows 6.3 (Windows Server 2012, Windows 10).
126 127 128 129
	 "NT_STATUS_ACCESS_DENIED"
	 "NT_STATUS_ACCOUNT_LOCKED_OUT"
	 "NT_STATUS_BAD_NETWORK_NAME"
	 "NT_STATUS_CANNOT_DELETE"
130
	 "NT_STATUS_CONNECTION_DISCONNECTED"
131
	 "NT_STATUS_CONNECTION_REFUSED"
Michael Albinus's avatar
Michael Albinus committed
132
	 "NT_STATUS_CONNECTION_RESET"
133 134 135
	 "NT_STATUS_DIRECTORY_NOT_EMPTY"
	 "NT_STATUS_DUPLICATE_NAME"
	 "NT_STATUS_FILE_IS_A_DIRECTORY"
136
	 "NT_STATUS_HOST_UNREACHABLE"
137
	 "NT_STATUS_IMAGE_ALREADY_LOADED"
138
	 "NT_STATUS_INVALID_LEVEL"
139
	 "NT_STATUS_INVALID_PARAMETER_MIX"
140 141 142 143
	 "NT_STATUS_IO_TIMEOUT"
	 "NT_STATUS_LOGON_FAILURE"
	 "NT_STATUS_NETWORK_ACCESS_DENIED"
	 "NT_STATUS_NOT_IMPLEMENTED"
144
	 "NT_STATUS_NO_LOGON_SERVERS"
145 146
	 "NT_STATUS_NO_SUCH_FILE"
	 "NT_STATUS_NO_SUCH_USER"
Michael Albinus's avatar
Michael Albinus committed
147
	 "NT_STATUS_NOT_A_DIRECTORY"
148 149 150
	 "NT_STATUS_OBJECT_NAME_COLLISION"
	 "NT_STATUS_OBJECT_NAME_INVALID"
	 "NT_STATUS_OBJECT_NAME_NOT_FOUND"
151
	 "NT_STATUS_OBJECT_PATH_SYNTAX_BAD"
152
	 "NT_STATUS_PASSWORD_MUST_CHANGE"
153
	 "NT_STATUS_RESOURCE_NAME_NOT_FOUND"
154
	 "NT_STATUS_REVISION_MISMATCH"
155 156 157 158
	 "NT_STATUS_SHARING_VIOLATION"
	 "NT_STATUS_TRUSTED_RELATIONSHIP_FAILURE"
	 "NT_STATUS_UNSUCCESSFUL"
	 "NT_STATUS_WRONG_PASSWORD")))
159 160 161 162
   "\\|")
  "Regexp for possible error strings of SMB servers.
Used instead of analyzing error codes of commands.")

163 164 165 166 167 168 169 170 171 172
(defconst tramp-smb-actions-with-share
  '((tramp-smb-prompt tramp-action-succeed)
    (tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-process-alive))
  "List of pattern/action pairs.
This list is used for login to SMB servers.

See `tramp-actions-before-shell' for more info.")
173

174 175 176 177 178 179 180
(defconst tramp-smb-actions-without-share
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-action-out-of-band))
  "List of pattern/action pairs.
This list is used for login to SMB servers.
181

182
See `tramp-actions-before-shell' for more info.")
183

Michael Albinus's avatar
Michael Albinus committed
184 185 186 187 188 189 190 191 192 193
(defconst tramp-smb-actions-with-tar
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-smb-action-with-tar))
  "List of pattern/action pairs.
This list is used for tar-like copy of directories.

See `tramp-actions-before-shell' for more info.")

Michael Albinus's avatar
Michael Albinus committed
194
(defconst tramp-smb-actions-get-acl
195 196 197
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
Michael Albinus's avatar
Michael Albinus committed
198 199 200 201 202 203 204 205 206 207 208
    (tramp-process-alive-regexp tramp-smb-action-get-acl))
  "List of pattern/action pairs.
This list is used for smbcacls actions.

See `tramp-actions-before-shell' for more info.")

(defconst tramp-smb-actions-set-acl
  '((tramp-password-prompt-regexp tramp-action-password)
    (tramp-wrong-passwd-regexp tramp-action-permission-denied)
    (tramp-smb-errors tramp-action-permission-denied)
    (tramp-process-alive-regexp tramp-smb-action-set-acl))
209 210 211 212 213
  "List of pattern/action pairs.
This list is used for smbcacls actions.

See `tramp-actions-before-shell' for more info.")

214
;; New handlers should be added here.
Michael Albinus's avatar
Michael Albinus committed
215
;;;###tramp-autoload
216
(defconst tramp-smb-file-name-handler-alist
Michael Albinus's avatar
Michael Albinus committed
217
  '(;; `access-file' performed by default handler.
218
    (add-name-to-file . tramp-smb-handle-add-name-to-file)
219 220
    ;; `byte-compiler-base-file-name' performed by default handler.
    (copy-directory . tramp-smb-handle-copy-directory)
221 222 223
    (copy-file . tramp-smb-handle-copy-file)
    (delete-directory . tramp-smb-handle-delete-directory)
    (delete-file . tramp-smb-handle-delete-file)
224
    ;; `diff-latest-backup-file' performed by default handler.
225
    (directory-file-name . tramp-handle-directory-file-name)
226
    (directory-files . tramp-smb-handle-directory-files)
227
    (directory-files-and-attributes
228
     . tramp-handle-directory-files-and-attributes)
229
    (dired-compress-file . ignore)
230
    (dired-uncache . tramp-handle-dired-uncache)
231
    (exec-path . ignore)
232
    (expand-file-name . tramp-smb-handle-expand-file-name)
Michael Albinus's avatar
Michael Albinus committed
233
    (file-accessible-directory-p . tramp-handle-file-accessible-directory-p)
234
    (file-acl . tramp-smb-handle-file-acl)
235
    (file-attributes . tramp-smb-handle-file-attributes)
Michael Albinus's avatar
Michael Albinus committed
236
    (file-directory-p .  tramp-handle-file-directory-p)
237
    (file-file-equal-p . tramp-handle-file-equal-p)
238 239
    (file-executable-p . tramp-handle-file-exists-p)
    (file-exists-p . tramp-handle-file-exists-p)
240
    (file-in-directory-p . tramp-handle-file-in-directory-p)
241 242 243
    (file-local-copy . tramp-smb-handle-file-local-copy)
    (file-modes . tramp-handle-file-modes)
    (file-name-all-completions . tramp-smb-handle-file-name-all-completions)
244
    (file-name-as-directory . tramp-handle-file-name-as-directory)
245
    (file-name-case-insensitive-p . tramp-handle-file-name-case-insensitive-p)
246 247 248
    (file-name-completion . tramp-handle-file-name-completion)
    (file-name-directory . tramp-handle-file-name-directory)
    (file-name-nondirectory . tramp-handle-file-name-nondirectory)
249
    ;; `file-name-sans-versions' performed by default handler.
250
    (file-newer-than-file-p . tramp-handle-file-newer-than-file-p)
251
    (file-notify-add-watch . tramp-handle-file-notify-add-watch)
Michael Albinus's avatar
Michael Albinus committed
252
    (file-notify-rm-watch . tramp-handle-file-notify-rm-watch)
253
    (file-notify-valid-p . tramp-handle-file-notify-valid-p)
254
    (file-ownership-preserved-p . ignore)
255
    (file-readable-p . tramp-handle-file-exists-p)
256
    (file-regular-p . tramp-handle-file-regular-p)
Michael Albinus's avatar
Michael Albinus committed
257
    (file-remote-p . tramp-handle-file-remote-p)
Michael Albinus's avatar
Michael Albinus committed
258
    (file-selinux-context . tramp-handle-file-selinux-context)
259
    (file-symlink-p . tramp-handle-file-symlink-p)
260
    (file-system-info . tramp-smb-handle-file-system-info)
261
    (file-truename . tramp-handle-file-truename)
262
    (file-writable-p . tramp-smb-handle-file-writable-p)
263
    (find-backup-file-name . tramp-handle-find-backup-file-name)
264
    ;; `get-file-buffer' performed by default handler.
265 266 267
    (insert-directory . tramp-smb-handle-insert-directory)
    (insert-file-contents . tramp-handle-insert-file-contents)
    (load . tramp-handle-load)
268
    (make-auto-save-file-name . tramp-handle-make-auto-save-file-name)
269 270
    (make-directory . tramp-smb-handle-make-directory)
    (make-directory-internal . tramp-smb-handle-make-directory-internal)
271
    (make-nearby-temp-file . tramp-handle-make-nearby-temp-file)
272
    (make-process . ignore)
273
    (make-symbolic-link . tramp-smb-handle-make-symbolic-link)
Michael Albinus's avatar
Michael Albinus committed
274
    (process-file . tramp-smb-handle-process-file)
275
    (rename-file . tramp-smb-handle-rename-file)
276
    (set-file-acl . tramp-smb-handle-set-file-acl)
277
    (set-file-modes . tramp-smb-handle-set-file-modes)
278
    (set-file-selinux-context . ignore)
279
    (set-file-times . ignore)
Michael Albinus's avatar
Michael Albinus committed
280
    (set-visited-file-modtime . tramp-handle-set-visited-file-modtime)
Michael Albinus's avatar
Michael Albinus committed
281 282
    (shell-command . tramp-handle-shell-command)
    (start-file-process . tramp-smb-handle-start-file-process)
Michael Albinus's avatar
Michael Albinus committed
283
    (substitute-in-file-name . tramp-smb-handle-substitute-in-file-name)
284
    (temporary-file-directory . tramp-handle-temporary-file-directory)
Michael Albinus's avatar
Michael Albinus committed
285
    (tramp-set-file-uid-gid . ignore)
286
    (unhandled-file-name-directory . ignore)
287
    (vc-registered . ignore)
Michael Albinus's avatar
Michael Albinus committed
288 289
    (verify-visited-file-modtime . tramp-handle-verify-visited-file-modtime)
    (write-region . tramp-smb-handle-write-region))
290 291 292
  "Alist of handler functions for Tramp SMB method.
Operations not mentioned here will be handled by the default Emacs primitives.")

Michael Albinus's avatar
Michael Albinus committed
293 294 295 296 297 298 299
;; Options for remote processes via winexe.
(defcustom tramp-smb-winexe-program "winexe"
  "Name of winexe client to run.
If it isn't found in the local $PATH, the absolute path of winexe
shall be given.  This is needed for remote processes."
  :group 'tramp
  :type 'string
Michael Albinus's avatar
Michael Albinus committed
300
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
301 302 303 304 305 306

(defcustom tramp-smb-winexe-shell-command "powershell.exe"
  "Shell to be used for processes on remote machines.
This must be Powershell V2 compatible."
  :group 'tramp
  :type 'string
Michael Albinus's avatar
Michael Albinus committed
307
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
308 309 310 311 312 313

(defcustom tramp-smb-winexe-shell-command-switch "-file -"
  "Command switch used together with `tramp-smb-winexe-shell-command'.
This can be used to disable echo etc."
  :group 'tramp
  :type 'string
Michael Albinus's avatar
Michael Albinus committed
314
  :version "24.3")
Michael Albinus's avatar
Michael Albinus committed
315

316 317
;; It must be a `defsubst' in order to push the whole code into
;; tramp-loaddefs.el.  Otherwise, there would be recursive autoloading.
318 319
;;;###tramp-autoload
(defsubst tramp-smb-file-name-p (filename)
320
  "Check if it's a filename for SMB servers."
Michael Albinus's avatar
Michael Albinus committed
321 322 323
  (and (tramp-tramp-file-p filename)
       (string= (tramp-file-name-method (tramp-dissect-file-name filename))
		tramp-smb-method)))
324

325
;;;###tramp-autoload
326 327 328 329 330 331
(defun tramp-smb-file-name-handler (operation &rest args)
  "Invoke the SMB related OPERATION.
First arg specifies the OPERATION, second arg is a list of arguments to
pass to the OPERATION."
  (let ((fn (assoc operation tramp-smb-file-name-handler-alist)))
    (if fn
332
	(save-match-data (apply (cdr fn) args))
333 334
      (tramp-run-real-handler operation args))))

335 336
;;;###tramp-autoload
(unless (memq system-type '(cygwin windows-nt))
337 338 339
  (tramp--with-startup
   (tramp-register-foreign-file-name-handler
    #'tramp-smb-file-name-p #'tramp-smb-file-name-handler)))
340

341 342
;; File name primitives.

343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358
(defun tramp-smb-handle-add-name-to-file
  (filename newname &optional ok-if-already-exists)
  "Like `add-name-to-file' for Tramp files."
  (unless (tramp-equal-remote filename newname)
    (with-parsed-tramp-file-name
	(if (tramp-tramp-file-p filename) filename newname) nil
      (tramp-error
       v 'file-error
       "add-name-to-file: %s"
       "only implemented for same method, same user, same host")))
  (with-parsed-tramp-file-name filename v1
    (with-parsed-tramp-file-name newname v2
      (when (file-directory-p filename)
	(tramp-error
	 v2 'file-error
	 "add-name-to-file: %s must not be a directory" filename))
Michael Albinus's avatar
Michael Albinus committed
359 360 361 362 363 364 365 366 367 368 369
	;; Do the 'confirm if exists' thing.
	(when (file-exists-p newname)
	  ;; What to do?
	  (if (or (null ok-if-already-exists) ; not allowed to exist
		  (and (numberp ok-if-already-exists)
		       (not (yes-or-no-p
			     (format
			      "File %s already exists; make it a link anyway? "
			      v2-localname)))))
	      (tramp-error v2 'file-already-exists newname)
	    (delete-file newname)))
370 371
      ;; We must also flush the cache of the directory, because
      ;; `file-attributes' reads the values from there.
372 373
      (tramp-flush-file-properties v2 (file-name-directory v2-localname))
      (tramp-flush-file-properties v2 v2-localname)
374 375 376 377 378 379 380 381 382 383
      (unless
	  (tramp-smb-send-command
	   v1
	   (format
	    "%s \"%s\" \"%s\""
	    (if (tramp-smb-get-cifs-capabilities v1) "link" "hardlink")
	    (tramp-smb-get-localname v1)
	    (tramp-smb-get-localname v2)))
	(tramp-error
	 v2 'file-error
384
	 "error with add-name-to-file, see buffer `%s' for details"
385
	 (buffer-name))))))
386

Michael Albinus's avatar
Michael Albinus committed
387 388
(defun tramp-smb-action-with-tar (proc vec)
  "Untar from connection buffer."
389
  (if (not (process-live-p proc))
Michael Albinus's avatar
Michael Albinus committed
390 391 392 393 394 395 396 397 398 399 400 401
      (throw 'tramp-action 'process-died)

    (with-current-buffer (tramp-get-connection-buffer vec)
      (goto-char (point-min))
      (when (search-forward-regexp tramp-smb-server-version nil t)
	;; There might be a hidden password prompt.
	(widen)
	(forward-line)
	(tramp-message vec 6 (buffer-substring (point-min) (point)))
	(delete-region (point-min) (point))
	(throw 'tramp-action 'ok)))))

402
(defun tramp-smb-handle-copy-directory
403
  (dirname newname &optional keep-date parents copy-contents)
Michael Albinus's avatar
Michael Albinus committed
404
  "Like `copy-directory' for Tramp files."
405 406 407 408 409 410 411 412 413 414 415 416
  (if copy-contents
      ;; We must do it file-wise.
      (tramp-run-real-handler
       'copy-directory (list dirname newname keep-date parents copy-contents))

    (setq dirname (expand-file-name dirname)
	  newname (expand-file-name newname))
    (let ((t1 (tramp-tramp-file-p dirname))
	  (t2 (tramp-tramp-file-p newname)))
      (with-parsed-tramp-file-name (if t1 dirname newname) nil
	(with-tramp-progress-reporter
	    v 0 (format "Copying %s to %s" dirname newname)
417
	  (when (and (file-directory-p newname)
418
		     (not (tramp-compat-directory-name-p newname)))
419
	    (tramp-error v 'file-already-exists newname))
420 421 422 423 424 425 426 427 428 429
	  (cond
	   ;; We must use a local temporary directory.
	   ((and t1 t2)
	    (let ((tmpdir
		   (make-temp-name
		    (expand-file-name
		     tramp-temp-name-prefix
		     (tramp-compat-temporary-file-directory)))))
	      (unwind-protect
		  (progn
430
		    (make-directory tmpdir)
431 432
		    (copy-directory
		     dirname (file-name-as-directory tmpdir) keep-date 'parents)
433
		    (copy-directory
434 435
		     (expand-file-name (file-name-nondirectory dirname) tmpdir)
		     newname keep-date parents))
436
		(delete-directory tmpdir 'recursive))))
437 438

	   ;; We can copy recursively.
Michael Albinus's avatar
Michael Albinus committed
439
	   ;; TODO: Does not work reliably.
Michael Albinus's avatar
Michael Albinus committed
440
	   (nil ;(and (or t1 t2) (tramp-smb-get-cifs-capabilities v))
441 442 443 444 445 446 447 448 449 450
	    (when (and (file-directory-p newname)
		       (not (string-equal (file-name-nondirectory dirname)
					  (file-name-nondirectory newname))))
	      (setq newname
		    (expand-file-name
		     (file-name-nondirectory dirname) newname))
	      (if t2 (setq v (tramp-dissect-file-name newname))))
	    (if (not (file-directory-p newname))
		(make-directory newname parents))

451
	    (let* ((share (tramp-smb-get-share v))
452
		   (localname (file-name-as-directory
453
			       (replace-regexp-in-string
454 455 456 457 458
				"\\\\" "/" (tramp-smb-get-localname v))))
		   (tmpdir    (make-temp-name
			       (expand-file-name
				tramp-temp-name-prefix
				(tramp-compat-temporary-file-directory))))
459 460 461
		   (args      (list (concat "//" host "/" share) "-E"))
		   ;; We do not want to run timers.
		   timer-list timer-idle-list)
462

463 464
	      (if (not (zerop (length user)))
		  (setq args (append args (list "-U" user)))
465 466 467 468 469 470 471 472 473 474
		(setq args (append args (list "-N"))))

	      (when domain (setq args (append args (list "-W" domain))))
	      (when port   (setq args (append args (list "-p" port))))
	      (when tramp-smb-conf
		(setq args (append args (list "-s" tramp-smb-conf))))
	      (setq args
		    (if t1
			;; Source is remote.
			(append args
475 476
				(list "-D" (tramp-unquote-shell-quote-argument
					    localname)
477 478
				      "-c" (shell-quote-argument "tar qc - *")
				      "|" "tar" "xfC" "-"
479 480
				      (tramp-unquote-shell-quote-argument
				       tmpdir)))
481 482
		      ;; Target is remote.
		      (append (list "tar" "cfC" "-"
483 484
				    (tramp-unquote-shell-quote-argument dirname)
				    "." "|")
485
			      args
486 487
			      (list "-D" (tramp-unquote-shell-quote-argument
					  localname)
488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504
				    "-c" (shell-quote-argument "tar qx -")))))

	      (unwind-protect
		  (with-temp-buffer
		    ;; Set the transfer process properties.
		    (tramp-set-connection-property
		     v "process-name" (buffer-name (current-buffer)))
		    (tramp-set-connection-property
		     v "process-buffer" (current-buffer))

		    (when t1
		      ;; The smbclient tar command creates always
		      ;; complete paths.  We must emulate the
		      ;; directory structure, and symlink to the real
		      ;; target.
		      (make-directory
		       (expand-file-name
505 506
			".." (concat tmpdir localname))
		       'parents)
507 508 509 510 511 512
		      (make-symbolic-link
		       newname (directory-file-name (concat tmpdir localname))))

		    ;; Use an asynchronous processes.  By this,
		    ;; password can be handled.
		    (let* ((default-directory tmpdir)
513 514
			   (p (apply
			       'start-process
515 516
			       (tramp-get-connection-name v)
			       (tramp-get-connection-buffer v)
517
			       tramp-smb-program args)))
518 519 520

		      (tramp-message
		       v 6 "%s" (mapconcat 'identity (process-command p) " "))
Michael Albinus's avatar
Michael Albinus committed
521
		      (process-put p 'vector v)
522
		      (process-put p 'adjust-window-size-function 'ignore)
523
		      (set-process-query-on-exit-flag p nil)
524 525
		      (tramp-process-actions p v nil tramp-smb-actions-with-tar)

526
		      (while (process-live-p p)
527 528 529 530
			(sit-for 0.1))
		      (tramp-message v 6 "\n%s" (buffer-string))))

		;; Reset the transfer process properties.
531 532
		(tramp-flush-connection-property v "process-name")
		(tramp-flush-connection-property v "process-buffer")
533
		(when t1 (delete-directory tmpdir 'recursive))))
534 535 536

	    ;; Handle KEEP-DATE argument.
	    (when keep-date
537 538 539 540
	      (set-file-times
	       newname
	       (tramp-compat-file-attribute-modification-time
		(file-attributes dirname))))
541 542 543 544 545 546 547 548

	    ;; Set the mode.
	    (unless keep-date
	      (set-file-modes newname (tramp-default-file-modes dirname)))

	    ;; When newname did exist, we have wrong cached values.
	    (when t2
	      (with-parsed-tramp-file-name newname nil
549 550
		(tramp-flush-file-properties v (file-name-directory localname))
		(tramp-flush-file-properties v localname))))
551 552 553 554 555

	   ;; We must do it file-wise.
	   (t
	    (tramp-run-real-handler
	     'copy-directory (list dirname newname keep-date parents)))))))))
556 557

(defun tramp-smb-handle-copy-file
Michael Albinus's avatar
Michael Albinus committed
558
  (filename newname &optional ok-if-already-exists keep-date
559
   _preserve-uid-gid _preserve-extended-attributes)
560
  "Like `copy-file' for Tramp files.
Michael Albinus's avatar
Michael Albinus committed
561
KEEP-DATE has no effect in case NEWNAME resides on an SMB server.
562
PRESERVE-UID-GID and PRESERVE-EXTENDED-ATTRIBUTES are completely ignored."
563 564
  (setq filename (expand-file-name filename)
	newname (expand-file-name newname))
565
  (with-tramp-progress-reporter
Michael Albinus's avatar
Michael Albinus committed
566 567
      (tramp-dissect-file-name
       (if (tramp-tramp-file-p filename) filename newname))
568 569
      0 (format "Copying %s to %s" filename newname)

Michael Albinus's avatar
Michael Albinus committed
570
    (if (file-directory-p filename)
571
	(copy-directory filename newname keep-date 'parents 'copy-contents)
Michael Albinus's avatar
Michael Albinus committed
572 573 574 575 576 577 578 579 580 581 582

      (let ((tmpfile (file-local-copy filename)))
	(if tmpfile
	    ;; Remote filename.
	    (condition-case err
		(rename-file tmpfile newname ok-if-already-exists)
	      ((error quit)
	       (delete-file tmpfile)
	       (signal (car err) (cdr err))))

	  ;; Remote newname.
583
	  (when (and (file-directory-p newname)
584
		     (tramp-compat-directory-name-p newname))
Michael Albinus's avatar
Michael Albinus committed
585 586 587 588 589 590 591 592 593 594
	    (setq newname
		  (expand-file-name (file-name-nondirectory filename) newname)))

	  (with-parsed-tramp-file-name newname nil
	    (when (and (not ok-if-already-exists)
		       (file-exists-p newname))
	      (tramp-error v 'file-already-exists newname))

	    ;; We must also flush the cache of the directory, because
	    ;; `file-attributes' reads the values from there.
595 596
	    (tramp-flush-file-properties v (file-name-directory localname))
	    (tramp-flush-file-properties v localname)
Michael Albinus's avatar
Michael Albinus committed
597 598
	    (unless (tramp-smb-get-share v)
	      (tramp-error
599
	       v 'file-error "Target `%s' must contain a share name" newname))
Michael Albinus's avatar
Michael Albinus committed
600 601
	    (unless (tramp-smb-send-command
		     v (format "put \"%s\" \"%s\""
602 603
			       (tramp-compat-file-name-unquote filename)
			       (tramp-smb-get-localname v)))
604
	      (tramp-error
605
	       v 'file-error "Cannot copy `%s' to `%s'" filename newname))))))
606

Michael Albinus's avatar
Michael Albinus committed
607 608
    ;; KEEP-DATE handling.
    (when keep-date
609 610 611 612
      (set-file-times
       newname
       (tramp-compat-file-attribute-modification-time
	(file-attributes filename))))))
613

Michael Albinus's avatar
Michael Albinus committed
614
(defun tramp-smb-handle-delete-directory (directory &optional recursive _trash)
615
  "Like `delete-directory' for Tramp files."
616
  (setq directory (directory-file-name (expand-file-name directory)))
Michael Albinus's avatar
Michael Albinus committed
617
  (when (file-exists-p directory)
618 619 620 621 622 623 624 625
    (when recursive
      (mapc
       (lambda (file)
	 (if (file-directory-p file)
	     (delete-directory file recursive)
	   (delete-file file)))
       ;; We do not want to delete "." and "..".
       (directory-files directory 'full directory-files-no-dot-files-regexp)))
626

Michael Albinus's avatar
Michael Albinus committed
627
    (with-parsed-tramp-file-name directory nil
628
      ;; We must also flush the cache of the directory, because
629
      ;; `file-attributes' reads the values from there.
630 631
      (tramp-flush-file-properties v (file-name-directory localname))
      (tramp-flush-directory-properties v localname)
632 633 634 635 636 637 638 639 640 641
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_rmdir" "rmdir")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
642 643 644 645 646 647
	   v 'file-error "%s `%s'" (match-string 0) directory)))

      ;; "rmdir" does not report an error.  So we check ourselves.
      (when (file-exists-p directory)
	(tramp-error
	 v 'file-error "`%s' not removed." directory)))))
648

649
(defun tramp-smb-handle-delete-file (filename &optional _trash)
650
  "Like `delete-file' for Tramp files."
651
  (setq filename (expand-file-name filename))
Michael Albinus's avatar
Michael Albinus committed
652 653
  (when (file-exists-p filename)
    (with-parsed-tramp-file-name filename nil
654
      ;; We must also flush the cache of the directory, because
655
      ;; `file-attributes' reads the values from there.
656 657
      (tramp-flush-file-properties v (file-name-directory localname))
      (tramp-flush-file-properties v localname)
658 659 660 661 662 663 664 665 666 667
      (unless (tramp-smb-send-command
	       v (format
		  "%s \"%s\""
		  (if (tramp-smb-get-cifs-capabilities v) "posix_unlink" "rm")
		  (tramp-smb-get-localname v)))
	;; Error.
	(with-current-buffer (tramp-get-connection-buffer v)
	  (goto-char (point-min))
	  (search-forward-regexp tramp-smb-errors nil t)
	  (tramp-error
668
	   v 'file-error "%s `%s'" (match-string 0) filename))))))
669 670 671

(defun tramp-smb-handle-directory-files
  (directory &optional full match nosort)
672 673
  "Like `directory-files' for Tramp files."
  (let ((result (mapcar 'directory-file-name
674
			(file-name-all-completions "" directory))))
675
    ;; Discriminate with regexp.
676 677 678
    (when match
      (setq result
	    (delete nil
679
		    (mapcar (lambda (x) (when (string-match-p match x) x))
680
			    result))))
681
    ;; Append directory.
682 683 684
    (when full
      (setq result
	    (mapcar
685
	     (lambda (x) (format "%s/%s" directory x))
686
	     result)))
687
    ;; Sort them if necessary.
688
    (unless nosort (setq result (sort result 'string-lessp)))
Michael Albinus's avatar
Michael Albinus committed
689
    result))
690

691 692 693 694 695 696 697 698 699 700 701 702 703
(defun tramp-smb-handle-expand-file-name (name &optional dir)
  "Like `expand-file-name' for Tramp files."
  ;; If DIR is not given, use DEFAULT-DIRECTORY or "/".
  (setq dir (or dir default-directory "/"))
  ;; Unless NAME is absolute, concat DIR and NAME.
  (unless (file-name-absolute-p name)
    (setq name (concat (file-name-as-directory dir) name)))
  ;; If NAME is not a Tramp file, run the real handler.
  (if (not (tramp-tramp-file-p name))
      (tramp-run-real-handler 'expand-file-name (list name nil))
    ;; Dissect NAME.
    (with-parsed-tramp-file-name name nil
      ;; Tilde expansion if necessary.  We use the user name as share,
Paul Eggert's avatar
Paul Eggert committed
704
      ;; which is often the case in domains.
705
      (when (string-match "\\`/?~\\([^/]*\\)" localname)
706 707
	(setq localname
	      (replace-match
708
	       (if (zerop (length (match-string 1 localname)))
709
		   user
710
		 (match-string 1 localname))
711
	       nil nil localname)))
712 713 714
      ;; Make the file name absolute.
      (unless (tramp-run-real-handler 'file-name-absolute-p (list localname))
	(setq localname (concat "/" localname)))
715 716 717
      ;; No tilde characters in file name, do normal
      ;; `expand-file-name' (this does "/./" and "/../").
      (tramp-make-tramp-file-name
718
       v (tramp-run-real-handler 'expand-file-name (list localname))))))
719

Michael Albinus's avatar
Michael Albinus committed
720
(defun tramp-smb-action-get-acl (proc vec)
721
  "Read ACL data from connection buffer."
722
  (unless (process-live-p proc)
723
    ;; Accept pending output.
724
    (while (tramp-accept-process-output proc))
725 726 727 728 729
    (with-current-buffer (tramp-get-connection-buffer vec)
      ;; There might be a hidden password prompt.
      (widen)
      (tramp-message vec 10 "\n%s" (buffer-string))
      (goto-char (point-min))
730
      (while (and (not (eobp)) (not (looking-at-p "^REVISION:")))
731 732
	(forward-line)
	(delete-region (point-min) (point)))
733
      (while (and (not (eobp)) (looking-at-p "^.+:.+"))
734 735 736 737
 	(forward-line))
      (delete-region (point) (point-max))
      (throw 'tramp-action 'ok))))

738 739
(defun tramp-smb-handle-file-acl (filename)
  "Like `file-acl' for Tramp files."
Michael Albinus's avatar
Michael Albinus committed
740 741 742 743 744 745 746
  (ignore-errors
    (with-parsed-tramp-file-name filename nil
      (with-tramp-file-property v localname "file-acl"
	(when (executable-find tramp-smb-acl-program)
	  (let* ((share     (tramp-smb-get-share v))
		 (localname (replace-regexp-in-string
			     "\\\\" "/" (tramp-smb-get-localname v)))
747 748 749
		 (args      (list (concat "//" host "/" share) "-E"))
		 ;; We do not want to run timers.
		 timer-list timer-idle-list)
Michael Albinus's avatar
Michael Albinus committed
750 751 752 753 754 755 756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781

	    (if (not (zerop (length user)))
		(setq args (append args (list "-U" user)))
	      (setq args (append args (list "-N"))))

	    (when domain (setq args (append args (list "-W" domain))))
	    (when port   (setq args (append args (list "-p" port))))
	    (when tramp-smb-conf
	      (setq args (append args (list "-s" tramp-smb-conf))))
	    (setq
	     args
	     (append args (list (tramp-unquote-shell-quote-argument localname)
				"2>/dev/null")))

	    (unwind-protect
		(with-temp-buffer
		  ;; Set the transfer process properties.
		  (tramp-set-connection-property
		   v "process-name" (buffer-name (current-buffer)))
		  (tramp-set-connection-property
		   v "process-buffer" (current-buffer))

		  ;; Use an asynchronous process.  By this, password can
		  ;; be handled.
		  (let ((p (apply
			    'start-process
			    (tramp-get-connection-name v)
			    (tramp-get-connection-buffer v)
			    tramp-smb-acl-program args)))

		    (tramp-message
		     v 6 "%s" (mapconcat 'identity (process-command p) " "))
Michael Albinus's avatar
Michael Albinus committed
782
		    (process-put p 'vector v)
Michael Albinus's avatar
Michael Albinus committed
783 784 785 786 787 788 789
		    (process-put p 'adjust-window-size-function 'ignore)
		    (set-process-query-on-exit-flag p nil)
		    (tramp-process-actions p v nil tramp-smb-actions-get-acl)
		    (when (> (point-max) (point-min))
		      (substring-no-properties (buffer-string)))))

	      ;; Reset the transfer process properties.
790 791
	      (tramp-flush-connection-property v "process-name")
	      (tramp-flush-connection-property v "process-buffer"))))))))
792

793
(defun tramp-smb-handle-file-attributes (filename &optional id-format)
794
  "Like `file-attributes' for Tramp files."
795
  (unless id-format (setq id-format 'integer))
796 797
  (ignore-errors
    (with-parsed-tramp-file-name filename nil
798 799
      (with-tramp-file-property
	  v localname (format "file-attributes-%s" id-format)
800
	(if (tramp-smb-get-stat-capability v)
801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817
	    (tramp-smb-do-file-attributes-with-stat v id-format)
	  ;; Reading just the filename entry via "dir localname" is not
	  ;; possible, because when filename is a directory, some
	  ;; smbclient versions return the content of the directory, and
	  ;; other versions don't.  Therefore, the whole content of the
	  ;; upper directory is retrieved, and the entry of the filename
	  ;; is extracted from.
	  (let* ((entries (tramp-smb-get-file-entries
			   (file-name-directory filename)))
		 (entry (assoc (file-name-nondirectory filename) entries))
		 (uid (if (equal id-format 'string) "nobody" -1))
		 (gid (if (equal id-format 'string) "nogroup" -1))
		 (inode (tramp-get-inode v))
		 (device (tramp-get-device v)))

	    ;; Check result.
	    (when entry
818
	      (list (and (string-match-p "d" (nth 1 entry))
819 820 821 822 823 824 825 826 827 828 829 830
			 t)              ;0 file type
		    -1	                 ;1 link count
		    uid	                 ;2 uid
		    gid	                 ;3 gid
		    tramp-time-dont-know ;4 atime
		    (nth 3 entry)        ;5 mtime
		    tramp-time-dont-know ;6 ctime
		    (nth 2 entry)        ;7 size
		    (nth 1 entry)        ;8 mode
		    nil	                 ;9 gid weird
		    inode	         ;10 inode number
		    device))))))))       ;11 file system number
831

832
(defun tramp-smb-do-file-attributes-with-stat (vec &optional id-format)
833
  "Implement `file-attributes' for Tramp files using stat command."
834 835
  (tramp-message
   vec 5 "file attributes with stat: %s" (tramp-file-name-localname vec))
Michael Albinus's avatar
Michael Albinus committed
836
  (with-current-buffer (tramp-get-connection-buffer vec)
837
    (let* (size id link uid gid atime mtime ctime mode inode)
838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892
      (when (tramp-smb-send-command
	     vec (format "stat \"%s\"" (tramp-smb-get-localname vec)))

	;; Loop the listing.
	(goto-char (point-min))
	(unless (re-search-forward tramp-smb-errors nil t)
	  (while (not (eobp))
	    (cond
	     ((looking-at
	       "Size:\\s-+\\([0-9]+\\)\\s-+Blocks:\\s-+[0-9]+\\s-+\\(\\w+\\)")
	      (setq size (string-to-number (match-string 1))
		    id (if (string-equal "directory" (match-string 2)) t
			 (if (string-equal "symbolic" (match-string 2)) ""))))
	     ((looking-at
	       "Inode:\\s-+\\([0-9]+\\)\\s-+Links:\\s-+\\([0-9]+\\)")
	      (setq inode (string-to-number (match-string 1))
		    link (string-to-number (match-string 2))))
	     ((looking-at
	       "Access:\\s-+([0-9]+/\\(\\S-+\\))\\s-+Uid:\\s-+\\([0-9]+\\)\\s-+Gid:\\s-+\\([0-9]+\\)")
	      (setq mode (match-string 1)
		    uid (if (equal id-format 'string) (match-string 2)
			  (string-to-number (match-string 2)))
		    gid (if (equal id-format 'string) (match-string 3)
			  (string-to-number (match-string 3)))))
	     ((looking-at
	       "Access:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq atime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Modify:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq mtime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1))))) ;; year
	     ((looking-at
	       "Change:\\s-+\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)\\s-+\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)")
	      (setq ctime
		    (encode-time
		     (string-to-number (match-string 6)) ;; sec
		     (string-to-number (match-string 5)) ;; min
		     (string-to-number (match-string 4)) ;; hour
		     (string-to-number (match-string 3)) ;; day
		     (string-to-number (match-string 2)) ;; month
		     (string-to-number (match-string 1)))))) ;; year
	    (forward-line))
Michael Albinus's avatar
Michael Albinus committed
893 894 895 896 897 898 899 900 901 902

	  ;; Resolve symlink.
	  (when (and (stringp id)
		     (tramp-smb-send-command
		      vec
		      (format "readlink \"%s\"" (tramp-smb-get-localname vec))))
	    (goto-char (point-min))
	    (and (looking-at ".+ -> \\(.+\\)")
		 (setq id (match-string 1))))

903
	  ;; Return the result.
904 905 906
	  (when (or id link uid gid atime mtime ctime size mode inode)
	    (list id link uid gid atime mtime ctime size mode nil inode
		  (tramp-get-device vec))))))))
907 908

(defun tramp-smb-handle-file-local-copy (filename)
909
  "Like `file-local-copy' for Tramp files."
910 911
  (with-parsed-tramp-file-name (file-truename filename) nil
    (unless (file-exists-p (file-truename filename))
912
      (tramp-error
Michael Albinus's avatar
Michael Albinus committed
913
       v tramp-file-missing
914
       "Cannot make local copy of non-existing file `%s'" filename))
915
    (let ((tmpfile (tramp-compat-make-temp-file filename)))
916
      (with-tramp-progress-reporter
917 918 919 920 921
	  v 3 (format "Fetching %s to tmp file %s" filename tmpfile)
	(unless (tramp-smb-send-command
		 v (format "get \"%s\" \"%s\""
			   (tramp-smb-get-localname v) tmpfile))
	  ;; Oops, an error.  We shall cleanup.
922
	  (delete-file tmpfile)
923
	  (tramp-error
924
	   v 'file-error "Cannot make local copy of file `%s'" filename)))
925
      tmpfile)))
926 927 928 929

;; This function should return "foo/" for directories and "bar" for
;; files.
(defun tramp-smb-handle-file-name-all-completions (filename directory)
930 931 932
  "Like `file-name-all-completions' for Tramp files."
  (all-completions
   filename
Michael Albinus's avatar
Michael Albinus committed
933
   (with-parsed-tramp-file-name (expand-file-name directory) nil
934
     (with-tramp-file-property v localname "file-name-all-completions"
935 936 937 938 939 940 941 942
       (delete-dups
	(mapcar
	 (lambda (x)
	   (list
	    (if (string-match-p "d" (nth 1 x))
		(file-name-as-directory (nth 0 x))
	      (nth 0 x))))
	 (tramp-smb-get-file-entries directory)))))))
943

944 945 946 947 948 949 950 951 952 953 954 955 956
(defun tramp-smb-handle-file-system-info (filename)
  "Like `file-system-info' for Tramp files."
  (ignore-errors
    (unless (file-directory-p filename)
      (setq filename (file-name-directory filename)))
    (with-parsed-tramp-file-name (expand-file-name filename) nil
      (tramp-message v 5 "file system info: %s" localname)
      (tramp-smb-send-command v (format "du %s/*" (tramp-smb-get-localname v)))
      (with-current-buffer (tramp-get-connection-buffer v)
	(let (total avail blocksize)
	  (goto-char (point-min))
	  (forward-line)
	  (when (looking-at
957 958 959 960
		 (eval-when-compile
		   (concat "[[:space:]]*\\([[:digit:]]+\\)"
			   " blocks of size \\([[:digit:]]+\\)"
			   "\\. \\([[:digit:]]+\\) blocks available")))
Michael Albinus's avatar
Michael Albinus committed
961 962 963
	    (setq blocksize (string-to-number (match-string 2))
		  total (* blocksize (string-to-number (match-string 1)))
		  avail (* blocksize (string-to-number (match-string 3)))))
964 965 966 967 968
	  (forward-line)
	  (when (looking-at "Total number of bytes: \\([[:digit:]]+\\)")
	    ;; The used number of bytes is not part of the result.  As
	    ;; side effect, we store it as file property.
	    (tramp-set-file-property
Michael Albinus's avatar
Michael Albinus committed
969
	     v localname "used-bytes" (string-to-number (match-string 1))))
970 971 972 973
	  ;; Result.
	  (when (and total avail)
	    (list total (- total avail) avail)))))))

974
(defun tramp-smb-handle-file-writable-p (filename)
975 976
  "Like `file-writable-p' for Tramp files."
  (if (file-exists-p filename)
977
      (string-match-p
978 979
       "w"
       (or (tramp-compat-file-attribute-modes (file-attributes filename)) ""))
980 981 982
    (let ((dir (file-name-directory filename)))
      (and (file-exists-p dir)
	   (file-writable-p dir)))))
983 984 985

(defun tramp-smb-handle-insert-directory
  (filename switches &optional wildcard full-directory-p)
986
  "Like `insert-directory' for Tramp files."
987
  (setq filename (expand-file-name filename))
988
  (unless switches (setq switches ""))
989 990 991 992
  ;; Mark trailing "/".
  (when (and (zerop (length (file-name-nondirectory filename)))
	     (not full-directory-p))
    (setq switches (concat switches "F")))
993 994 995 996
  (if full-directory-p
      ;; Called from `dired-add-entry'.
      (setq filename (file-name-as-directory filename))
    (setq filename (directory-file-name filename)))
Michael Albinus's avatar
Michael Albinus committed
997
  (with-parsed-tramp-file-name filename nil
998 999 1000 1001
    (with-tramp-progress-reporter v 0 (format "Opening directory %s" filename)
      (save-match-data
	(let ((base (file-name-nondirectory filename))
	      ;; We should not destroy the cache entry.
Michael Albinus's avatar
Michael Albinus committed
1002
	      (entries (copy-tree
1003
			(tramp-smb-get-file-entries
1004 1005 1006 1007 1008 1009 1010 1011
			 (file-name-directory filename))))
	      (avail (get-free-disk-space filename))
	      ;; `get-free-disk-space' calls `file-system-info', which
	      ;; sets file property "used-bytes" as side effect.
	      (used
	       (format
		"%.0f"
		(/ (tramp-get-file-property v localname "used-bytes" 0) 1024))))
1012 1013 1014 1015 1016 1017 1018 1019 1020 1021 1022 1023 1024 1025 1026 1027 1028

	  (when wildcard
	    (string-match "\\." base)
	    (setq base (replace-match "\\\\." nil nil base))
	    (string-match "\\*" base)
	    (setq base (replace-match ".*" nil nil base))
	    (string-match "\\?" base)
	    (setq base (replace-match ".?" nil nil base)))

	  ;; Filter entries.
	  (setq entries
		(delq
		 nil
		 (if (or wildcard (zerop (length