replace.el 42 KB
Newer Older
Eric S. Raymond's avatar
Eric S. Raymond committed
1 2
;;; replace.el --- replace commands for Emacs.

3
;; Copyright (C) 1985, 86, 87, 92, 94, 96, 1997, 2000, 2001
4
;;  Free Software Foundation, Inc.
Eric S. Raymond's avatar
Eric S. Raymond committed
5

Richard M. Stallman's avatar
Richard M. Stallman committed
6 7 8 9
;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
Jim Blandy's avatar
Jim Blandy committed
10
;; the Free Software Foundation; either version 2, or (at your option)
Richard M. Stallman's avatar
Richard M. Stallman committed
11 12 13 14 15 16 17 18
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
Erik Naggum's avatar
Erik Naggum committed
19 20 21
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.
Richard M. Stallman's avatar
Richard M. Stallman committed
22

23 24 25 26 27
;;; Commentary:

;; This package supplies the string and regular-expression replace functions
;; documented in the Emacs user's manual.

Eric S. Raymond's avatar
Eric S. Raymond committed
28
;;; Code:
Richard M. Stallman's avatar
Richard M. Stallman committed
29

30
(defcustom case-replace t
31
  "*Non-nil means `query-replace' should preserve case in replacements."
32 33
  :type 'boolean
  :group 'matching)
Roland McGrath's avatar
Roland McGrath committed
34

35 36
(defvar query-replace-history nil)

37 38 39 40
(defvar query-replace-interactive nil
  "Non-nil means `query-replace' uses the last search string.
That becomes the \"string to replace\".")

41
(defcustom query-replace-from-history-variable 'query-replace-history
42
  "History list to use for the FROM argument of `query-replace' commands.
43 44 45 46
The value of this variable should be a symbol; that symbol
is used as a variable to hold a history list for the strings
or patterns to be replaced."
  :group 'matching
Dan Nicolaescu's avatar
Dan Nicolaescu committed
47 48
  :type 'symbol
  :version "20.3")
49 50

(defcustom query-replace-to-history-variable 'query-replace-history
51
  "History list to use for the TO argument of `query-replace' commands.
52 53 54 55
The value of this variable should be a symbol; that symbol
is used as a variable to hold a history list for replacement
strings or patterns."
  :group 'matching
Dan Nicolaescu's avatar
Dan Nicolaescu committed
56 57
  :type 'symbol
  :version "20.3")
58

59
(defun query-replace-read-args (string regexp-flag)
60
  (let (from to)
61 62 63 64
    (if query-replace-interactive
	(setq from (car (if regexp-flag regexp-search-ring search-ring)))
      (setq from (read-from-minibuffer (format "%s: " string)
				       nil nil nil
65 66
				       query-replace-from-history-variable
				       nil t)))
67 68
    (setq to (read-from-minibuffer (format "%s %s with: " string from)
				   nil nil nil
69
				   query-replace-to-history-variable from t))
70 71 72
    (if (and transient-mark-mode mark-active)
	(list from to current-prefix-arg (region-beginning) (region-end))
      (list from to current-prefix-arg nil nil))))
73

74
(defun query-replace (from-string to-string &optional delimited start end)
Roland McGrath's avatar
Roland McGrath committed
75 76 77 78
  "Replace some occurrences of FROM-STRING with TO-STRING.
As each match is found, the user must type a character saying
what to do with it.  For directions, type \\[help-command] at that time.

79 80 81
In Transient Mark mode, if the mark is active, operate on the contents
of the region.  Otherwise, operate from point to the end of the buffer.

82 83 84 85
If `query-replace-interactive' is non-nil, the last incremental search
string is used as FROM-STRING--you don't have to specify it with the
minibuffer.

86 87
Replacement transfers the case of the old text to the new text,
if `case-replace' and `case-fold-search'
Roland McGrath's avatar
Roland McGrath committed
88
are non-nil and FROM-STRING has no uppercase letters.
89 90 91
\(Preserving case means that if the string matched is all caps, or capitalized,
then its replacement is upcased or capitalized.)

Richard M. Stallman's avatar
Richard M. Stallman committed
92
Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
93
only matches surrounded by word boundaries.
94
Fourth and fifth arg START and END specify the region to operate on.
95 96

To customize possible responses, change the \"bindings\" in `query-replace-map'."
97
  (interactive (query-replace-read-args "Query replace" nil))
98
  (perform-replace from-string to-string start end t nil delimited))
99

Brian Preble's avatar
Brian Preble committed
100
(define-key esc-map "%" 'query-replace)
Roland McGrath's avatar
Roland McGrath committed
101

102
(defun query-replace-regexp (regexp to-string &optional delimited start end)
Roland McGrath's avatar
Roland McGrath committed
103 104 105 106
  "Replace some things after point matching REGEXP with TO-STRING.
As each match is found, the user must type a character saying
what to do with it.  For directions, type \\[help-command] at that time.

107 108 109
In Transient Mark mode, if the mark is active, operate on the contents
of the region.  Otherwise, operate from point to the end of the buffer.

110 111 112 113
If `query-replace-interactive' is non-nil, the last incremental search
regexp is used as REGEXP--you don't have to specify it with the
minibuffer.

Richard M. Stallman's avatar
Richard M. Stallman committed
114
Preserves case in each replacement if `case-replace' and `case-fold-search'
Roland McGrath's avatar
Roland McGrath committed
115
are non-nil and REGEXP has no uppercase letters.
116

Richard M. Stallman's avatar
Richard M. Stallman committed
117
Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
Roland McGrath's avatar
Roland McGrath committed
118
only matches surrounded by word boundaries.
119 120
Fourth and fifth arg START and END specify the region to operate on.

Richard M. Stallman's avatar
Richard M. Stallman committed
121 122 123
In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
and `\\=\\N' (where N is a digit) stands for
 whatever what matched the Nth `\\(...\\)' in REGEXP."
124
  (interactive (query-replace-read-args "Query replace regexp" t))
125
  (perform-replace regexp to-string start end t t delimited))
126
(define-key esc-map [?\C-%] 'query-replace-regexp)
Roland McGrath's avatar
Roland McGrath committed
127

128
(defun query-replace-regexp-eval (regexp to-expr &optional delimited start end)
129 130 131 132 133 134 135 136 137 138
  "Replace some things after point matching REGEXP with the result of TO-EXPR.
As each match is found, the user must type a character saying
what to do with it.  For directions, type \\[help-command] at that time.

TO-EXPR is a Lisp expression evaluated to compute each replacement.  It may
reference `replace-count' to get the number of replacements already made.
If the result of TO-EXPR is not a string, it is converted to one using
`prin1-to-string' with the NOESCAPE argument (which see).

For convenience, when entering TO-EXPR interactively, you can use `\\&' or
139 140
`\0' to stand for whatever matched the whole of REGEXP, and `\N' (where
N is a digit) to stand for whatever matched the Nth `\(...\)' in REGEXP.
141 142 143 144 145 146 147 148 149 150 151
Use `\\#&' or `\\#N' if you want a number instead of a string.

In Transient Mark mode, if the mark is active, operate on the contents
of the region.  Otherwise, operate from point to the end of the buffer.

If `query-replace-interactive' is non-nil, the last incremental search
regexp is used as REGEXP--you don't have to specify it with the
minibuffer.

Preserves case in each replacement if `case-replace' and `case-fold-search'
are non-nil and REGEXP has no uppercase letters.
152

153
Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
154
only matches that are surrounded by word boundaries.
155
Fourth and fifth arg START and END specify the region to operate on."
156
  (interactive
157 158 159 160
   (let (from to start end)
     (when (and transient-mark-mode mark-active)
       (setq start (region-beginning)
	     end (region-end)))
161 162 163 164 165 166 167 168 169 170 171 172
     (if query-replace-interactive
         (setq from (car regexp-search-ring))
       (setq from (read-from-minibuffer "Query replace regexp: "
                                        nil nil nil
                                        query-replace-from-history-variable
                                        nil t)))
     (setq to (list (read-from-minibuffer
                     (format "Query replace regexp %s with eval: " from)
                     nil nil t query-replace-to-history-variable from t)))
     ;; We make TO a list because replace-match-string-symbols requires one,
     ;; and the user might enter a single token.
     (replace-match-string-symbols to)
173
     (list from (car to) start end current-prefix-arg)))
174
  (perform-replace regexp (cons 'replace-eval-replacement to-expr)
175
		   start end t t delimited))
176

177
(defun map-query-replace-regexp (regexp to-strings &optional n start end)
Roland McGrath's avatar
Roland McGrath committed
178
  "Replace some matches for REGEXP with various strings, in rotation.
Dave Love's avatar
Dave Love committed
179 180 181 182 183
The second argument TO-STRINGS contains the replacement strings,
separated by spaces.  Third arg DELIMITED (prefix arg if interactive),
if non-nil, means replace only matches surrounded by word boundaries.
This command works like `query-replace-regexp' except that each
successive replacement uses the next successive replacement string,
Roland McGrath's avatar
Roland McGrath committed
184 185
wrapping around from the last such string to the first.

186 187 188
In Transient Mark mode, if the mark is active, operate on the contents
of the region.  Otherwise, operate from point to the end of the buffer.

Roland McGrath's avatar
Roland McGrath committed
189 190
Non-interactively, TO-STRINGS may be a list of replacement strings.

191 192 193
If `query-replace-interactive' is non-nil, the last incremental search
regexp is used as REGEXP--you don't have to specify it with the minibuffer.

Roland McGrath's avatar
Roland McGrath committed
194
A prefix argument N says to use each replacement string N times
195 196
before rotating to the next.
Fourth and fifth arg START and END specify the region to operate on."
197
  (interactive
198 199 200 201
   (let (from to start end)
     (when (and transient-mark-mode mark-active)
       (setq start (region-beginning)
	     end (region-end)))
202 203 204 205
     (setq from (if query-replace-interactive
		    (car regexp-search-ring)
		  (read-from-minibuffer "Map query replace (regexp): "
					nil nil nil
206
					'query-replace-history nil t)))
207 208 209 210
     (setq to (read-from-minibuffer
	       (format "Query replace %s with (space-separated strings): "
		       from)
	       nil nil nil
211
	       'query-replace-history from t))
212
     (list from to start end current-prefix-arg)))
Roland McGrath's avatar
Roland McGrath committed
213 214 215 216 217 218 219 220 221 222 223 224 225
  (let (replacements)
    (if (listp to-strings)
	(setq replacements to-strings)
      (while (/= (length to-strings) 0)
	(if (string-match " " to-strings)
	    (setq replacements
		  (append replacements
			  (list (substring to-strings 0
					   (string-match " " to-strings))))
		  to-strings (substring to-strings
				       (1+ (string-match " " to-strings))))
	  (setq replacements (append replacements (list to-strings))
		to-strings ""))))
226
    (perform-replace regexp replacements start end t t nil n)))
Roland McGrath's avatar
Roland McGrath committed
227

228
(defun replace-string (from-string to-string &optional delimited start end)
Roland McGrath's avatar
Roland McGrath committed
229 230 231
  "Replace occurrences of FROM-STRING with TO-STRING.
Preserve case in each match if `case-replace' and `case-fold-search'
are non-nil and FROM-STRING has no uppercase letters.
232 233 234
\(Preserving case means that if the string matched is all caps, or capitalized,
then its replacement is upcased or capitalized.)

235 236 237
In Transient Mark mode, if the mark is active, operate on the contents
of the region.  Otherwise, operate from point to the end of the buffer.

Richard M. Stallman's avatar
Richard M. Stallman committed
238
Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
Roland McGrath's avatar
Roland McGrath committed
239
only matches surrounded by word boundaries.
240
Fourth and fifth arg START and END specify the region to operate on.
Roland McGrath's avatar
Roland McGrath committed
241

242 243 244 245
If `query-replace-interactive' is non-nil, the last incremental search
string is used as FROM-STRING--you don't have to specify it with the
minibuffer.

Roland McGrath's avatar
Roland McGrath committed
246 247
This function is usually the wrong thing to use in a Lisp program.
What you probably want is a loop like this:
Richard M. Stallman's avatar
Richard M. Stallman committed
248 249
  (while (search-forward FROM-STRING nil t)
    (replace-match TO-STRING nil t))
250 251 252
which will run faster and will not set the mark or print anything.
\(You may need a more complex loop if FROM-STRING can match the null string
and TO-STRING is also null.)"
253
  (interactive (query-replace-read-args "Replace string" nil))
254
  (perform-replace from-string to-string start end nil nil delimited))
Roland McGrath's avatar
Roland McGrath committed
255

256
(defun replace-regexp (regexp to-string &optional delimited start end)
Roland McGrath's avatar
Roland McGrath committed
257
  "Replace things after point matching REGEXP with TO-STRING.
Richard M. Stallman's avatar
Richard M. Stallman committed
258
Preserve case in each match if `case-replace' and `case-fold-search'
Roland McGrath's avatar
Roland McGrath committed
259
are non-nil and REGEXP has no uppercase letters.
260 261 262 263

In Transient Mark mode, if the mark is active, operate on the contents
of the region.  Otherwise, operate from point to the end of the buffer.

Richard M. Stallman's avatar
Richard M. Stallman committed
264
Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
Roland McGrath's avatar
Roland McGrath committed
265
only matches surrounded by word boundaries.
266 267
Fourth and fifth arg START and END specify the region to operate on.

Richard M. Stallman's avatar
Richard M. Stallman committed
268 269
In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
and `\\=\\N' (where N is a digit) stands for
270
 whatever what matched the Nth `\\(...\\)' in REGEXP.
Roland McGrath's avatar
Roland McGrath committed
271

272 273 274
If `query-replace-interactive' is non-nil, the last incremental search
regexp is used as REGEXP--you don't have to specify it with the minibuffer.

Roland McGrath's avatar
Roland McGrath committed
275 276 277
This function is usually the wrong thing to use in a Lisp program.
What you probably want is a loop like this:
  (while (re-search-forward REGEXP nil t)
Richard M. Stallman's avatar
Richard M. Stallman committed
278
    (replace-match TO-STRING nil nil))
Roland McGrath's avatar
Roland McGrath committed
279
which will run faster and will not set the mark or print anything."
280
  (interactive (query-replace-read-args "Replace regexp" t))
281
  (perform-replace regexp to-string start end nil t delimited))
282

283 284 285

(defvar regexp-history nil
  "History list for some commands that read regular expressions.")
Roland McGrath's avatar
Roland McGrath committed
286

287

288
(defalias 'delete-non-matching-lines 'keep-lines)
289 290 291 292 293 294 295 296 297 298
(defalias 'delete-matching-lines 'flush-lines)
(defalias 'count-matches 'how-many)


(defun keep-lines-read-args (prompt)
  "Read arguments for `keep-lines' and friends.
Prompt for a regexp with PROMPT.

Value is a list (REGEXP START END).

299 300 301 302
If in Transient Mark mode, and the mark is active, START is the
start of the region, and END is a marker for the end of the region.
Otherwise, START is the current point, and END is the value of
function `point-max-marker'."
303 304 305 306 307
  (let ((regexp (read-from-minibuffer prompt nil nil nil
				      'regexp-history nil t))
	start end)
    (if (and transient-mark-mode mark-active)
	(setq start (region-beginning)
308
	      end (copy-marker (region-end)))
309 310 311 312 313 314
      (setq start (point)
	    end (point-max-marker)))
    (list regexp start end)))


(defun keep-lines (regexp &optional rstart rend)
Richard M. Stallman's avatar
Richard M. Stallman committed
315 316
  "Delete all lines except those containing matches for REGEXP.
A match split across lines preserves all the lines it lies in.
317 318 319
Applies to all lines after point.

If REGEXP contains upper case characters (excluding those preceded by `\\'),
320 321 322 323 324 325 326 327 328 329 330
the matching is case-sensitive.

Second and third arg RSTART and REND specify the region to operate on.

In Transient Mark mode, if the mark is active, operate on the contents
of the region.  Otherwise, operate from point to the end of the buffer."
  (interactive
   (keep-lines-read-args "Keep lines (containing match for regexp): "))
  (if rstart
      (goto-char (min rstart rend))
    (setq rstart (point) rend (point-max-marker)))
Richard M. Stallman's avatar
Richard M. Stallman committed
331 332
  (save-excursion
    (or (bolp) (forward-line 1))
333 334 335
    (let ((start (point))
	  (case-fold-search  (and case-fold-search
				  (isearch-no-upper-case-p regexp t))))
336
      (while (< (point) rend)
Richard M. Stallman's avatar
Richard M. Stallman committed
337
	;; Start is first char not preserved by previous match.
338 339
	(if (not (re-search-forward regexp rend 'move))
	    (delete-region start rend)
Richard M. Stallman's avatar
Richard M. Stallman committed
340 341 342 343 344 345
	  (let ((end (save-excursion (goto-char (match-beginning 0))
				     (beginning-of-line)
				     (point))))
	    ;; Now end is first char preserved by the new match.
	    (if (< start end)
		(delete-region start end))))
346 347
	
	(setq start (save-excursion (forward-line 1) (point)))
Richard M. Stallman's avatar
Richard M. Stallman committed
348
	;; If the match was empty, avoid matching again at same place.
349 350
	(and (< (point) rend)
	     (= (match-beginning 0) (match-end 0))
Richard M. Stallman's avatar
Richard M. Stallman committed
351 352
	     (forward-char 1))))))

353 354

(defun flush-lines (regexp &optional rstart rend)
Richard M. Stallman's avatar
Richard M. Stallman committed
355 356
  "Delete lines containing matches for REGEXP.
If a match is split across lines, all the lines it lies in are deleted.
357 358 359
Applies to lines after point.

If REGEXP contains upper case characters (excluding those preceded by `\\'),
360 361 362 363 364 365 366 367 368 369 370
the matching is case-sensitive.

Second and third arg RSTART and REND specify the region to operate on.

In Transient Mark mode, if the mark is active, operate on the contents
of the region.  Otherwise, operate from point to the end of the buffer."
  (interactive
   (keep-lines-read-args "Flush lines (containing match for regexp): "))
  (if rstart
      (goto-char (min rstart rend))
    (setq rstart (point) rend (point-max-marker)))
371 372 373
  (let ((case-fold-search (and case-fold-search
			       (isearch-no-upper-case-p regexp t))))
    (save-excursion
374 375
      (while (and (< (point) rend)
		  (re-search-forward regexp rend t))
376 377 378 379
	(delete-region (save-excursion (goto-char (match-beginning 0))
				       (beginning-of-line)
				       (point))
		       (progn (forward-line 1) (point)))))))
Richard M. Stallman's avatar
Richard M. Stallman committed
380

381 382

(defun how-many (regexp &optional rstart rend)
383 384 385
  "Print number of matches for REGEXP following point.

If REGEXP contains upper case characters (excluding those preceded by `\\'),
386 387 388 389 390 391 392 393
the matching is case-sensitive.

Second and third arg RSTART and REND specify the region to operate on.

In Transient Mark mode, if the mark is active, operate on the contents
of the region.  Otherwise, operate from point to the end of the buffer."
  (interactive
   (keep-lines-read-args "How many matches for (regexp): "))
394 395 396 397 398 399 400 401 402 403 404 405 406 407 408
  (save-excursion
    (if rstart
	(goto-char (min rstart rend))
      (setq rstart (point) rend (point-max-marker)))
    (let ((count 0)
	  opoint
	  (case-fold-search (and case-fold-search
				 (isearch-no-upper-case-p regexp t))))
      (while (and (< (point) rend)
		  (progn (setq opoint (point))
			 (re-search-forward regexp rend t)))
	(if (= opoint (point))
	    (forward-char 1)
	  (setq count (1+ count))))
      (message "%d occurrences" count))))
409

410

411 412 413 414 415 416 417 418 419 420
(defvar occur-mode-map
  (let ((map (make-sparse-keymap)))
    (define-key map [mouse-2] 'occur-mode-mouse-goto)
    (define-key map "\C-c\C-c" 'occur-mode-goto-occurrence)
    (define-key map "\C-m" 'occur-mode-goto-occurrence)
    (define-key map "\M-n" 'occur-next)
    (define-key map "\M-p" 'occur-prev)
    (define-key map "g" 'revert-buffer)
    map)
  "Keymap for `occur-mode'.")
Richard M. Stallman's avatar
Richard M. Stallman committed
421

422 423 424 425 426 427 428 429

(defvar occur-buffer nil
  "Name of buffer for last occur.")


(defvar occur-nlines nil
  "Number of lines of context to show around matching line.")

430 431
(defvar occur-command-arguments nil
  "Arguments that were given to `occur' when it made this buffer.")
Richard M. Stallman's avatar
Richard M. Stallman committed
432

433 434
(put 'occur-mode 'mode-class 'special)

435
(define-derived-mode occur-mode nil "Occur"
Richard M. Stallman's avatar
Richard M. Stallman committed
436
  "Major mode for output from \\[occur].
437 438 439 440
\\<occur-mode-map>Move point to one of the items in this buffer, then use
\\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.

Richard M. Stallman's avatar
Richard M. Stallman committed
441
\\{occur-mode-map}"
442
  (set (make-local-variable 'revert-buffer-function) 'occur-revert-function)
Richard M. Stallman's avatar
Richard M. Stallman committed
443 444
  (make-local-variable 'occur-buffer)
  (make-local-variable 'occur-nlines)
445
  (make-local-variable 'occur-command-arguments))
Richard M. Stallman's avatar
Richard M. Stallman committed
446

447
(defun occur-revert-function (ignore1 ignore2)
448
  "Handle `revert-buffer' for *Occur* buffers."
449 450 451 452 453
  (let ((args occur-command-arguments ))
    (save-excursion
      (set-buffer occur-buffer)
      (apply 'occur args))))

454 455 456 457 458 459 460 461 462 463 464 465 466 467
(defun occur-mode-mouse-goto (event)
  "In Occur mode, go to the occurrence whose line you click on."
  (interactive "e")
  (let (buffer pos)
    (save-excursion
      (set-buffer (window-buffer (posn-window (event-end event))))
      (save-excursion
	(goto-char (posn-point (event-end event)))
	(setq pos (occur-mode-find-occurrence))
	(setq buffer occur-buffer)))
    (pop-to-buffer buffer)
    (goto-char (marker-position pos))))

(defun occur-mode-find-occurrence ()
Richard M. Stallman's avatar
Richard M. Stallman committed
468 469 470
  (if (or (null occur-buffer)
	  (null (buffer-name occur-buffer)))
      (progn
471
	(setq occur-buffer nil)
Richard M. Stallman's avatar
Richard M. Stallman committed
472
	(error "Buffer in which occurrences were found is deleted")))
473 474 475 476
  (let ((pos (get-text-property (point) 'occur)))
    (if (null pos)
	(error "No occurrence on this line")
      pos)))
477 478 479 480 481

(defun occur-mode-goto-occurrence ()
  "Go to the occurrence the current line describes."
  (interactive)
  (let ((pos (occur-mode-find-occurrence)))
Richard M. Stallman's avatar
Richard M. Stallman committed
482
    (pop-to-buffer occur-buffer)
483
    (goto-char (marker-position pos))))
484 485 486 487 488 489 490 491 492 493 494 495

(defun occur-next (&optional n)
  "Move to the Nth (default 1) next match in the *Occur* buffer."
  (interactive "p")
  (if (not n) (setq n 1))
  (let ((r))
    (while (> n 0)
      (if (get-text-property (point) 'occur-point)
	  (forward-char 1))
      (setq r (next-single-property-change (point) 'occur-point))
      (if r
	  (goto-char r)
Dave Love's avatar
Dave Love committed
496
	(error "No more matches"))
497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513
      (setq n (1- n)))))



(defun occur-prev (&optional n)
  "Move to the Nth (default 1) previous match in the *Occur* buffer."
  (interactive "p")
  (if (not n) (setq n 1))
  (let ((r))
    (while (> n 0)
    
      (setq r (get-text-property (point) 'occur-point))
      (if r (forward-char -1))
      
      (setq r (previous-single-property-change (point) 'occur-point))
      (if r
	  (goto-char (- r 1))
Dave Love's avatar
Dave Love committed
514
	(error "No earlier matches"))
515 516
      
      (setq n (1- n)))))
517

518
(defcustom list-matching-lines-default-context-lines 0
Dave Love's avatar
Dave Love committed
519 520
  "*Default number of context lines included around `list-matching-lines' matches.
A negative number means to include that many lines before the match.
521 522 523
A positive number means to include that many lines both before and after."
  :type 'integer
  :group 'matching)
Richard M. Stallman's avatar
Richard M. Stallman committed
524

525
(defalias 'list-matching-lines 'occur)
Richard M. Stallman's avatar
Richard M. Stallman committed
526

527
(defvar list-matching-lines-face 'bold
Dave Love's avatar
Dave Love committed
528
  "*Face used by \\[list-matching-lines] to show the text that matches.
529 530
If the value is nil, don't highlight the matching portions specially.")

Richard M. Stallman's avatar
Richard M. Stallman committed
531
(defun occur (regexp &optional nlines)
532
  "Show all lines in the current buffer containing a match for REGEXP.
Roland McGrath's avatar
Roland McGrath committed
533 534

If a match spreads across multiple lines, all those lines are shown.
Richard M. Stallman's avatar
Richard M. Stallman committed
535

Roland McGrath's avatar
Roland McGrath committed
536 537 538
Each line is displayed with NLINES lines before and after, or -NLINES
before if NLINES is negative.
NLINES defaults to `list-matching-lines-default-context-lines'.
Richard M. Stallman's avatar
Richard M. Stallman committed
539 540
Interactively it is the prefix arg.

541
The lines are shown in a buffer named `*Occur*'.
Richard M. Stallman's avatar
Richard M. Stallman committed
542
It serves as a menu to find any of the occurrences in this buffer.
543
\\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
544

545 546
If REGEXP contains upper case characters (excluding those preceded by `\\'),
the matching is case-sensitive."
547 548 549 550 551 552 553 554
  (interactive
   (list (let* ((default (car regexp-history))
		(input
		 (read-from-minibuffer
		  (if default
		      (format "List lines matching regexp (default `%s'): "
			      default)
		    "List lines matching regexp: ")
555
		  nil nil nil 'regexp-history default t)))
556 557
	   (and (equal input "") default
		(setq input default))
558
	   input)
559
	 current-prefix-arg))
560 561 562 563 564 565
  (let* ((nlines (if nlines
		     (prefix-numeric-value nlines)
		   list-matching-lines-default-context-lines))
	 (current-tab-width tab-width)
	 ;; Minimum width of line number plus trailing colon.
	 (min-line-number-width 6)
566 567 568 569 570 571 572 573
	 ;; Width of line number prefix without the colon.  Choose a
	 ;; width that's a multiple of `tab-width' in the original
	 ;; buffer so that lines in *Occur* appear right.
	 (line-number-width (1- (* (/ (- (+ min-line-number-width
					    tab-width)
					 1)
				      tab-width)
				   tab-width)))
574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591
	 ;; Format string for line numbers.
	 (line-number-format (format "%%%dd" line-number-width))
	 (empty (make-string line-number-width ?\ ))
	 (first t)
	 ;;flag to prevent printing separator for first match
	 (occur-num-matches 0)
	 (buffer (current-buffer))
	 (dir default-directory)
	 (linenum 1)
	 (prevpos
	  ;;position of most recent match
	  (point-min))
	 (case-fold-search  (and case-fold-search
				 (isearch-no-upper-case-p regexp t)))
	 (final-context-start
	  ;; Marker to the start of context immediately following
	  ;; the matched text in *Occur*.
	  (make-marker)))
592 593 594 595
;;;	(save-excursion
;;;	  (beginning-of-line)
;;;	  (setq linenum (1+ (count-lines (point-min) (point))))
;;;	  (setq prevpos (point)))
596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614
    (save-excursion
      (goto-char (point-min))
      ;; Check first whether there are any matches at all.
      (if (not (re-search-forward regexp nil t))
	  (message "No matches for `%s'" regexp)
	;; Back up, so the search loop below will find the first match.
	(goto-char (match-beginning 0))
	(with-output-to-temp-buffer "*Occur*"
	  (save-excursion
	    (set-buffer standard-output)
	    (setq default-directory dir)
	    ;; We will insert the number of lines, and "lines", later.
	    (insert " matching ")
	    (let ((print-escape-newlines t))
	      (prin1 regexp))
	    (insert " in buffer " (buffer-name buffer) ?. ?\n)
	    (occur-mode)
	    (setq occur-buffer buffer)
	    (setq occur-nlines nlines)
615 616
	    (setq occur-command-arguments
		  (list regexp nlines)))
617
	  (if (eq buffer standard-output)
618
	      (goto-char (point-max)))
619 620
	  (save-excursion
	    ;; Find next match, but give up if prev match was at end of buffer.
621
	    (while (and (not (eobp))
622 623 624 625 626 627 628
			(re-search-forward regexp nil t))
	      (goto-char (match-beginning 0))
	      (beginning-of-line)
	      (save-match-data
		(setq linenum (+ linenum (count-lines prevpos (point)))))
	      (setq prevpos (point))
	      (goto-char (match-end 0))
629 630 631
	      (let* (;;start point of text in source buffer to be put
		     ;;into *Occur*
		     (start (save-excursion
632
			      (goto-char (match-beginning 0))
633 634 635
			      (forward-line (if (< nlines 0)
						nlines
					      (- nlines)))
636
			      (point)))
637 638
		      ;; end point of text in source buffer to be put
		      ;; into *Occur*
639 640 641 642 643 644
		     (end (save-excursion
			    (goto-char (match-end 0))
			    (if (> nlines 0)
				(forward-line (1+ nlines))
			      (forward-line 1))
			    (point)))
645
		      ;; Amount of context before matching text
646
		     (match-beg (- (match-beginning 0) start))
647
		      ;; Length of matching text
648 649
		     (match-len (- (match-end 0) (match-beginning 0)))
		     (tag (format line-number-format linenum))
Dave Love's avatar
Dave Love committed
650
		     tem
651
		     insertion-start
652
		     ;; Number of lines of context to show for current match.
Dave Love's avatar
Dave Love committed
653
		     occur-marker
654 655 656 657 658
		     ;; Marker pointing to end of match in source buffer.
		     (text-beg
		      ;; Marker pointing to start of text for one
		      ;; match in *Occur*.
		      (make-marker))
Dave Love's avatar
Dave Love committed
659
		     (text-end
660 661
		      ;; Marker pointing to end of text for one match
		      ;; in *Occur*.
662
		      (make-marker)))
663
		(save-excursion
664 665
		  (setq occur-marker (make-marker))
		  (set-marker occur-marker (point))
666
		  (set-buffer standard-output)
667
		  (setq occur-num-matches (1+ occur-num-matches))
668 669 670
		  (or first (zerop nlines)
		      (insert "--------\n"))
		  (setq first nil)
671 672 673
		  (save-excursion
		    (set-buffer "*Occur*")
		    (setq tab-width current-tab-width))
674 675 676

		  ;; Insert matching text including context lines from
		  ;; source buffer into *Occur*
677
		  (set-marker text-beg (point))
678
		  (setq insertion-start (point))
679
		  (insert-buffer-substring buffer start end)
680 681 682 683
		  (or (and (/= (+ start match-beg) end)
			   (with-current-buffer buffer
			     (eq (char-before end) ?\n)))
		      (insert "\n"))
Dave Love's avatar
Dave Love committed
684
		  (set-marker final-context-start
685 686 687 688 689 690 691 692
			      (+ (- (point) (- end (match-end 0)))
				 (if (save-excursion
				       (set-buffer buffer)
				       (save-excursion
					 (goto-char (match-end 0))
					 (end-of-line)
					 (bolp)))
				     1 0)))
693
		  (set-marker text-end (point))
694 695
		  
		  ;; Highlight text that was matched.
696 697 698 699 700 701
		  (if list-matching-lines-face
		      (put-text-property
		       (+ (marker-position text-beg) match-beg)
		       (+ (marker-position text-beg) match-beg match-len)
		       'face list-matching-lines-face))

702 703
		  ;; `occur-point' property is used by occur-next and
		  ;; occur-prev to move between matching lines.
704 705 706 707
		  (put-text-property
		   (+ (marker-position text-beg) match-beg match-len)
		   (+ (marker-position text-beg) match-beg match-len 1)
		   'occur-point t)
708 709 710
		  
		  ;; Now go back to the start of the matching text
		  ;; adding the space and colon to the start of each line.
711
		  (goto-char insertion-start)
712
		  ;; Insert space and colon for lines of context before match.
713 714 715
		  (setq tem (if (< linenum nlines)
				(- nlines linenum)
			      nlines))
716 717 718 719
		  (while (> tem 0)
		    (insert empty ?:)
		    (forward-line 1)
		    (setq tem (1- tem)))
720 721 722 723

		  ;; Insert line number and colon for the lines of
		  ;; matching text.
		  (let ((this-linenum linenum))
724 725
		    (while (< (point) final-context-start)
		      (if (null tag)
726
			  (setq tag (format line-number-format this-linenum)))
727 728 729 730
		      (insert tag ?:)
		      (forward-line 1)
		      (setq tag nil)
		      (setq this-linenum (1+ this-linenum)))
731
		    (while (and (not (eobp)) (<= (point) final-context-start))
732 733 734
		      (insert empty ?:)
		      (forward-line 1)
		      (setq this-linenum (1+ this-linenum))))
735 736

		  ;; Insert space and colon for lines of context after match.
737
		  (while (and (< (point) (point-max)) (< tem nlines))
738 739 740
		    (insert empty ?:)
		    (forward-line 1)
		    (setq tem (1+ tem)))
741 742 743 744 745 746 747 748
		  
		  ;; Add text properties.  The `occur' prop is used to
		  ;; store the marker of the matching text in the
		  ;; source buffer.
		  (put-text-property (marker-position text-beg)
				     (- (marker-position text-end) 1)
				     'mouse-face 'highlight)
		  (put-text-property (marker-position text-beg)
749
				     (marker-position text-end)
750
				     'occur occur-marker)
751 752 753
		  (goto-char (point-max)))
		(forward-line 1)))
	    (set-buffer standard-output)
754 755
	    ;; Go back to top of *Occur* and finish off by printing the
	    ;; number of matching lines.
756
	    (goto-char (point-min))
757
	    (let ((message-string
758
		   (if (= occur-num-matches 1)
759
		       "1 line"
760
		     (format "%d lines" occur-num-matches))))
761 762
	      (insert message-string)
	      (if (interactive-p)
Karl Heuer's avatar
Karl Heuer committed
763 764
		  (message "%s matched" message-string)))
	    (setq buffer-read-only t)))))))
Richard M. Stallman's avatar
Richard M. Stallman committed
765

766 767
;; It would be nice to use \\[...], but there is no reasonable way
;; to make that display both SPC and Y.
Richard M. Stallman's avatar
Richard M. Stallman committed
768 769
(defconst query-replace-help
  "Type Space or `y' to replace one match, Delete or `n' to skip to next,
770
RET or `q' to exit, Period to replace one match and exit,
Richard M. Stallman's avatar
Richard M. Stallman committed
771 772 773 774 775
Comma to replace but not move point immediately,
C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
C-w to delete match and recursive edit,
C-l to clear the screen, redisplay, and offer same replacement again,
! to replace all remaining matches with no more questions,
776 777
^ to move point back to previous match,
E to edit the replacement string"
778
  "Help message while in `query-replace'.")
Richard M. Stallman's avatar
Richard M. Stallman committed
779

780 781 782 783 784
(defvar query-replace-map (make-sparse-keymap)
  "Keymap that defines the responses to questions in `query-replace'.
The \"bindings\" in this map are not commands; they are answers.
The valid answers include `act', `skip', `act-and-show',
`exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
785
`automatic', `backup', `exit-prefix', and `help'.")
786 787 788 789

(define-key query-replace-map " " 'act)
(define-key query-replace-map "\d" 'skip)
(define-key query-replace-map [delete] 'skip)
790
(define-key query-replace-map [backspace] 'skip)
791 792
(define-key query-replace-map "y" 'act)
(define-key query-replace-map "n" 'skip)
793 794
(define-key query-replace-map "Y" 'act)
(define-key query-replace-map "N" 'skip)
795
(define-key query-replace-map "e" 'edit-replacement)
796
(define-key query-replace-map "E" 'edit-replacement)
797 798
(define-key query-replace-map "," 'act-and-show)
(define-key query-replace-map "q" 'exit)
799
(define-key query-replace-map "\r" 'exit)
800
(define-key query-replace-map [return] 'exit)
801 802 803 804 805 806 807
(define-key query-replace-map "." 'act-and-exit)
(define-key query-replace-map "\C-r" 'edit)
(define-key query-replace-map "\C-w" 'delete-and-edit)
(define-key query-replace-map "\C-l" 'recenter)
(define-key query-replace-map "!" 'automatic)
(define-key query-replace-map "^" 'backup)
(define-key query-replace-map "\C-h" 'help)
808 809
(define-key query-replace-map [f1] 'help)
(define-key query-replace-map [help] 'help)
810
(define-key query-replace-map "?" 'help)
811 812
(define-key query-replace-map "\C-g" 'quit)
(define-key query-replace-map "\C-]" 'quit)
813 814
(define-key query-replace-map "\e" 'exit-prefix)
(define-key query-replace-map [escape] 'exit-prefix)
815

816
(defun replace-match-string-symbols (n)
Dave Love's avatar
Dave Love committed
817 818 819 820 821 822 823 824 825
  "Process a list (and any sub-lists), expanding certain symbols.
Symbol  Expands To
N     (match-string N)           (where N is a string of digits)
#N    (string-to-number (match-string N))
&     (match-string 0)
#&    (string-to-number (match-string 0))

Note that these symbols must be preceeded by a backslash in order to
type them."
826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862 863
  (while n
    (cond
     ((consp (car n))
      (replace-match-string-symbols (car n))) ;Process sub-list
     ((symbolp (car n))
      (let ((name (symbol-name (car n))))
        (cond
         ((string-match "^[0-9]+$" name)
          (setcar n (list 'match-string (string-to-number name))))
         ((string-match "^#[0-9]+$" name)
          (setcar n (list 'string-to-number
                          (list 'match-string
                                (string-to-number (substring name 1))))))
         ((string= "&" name)
          (setcar n '(match-string 0)))
         ((string= "#&" name)
          (setcar n '(string-to-number (match-string 0))))))))
    (setq n (cdr n))))

(defun replace-eval-replacement (expression replace-count)
  (let ((replacement (eval expression)))
    (if (stringp replacement)
        replacement
      (prin1-to-string replacement t))))

(defun replace-loop-through-replacements (data replace-count)
  ;; DATA is a vector contaning the following values:
  ;;   0 next-rotate-count
  ;;   1 repeat-count
  ;;   2 next-replacement
  ;;   3 replacements
  (if (= (aref data 0) replace-count)
      (progn
        (aset data 0 (+ replace-count (aref data 1)))
        (let ((next (cdr (aref data 2))))
          (aset data 2 (if (consp next) next (aref data 3))))))
  (car (aref data 2)))

864
(defun perform-replace (from-string replacements start end
Richard M. Stallman's avatar
Richard M. Stallman committed
865
		        query-flag regexp-flag delimited-flag
866
			&optional repeat-count map)
Richard M. Stallman's avatar
Richard M. Stallman committed
867 868 869 870 871
  "Subroutine of `query-replace'.  Its complexity handles interactive queries.
Don't use this in your own program unless you want to query and set the mark
just as `query-replace' does.  Instead, write a simple loop like this:
  (while (re-search-forward \"foo[ \t]+bar\" nil t)
    (replace-match \"foobar\" nil nil))
872
which will run faster and probably do exactly what you want."
873
  (or map (setq map query-replace-map))
874 875
  (and query-flag minibuffer-auto-raise
       (raise-frame (window-frame (minibuffer-window))))
Richard M. Stallman's avatar
Richard M. Stallman committed
876 877 878
  (let ((nocasify (not (and case-fold-search case-replace
			    (string-equal from-string
					  (downcase from-string)))))
879 880 881
	(case-fold-search (and case-fold-search
			       (string-equal from-string
					     (downcase from-string))))
Richard M. Stallman's avatar
Richard M. Stallman committed
882 883 884
	(literal (not regexp-flag))
	(search-function (if regexp-flag 're-search-forward 'search-forward))
	(search-string from-string)
Jim Blandy's avatar
Jim Blandy committed
885
	(real-match-data nil)		; the match data for the current match
Richard M. Stallman's avatar
Richard M. Stallman committed
886 887 888 889
	(next-replacement nil)
	(keep-going t)
	(stack nil)
	(replace-count 0)
890 891
	(nonempty-match nil)

892 893 894
	;; If non-nil, it is marker saying where in the buffer to stop.
	(limit nil)

895 896
	;; Data for the next match.  If a cons, it has the same format as
	;; (match-data); otherwise it is t if a match is possible at point.
897
	(match-again t)
898

899 900 901 902
	(message
	 (if query-flag
	     (substitute-command-keys
	      "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
903 904

    ;; If region is active, in Transient Mark mode, operate on region.
905 906 907 908
    (when start
      (setq limit (copy-marker (max start end)))
      (goto-char (min start end))
      (deactivate-mark))
909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924

    ;; REPLACEMENTS is either a string, a list of strings, or a cons cell
    ;; containing a function and its first argument.  The function is
    ;; called to generate each replacement like this:
    ;;   (funcall (car replacements) (cdr replacements) replace-count)
    ;; It must return a string.
    (cond
     ((stringp replacements)
      (setq next-replacement replacements
            replacements     nil))
     ((stringp (car replacements)) ; If it isn't a string, it must be a cons
      (or repeat-count (setq repeat-count 1))
      (setq replacements (cons 'replace-loop-through-replacements
                               (vector repeat-count repeat-count
                                       replacements replacements)))))

Richard M. Stallman's avatar
Richard M. Stallman committed
925 926 927 928 929 930 931 932
    (if delimited-flag
	(setq search-function 're-search-forward
	      search-string (concat "\\b"
				    (if regexp-flag from-string
				      (regexp-quote from-string))
				    "\\b")))
    (push-mark)
    (undo-boundary)
933 934 935 936
    (unwind-protect
	;; Loop finding occurrences that perhaps should be replaced.
	(while (and keep-going
		    (not (eobp))
937 938 939 940 941 942 943 944
		    ;; Use the next match if it is already known;
		    ;; otherwise, search for a match after moving forward
		    ;; one char if progress is required.
		    (setq real-match-data
			  (if (consp match-again)
			      (progn (goto-char (nth 1 match-again))
				     match-again)
			    (and (or match-again
945 946 947 948 949 950 951
				     ;; MATCH-AGAIN non-nil means we
				     ;; accept an adjacent match.  If
				     ;; we don't, move one char to the
				     ;; right.  This takes us a
				     ;; character too far at the end,
				     ;; but this is undone after the
				     ;; while-loop.
952
				     (progn (forward-char 1) (not (eobp))))
953
				 (funcall search-function search-string limit t)
954 955 956 957 958 959 960 961 962
				 ;; For speed, use only integers and
				 ;; reuse the list used last time.
				 (match-data t real-match-data)))))

	  ;; Record whether the match is nonempty, to avoid an infinite loop
	  ;; repeatedly matching the same empty string.
	  (setq nonempty-match
		(/= (nth 0 real-match-data) (nth 1 real-match-data)))

963 964 965
	  ;; If the match is empty, record that the next one can't be
	  ;; adjacent.

966 967 968
	  ;; Otherwise, if matching a regular expression, do the next
	  ;; match now, since the replacement for this match may
	  ;; affect whether the next match is adjacent to this one.
969
	  ;; If that match is empty, don't use it.
970 971 972 973
	  (setq match-again
		(and nonempty-match
		     (or (not regexp-flag)
			 (and (looking-at search-string)
974 975 976
			      (let ((match (match-data)))
				(and (/= (nth 0 match) (nth 1 match))
				     match))))))
977

978 979 980 981 982 983
	  ;; Calculate the replacement string, if necessary.
	  (when replacements
            (set-match-data real-match-data)
            (setq next-replacement
                  (funcall (car replacements) (cdr replacements)
                           replace-count)))
984 985
	  (if (not query-flag)
	      (progn
Richard M. Stallman's avatar