shr.el 22 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32
;;; shr.el --- Simple HTML Renderer

;; Copyright (C) 2010 Free Software Foundation, Inc.

;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
;; Keywords: html

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; This package takes a HTML parse tree (as provided by
;; libxml-parse-html-region) and renders it in the current buffer.  It
;; does not do CSS, JavaScript or anything advanced: It's geared
;; towards rendering typical short snippets of HTML, like what you'd
;; find in HTML email and the like.

;;; Code:

33
(eval-when-compile (require 'cl))
34 35
(require 'browse-url)

36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55
(defgroup shr nil
  "Simple HTML Renderer"
  :group 'mail)

(defcustom shr-max-image-proportion 0.9
  "How big pictures displayed are in relation to the window they're in.
A value of 0.7 means that they are allowed to take up 70% of the
width and height of the window.  If they are larger than this,
and Emacs supports it, then the images will be rescaled down to
fit these criteria."
  :version "24.1"
  :group 'shr
  :type 'float)

(defcustom shr-blocked-images nil
  "Images that have URLs matching this regexp will be blocked."
  :version "24.1"
  :group 'shr
  :type 'regexp)

56 57 58
(defcustom shr-table-line ?-
  "Character used to draw table line."
  :group 'shr
59
  :type 'character)
60 61

(defcustom shr-table-corner ?+
62 63
  "Character used to draw table corner."
  :group 'shr
64
  :type 'character)
65 66 67

(defcustom shr-hr-line ?-
  "Character used to draw hr line."
68
  :group 'shr
69
  :type 'character)
70

71 72 73 74 75
(defcustom shr-width fill-column
  "Frame width to use for rendering."
  :type 'integer
  :group 'shr)

76 77 78 79 80
(defvar shr-content-function nil
  "If bound, this should be a function that will return the content.
This is used for cid: URLs, and the function is called with the
cid: URL as the argument.")

81 82
;;; Internal variables.

83 84 85
(defvar shr-folding-mode nil)
(defvar shr-state nil)
(defvar shr-start nil)
86
(defvar shr-indentation 0)
87
(defvar shr-inhibit-images nil)
88
(defvar shr-list-mode nil)
89
(defvar shr-content-cache nil)
90

91 92 93 94 95 96 97 98 99 100
(defvar shr-map
  (let ((map (make-sparse-keymap)))
    (define-key map "a" 'shr-show-alt-text)
    (define-key map "i" 'shr-browse-image)
    (define-key map "I" 'shr-insert-image)
    (define-key map "u" 'shr-copy-url)
    (define-key map "v" 'shr-browse-url)
    (define-key map "\r" 'shr-browse-url)
    map))

101 102 103 104
;; Public functions and commands.

;;;###autoload
(defun shr-insert-document (dom)
105
  (setq shr-content-cache nil)
106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157
  (let ((shr-state nil)
	(shr-start nil))
    (shr-descend (shr-transform-dom dom))))

(defun shr-copy-url ()
  "Copy the URL under point to the kill ring.
If called twice, then try to fetch the URL and see whether it
redirects somewhere else."
  (interactive)
  (let ((url (get-text-property (point) 'shr-url)))
    (cond
     ((not url)
      (message "No URL under point"))
     ;; Resolve redirected URLs.
     ((equal url (car kill-ring))
      (url-retrieve
       url
       (lambda (a)
	 (when (and (consp a)
		    (eq (car a) :redirect))
	   (with-temp-buffer
	     (insert (cadr a))
	     (goto-char (point-min))
	     ;; Remove common tracking junk from the URL.
	     (when (re-search-forward ".utm_.*" nil t)
	       (replace-match "" t t))
	     (message "Copied %s" (buffer-string))
	     (copy-region-as-kill (point-min) (point-max)))))))
     ;; Copy the URL to the kill ring.
     (t
      (with-temp-buffer
	(insert url)
	(copy-region-as-kill (point-min) (point-max))
	(message "Copied %s" url))))))

(defun shr-show-alt-text ()
  "Show the ALT text of the image under point."
  (interactive)
  (let ((text (get-text-property (point) 'shr-alt)))
    (if (not text)
	(message "No image under point")
      (message "%s" text))))

(defun shr-browse-image ()
  "Browse the image under point."
  (interactive)
  (let ((url (get-text-property (point) 'shr-image)))
    (if (not url)
	(message "No image under point")
      (message "Browsing %s..." url)
      (browse-url url))))

158 159 160 161 162 163 164 165 166 167 168
(defun shr-insert-image ()
  "Insert the image under point into the buffer."
  (interactive)
  (let ((url (get-text-property (point) 'shr-image)))
    (if (not url)
	(message "No image under point")
      (message "Inserting %s..." url)
      (url-retrieve url 'shr-image-fetched
		    (list (current-buffer) (1- (point)) (point-marker))
		    t))))

169 170
;;; Utility functions.

171 172 173 174 175 176 177 178 179 180 181 182 183
(defun shr-transform-dom (dom)
  (let ((result (list (pop dom))))
    (dolist (arg (pop dom))
      (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
		  (cdr arg))
	    result))
    (dolist (sub dom)
      (if (stringp sub)
	  (push (cons :text sub) result)
	(push (shr-transform-dom sub) result)))
    (nreverse result)))

(defun shr-descend (dom)
184
  (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray)))
185 186 187 188 189 190 191 192 193
    (if (fboundp function)
	(funcall function (cdr dom))
      (shr-generic (cdr dom)))))

(defun shr-generic (cont)
  (dolist (sub cont)
    (cond
     ((eq (car sub) :text)
      (shr-insert (cdr sub)))
194
     ((listp (cdr sub))
195 196
      (shr-descend sub)))))

197
(defun shr-insert (text)
198 199
  (when (and (eq shr-state 'image)
	     (not (string-match "\\`[ \t\n]+\\'" text)))
200 201 202 203 204 205 206 207 208
    (insert "\n")
    (setq shr-state nil))
  (cond
   ((eq shr-folding-mode 'none)
    (insert text))
   (t
    (let ((first t)
	  column)
      (when (and (string-match "\\`[ \t\n]" text)
209 210
		 (not (bolp))
		 (not (eq (char-after (1- (point))) ? )))
211
	(insert " "))
212 213 214 215 216 217 218 219 220
      (dolist (elem (split-string text))
	(when (and (bolp)
		   (> shr-indentation 0))
	  (shr-indent))
	;; The shr-start is a special variable that is used to pass
	;; upwards the first point in the buffer where the text really
	;; starts.
	(unless shr-start
	  (setq shr-start (point)))
221
	(insert elem)
222 223
	(while (> (current-column) shr-width)
	  (if (not (shr-find-fill-point))
224 225 226 227 228 229 230 231 232 233
	      (insert "\n")
	    (delete-char 1)
	    (insert "\n")
	    (put-text-property (1- (point)) (point) 'shr-break t)
	    (when (> shr-indentation 0)
	      (shr-indent))
	    (end-of-line)))
	(insert " "))
      (unless (string-match "[ \t\n]\\'" text)
	(delete-char -1))))))
234

235 236 237
(defun shr-find-fill-point ()
  (let ((found nil))
    (while (and (not found)
238 239 240 241 242
		(> (current-column) shr-indentation))
      (when (and (or (eq (preceding-char) ? )
		     (aref fill-find-break-point-function-table
			   (preceding-char)))
		 (<= (current-column) shr-width))
243 244 245 246 247
	(setq found (point)))
      (backward-char 1))
    (or found
	(end-of-line))))

248 249 250
(defun shr-ensure-newline ()
  (unless (zerop (current-column))
    (insert "\n")))
251 252 253

(defun shr-ensure-paragraph ()
  (unless (bobp)
254
    (if (<= (current-column) shr-indentation)
255 256 257
	(unless (save-excursion
		  (forward-line -1)
		  (looking-at " *$"))
258 259 260
	  (insert "\n"))
      (if (save-excursion
	    (beginning-of-line)
261
	    (looking-at " *$"))
262 263 264
	  (insert "\n")
	(insert "\n\n")))))

265
(defun shr-indent ()
266 267
  (when (> shr-indentation 0)
    (insert (make-string shr-indentation ? ))))
268

269
(defun shr-fontize-cont (cont &rest types)
270 271
  (let (shr-start)
    (shr-generic cont)
272 273
    (dolist (type types)
      (shr-add-font (or shr-start (point)) (point) type))))
274 275 276 277 278

(defun shr-add-font (start end type)
  (let ((overlay (make-overlay start end)))
    (overlay-put overlay 'face type)))

279 280 281 282 283 284 285 286
(defun shr-browse-url ()
  "Browse the URL under point."
  (interactive)
  (let ((url (get-text-property (point) 'shr-url)))
    (if (not url)
	(message "No link under point")
      (browse-url url))))

287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303
(defun shr-image-fetched (status buffer start end)
  (when (and (buffer-name buffer)
	     (not (plist-get status :error)))
    (url-store-in-cache (current-buffer))
    (when (or (search-forward "\n\n" nil t)
	      (search-forward "\r\n\r\n" nil t))
      (let ((data (buffer-substring (point) (point-max))))
        (with-current-buffer buffer
          (let ((alt (buffer-substring start end))
		(inhibit-read-only t))
	    (delete-region start end)
	    (shr-put-image data start alt))))))
  (kill-buffer (current-buffer)))

(defun shr-put-image (data point alt)
  (if (not (display-graphic-p))
      (insert alt)
304 305 306 307
    (let ((image (ignore-errors
		   (shr-rescale-image data))))
      (when image
	(put-image image point alt)))))
308 309 310 311 312 313

(defun shr-rescale-image (data)
  (if (or (not (fboundp 'imagemagick-types))
	  (not (get-buffer-window (current-buffer))))
      (create-image data nil t)
    (let* ((image (create-image data nil t))
314
	   (size (image-size image t))
315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340
	   (width (car size))
	   (height (cdr size))
	   (edges (window-inside-pixel-edges
		   (get-buffer-window (current-buffer))))
	   (window-width (truncate (* shr-max-image-proportion
				      (- (nth 2 edges) (nth 0 edges)))))
	   (window-height (truncate (* shr-max-image-proportion
				       (- (nth 3 edges) (nth 1 edges)))))
	   scaled-image)
      (when (> height window-height)
	(setq image (or (create-image data 'imagemagick t
				      :height window-height)
			image))
	(setq size (image-size image t)))
      (when (> (car size) window-width)
	(setq image (or
		     (create-image data 'imagemagick t
				   :width window-width)
		     image)))
      image)))

(defun shr-get-image-data (url)
  "Get image data for URL.
Return a string with image data."
  (with-temp-buffer
    (mm-disable-multibyte)
341
    (when (ignore-errors
342
	    (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
343 344 345 346
	    t)
      (when (or (search-forward "\n\n" nil t)
		(search-forward "\r\n\r\n" nil t))
	(buffer-substring (point) (point-max))))))
347

348 349 350 351 352 353 354 355 356
(defun shr-heading (cont &rest types)
  (shr-ensure-paragraph)
  (apply #'shr-fontize-cont cont types)
  (shr-ensure-paragraph))

;;; Tag-specific rendering rules.

(defun shr-tag-p (cont)
  (shr-ensure-paragraph)
357
  (shr-indent)
358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381
  (shr-generic cont)
  (shr-ensure-paragraph))

(defun shr-tag-b (cont)
  (shr-fontize-cont cont 'bold))

(defun shr-tag-i (cont)
  (shr-fontize-cont cont 'italic))

(defun shr-tag-em (cont)
  (shr-fontize-cont cont 'bold))

(defun shr-tag-u (cont)
  (shr-fontize-cont cont 'underline))

(defun shr-tag-s (cont)
  (shr-fontize-cont cont 'strike-through))

(defun shr-tag-a (cont)
  (let ((url (cdr (assq :href cont)))
	(start (point))
	shr-start)
    (shr-generic cont)
    (widget-convert-button
382 383 384 385
     'url-link (or shr-start start) (point)
     :help-echo url
     :keymap shr-map
     url)
386 387
    (put-text-property (or shr-start start) (point) 'shr-url url)))

388 389 390 391
(defun shr-encode-url (url)
  "Encode URL."
  (browse-url-url-encode-chars url "[)$ ]"))

392 393 394 395
(defun shr-tag-img (cont)
  (when (and (> (current-column) 0)
	     (not (eq shr-state 'image)))
    (insert "\n"))
396 397 398 399 400 401 402
  (let ((alt (cdr (assq :alt cont)))
        (url (cdr (assq :src cont)))
        (width (cdr (assq :width cont))))
    ;; Only respect align if width specified.
    (when width
      ;; Check that width is not larger than max width, otherwise ignore
      ;; align
403
      (let ((max-width (* shr-width (frame-char-width)))
404 405 406
            (width (string-to-number width)))
        (when (< width max-width)
          (let ((align (cdr (assq :align cont))))
407 408 409 410 411 412 413 414 415 416 417
            (cond
	     ((string= align "right")
	      (insert (propertize
		       " " 'display
		       `(space . (:align-to
				  ,(list (- max-width width)))))))
	     ((string= align "center")
	      (insert (propertize
		       " " 'display
		       `(space . (:balign-to
				  ,(list (- (/ max-width 2) width))))))))))))
418
    (let ((start (point-marker)))
419
      (when (zerop (length alt))
420
        (setq alt "[img]"))
421 422
      (cond
       ((and (not shr-inhibit-images)
423 424
             (string-match "\\`cid:" url))
        (let ((url (substring url (match-end 0)))
425 426 427 428 429 430 431 432 433 434 435 436 437
	      image)
	  (if (or (not shr-content-function)
		  (not (setq image (funcall shr-content-function url))))
	      (insert alt)
	    (shr-put-image image (point) alt))))
       ((or shr-inhibit-images
	    (and shr-blocked-images
		 (string-match shr-blocked-images url)))
	(setq shr-start (point))
	(let ((shr-state 'space))
	  (if (> (length alt) 8)
	      (shr-insert (substring alt 0 8))
	    (shr-insert alt))))
438
       ((url-is-cached (shr-encode-url url))
439 440 441 442
	(shr-put-image (shr-get-image-data url) (point) alt))
       (t
	(insert alt)
	(ignore-errors
443
	  (url-retrieve (shr-encode-url url) 'shr-image-fetched
444 445 446 447 448 449 450 451 452 453 454
			(list (current-buffer) start (point-marker))
			t))))
      (insert " ")
      (put-text-property start (point) 'keymap shr-map)
      (put-text-property start (point) 'shr-alt alt)
      (put-text-property start (point) 'shr-image url)
      (setq shr-state 'image))))

(defun shr-tag-pre (cont)
  (let ((shr-folding-mode 'none))
    (shr-ensure-newline)
455
    (shr-indent)
456 457 458 459 460
    (shr-generic cont)
    (shr-ensure-newline)))

(defun shr-tag-blockquote (cont)
  (shr-ensure-paragraph)
461
  (shr-indent)
462 463 464
  (let ((shr-indentation (+ shr-indentation 4)))
    (shr-generic cont))
  (shr-ensure-paragraph))
465 466 467 468

(defun shr-tag-ul (cont)
  (shr-ensure-paragraph)
  (let ((shr-list-mode 'ul))
469 470
    (shr-generic cont))
  (shr-ensure-paragraph))
471 472

(defun shr-tag-ol (cont)
473
  (shr-ensure-paragraph)
474
  (let ((shr-list-mode 1))
475 476
    (shr-generic cont))
  (shr-ensure-paragraph))
477 478

(defun shr-tag-li (cont)
479 480
  (shr-ensure-paragraph)
  (shr-indent)
481 482 483 484 485 486 487 488 489
  (let* ((bullet
	  (if (numberp shr-list-mode)
	      (prog1
		  (format "%d " shr-list-mode)
		(setq shr-list-mode (1+ shr-list-mode)))
	    "* "))
	 (shr-indentation (+ shr-indentation (length bullet))))
    (insert bullet)
    (shr-generic cont)))
490 491

(defun shr-tag-br (cont)
492
  (unless (bobp)
493 494
    (insert "\n")
    (shr-indent))
495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514
  (shr-generic cont))

(defun shr-tag-h1 (cont)
  (shr-heading cont 'bold 'underline))

(defun shr-tag-h2 (cont)
  (shr-heading cont 'bold))

(defun shr-tag-h3 (cont)
  (shr-heading cont 'italic))

(defun shr-tag-h4 (cont)
  (shr-heading cont))

(defun shr-tag-h5 (cont)
  (shr-heading cont))

(defun shr-tag-h6 (cont)
  (shr-heading cont))

515 516
(defun shr-tag-hr (cont)
  (shr-ensure-newline)
517
  (insert (make-string shr-width shr-hr-line) "\n"))
518

519
;;; Table rendering algorithm.
520

521 522 523 524 525 526 527 528
;; Table rendering is the only complicated thing here.  We do this by
;; first counting how many TDs there are in each TR, and registering
;; how wide they think they should be ("width=45%", etc).  Then we
;; render each TD separately (this is done in temporary buffers, so
;; that we can use all the rendering machinery as if we were in the
;; main buffer).  Now we know how much space each TD really takes, so
;; we then render everything again with the new widths, and finally
;; insert all these boxes into the main buffer.
529 530 531 532
(defun shr-tag-table (cont)
  (shr-ensure-paragraph)
  (setq cont (or (cdr (assq 'tbody cont))
		 cont))
533
  (let* ((shr-inhibit-images t)
534
	 ;; Find all suggested widths.
535
	 (columns (shr-column-specs cont))
536
	 ;; Compute how many characters wide each TD should be.
537
	 (suggested-widths (shr-pro-rate-columns columns))
538 539 540
	 ;; Do a "test rendering" to see how big each TD is (this can
	 ;; be smaller (if there's little text) or bigger (if there's
	 ;; unbreakable text).
541
	 (sketch (shr-make-table cont suggested-widths))
542
	 (sketch-widths (shr-table-widths sketch suggested-widths)))
543 544 545 546 547
    ;; This probably won't work very well.
    (when (> (1+ (loop for width across sketch-widths
		       summing (1+ width)))
	     (frame-width))
      (setq truncate-lines t))
548
    ;; Then render the table again with these new "hard" widths.
549
    (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
550 551 552
  ;; Finally, insert all the images after the table.  The Emacs buffer
  ;; model isn't strong enough to allow us to put the images actually
  ;; into the tables.
553 554 555 556 557 558 559 560 561 562 563
  (dolist (elem (shr-find-elements cont 'img))
    (shr-tag-img (cdr elem))))

(defun shr-find-elements (cont type)
  (let (result)
    (dolist (elem cont)
      (cond ((eq (car elem) type)
	     (push elem result))
	    ((consp (cdr elem))
	     (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
    (nreverse result)))
564 565 566 567 568 569 570 571 572 573 574 575 576 577

(defun shr-insert-table (table widths)
  (shr-insert-table-ruler widths)
  (dolist (row table)
    (let ((start (point))
	  (height (let ((max 0))
		    (dolist (column row)
		      (setq max (max max (cadr column))))
		    max)))
      (dotimes (i height)
	(shr-indent)
	(insert "|\n"))
      (dolist (column row)
	(goto-char start)
578
	(let ((lines (nth 2 column))
579 580
	      (overlay-lines (nth 3 column))
	      overlay overlay-line)
581
	  (dolist (line lines)
582
	    (setq overlay-line (pop overlay-lines))
583 584 585 586 587 588 589 590 591
	    (end-of-line)
	    (insert line "|")
	    (dolist (overlay overlay-line)
	      (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
				     (- (point) (nth 1 overlay) 1)))
		    (properties (nth 2 overlay)))
		(while properties
		  (overlay-put o (pop properties) (pop properties)))))
	    (forward-line 1))
592 593 594 595 596 597 598 599 600 601
	  ;; Add blank lines at padding at the bottom of the TD,
	  ;; possibly.
	  (dotimes (i (- height (length lines)))
	    (end-of-line)
	    (insert (make-string (length (car lines)) ? ) "|")
	    (forward-line 1)))))
    (shr-insert-table-ruler widths)))

(defun shr-insert-table-ruler (widths)
  (shr-indent)
602
  (insert shr-table-corner)
603
  (dotimes (i (length widths))
604
    (insert (make-string (aref widths i) shr-table-line) shr-table-corner))
605 606
  (insert "\n"))

607 608 609 610
(defun shr-table-widths (table suggested-widths)
  (let* ((length (length suggested-widths))
	 (widths (make-vector length 0))
	 (natural-widths (make-vector length 0)))
611 612 613 614 615
    (dolist (row table)
      (let ((i 0))
	(dolist (column row)
	  (aset widths i (max (aref widths i)
			      (car column)))
616 617 618
	  (aset natural-widths i (max (aref natural-widths i)
				      (cadr column)))
	  (setq i (1+ i)))))
619 620
    (let ((extra (- (apply '+ (append suggested-widths nil))
		    (apply '+ (append widths nil))))
621 622 623 624 625 626 627 628 629 630 631 632 633
	  (expanded-columns 0))
      (when (> extra 0)
	(dotimes (i length)
	  ;; If the natural width is wider than the rendered width, we
	  ;; want to allow the column to expand.
	  (when (> (aref natural-widths i) (aref widths i))
	    (setq expanded-columns (1+ expanded-columns))))
	(dotimes (i length)
	  (when (> (aref natural-widths i) (aref widths i))
	    (aset widths i (min
			    (1+ (aref natural-widths i))
			    (+ (/ extra expanded-columns)
			       (aref widths i))))))))
634 635 636 637 638 639
    widths))

(defun shr-make-table (cont widths &optional fill)
  (let ((trs nil))
    (dolist (row cont)
      (when (eq (car row) 'tr)
640 641 642 643 644 645 646 647
	(let ((tds nil)
	      (columns (cdr row))
	      (i 0)
	      column)
	  (while (< i (length widths))
	    (setq column (pop columns))
	    (when (or (memq (car column) '(td th))
		      (null column))
648 649 650 651 652 653 654 655
	      (push (shr-render-td (cdr column) (aref widths i) fill)
		    tds)
	      (setq i (1+ i))))
	  (push (nreverse tds) trs))))
    (nreverse trs)))

(defun shr-render-td (cont width fill)
  (with-temp-buffer
656 657 658 659 660 661 662 663 664 665 666 667
    (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
      (if cache
	  (insert cache)
	(let ((shr-width width)
	      (shr-indentation 0))
	  (shr-generic cont))
	(delete-region
	 (point)
	 (+ (point)
	    (skip-chars-backward " \t\n")))
	(push (cons (cons width cont) (buffer-string))
	      shr-content-cache)))
668 669 670 671 672 673 674 675
    (goto-char (point-min))
    (let ((max 0))
      (while (not (eobp))
	(end-of-line)
	(setq max (max max (current-column)))
	(forward-line 1))
      (when fill
	(goto-char (point-min))
676 677 678 679 680 681 682 683 684 685
	;; If the buffer is totally empty, then put a single blank
	;; line here.
	(if (zerop (buffer-size))
	    (insert (make-string width ? ))
	  ;; Otherwise, fill the buffer.
	  (while (not (eobp))
	    (end-of-line)
	    (when (> (- width (current-column)) 0)
	      (insert (make-string (- width (current-column)) ? )))
	    (forward-line 1))))
686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705
      (if fill
	  (list max
		(count-lines (point-min) (point-max))
		(split-string (buffer-string) "\n")
		(shr-collect-overlays))
	(list max
	      (shr-natural-width))))))

(defun shr-natural-width ()
  (goto-char (point-min))
  (let ((current 0)
	(max 0))
    (while (not (eobp))
      (end-of-line)
      (setq current (+ current (current-column)))
      (unless (get-text-property (point) 'shr-break)
	(setq max (max max current)
	      current 0))
      (forward-line 1))
    max))
706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728

(defun shr-collect-overlays ()
  (save-excursion
    (goto-char (point-min))
    (let ((overlays nil))
      (while (not (eobp))
	(push (shr-overlays-in-region (point) (line-end-position))
	      overlays)
	(forward-line 1))
      (nreverse overlays))))

(defun shr-overlays-in-region (start end)
  (let (result)
    (dolist (overlay (overlays-in start end))
      (push (list (if (> start (overlay-start overlay))
		      (- end start)
		    (- end (overlay-start overlay)))
		  (if (< end (overlay-end overlay))
		      0
		    (- end (overlay-end overlay)))
		  (overlay-properties overlay))
	    result))
    (nreverse result)))
729 730 731 732 733

(defun shr-pro-rate-columns (columns)
  (let ((total-percentage 0)
	(widths (make-vector (length columns) 0)))
    (dotimes (i (length columns))
734
      (setq total-percentage (+ total-percentage (aref columns i))))
735 736 737 738
    (setq total-percentage (/ 1.0 total-percentage))
    (dotimes (i (length columns))
      (aset widths i (max (truncate (* (aref columns i)
				       total-percentage
739
				       (- shr-width (1+ (length columns)))))
740 741 742 743 744 745 746 747 748 749 750 751 752 753 754 755
			  10)))
    widths))

;; Return a summary of the number and shape of the TDs in the table.
(defun shr-column-specs (cont)
  (let ((columns (make-vector (shr-max-columns cont) 1)))
    (dolist (row cont)
      (when (eq (car row) 'tr)
	(let ((i 0))
	  (dolist (column (cdr row))
	    (when (memq (car column) '(td th))
	      (let ((width (cdr (assq :width (cdr column)))))
		(when (and width
			   (string-match "\\([0-9]+\\)%" width))
		  (aset columns i
			(/ (string-to-number (match-string 1 width))
756 757
			   100.0))))
	      (setq i (1+ i)))))))
758 759 760 761 762 763 764 765 766 767 768 769 770
    columns))

(defun shr-count (cont elem)
  (let ((i 0))
    (dolist (sub cont)
      (when (eq (car sub) elem)
	(setq i (1+ i))))
    i))

(defun shr-max-columns (cont)
  (let ((max 0))
    (dolist (row cont)
      (when (eq (car row) 'tr)
771 772
	(setq max (max max (+ (shr-count (cdr row) 'td)
			      (shr-count (cdr row) 'th))))))
773 774
    max))

775
(provide 'shr)
776 777

;;; shr.el ends here