nadvice.el 22.1 KB
Newer Older
1 2
;;; nadvice.el --- Light-weight advice primitives for Elisp functions  -*- lexical-binding: t -*-

3
;; Copyright (C) 2012-2014 Free Software Foundation, Inc.
4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25

;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
;; Keywords: extensions, lisp, tools
;; Package: emacs

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; This package lets you add behavior (which we call "piece of advice") to
;; existing functions, like the old `advice.el' package, but with much fewer
26
;; bells and whistles.  It comes in 2 parts:
27 28 29 30 31 32
;;
;; - The first part lets you add/remove functions, similarly to
;;   add/remove-hook, from any "place" (i.e. as accepted by `setf') that
;;   holds a function.
;;   This part provides mainly 2 macros: `add-function' and `remove-function'.
;;
33
;; - The second part provides `advice-add' and `advice-remove' which are
34 35 36 37 38 39 40 41 42 43
;;   refined version of the previous macros specially tailored for the case
;;   where the place that we want to modify is a `symbol-function'.

;;; Code:

;;;; Lightweight advice/hook
(defvar advice--where-alist
  '((:around "\300\301\302\003#\207" 5)
    (:before "\300\301\002\"\210\300\302\002\"\207" 4)
    (:after "\300\302\002\"\300\301\003\"\210\207" 5)
44
    (:override "\300\301\"\207" 4)
45 46 47
    (:after-until "\300\302\002\"\206\013\000\300\301\002\"\207" 4)
    (:after-while "\300\302\002\"\205\013\000\300\301\002\"\207" 4)
    (:before-until "\300\301\002\"\206\013\000\300\302\002\"\207" 4)
48 49 50
    (:before-while "\300\301\002\"\205\013\000\300\302\002\"\207" 4)
    (:filter-args "\300\302\301!\"\207" 5)
    (:filter-return "\301\300\302\"!\207" 5))
51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114
  "List of descriptions of how to add a function.
Each element has the form (WHERE BYTECODE STACK) where:
  WHERE is a keyword indicating where the function is added.
  BYTECODE is the corresponding byte-code that will be used.
  STACK is the amount of stack space needed by the byte-code.")

(defvar advice--bytecodes (mapcar #'cadr advice--where-alist))

(defun advice--p (object)
  (and (byte-code-function-p object)
       (eq 128 (aref object 0))
       (memq (length object) '(5 6))
       (memq (aref object 1) advice--bytecodes)
       (eq #'apply (aref (aref object 2) 0))))

(defsubst advice--car   (f) (aref (aref f 2) 1))
(defsubst advice--cdr   (f) (aref (aref f 2) 2))
(defsubst advice--props (f) (aref (aref f 2) 3))

(defun advice--make-docstring (_string function)
  "Build the raw doc-string of SYMBOL, presumably advised."
  (let ((flist (indirect-function function))
        (docstring nil))
    (if (eq 'macro (car-safe flist)) (setq flist (cdr flist)))
    (while (advice--p flist)
      (let ((bytecode (aref flist 1))
            (where nil))
        (dolist (elem advice--where-alist)
          (if (eq bytecode (cadr elem)) (setq where (car elem))))
        (setq docstring
              (concat
               docstring
               (propertize (format "%s advice: " where)
                           'face 'warning)
               (let ((fun (advice--car flist)))
                 (if (symbolp fun) (format "`%S'" fun)
                   (let* ((name (cdr (assq 'name (advice--props flist))))
                          (doc (documentation fun t))
                          (usage (help-split-fundoc doc function)))
                     (if usage (setq doc (cdr usage)))
                     (if name
                         (if doc
                             (format "%s\n%s" name doc)
                           (format "%s" name))
                       (or doc "No documentation")))))
               "\n")))
      (setq flist (advice--cdr flist)))
    (if docstring (setq docstring (concat docstring "\n")))
    (let* ((origdoc (unless (eq function flist) ;Avoid inf-loops.
                      (documentation flist t)))
           (usage (help-split-fundoc origdoc function)))
      (setq usage (if (null usage)
                      (let ((arglist (help-function-arglist flist)))
                        (format "%S" (help-make-usage function arglist)))
                    (setq origdoc (cdr usage)) (car usage)))
      (help-add-fundoc-usage (concat docstring origdoc) usage))))

