mm-view.el 18.6 KB
Newer Older
1
;;; mm-view.el --- functions for viewing MIME objects
2 3
;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004
;;        Free Software Foundation, Inc.
Gerd Moellmann's avatar
Gerd Moellmann committed
4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19

;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.	 See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
Lute Kamstra's avatar
Lute Kamstra committed
20 21
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.
Gerd Moellmann's avatar
Gerd Moellmann committed
22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37

;;; Commentary:

;;; Code:

(eval-when-compile (require 'cl))
(require 'mail-parse)
(require 'mailcap)
(require 'mm-bodies)
(require 'mm-decode)

(eval-and-compile
  (autoload 'gnus-article-prepare-display "gnus-art")
  (autoload 'vcard-parse-string "vcard")
  (autoload 'vcard-format-string "vcard")
  (autoload 'fill-flowed "flow-fill")
38
  (autoload 'html2text "html2text")
39 40
  (unless (fboundp 'diff-mode)
    (autoload 'diff-mode "diff-mode" "" t nil)))
Gerd Moellmann's avatar
Gerd Moellmann committed
41

42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69
(defvar mm-text-html-renderer-alist
  '((w3  . mm-inline-text-html-render-with-w3)
    (w3m . mm-inline-text-html-render-with-w3m)
    (w3m-standalone mm-inline-render-with-stdin nil
		    "w3m" "-dump" "-T" "text/html")
    (links mm-inline-render-with-file
	   mm-links-remove-leading-blank
	   "links" "-dump" file)
    (lynx  mm-inline-render-with-stdin nil
	   "lynx" "-dump" "-force_html" "-stdin" "-nolist")
    (html2text  mm-inline-render-with-function html2text))
  "The attributes of renderer types for text/html.")

(defvar mm-text-html-washer-alist
  '((w3  . gnus-article-wash-html-with-w3)
    (w3m . gnus-article-wash-html-with-w3m)
    (w3m-standalone mm-inline-wash-with-stdin nil
		    "w3m" "-dump" "-T" "text/html")
    (links mm-inline-wash-with-file
	   mm-links-remove-leading-blank
	   "links" "-dump" file)
    (lynx  mm-inline-wash-with-stdin nil
	   "lynx" "-dump" "-force_html" "-stdin" "-nolist")
    (html2text  html2text))
  "The attributes of washer types for text/html.")

;;; Internal variables.

Gerd Moellmann's avatar
Gerd Moellmann committed
70 71 72
;;;
;;; Functions for displaying various formats inline
;;;
73

Gerd Moellmann's avatar
Gerd Moellmann committed
74 75 76 77
(defun mm-inline-image-emacs (handle)
  (let ((b (point-marker))
	buffer-read-only)
    (put-image (mm-get-image handle) b)
78
    (insert "\n\n")
Gerd Moellmann's avatar
Gerd Moellmann committed
79 80
    (mm-handle-set-undisplayer
     handle
81 82 83 84 85
     `(lambda ()
	(let ((b ,b)
	      buffer-read-only)
	  (remove-images b b)
	  (delete-region b (+ b 2)))))))
Gerd Moellmann's avatar
Gerd Moellmann committed
86 87

(defun mm-inline-image-xemacs (handle)
88 89 90
  (insert "\n\n")
  (forward-char -2)
  (let ((annot (make-annotation (mm-get-image handle) nil 'text))
Gerd Moellmann's avatar
Gerd Moellmann committed
91 92 93 94
	buffer-read-only)
    (mm-handle-set-undisplayer
     handle
     `(lambda ()
95 96
	(let ((b ,(point-marker))
	      buffer-read-only)
Gerd Moellmann's avatar
Gerd Moellmann committed
97
	  (delete-annotation ,annot)
98
	  (delete-region (- b 2) b))))
Gerd Moellmann's avatar
Gerd Moellmann committed
99 100 101 102
    (set-extent-property annot 'mm t)
    (set-extent-property annot 'duplicable t)))

(eval-and-compile
Dave Love's avatar
Dave Love committed
103
  (if (featurep 'xemacs)
Gerd Moellmann's avatar
Gerd Moellmann committed
104 105 106 107 108 109 110 111 112 113 114 115 116
      (defalias 'mm-inline-image 'mm-inline-image-xemacs)
    (defalias 'mm-inline-image 'mm-inline-image-emacs)))

(defvar mm-w3-setup nil)
(defun mm-setup-w3 ()
  (unless mm-w3-setup
    (require 'w3)
    (w3-do-setup)
    (require 'url)
    (require 'w3-vars)
    (require 'url-vars)
    (setq mm-w3-setup t)))

117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150
(defun mm-inline-text-html-render-with-w3 (handle)
  (mm-setup-w3)
  (let ((text (mm-get-part handle))
	(b (point))
	(url-standalone-mode t)
	(url-gateway-unplugged t)
	(w3-honor-stylesheets nil)
	(url-current-object
	 (url-generic-parse-url (format "cid:%s" (mm-handle-id handle))))
	(width (window-width))
	(charset (mail-content-type-get
		  (mm-handle-type handle) 'charset)))
    (save-excursion
      (insert text)
      (save-restriction
	(narrow-to-region b (point))
	(goto-char (point-min))
	(if (or (and (boundp 'w3-meta-content-type-charset-regexp)
		     (re-search-forward
		      w3-meta-content-type-charset-regexp nil t))
		(and (boundp 'w3-meta-charset-content-type-regexp)
		     (re-search-forward
		      w3-meta-charset-content-type-regexp nil t)))
	    (setq charset
		  (or (let ((bsubstr (buffer-substring-no-properties
				      (match-beginning 2)
				      (match-end 2))))
			(if (fboundp 'w3-coding-system-for-mime-charset)
			    (w3-coding-system-for-mime-charset bsubstr)
			  (mm-charset-to-coding-system bsubstr)))
		      charset)))
	(delete-region (point-min) (point-max))
	(insert (mm-decode-string text charset))
	(save-window-excursion
Gerd Moellmann's avatar
Gerd Moellmann committed
151
	  (save-restriction
152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201
	    (let ((w3-strict-width width)
		  ;; Don't let w3 set the global version of
		  ;; this variable.
		  (fill-column fill-column))
	      (if (or debug-on-error debug-on-quit)
		  (w3-region (point-min) (point-max))
		(condition-case ()
		    (w3-region (point-min) (point-max))
		  (error
		   (delete-region (point-min) (point-max))
		   (let ((b (point))
			 (charset (mail-content-type-get
				   (mm-handle-type handle) 'charset)))
		     (if (or (eq charset 'gnus-decoded)
			     (eq mail-parse-charset 'gnus-decoded))
		       (save-restriction
			 (narrow-to-region (point) (point))
			 (mm-insert-part handle)
			 (goto-char (point-max)))
		       (insert (mm-decode-string (mm-get-part handle)
						 charset))))
		   (message
		    "Error while rendering html; showing as text/plain")))))))
	(mm-handle-set-undisplayer
	 handle
	 `(lambda ()
	    (let (buffer-read-only)
	      (if (functionp 'remove-specifier)
		  (mapcar (lambda (prop)
			    (remove-specifier
			     (face-property 'default prop)
			     (current-buffer)))
			  '(background background-pixmap foreground)))
	      (delete-region ,(point-min-marker)
			     ,(point-max-marker)))))))))

(defvar mm-w3m-setup nil
  "Whether gnus-article-mode has been setup to use emacs-w3m.")

(defun mm-setup-w3m ()
  "Setup gnus-article-mode to use emacs-w3m."
  (unless mm-w3m-setup
    (require 'w3m)
    (unless (assq 'gnus-article-mode w3m-cid-retrieve-function-alist)
      (push (cons 'gnus-article-mode 'mm-w3m-cid-retrieve)
	    w3m-cid-retrieve-function-alist))
    (setq mm-w3m-setup t))
  (setq w3m-display-inline-images mm-inline-text-html-with-images))

(defun mm-w3m-cid-retrieve-1 (url handle)
202 203 204 205 206 207 208 209
  (dolist (elem handle)
    (when (listp elem)
      (if (equal url (mm-handle-id elem))
	  (progn
	    (mm-insert-part elem)
	    (throw 'found-handle (mm-handle-media-type elem))))
      (if (equal "multipart" (mm-handle-media-supertype elem))
	  (mm-w3m-cid-retrieve-1 url elem)))))
210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231

(defun mm-w3m-cid-retrieve (url &rest args)
  "Insert a content pointed by URL if it has the cid: scheme."
  (when (string-match "\\`cid:" url)
    (catch 'found-handle
      (mm-w3m-cid-retrieve-1 (concat "<" (substring url (match-end 0)) ">")
			     (with-current-buffer w3m-current-buffer
			       gnus-article-mime-handles)))))

(defun mm-inline-text-html-render-with-w3m (handle)
  "Render a text/html part using emacs-w3m."
  (mm-setup-w3m)
  (let ((text (mm-get-part handle))
	(b (point))
	(charset (mail-content-type-get (mm-handle-type handle) 'charset)))
    (save-excursion
      (insert (if charset (mm-decode-string text charset) text))
      (save-restriction
	(narrow-to-region b (point))
	(unless charset
	  (goto-char (point-min))
	  (when (setq charset (w3m-detect-meta-charset))
Gerd Moellmann's avatar
Gerd Moellmann committed
232
	    (delete-region (point-min) (point-max))
233 234 235 236 237 238 239 240 241 242 243 244 245
	    (insert (mm-decode-string text charset))))
	(let ((w3m-safe-url-regexp mm-w3m-safe-url-regexp)
	      w3m-force-redisplay)
	  (w3m-region (point-min) (point-max) nil charset))
	(when (and mm-inline-text-html-with-w3m-keymap
		   (boundp 'w3m-minor-mode-map)
		   w3m-minor-mode-map)
	  (add-text-properties
	   (point-min) (point-max)
	   (list 'keymap w3m-minor-mode-map
		 ;; Put the mark meaning this part was rendered by emacs-w3m.
		 'mm-inline-text-html-with-w3m t))))
      (mm-handle-set-undisplayer
Gerd Moellmann's avatar
Gerd Moellmann committed
246
       handle
247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320
       `(lambda ()
	  (let (buffer-read-only)
	    (if (functionp 'remove-specifier)
		(mapcar (lambda (prop)
			  (remove-specifier
			   (face-property 'default prop)
			   (current-buffer)))
			'(background background-pixmap foreground)))
	    (delete-region ,(point-min-marker)
			   ,(point-max-marker))))))))

(defun mm-links-remove-leading-blank ()
  ;; Delete the annoying three spaces preceding each line of links
  ;; output.
  (goto-char (point-min))
  (while (re-search-forward "^   " nil t)
    (delete-region (match-beginning 0) (match-end 0))))

(defun mm-inline-wash-with-file (post-func cmd &rest args)
  (let ((file (mm-make-temp-file
	       (expand-file-name "mm" mm-tmp-directory))))
    (let ((coding-system-for-write 'binary))
      (write-region (point-min) (point-max) file nil 'silent))
    (delete-region (point-min) (point-max))
    (unwind-protect
	(apply 'call-process cmd nil t nil (mapcar 'eval args))
      (delete-file file))
    (and post-func (funcall post-func))))

(defun mm-inline-wash-with-stdin (post-func cmd &rest args)
  (let ((coding-system-for-write 'binary))
    (apply 'call-process-region (point-min) (point-max)
	   cmd t t nil args))
  (and post-func (funcall post-func)))

(defun mm-inline-render-with-file (handle post-func cmd &rest args)
  (let ((source (mm-get-part handle)))
    (mm-insert-inline
     handle
     (mm-with-unibyte-buffer
       (insert source)
       (apply 'mm-inline-wash-with-file post-func cmd args)
       (buffer-string)))))

(defun mm-inline-render-with-stdin (handle post-func cmd &rest args)
  (let ((source (mm-get-part handle)))
    (mm-insert-inline
     handle
     (mm-with-unibyte-buffer
       (insert source)
       (apply 'mm-inline-wash-with-stdin post-func cmd args)
       (buffer-string)))))

(defun mm-inline-render-with-function (handle func &rest args)
  (let ((source (mm-get-part handle))
	(charset (mail-content-type-get (mm-handle-type handle) 'charset)))
    (mm-insert-inline
     handle
     (mm-with-multibyte-buffer
       (insert (if charset
		   (mm-decode-string source charset)
		 source))
       (apply func args)
       (buffer-string)))))

(defun mm-inline-text-html (handle)
  (let* ((func (or mm-inline-text-html-renderer mm-text-html-renderer))
	 (entry (assq func mm-text-html-renderer-alist))
	 buffer-read-only)
    (if entry
	(setq func (cdr entry)))
    (cond
     ((functionp func)
      (funcall func handle))
Gerd Moellmann's avatar
Gerd Moellmann committed
321
     (t
322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345
      (apply (car func) handle (cdr func))))))

(defun mm-inline-text-vcard (handle)
  (let (buffer-read-only)
    (mm-insert-inline
     handle
     (concat "\n-- \n"
	     (ignore-errors
	       (if (fboundp 'vcard-pretty-print)
		   (vcard-pretty-print (mm-get-part handle))
		 (vcard-format-string
		  (vcard-parse-string (mm-get-part handle)
				      'vcard-standard-filter))))))))

(defun mm-inline-text (handle)
  (let ((b (point))
	(type (mm-handle-media-subtype handle))
	(charset (mail-content-type-get
		  (mm-handle-type handle) 'charset))
	buffer-read-only)
    (if (or (eq charset 'gnus-decoded)
	    ;; This is probably not entirely correct, but
	    ;; makes rfc822 parts with embedded multiparts work.
	    (eq mail-parse-charset 'gnus-decoded))
Gerd Moellmann's avatar
Gerd Moellmann committed
346
	(save-restriction
347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371
	  (narrow-to-region (point) (point))
	  (mm-insert-part handle)
	  (goto-char (point-max)))
      (insert (mm-decode-string (mm-get-part handle) charset)))
    (when (and (equal type "plain")
	       (equal (cdr (assoc 'format (mm-handle-type handle)))
		      "flowed"))
      (save-restriction
	(narrow-to-region b (point))
	(goto-char b)
	(fill-flowed)
	(goto-char (point-max))))
    (save-restriction
      (narrow-to-region b (point))
      (set-text-properties (point-min) (point-max) nil)
      (when (or (equal type "enriched")
		(equal type "richtext"))
	(ignore-errors
	  (enriched-decode (point-min) (point-max))))
      (mm-handle-set-undisplayer
       handle
       `(lambda ()
	  (let (buffer-read-only)
	    (delete-region ,(point-min-marker)
			   ,(point-max-marker))))))))
Gerd Moellmann's avatar
Gerd Moellmann committed
372 373 374

(defun mm-insert-inline (handle text)
  "Insert TEXT inline from HANDLE."
375
  (let ((b (point)))
Gerd Moellmann's avatar
Gerd Moellmann committed
376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391
    (insert text)
    (mm-handle-set-undisplayer
     handle
     `(lambda ()
	(let (buffer-read-only)
	  (delete-region ,(set-marker (make-marker) b)
			 ,(set-marker (make-marker) (point))))))))

(defun mm-inline-audio (handle)
  (message "Not implemented"))

(defun mm-view-sound-file ()
  (message "Not implemented"))

(defun mm-w3-prepare-buffer ()
  (require 'w3)
392
  (let ((url-standalone-mode t)
393 394
	(url-gateway-unplugged t)
	(w3-honor-stylesheets nil))
Gerd Moellmann's avatar
Gerd Moellmann committed
395 396 397 398 399 400 401 402 403 404 405 406
    (w3-prepare-buffer)))

(defun mm-view-message ()
  (mm-enable-multibyte)
  (let (handles)
    (let (gnus-article-mime-handles)
      ;; Double decode problem may happen.  See mm-inline-message.
      (run-hooks 'gnus-article-decode-hook)
      (gnus-article-prepare-display)
      (setq handles gnus-article-mime-handles))
    (when handles
      (setq gnus-article-mime-handles
407
	    (mm-merge-handles gnus-article-mime-handles handles))))
Gerd Moellmann's avatar
Gerd Moellmann committed
408 409 410 411 412
  (fundamental-mode)
  (goto-char (point-min)))

(defun mm-inline-message (handle)
  (let ((b (point))
413
	(bolp (bolp))
Gerd Moellmann's avatar
Gerd Moellmann committed
414 415 416 417 418 419 420 421 422 423 424 425 426
	(charset (mail-content-type-get
		  (mm-handle-type handle) 'charset))
	gnus-displaying-mime handles)
    (when (and charset
	       (stringp charset))
      (setq charset (intern (downcase charset)))
      (when (eq charset 'us-ascii)
	(setq charset nil)))
    (save-excursion
      (save-restriction
	(narrow-to-region b b)
	(mm-insert-part handle)
	(let (gnus-article-mime-handles
427 428
	      ;; disable prepare hook
	      gnus-article-prepare-hook
Gerd Moellmann's avatar
Gerd Moellmann committed
429 430
	      (gnus-newsgroup-charset
	       (or charset gnus-newsgroup-charset)))
431 432
	  (let ((gnus-original-article-buffer (mm-handle-buffer handle)))
	    (run-hooks 'gnus-article-decode-hook))
Gerd Moellmann's avatar
Gerd Moellmann committed
433 434
	  (gnus-article-prepare-display)
	  (setq handles gnus-article-mime-handles))
435 436 437
	(goto-char (point-min))
	(unless bolp
	  (insert "\n"))
Gerd Moellmann's avatar
Gerd Moellmann committed
438 439 440 441 442 443
	(goto-char (point-max))
	(unless (bolp)
	  (insert "\n"))
	(insert "----------\n\n")
	(when handles
	  (setq gnus-article-mime-handles
444
		(mm-merge-handles gnus-article-mime-handles handles)))
Gerd Moellmann's avatar
Gerd Moellmann committed
445 446 447 448
	(mm-handle-set-undisplayer
	 handle
	 `(lambda ()
	    (let (buffer-read-only)
Dave Love's avatar
Dave Love committed
449
	      (if (fboundp 'remove-specifier)
Gerd Moellmann's avatar
Gerd Moellmann committed
450 451 452 453
		  ;; This is only valid on XEmacs.
		  (mapcar (lambda (prop)
			    (remove-specifier
			     (face-property 'default prop) (current-buffer)))
Dave Love's avatar
Dave Love committed
454
			  '(background background-pixmap foreground)))
Gerd Moellmann's avatar
Gerd Moellmann committed
455 456
	      (delete-region ,(point-min-marker) ,(point-max-marker)))))))))

Dave Love's avatar
Dave Love committed
457
(defun mm-display-inline-fontify (handle mode)
Gerd Moellmann's avatar
Gerd Moellmann committed
458
  (let (text)
459 460 461 462 463 464 465 466 467 468 469
    ;; XEmacs @#$@ version of font-lock refuses to fully turn itself
    ;; on for buffers whose name begins with " ".  That's why we use
    ;; save-current-buffer/get-buffer-create rather than
    ;; with-temp-buffer.
    (save-current-buffer
      (set-buffer (generate-new-buffer "*fontification*"))
      (unwind-protect
	  (progn
	    (buffer-disable-undo)
	    (mm-insert-part handle)
	    (require 'font-lock)
470 471 472 473 474
	    ;; Inhibit font-lock this time (*-mode-hook might run
	    ;; `turn-on-font-lock') so that jit-lock may not turn off
	    ;; font-lock immediately after this.
	    (let ((font-lock-mode t))
	      (funcall mode))
475 476 477 478 479 480 481 482 483 484 485 486 487
	    (let ((font-lock-verbose nil))
	      ;; I find font-lock a bit too verbose.
	      (font-lock-fontify-buffer))
	    ;; By default, XEmacs font-lock uses non-duplicable text
	    ;; properties.  This code forces all the text properties
	    ;; to be copied along with the text.
	    (when (fboundp 'extent-list)
	      (map-extents (lambda (ext ignored)
			     (set-extent-property ext 'duplicable t)
			     nil)
			   nil nil nil nil nil 'text-prop))
	    (setq text (buffer-string)))
	(kill-buffer (current-buffer))))
Gerd Moellmann's avatar
Gerd Moellmann committed
488 489
    (mm-insert-inline handle text)))

490 491 492 493 494
;; Shouldn't these functions check whether the user even wants to use
;; font-lock?  At least under XEmacs, this fontification is pretty
;; much unconditional.  Also, it would be nice to change for the size
;; of the fontified region.

Dave Love's avatar
Dave Love committed
495 496 497 498 499 500
(defun mm-display-patch-inline (handle)
  (mm-display-inline-fontify handle 'diff-mode))

(defun mm-display-elisp-inline (handle)
  (mm-display-inline-fontify handle 'emacs-lisp-mode))

501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576
;;      id-signedData OBJECT IDENTIFIER ::= { iso(1) member-body(2)
;;          us(840) rsadsi(113549) pkcs(1) pkcs7(7) 2 }
(defvar mm-pkcs7-signed-magic
  (mm-string-as-unibyte
   (apply 'concat
	  (mapcar 'char-to-string
		  (list ?\x30 ?\x5c ?\x28 ?\x80 ?\x5c ?\x7c ?\x81 ?\x2e ?\x5c
			?\x7c ?\x82 ?\x2e ?\x2e ?\x5c ?\x7c ?\x83 ?\x2e ?\x2e
			?\x2e ?\x5c ?\x29 ?\x06 ?\x09 ?\x5c ?\x2a ?\x86 ?\x48
			?\x86 ?\xf7 ?\x0d ?\x01 ?\x07 ?\x02)))))

;;      id-envelopedData OBJECT IDENTIFIER ::= { iso(1) member-body(2)
;;          us(840) rsadsi(113549) pkcs(1) pkcs7(7) 3 }
(defvar mm-pkcs7-enveloped-magic
  (mm-string-as-unibyte
   (apply 'concat
	  (mapcar 'char-to-string
		  (list ?\x30 ?\x5c ?\x28 ?\x80 ?\x5c ?\x7c ?\x81 ?\x2e ?\x5c
			?\x7c ?\x82 ?\x2e ?\x2e ?\x5c ?\x7c ?\x83 ?\x2e ?\x2e
			?\x2e ?\x5c ?\x29 ?\x06 ?\x09 ?\x5c ?\x2a ?\x86 ?\x48
			?\x86 ?\xf7 ?\x0d ?\x01 ?\x07 ?\x03)))))

(defun mm-view-pkcs7-get-type (handle)
  (mm-with-unibyte-buffer
    (mm-insert-part handle)
    (cond ((looking-at mm-pkcs7-enveloped-magic)
	   'enveloped)
	  ((looking-at mm-pkcs7-signed-magic)
	   'signed)
	  (t
	   (error "Could not identify PKCS#7 type")))))

(defun mm-view-pkcs7 (handle)
  (case (mm-view-pkcs7-get-type handle)
    (enveloped (mm-view-pkcs7-decrypt handle))
    (signed (mm-view-pkcs7-verify handle))
    (otherwise (error "Unknown or unimplemented PKCS#7 type"))))

(defun mm-view-pkcs7-verify (handle)
  ;; A bogus implementation of PKCS#7. FIXME::
  (mm-insert-part handle)
  (goto-char (point-min))
  (if (search-forward "Content-Type: " nil t)
      (delete-region (point-min) (match-beginning 0)))
  (goto-char (point-max))
  (if (re-search-backward "--\r?\n?" nil t)
      (delete-region (match-end 0) (point-max)))
  (goto-char (point-min))
  (while (search-forward "\r\n" nil t)
    (replace-match "\n"))
  (message "Verify signed PKCS#7 message is unimplemented.")
  (sit-for 1)
  t)

(autoload 'gnus-completing-read-maybe-default "gnus-util" nil nil 'macro)

(defun mm-view-pkcs7-decrypt (handle)
  (insert-buffer-substring (mm-handle-buffer handle))
  (goto-char (point-min))
  (insert "MIME-Version: 1.0\n")
  (mm-insert-headers "application/pkcs7-mime" "base64" "smime.p7m")
  (smime-decrypt-region
   (point-min) (point-max)
   (if (= (length smime-keys) 1)
       (cadar smime-keys)
     (smime-get-key-by-email
      (gnus-completing-read-maybe-default
       (concat "Decipher using which key? "
	       (if smime-keys (concat "(default " (caar smime-keys) ") ")
		 ""))
       smime-keys nil nil nil nil (car-safe (car-safe smime-keys))))))
  (goto-char (point-min))
  (while (search-forward "\r\n" nil t)
    (replace-match "\n"))
  (goto-char (point-min)))

Gerd Moellmann's avatar
Gerd Moellmann committed
577 578
(provide 'mm-view)

Miles Bader's avatar
Miles Bader committed
579
;;; arch-tag: b60e749a-d05c-47f2-bccd-bdaa59327cb2
580
;;; mm-view.el ends here