(defvar advice--docstring
  ;; Can't eval-when-compile nor use defconst because it then gets pure-copied,
  ;; which drops the text-properties.
  ;;(eval-when-compile
  (propertize "Advised function"
              'dynamic-docstring-function #'advice--make-docstring)) ;; )

115 116 117 118 119 120 121 122 123 124 125 126 127
(defun advice-eval-interactive-spec (spec)
  "Evaluate the interactive spec SPEC."
  (cond
   ((stringp spec)
    ;; There's no direct access to the C code (in call-interactively) that
    ;; processes those specs, but that shouldn't stop us, should it?
    ;; FIXME: Despite appearances, this is not faithful: SPEC and
    ;; (advice-eval-interactive-spec SPEC) will behave subtly differently w.r.t
    ;; command-history (and maybe a few other details).
    (call-interactively `(lambda (&rest args) (interactive ,spec) args)))
   ;; ((functionp spec) (funcall spec))
   (t (eval spec))))

128 129 130
(defun advice--make-interactive-form (function main)
  ;; TODO: make it so that interactive spec can be a constant which
  ;; dynamically checks the advice--car/cdr to do its job.
131 132
  ;; For that, advice-eval-interactive-spec needs to be more faithful.
  (let ((fspec (cadr (interactive-form function))))
133
    (when (eq 'function (car-safe fspec)) ;; Macroexpanded lambda?
134 135 136 137
      (setq fspec (nth 1 fspec)))
    (if (functionp fspec)
        `(funcall ',fspec
                  ',(cadr (interactive-form main)))
138
  (cadr (or (interactive-form function)
139
                (interactive-form main))))))
140 141 142 143 144 145 146 147

(defsubst advice--make-1 (byte-code stack-depth function main props)
  "Build a function value that adds FUNCTION to MAIN."
  (let ((adv-sig (gethash main advertised-signature-table))
        (advice
         (apply #'make-byte-code 128 byte-code
                (vector #'apply function main props) stack-depth
                advice--docstring
148 149 150 151 152
                (and (or (commandp function) (commandp main))
		     (not (and (symbolp main) ;; Don't autoload too eagerly!
			       (autoloadp (symbol-function main))))
                     (list (advice--make-interactive-form
                            function main))))))
153 154 155 156 157 158
    (when adv-sig (puthash advice adv-sig advertised-signature-table))
    advice))

(defun advice--make (where function main props)
  "Build a function value that adds FUNCTION to MAIN at WHERE.
WHERE is a symbol to select an entry in `advice--where-alist'."
159 160 161 162 163 164 165 166 167 168 169 170
  (let ((fd (or (cdr (assq 'depth props)) 0))
        (md (if (advice--p main)
                (or (cdr (assq 'depth (advice--props main))) 0))))
    (if (and md (> fd md))
        ;; `function' should go deeper.
        (let ((rest (advice--make where function (advice--cdr main) props)))
          (advice--make-1 (aref main 1) (aref main 3)
                          (advice--car main) rest (advice--props main)))
      (let ((desc (assq where advice--where-alist)))
        (unless desc (error "Unknown add-function location `%S'" where))
        (advice--make-1 (nth 1 desc) (nth 2 desc)
                        function main props)))))
171

172
(defun advice--member-p (function name definition)
173 174 175
  (let ((found nil))
    (while (and (not found) (advice--p definition))
      (if (or (equal function (advice--car definition))
176 177
              (when name
                (equal name (cdr (assq 'name (advice--props definition))))))
178
          (setq found definition)
179 180 181
        (setq definition (advice--cdr definition))))
    found))

182
(defun advice--tweak (flist tweaker)
183
  (if (not (advice--p flist))
184
      (funcall tweaker nil flist nil)
185
    (let ((first (advice--car flist))
186
          (rest (advice--cdr flist))
187
          (props (advice--props flist)))
188 189
      (let ((val (funcall tweaker first rest props)))
        (if val (car val)
190 191 192
          (let ((nrest (advice--tweak rest tweaker)))
            (if (eq rest nrest) flist
              (advice--make-1 (aref flist 1) (aref flist 3)
193
                              first nrest props))))))))
194 195 196 197 198

;;;###autoload
(defun advice--remove-function (flist function)
  (advice--tweak flist
                 (lambda (first rest props)
199 200
                   (cond ((not first) rest)
                         ((or (equal function first)
201
                           (equal function (cdr (assq 'name props))))
202
                          (list rest))))))
203

204 205 206 207 208
(defvar advice--buffer-local-function-sample nil
  "keeps an example of the special \"run the default value\" functions.
These functions play the same role as t in buffer-local hooks, and to recognize
them, we keep a sample here against which to compare.  Each instance is
different, but `function-equal' will hopefully ignore those differences.")
209 210 211 212 213 214 215 216 217 218 219 220

(defun advice--set-buffer-local (var val)
  (if (function-equal val advice--buffer-local-function-sample)
      (kill-local-variable var)
    (set (make-local-variable var) val)))

;;;###autoload
(defun advice--buffer-local (var)
  "Buffer-local value of VAR, presumed to contain a function."
  (declare (gv-setter advice--set-buffer-local))
  (if (local-variable-p var) (symbol-value var)
    (setq advice--buffer-local-function-sample
221
          ;; This function acts like the t special value in buffer-local hooks.
222 223
          (lambda (&rest args) (apply (default-value var) args)))))

224 225 226
;;;###autoload
(defmacro add-function (where place function &optional props)
  ;; TODO:
227
  ;; - maybe let `where' specify some kind of predicate and use it
228
  ;;   to implement things like mode-local or eieio-defmethod.
229 230
  ;;   Of course, that only makes sense if the predicates of all advices can
  ;;   be combined and made more efficient.
231 232 233 234 235 236 237 238 239 240 241 242
  ;; :before is like a normal add-hook on a normal hook.
  ;; :before-while is like add-hook on run-hook-with-args-until-failure.
  ;; :before-until is like add-hook on run-hook-with-args-until-success.
  ;; Same with :after-* but for (add-hook ... 'append).
  "Add a piece of advice on the function stored at PLACE.
FUNCTION describes the code to add.  WHERE describes where to add it.
WHERE can be explained by showing the resulting new function, as the
result of combining FUNCTION and the previous value of PLACE, which we
call OLDFUN here:
`:before'	(lambda (&rest r) (apply FUNCTION r) (apply OLDFUN r))
`:after'	(lambda (&rest r) (prog1 (apply OLDFUN r) (apply FUNCTION r)))
`:around'	(lambda (&rest r) (apply FUNCTION OLDFUN r))
243
`:override'	(lambda (&rest r) (apply FUNCTION r))
244 245 246 247
`:before-while'	(lambda (&rest r) (and (apply FUNCTION r) (apply OLDFUN r)))
`:before-until'	(lambda (&rest r) (or  (apply FUNCTION r) (apply OLDFUN r)))
`:after-while'	(lambda (&rest r) (and (apply OLDFUN r) (apply FUNCTION r)))
`:after-until'	(lambda (&rest r) (or  (apply OLDFUN r) (apply FUNCTION r)))
248 249
`:filter-args'	(lambda (&rest r) (apply OLDFUN (funcall FUNCTION r)))
`:filter-return'(lambda (&rest r) (funcall FUNCTION (apply OLDFUN r)))
250 251 252
If FUNCTION was already added, do nothing.
PROPS is an alist of additional properties, among which the following have
a special meaning:
253
- `name': a string or symbol.  It can be used to refer to this piece of advice.
254 255 256 257
- `depth': a number indicating a preference w.r.t ordering.
  The default depth is 0.  By convention, a depth of 100 means that
  the advice  should be innermost (i.e. at the end of the list),
  whereas a depth of -100 means that the advice should be outermost.
258

259 260
If PLACE is a simple variable, only its global value will be affected.
Use (local 'VAR) if you want to apply FUNCTION to VAR buffer-locally.
261

262 263 264 265 266 267 268
If one of FUNCTION or OLDFUN is interactive, then the resulting function
is also interactive.  There are 3 cases:
- FUNCTION is not interactive: the interactive spec of OLDFUN is used.
- The interactive spec of FUNCTION is itself a function: it should take one
  argument (the interactive spec of OLDFUN, which it can pass to
  `advice-eval-interactive-spec') and return the list of arguments to use.
- Else, use the interactive spec of FUNCTION and ignore the one of OLDFUN."
269
  (declare (debug t)) ;;(indent 2)
270 271 272
  (cond ((eq 'local (car-safe place))
         (setq place `(advice--buffer-local ,@(cdr place))))
        ((symbolp place)
273
         (setq place `(default-value ',place))))
274 275 276 277
  `(advice--add-function ,where (gv-ref ,place) ,function ,props))

;;;###autoload
(defun advice--add-function (where ref function props)
278 279 280 281 282 283
  (let ((a (advice--member-p function (cdr (assq 'name props))
                             (gv-deref ref))))
    (when a
      ;; The advice is already present.  Remove the old one, first.
      (setf (gv-deref ref)
            (advice--remove-function (gv-deref ref) (advice--car a))))
284 285 286
    (setf (gv-deref ref)
          (advice--make where function (gv-deref ref) props))))

287
;;;###autoload
288 289 290 291 292 293
(defmacro remove-function (place function)
  "Remove the FUNCTION piece of advice from PLACE.
If FUNCTION was not added to PLACE, do nothing.
Instead of FUNCTION being the actual function, it can also be the `name'
of the piece of advice."
  (declare (debug t))
294 295 296
  (cond ((eq 'local (car-safe place))
         (setq place `(advice--buffer-local ,@(cdr place))))
        ((symbolp place)
297
         (setq place `(default-value ',place))))
298 299 300 301
  (gv-letplace (getter setter) place
    (macroexp-let2 nil new `(advice--remove-function ,getter ,function)
      `(unless (eq ,new ,getter) ,(funcall setter new)))))

302 303 304 305 306 307 308 309 310 311 312 313 314 315
(defun advice-function-mapc (f function-def)
  "Apply F to every advice function in FUNCTION-DEF.
F is called with two arguments: the function that was added, and the
properties alist that was specified when it was added."
  (while (advice--p function-def)
    (funcall f (advice--car function-def) (advice--props function-def))
    (setq function-def (advice--cdr function-def))))

(defun advice-function-member-p (advice function-def)
  "Return non-nil if ADVICE is already in FUNCTION-DEF.
Instead of ADVICE being the actual function, it can also be the `name'
of the piece of advice."
  (advice--member-p advice advice function-def))

316 317 318
;;;; Specific application of add-function to `symbol-function' for advice.

(defun advice--subst-main (old new)
319 320
  (advice--tweak old
                 (lambda (first _rest _props) (if (not first) new))))
321

322 323 324 325
(defun advice--normalize (symbol def)
  (cond
   ((special-form-p def)
    ;; Not worth the trouble trying to handle this, I think.
326
    (error "Advice impossible: %S is a special form" symbol))
327 328
   ((and (symbolp def) (macrop def))
    (let ((newval `(macro . ,(lambda (&rest r) (macroexpand `(,def . ,r))))))
329
      (put symbol 'advice--saved-rewrite (cons def (cdr newval)))
330 331 332 333 334 335 336 337 338 339
      newval))
   ;; `f' might be a pure (hence read-only) cons!
   ((and (eq 'macro (car-safe def))
	 (not (ignore-errors (setcdr def (cdr def)) t)))
    (cons 'macro (cdr def)))
   (t def)))

(defsubst advice--strip-macro (x)
  (if (eq 'macro (car-safe x)) (cdr x) x))

340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357
(defun advice--symbol-function (symbol)
  ;; The value conceptually stored in `symbol-function' is split into two
  ;; parts:
  ;; - the normal function definition.
  ;; - the list of advice applied to it.
  ;; `advice--symbol-function' is intended to return the second part (i.e. the
  ;; list of advice, which includes a hole at the end which typically holds the
  ;; first part, but this function doesn't care much which value is found
  ;; there).
  ;; In the "normal" state both parts are combined into a single value stored
  ;; in the "function slot" of the symbol.  But the way they are combined is
  ;; different depending on whether the definition is a function or a macro.
  ;; Also if the function definition is nil (i.e. unbound) or is an autoload,
  ;; the second part is stashed away temporarily in the `advice--pending'
  ;; symbol property.
  (or (get symbol 'advice--pending)
      (advice--strip-macro (symbol-function symbol))))

358
(defun advice--defalias-fset (fsetfun symbol newdef)
359
  (unless fsetfun (setq fsetfun #'fset))
360 361 362
  (when (get symbol 'advice--saved-rewrite)
    (put symbol 'advice--saved-rewrite nil))
  (setq newdef (advice--normalize symbol newdef))
363
  (let ((oldadv (advice--symbol-function symbol)))
364 365 366 367
    (if (and newdef (not (autoloadp newdef)))
        (let* ((snewdef (advice--strip-macro newdef))
               (snewadv (advice--subst-main oldadv snewdef)))
          (put symbol 'advice--pending nil)
368
          (funcall fsetfun symbol
369 370 371
                   (if (eq snewdef newdef) snewadv (cons 'macro snewadv))))
      (unless (eq oldadv (get symbol 'advice--pending))
        (put symbol 'advice--pending (advice--subst-main oldadv nil)))
372
      (funcall fsetfun symbol newdef))))
373 374 375 376 377 378 379 380 381 382 383
    

;;;###autoload
(defun advice-add (symbol where function &optional props)
  "Like `add-function' but for the function named SYMBOL.
Contrary to `add-function', this will properly handle the cases where SYMBOL
is defined as a macro, alias, command, ..."
  ;; TODO:
  ;; - record the advice location, to display in describe-function.
  ;; - change all defadvice in lisp/**/*.el.
  ;; - obsolete advice.el.
384
  (let* ((f (symbol-function symbol))
385
	 (nf (advice--normalize symbol f)))
386
    (unless (eq f nf) (fset symbol nf))
387
    (add-function where (cond
388
                         ((eq (car-safe nf) 'macro) (cdr nf))
389 390 391 392 393 394 395 396 397
                         ;; Reasons to delay installation of the advice:
                         ;; - If the function is not yet defined, installing
                         ;;   the advice would affect `fboundp'ness.
                         ;; - If it's an autoloaded command,
                         ;;   advice--make-interactive-form would end up
                         ;;   loading the command eagerly.
                         ;; - `autoload' does nothing if the function is
                         ;;   not an autoload or undefined.
                         ((or (not nf) (autoloadp nf))
398 399 400 401 402 403 404 405 406 407
                          (get symbol 'advice--pending))
                         (t (symbol-function symbol)))
                  function props)
    (add-function :around (get symbol 'defalias-fset-function)
                  #'advice--defalias-fset))
  nil)

;;;###autoload
(defun advice-remove (symbol function)
  "Like `remove-function' but for the function named SYMBOL.
408 409
Contrary to `remove-function', this also works when SYMBOL is a macro
or an autoload and it preserves `fboundp'.
410 411
Instead of the actual function to remove, FUNCTION can also be the `name'
of the piece of advice."
412
  (let ((f (symbol-function symbol)))
413 414 415 416 417
    (remove-function (cond ;This is `advice--symbol-function' but as a "place".
                      ((get symbol 'advice--pending)
                       (get symbol 'advice--pending))
                      ((eq (car-safe f) 'macro) (cdr f))
                      (t (symbol-function symbol)))
418
                     function)
419
    (unless (advice--p (advice--symbol-function symbol))
420 421 422
      ;; Not advised any more.
      (remove-function (get symbol 'defalias-fset-function)
                       #'advice--defalias-fset)
423 424 425 426
      (let ((asr (get symbol 'advice--saved-rewrite)))
        (and asr (eq (cdr-safe (symbol-function symbol))
                     (cdr asr))
             (fset symbol (car (get symbol 'advice--saved-rewrite)))))))
427 428
  nil)

429 430
(defun advice-mapc (fun symbol)
  "Apply FUN to every advice function in SYMBOL.
431 432
FUN is called with a two arguments: the function that was added, and the
properties alist that was specified when it was added."
433
  (advice-function-mapc fun (advice--symbol-function symbol)))
434 435

;;;###autoload
436 437
(defun advice-member-p (advice symbol)
  "Return non-nil if ADVICE has been added to SYMBOL.
438
Instead of ADVICE being the actual function, it can also be the `name'
439
of the piece of advice."
440
  (advice-function-member-p advice (advice--symbol-function symbol)))
441

442 443 444 445 446 447 448 449 450 451 452 453 454 455
;; When code is advised, called-interactively-p needs to be taught to skip
;; the advising frames.
;; FIXME: This Major Ugly Hack won't handle calls to called-interactively-p
;; done from the advised function if the deepest advice is an around advice!
;; In other cases (calls from an advice or calls from the advised function when
;; the deepest advice is not an around advice), it should hopefully get
;; it right.
(add-hook 'called-interactively-p-functions
          #'advice--called-interactively-skip)
(defun advice--called-interactively-skip (origi frame1 frame2)
  (let* ((i origi)
         (get-next-frame
          (lambda ()
            (setq frame1 frame2)
456
            (setq frame2 (backtrace-frame i #'called-interactively-p))
457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491
            ;; (message "Advice Frame %d = %S" i frame2)
            (setq i (1+ i)))))
    (when (and (eq (nth 1 frame2) 'apply)
               (progn
                 (funcall get-next-frame)
                 (advice--p (indirect-function (nth 1 frame2)))))
      (funcall get-next-frame)
      ;; If we now have the symbol, this was the head advice and
      ;; we're done.
      (while (advice--p (nth 1 frame1))
        ;; This was an inner advice called from some earlier advice.
        ;; The stack frames look different depending on the particular
        ;; kind of the earlier advice.
        (let ((inneradvice (nth 1 frame1)))
          (if (and (eq (nth 1 frame2) 'apply)
                   (progn
                     (funcall get-next-frame)
                     (advice--p (indirect-function
                                 (nth 1 frame2)))))
              ;; The earlier advice was something like a before/after
              ;; advice where the "next" code is called directly by the
              ;; advice--p object.
              (funcall get-next-frame)
            ;; It's apparently an around advice, where the "next" is
            ;; called by the body of the advice in any way it sees fit,
            ;; so we need to skip the frames of that body.
            (while
                (progn
                  (funcall get-next-frame)
                  (not (and (eq (nth 1 frame2) 'apply)
                            (eq (nth 3 frame2) inneradvice)))))
            (funcall get-next-frame)
            (funcall get-next-frame))))
      (- i origi 1))))

492 493 494

(provide 'nadvice)
;;; nadvice.el ends here