shr.el 35.2 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32
;;; shr.el --- Simple HTML Renderer

;; Copyright (C) 2010 Free Software Foundation, Inc.

;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
;; Keywords: html

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; This package takes a HTML parse tree (as provided by
;; libxml-parse-html-region) and renders it in the current buffer.  It
;; does not do CSS, JavaScript or anything advanced: It's geared
;; towards rendering typical short snippets of HTML, like what you'd
;; find in HTML email and the like.

;;; Code:

33
(eval-when-compile (require 'cl))
34 35
(require 'browse-url)

36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55
(defgroup shr nil
  "Simple HTML Renderer"
  :group 'mail)

(defcustom shr-max-image-proportion 0.9
  "How big pictures displayed are in relation to the window they're in.
A value of 0.7 means that they are allowed to take up 70% of the
width and height of the window.  If they are larger than this,
and Emacs supports it, then the images will be rescaled down to
fit these criteria."
  :version "24.1"
  :group 'shr
  :type 'float)

(defcustom shr-blocked-images nil
  "Images that have URLs matching this regexp will be blocked."
  :version "24.1"
  :group 'shr
  :type 'regexp)

56 57 58 59 60 61 62
(defcustom shr-table-horizontal-line ?-
  "Character used to draw horizontal table lines."
  :group 'shr
  :type 'character)

(defcustom shr-table-vertical-line ?|
  "Character used to draw vertical table lines."
63
  :group 'shr
64
  :type 'character)
65 66

(defcustom shr-table-corner ?+
67
  "Character used to draw table corners."
68
  :group 'shr
69
  :type 'character)
70 71

(defcustom shr-hr-line ?-
72
  "Character used to draw hr lines."
73
  :group 'shr
74
  :type 'character)
75

76 77 78 79 80
(defcustom shr-width fill-column
  "Frame width to use for rendering."
  :type 'integer
  :group 'shr)

81 82 83 84 85
(defvar shr-content-function nil
  "If bound, this should be a function that will return the content.
This is used for cid: URLs, and the function is called with the
cid: URL as the argument.")

86 87
;;; Internal variables.

88 89 90
(defvar shr-folding-mode nil)
(defvar shr-state nil)
(defvar shr-start nil)
91
(defvar shr-indentation 0)
92
(defvar shr-inhibit-images nil)
93
(defvar shr-list-mode nil)
94
(defvar shr-content-cache nil)
95
(defvar shr-kinsoku-shorten nil)
96
(defvar shr-table-depth 0)
97

98 99 100 101 102 103 104
(defvar shr-map
  (let ((map (make-sparse-keymap)))
    (define-key map "a" 'shr-show-alt-text)
    (define-key map "i" 'shr-browse-image)
    (define-key map "I" 'shr-insert-image)
    (define-key map "u" 'shr-copy-url)
    (define-key map "v" 'shr-browse-url)
105
    (define-key map "o" 'shr-save-contents)
106 107 108
    (define-key map "\r" 'shr-browse-url)
    map))

109 110 111 112
;; Public functions and commands.

;;;###autoload
(defun shr-insert-document (dom)
113
  (setq shr-content-cache nil)
114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159
  (let ((shr-state nil)
	(shr-start nil))
    (shr-descend (shr-transform-dom dom))))

(defun shr-copy-url ()
  "Copy the URL under point to the kill ring.
If called twice, then try to fetch the URL and see whether it
redirects somewhere else."
  (interactive)
  (let ((url (get-text-property (point) 'shr-url)))
    (cond
     ((not url)
      (message "No URL under point"))
     ;; Resolve redirected URLs.
     ((equal url (car kill-ring))
      (url-retrieve
       url
       (lambda (a)
	 (when (and (consp a)
		    (eq (car a) :redirect))
	   (with-temp-buffer
	     (insert (cadr a))
	     (goto-char (point-min))
	     ;; Remove common tracking junk from the URL.
	     (when (re-search-forward ".utm_.*" nil t)
	       (replace-match "" t t))
	     (message "Copied %s" (buffer-string))
	     (copy-region-as-kill (point-min) (point-max)))))))
     ;; Copy the URL to the kill ring.
     (t
      (with-temp-buffer
	(insert url)
	(copy-region-as-kill (point-min) (point-max))
	(message "Copied %s" url))))))

(defun shr-show-alt-text ()
  "Show the ALT text of the image under point."
  (interactive)
  (let ((text (get-text-property (point) 'shr-alt)))
    (if (not text)
	(message "No image under point")
      (message "%s" text))))

(defun shr-browse-image ()
  "Browse the image under point."
  (interactive)
160
  (let ((url (get-text-property (point) 'image-url)))
161 162 163 164 165
    (if (not url)
	(message "No image under point")
      (message "Browsing %s..." url)
      (browse-url url))))

166 167 168
(defun shr-insert-image ()
  "Insert the image under point into the buffer."
  (interactive)
169
  (let ((url (get-text-property (point) 'image-url)))
170 171 172 173 174 175 176
    (if (not url)
	(message "No image under point")
      (message "Inserting %s..." url)
      (url-retrieve url 'shr-image-fetched
		    (list (current-buffer) (1- (point)) (point-marker))
		    t))))

177 178
;;; Utility functions.

179 180 181 182 183 184 185 186
(defun shr-transform-dom (dom)
  (let ((result (list (pop dom))))
    (dolist (arg (pop dom))
      (push (cons (intern (concat ":" (symbol-name (car arg))) obarray)
		  (cdr arg))
	    result))
    (dolist (sub dom)
      (if (stringp sub)
187
	  (push (cons 'text sub) result)
188 189 190 191
	(push (shr-transform-dom sub) result)))
    (nreverse result)))

(defun shr-descend (dom)
192 193 194 195 196 197
  (let ((function (intern (concat "shr-tag-" (symbol-name (car dom))) obarray))
	(style (cdr (assq :style (cdr dom))))
	(start (point)))
    (when (and style
	       (string-match "color" style))
      (setq style (shr-parse-style style)))
198 199
    (if (fboundp function)
	(funcall function (cdr dom))
200 201
      (shr-generic (cdr dom)))
    (when (consp style)
202 203 204 205
      (shr-insert-background-overlay (cdr (assq 'background-color style))
                                     start)
      (shr-insert-foreground-overlay (cdr (assq 'color style))
                                     start (point)))))
206 207 208 209

(defun shr-generic (cont)
  (dolist (sub cont)
    (cond
210
     ((eq (car sub) 'text)
211
      (shr-insert (cdr sub)))
212
     ((listp (cdr sub))
213 214
      (shr-descend sub)))))

215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234
(defmacro shr-char-breakable-p (char)
  "Return non-nil if a line can be broken before and after CHAR."
  `(aref fill-find-break-point-function-table ,char))
(defmacro shr-char-nospace-p (char)
  "Return non-nil if no space is required before and after CHAR."
  `(aref fill-nospace-between-words-table ,char))

;; KINSOKU is a Japanese word meaning a rule that should not be violated.
;; In Emacs, it is a term used for characters, e.g. punctuation marks,
;; parentheses, and so on, that should not be placed in the beginning
;; of a line or the end of a line.
(defmacro shr-char-kinsoku-bol-p (char)
  "Return non-nil if a line ought not to begin with CHAR."
  `(aref (char-category-set ,char) ?>))
(defmacro shr-char-kinsoku-eol-p (char)
  "Return non-nil if a line ought not to end with CHAR."
  `(aref (char-category-set ,char) ?<))
(unless (shr-char-kinsoku-bol-p (make-char 'japanese-jisx0208 33 35))
  (load "kinsoku" nil t))

235
(defun shr-insert (text)
236 237
  (when (and (eq shr-state 'image)
	     (not (string-match "\\`[ \t\n]+\\'" text)))
238 239 240 241 242 243
    (insert "\n")
    (setq shr-state nil))
  (cond
   ((eq shr-folding-mode 'none)
    (insert text))
   (t
244 245 246 247 248 249 250 251 252 253 254 255 256 257
    (when (and (string-match "\\`[ \t\n]" text)
	       (not (bolp))
	       (not (eq (char-after (1- (point))) ? )))
      (insert " "))
    (dolist (elem (split-string text))
      (when (and (bolp)
		 (> shr-indentation 0))
	(shr-indent))
      ;; The shr-start is a special variable that is used to pass
      ;; upwards the first point in the buffer where the text really
      ;; starts.
      (unless shr-start
	(setq shr-start (point)))
      ;; No space is needed behind a wide character categorized as
258 259
      ;; kinsoku-bol, between characters both categorized as nospace,
      ;; or at the beginning of a line.
260
      (let (prev)
261 262
	(when (and (eq (preceding-char) ? )
		   (or (= (line-beginning-position) (1- (point)))
263 264 265 266 267
		       (and (shr-char-breakable-p
			     (setq prev (char-after (- (point) 2))))
			    (shr-char-kinsoku-bol-p prev))
		       (and (shr-char-nospace-p prev)
			    (shr-char-nospace-p (aref elem 0)))))
268 269
	  (delete-char -1)))
      (insert elem)
270 271 272 273
      (let (found)
	(while (and (> (current-column) shr-width)
		    (progn
		      (setq found (shr-find-fill-point))
274
		      (not (eolp))))
275 276 277 278
	  (when (eq (preceding-char) ? )
	    (delete-char -1))
	  (insert "\n")
	  (unless found
279 280 281 282 283 284 285 286
	    (put-text-property (1- (point)) (point) 'shr-break t)
	    ;; No space is needed at the beginning of a line.
	    (when (eq (following-char) ? )
	      (delete-char 1)))
	  (when (> shr-indentation 0)
	    (shr-indent))
	  (end-of-line))
	(insert " ")))
287 288
    (unless (string-match "[ \t\n]\\'" text)
      (delete-char -1)))))
289

290
(defun shr-find-fill-point ()
291 292
  (when (> (move-to-column shr-width) shr-width)
    (backward-char 1))
293 294 295 296 297 298 299 300 301 302 303 304 305 306
  (let ((bp (point))
	failed)
    (while (not (or (setq failed (= (current-column) shr-indentation))
		    (eq (preceding-char) ? )
		    (eq (following-char) ? )
		    (shr-char-breakable-p (preceding-char))
		    (shr-char-breakable-p (following-char))
		    (and (eq (preceding-char) ?')
			 (not (memq (char-after (- (point) 2))
				    (list nil ?\n ? ))))
		    ;; There're some kinsoku CJK chars that aren't breakable.
		    (and (shr-char-kinsoku-bol-p (preceding-char))
			 (not (shr-char-kinsoku-bol-p (following-char))))
		    (shr-char-kinsoku-eol-p (following-char))))
307
      (backward-char 1))
308 309 310 311 312 313 314
    (if (and (not (or failed (eolp)))
	     (eq (preceding-char) ?'))
	(while (not (or (setq failed (eolp))
			(eq (following-char) ? )
			(shr-char-breakable-p (following-char))
			(shr-char-kinsoku-eol-p (following-char))))
	  (forward-char 1)))
315
    (if failed
316
	;; There's no breakable point, so we give it up.
317 318 319 320 321 322 323 324 325
	(let (found)
	  (goto-char bp)
	  (unless shr-kinsoku-shorten
	    (while (and (setq found (re-search-forward
				     "\\(\\c>\\)\\| \\|\\c<\\|\\c|"
				     (line-end-position) 'move))
			(eq (preceding-char) ?')))
	    (if (and found (not (match-beginning 1)))
		(goto-char (match-beginning 0)))))
326 327
      (or
       (eolp)
328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357
       ;; Don't put kinsoku-bol characters at the beginning of a line,
       ;; or kinsoku-eol characters at the end of a line.
       (cond
	(shr-kinsoku-shorten
	 (while (and (not (memq (preceding-char) (list ?\C-@ ?\n ? )))
		     (shr-char-kinsoku-eol-p (preceding-char)))
	   (backward-char 1))
	 (when (setq failed (= (current-column) shr-indentation))
	   ;; There's no breakable point that doesn't violate kinsoku,
	   ;; so we look for the second best position.
	   (while (and (progn
			 (forward-char 1)
			 (<= (current-column) shr-width))
		       (progn
			 (setq bp (point))
			 (shr-char-kinsoku-eol-p (following-char)))))
	   (goto-char bp)))
	((shr-char-kinsoku-eol-p (preceding-char))
	 (if (shr-char-kinsoku-eol-p (following-char))
	     ;; There are consecutive kinsoku-eol characters.
	     (setq failed t)
	   (let ((count 4))
	     (while
		 (progn
		   (backward-char 1)
		   (and (> (setq count (1- count)) 0)
			(not (memq (preceding-char) (list ?\C-@ ?\n ? )))
			(or (shr-char-kinsoku-eol-p (preceding-char))
			    (shr-char-kinsoku-bol-p (following-char)))))))
	   (if (setq failed (= (current-column) shr-indentation))
358
	       ;; There's no breakable point that doesn't violate kinsoku,
359 360 361 362 363 364 365 366
	       ;; so we go to the second best position.
	       (if (looking-at "\\(\\c<+\\)\\c<")
		   (goto-char (match-end 1))
		 (forward-char 1)))))
	(t
	 (if (shr-char-kinsoku-bol-p (preceding-char))
	     ;; There are consecutive kinsoku-bol characters.
	     (setq failed t)
367 368
	   (let ((count 4))
	     (while (and (>= (setq count (1- count)) 0)
369 370 371 372 373 374
			 (shr-char-kinsoku-bol-p (following-char))
			 (shr-char-breakable-p (following-char)))
	       (forward-char 1))))))
       (when (eq (following-char) ? )
	 (forward-char 1))))
    (not failed)))
375

376 377 378
(defun shr-ensure-newline ()
  (unless (zerop (current-column))
    (insert "\n")))
379 380 381

(defun shr-ensure-paragraph ()
  (unless (bobp)
382
    (if (<= (current-column) shr-indentation)
383 384 385
	(unless (save-excursion
		  (forward-line -1)
		  (looking-at " *$"))
386 387 388
	  (insert "\n"))
      (if (save-excursion
	    (beginning-of-line)
389
	    (looking-at " *$"))
390 391 392
	  (insert "\n")
	(insert "\n\n")))))

393
(defun shr-indent ()
394 395
  (when (> shr-indentation 0)
    (insert (make-string shr-indentation ? ))))
396

397
(defun shr-fontize-cont (cont &rest types)
398 399
  (let (shr-start)
    (shr-generic cont)
400 401
    (dolist (type types)
      (shr-add-font (or shr-start (point)) (point) type))))
402

403 404 405
;; Add an overlay in the region, but avoid putting the font properties
;; on blank text at the start of the line, and the newline at the end,
;; to avoid ugliness.
406
(defun shr-add-font (start end type)
407 408 409 410 411 412 413 414 415 416
  (save-excursion
    (goto-char start)
    (while (< (point) end)
      (when (bolp)
	(skip-chars-forward " "))
      (let ((overlay (make-overlay (point) (min (line-end-position) end))))
	(overlay-put overlay 'face type))
      (if (< (line-end-position) end)
	  (forward-line 1)
	(goto-char end)))))
417

418 419 420 421
(defun shr-browse-url ()
  "Browse the URL under point."
  (interactive)
  (let ((url (get-text-property (point) 'shr-url)))
422 423 424 425
    (cond
     ((not url)
      (message "No link under point"))
     ((string-match "^mailto:" url)
426
      (browse-url-mailto url))
427 428
     (t
      (browse-url url)))))
429

430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446
(defun shr-save-contents (directory)
  "Save the contents from URL in a file."
  (interactive "DSave contents of URL to directory: ")
  (let ((url (get-text-property (point) 'shr-url)))
    (if (not url)
	(message "No link under point")
      (url-retrieve (shr-encode-url url)
		    'shr-store-contents (list url directory)))))

(defun shr-store-contents (status url directory)
  (unless (plist-get status :error)
    (when (or (search-forward "\n\n" nil t)
	      (search-forward "\r\n\r\n" nil t))
      (write-region (point) (point-max)
		    (expand-file-name (file-name-nondirectory url)
				      directory)))))

447 448 449 450 451 452 453 454 455 456 457
(defun shr-image-fetched (status buffer start end)
  (when (and (buffer-name buffer)
	     (not (plist-get status :error)))
    (url-store-in-cache (current-buffer))
    (when (or (search-forward "\n\n" nil t)
	      (search-forward "\r\n\r\n" nil t))
      (let ((data (buffer-substring (point) (point-max))))
        (with-current-buffer buffer
          (let ((alt (buffer-substring start end))
		(inhibit-read-only t))
	    (delete-region start end)
458 459
	    (goto-char start)
	    (shr-put-image data alt))))))
460 461
  (kill-buffer (current-buffer)))

462
(defun shr-put-image (data alt)
463 464 465 466
  (if (display-graphic-p)
      (let ((image (ignore-errors
                     (shr-rescale-image data))))
        (when image
467 468 469 470 471
	  ;; When inserting big-ish pictures, put them at the
	  ;; beginning of the line.
	  (when (and (> (current-column) 0)
		     (> (car (image-size image t)) 400))
	    (insert "\n"))
472 473
	  (insert-image image (or alt "*"))))
    (insert alt)))
474 475 476 477 478 479

(defun shr-rescale-image (data)
  (if (or (not (fboundp 'imagemagick-types))
	  (not (get-buffer-window (current-buffer))))
      (create-image data nil t)
    (let* ((image (create-image data nil t))
480
	   (size (image-size image t))
481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501
	   (width (car size))
	   (height (cdr size))
	   (edges (window-inside-pixel-edges
		   (get-buffer-window (current-buffer))))
	   (window-width (truncate (* shr-max-image-proportion
				      (- (nth 2 edges) (nth 0 edges)))))
	   (window-height (truncate (* shr-max-image-proportion
				       (- (nth 3 edges) (nth 1 edges)))))
	   scaled-image)
      (when (> height window-height)
	(setq image (or (create-image data 'imagemagick t
				      :height window-height)
			image))
	(setq size (image-size image t)))
      (when (> (car size) window-width)
	(setq image (or
		     (create-image data 'imagemagick t
				   :width window-width)
		     image)))
      image)))

Glenn Morris's avatar
Glenn Morris committed
502 503 504
;; url-cache-extract autoloads url-cache.
(declare-function url-cache-create-filename "url-cache" (url))
(autoload 'mm-disable-multibyte "mm-util")
505
(autoload 'browse-url-mailto "browse-url")
Glenn Morris's avatar
Glenn Morris committed
506

507 508 509 510 511
(defun shr-get-image-data (url)
  "Get image data for URL.
Return a string with image data."
  (with-temp-buffer
    (mm-disable-multibyte)
512
    (when (ignore-errors
513
	    (url-cache-extract (url-cache-create-filename (shr-encode-url url)))
514 515 516 517
	    t)
      (when (or (search-forward "\n\n" nil t)
		(search-forward "\r\n\r\n" nil t))
	(buffer-substring (point) (point-max))))))
518

519 520 521 522 523 524
(defun shr-image-displayer (content-function)
  "Return a function to display an image.
CONTENT-FUNCTION is a function to retrieve an image for a cid url that
is an argument.  The function to be returned takes three arguments URL,
START, and END."
  `(lambda (url start end)
525 526 527 528 529 530 531 532 533 534 535 536 537 538
     (when url
       (if (string-match "\\`cid:" url)
	   ,(when content-function
	      `(let ((image (funcall ,content-function
				     (substring url (match-end 0)))))
		 (when image
		   (goto-char start)
		   (shr-put-image image
				  (prog1
				      (buffer-substring-no-properties start end)
				    (delete-region start end))))))
	 (url-retrieve url 'shr-image-fetched
		       (list (current-buffer) start end)
		       t)))))
539

540 541 542 543 544
(defun shr-heading (cont &rest types)
  (shr-ensure-paragraph)
  (apply #'shr-fontize-cont cont types)
  (shr-ensure-paragraph))

Glenn Morris's avatar
Glenn Morris committed
545 546
(autoload 'widget-convert-button "wid-edit")

547 548 549 550 551 552 553 554 555 556 557 558
(defun shr-urlify (start url)
  (widget-convert-button
   'url-link start (point)
   :help-echo url
   :keymap shr-map
   url)
  (put-text-property start (point) 'shr-url url))

(defun shr-encode-url (url)
  "Encode URL."
  (browse-url-url-encode-chars url "[)$ ]"))

559 560
(autoload 'shr-color-visible "shr-color")
(autoload 'shr-color->hexadecimal "shr-color")
561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585

(defun shr-color-check (fg bg)
  "Check that FG is visible on BG.
Returns (fg bg) with corrected values.
Returns nil if the colors that would be used are the default
ones, in case fg and bg are nil."
  (when (or fg bg)
    (let ((fixed (cond ((null fg) 'fg)
                       ((null bg) 'bg))))
      ;; Convert colors to hexadecimal, or set them to default.
      (let ((fg (or (shr-color->hexadecimal fg)
                    (frame-parameter nil 'foreground-color)))
            (bg (or (shr-color->hexadecimal bg)
                    (frame-parameter nil 'background-color))))
        (cond ((eq fixed 'bg)
               ;; Only return the new fg
               (list nil (cadr (shr-color-visible bg fg t))))
              ((eq fixed 'fg)
               ;; Invert args and results and return only the new bg
               (list (cadr (shr-color-visible fg bg t)) nil))
              (t
               (shr-color-visible bg fg)))))))

(defun shr-get-background (pos)
  "Return background color at POS."
586
  (dolist (overlay (overlays-in pos (1+ pos)))
587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608
    (let ((background (plist-get (overlay-get overlay 'face)
                                 :background)))
      (when background
        (return background)))))

(defun shr-insert-foreground-overlay (fg start end)
  (when fg
    (let ((bg (shr-get-background start)))
      (let ((new-colors (shr-color-check fg bg)))
        (when new-colors
          (overlay-put (make-overlay start end) 'face
                       (list :foreground (cadr new-colors))))))))

(defun shr-insert-background-overlay (bg start)
  "Insert an overlay with background color BG at START.
The overlay has rear-advance set to t, so it will be used when
text will be inserted at start."
  (when bg
    (let ((new-colors (shr-color-check nil bg)))
      (when new-colors
        (overlay-put (make-overlay start start nil nil t) 'face
                     (list :background (car new-colors)))))))
609

610 611
;;; Tag-specific rendering rules.

612 613 614 615 616 617 618 619
(defun shr-tag-body (cont)
  (let ((start (point))
        (fgcolor (cdr (assq :fgcolor cont)))
        (bgcolor (cdr (assq :bgcolor cont))))
    (shr-insert-background-overlay bgcolor start)
    (shr-generic cont)
    (shr-insert-foreground-overlay fgcolor start (point))))

620 621
(defun shr-tag-p (cont)
  (shr-ensure-paragraph)
622
  (shr-indent)
623 624 625
  (shr-generic cont)
  (shr-ensure-paragraph))

Katsumi Yamaoka's avatar
Katsumi Yamaoka committed
626 627 628 629 630 631
(defun shr-tag-div (cont)
  (shr-ensure-newline)
  (shr-indent)
  (shr-generic cont)
  (shr-ensure-newline))

632 633 634 635 636 637 638 639 640
(defun shr-tag-b (cont)
  (shr-fontize-cont cont 'bold))

(defun shr-tag-i (cont)
  (shr-fontize-cont cont 'italic))

(defun shr-tag-em (cont)
  (shr-fontize-cont cont 'bold))

641 642 643
(defun shr-tag-strong (cont)
  (shr-fontize-cont cont 'bold))

644 645 646 647 648 649
(defun shr-tag-u (cont)
  (shr-fontize-cont cont 'underline))

(defun shr-tag-s (cont)
  (shr-fontize-cont cont 'strike-through))

650 651
(defun shr-parse-style (style)
  (when style
652 653 654
    (save-match-data
      (when (string-match "\n" style)
        (setq style (replace-match " " t t style))))
655 656 657 658 659 660 661 662
    (let ((plist nil))
      (dolist (elem (split-string style ";"))
	(when elem
	  (setq elem (split-string elem ":"))
	  (when (and (car elem)
		     (cadr elem))
	    (let ((name (replace-regexp-in-string "^ +\\| +$" "" (car elem)))
		  (value (replace-regexp-in-string "^ +\\| +$" "" (cadr elem))))
663 664
	      (when (string-match " *!important\\'" value)
		(setq value (substring value 0 (match-beginning 0))))
665 666 667 668 669
	      (push (cons (intern name obarray)
			  value)
		    plist)))))
      plist)))

670 671 672 673 674
(defun shr-tag-a (cont)
  (let ((url (cdr (assq :href cont)))
	(start (point))
	shr-start)
    (shr-generic cont)
675 676 677
    (shr-urlify (or shr-start start) url)))

(defun shr-tag-object (cont)
678 679 680 681 682 683 684 685
  (let ((start (point))
	url)
    (dolist (elem cont)
      (when (eq (car elem) 'embed)
	(setq url (or url (cdr (assq :src (cdr elem))))))
      (when (and (eq (car elem) 'param)
		 (equal (cdr (assq :name (cdr elem))) "movie"))
	(setq url (or url (cdr (assq :value (cdr elem)))))))
686 687
    (when url
      (shr-insert " [multimedia] ")
688 689 690 691 692 693 694 695 696
      (shr-urlify start url))
    (shr-generic cont)))

(defun shr-tag-video (cont)
  (let ((image (cdr (assq :poster cont)))
	(url (cdr (assq :src cont)))
	(start (point)))
    (shr-tag-img nil image)
    (shr-urlify start url)))
697

698 699 700 701
(defun shr-tag-img (cont &optional url)
  (when (or url
	    (and cont
		 (cdr (assq :src cont))))
702 703 704 705
    (when (and (> (current-column) 0)
	       (not (eq shr-state 'image)))
      (insert "\n"))
    (let ((alt (cdr (assq :alt cont)))
706
	  (url (or url (cdr (assq :src cont)))))
707 708
      (let ((start (point-marker)))
	(when (zerop (length alt))
709
	  (setq alt "*"))
710
	(cond
711 712 713 714
	 ((or (member (cdr (assq :height cont)) '("0" "1"))
	      (member (cdr (assq :width cont)) '("0" "1")))
	  ;; Ignore zero-sized or single-pixel images.
	  )
715 716 717 718 719 720 721
	 ((and (not shr-inhibit-images)
	       (string-match "\\`cid:" url))
	  (let ((url (substring url (match-end 0)))
		image)
	    (if (or (not shr-content-function)
		    (not (setq image (funcall shr-content-function url))))
		(insert alt)
722
	      (shr-put-image image alt))))
723 724 725 726 727
	 ((or shr-inhibit-images
	      (and shr-blocked-images
		   (string-match shr-blocked-images url)))
	  (setq shr-start (point))
	  (let ((shr-state 'space))
728 729
	    (if (> (string-width alt) 8)
		(shr-insert (truncate-string-to-width alt 8))
730 731
	      (shr-insert alt))))
	 ((url-is-cached (shr-encode-url url))
732
	  (shr-put-image (shr-get-image-data url) alt))
733 734 735 736 737 738 739 740
	 (t
	  (insert alt)
	  (ignore-errors
	    (url-retrieve (shr-encode-url url) 'shr-image-fetched
			  (list (current-buffer) start (point-marker))
			  t))))
	(put-text-property start (point) 'keymap shr-map)
	(put-text-property start (point) 'shr-alt alt)
741 742
	(put-text-property start (point) 'image-url url)
	(put-text-property start (point) 'image-displayer
743
			   (shr-image-displayer shr-content-function))
744
	(put-text-property start (point) 'help-echo alt)
745
	(setq shr-state 'image)))))
746 747 748 749

(defun shr-tag-pre (cont)
  (let ((shr-folding-mode 'none))
    (shr-ensure-newline)
750
    (shr-indent)
751 752 753 754 755
    (shr-generic cont)
    (shr-ensure-newline)))

(defun shr-tag-blockquote (cont)
  (shr-ensure-paragraph)
756
  (shr-indent)
757 758 759
  (let ((shr-indentation (+ shr-indentation 4)))
    (shr-generic cont))
  (shr-ensure-paragraph))
760 761 762 763

(defun shr-tag-ul (cont)
  (shr-ensure-paragraph)
  (let ((shr-list-mode 'ul))
764 765
    (shr-generic cont))
  (shr-ensure-paragraph))
766 767

(defun shr-tag-ol (cont)
768
  (shr-ensure-paragraph)
769
  (let ((shr-list-mode 1))
770 771
    (shr-generic cont))
  (shr-ensure-paragraph))
772 773

(defun shr-tag-li (cont)
774 775
  (shr-ensure-paragraph)
  (shr-indent)
776 777 778 779 780 781 782 783 784
  (let* ((bullet
	  (if (numberp shr-list-mode)
	      (prog1
		  (format "%d " shr-list-mode)
		(setq shr-list-mode (1+ shr-list-mode)))
	    "* "))
	 (shr-indentation (+ shr-indentation (length bullet))))
    (insert bullet)
    (shr-generic cont)))
785 786

(defun shr-tag-br (cont)
787
  (unless (bobp)
788 789
    (insert "\n")
    (shr-indent))
790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809
  (shr-generic cont))

(defun shr-tag-h1 (cont)
  (shr-heading cont 'bold 'underline))

(defun shr-tag-h2 (cont)
  (shr-heading cont 'bold))

(defun shr-tag-h3 (cont)
  (shr-heading cont 'italic))

(defun shr-tag-h4 (cont)
  (shr-heading cont))

(defun shr-tag-h5 (cont)
  (shr-heading cont))

(defun shr-tag-h6 (cont)
  (shr-heading cont))

810 811
(defun shr-tag-hr (cont)
  (shr-ensure-newline)
812
  (insert (make-string shr-width shr-hr-line) "\n"))
813

814 815 816
(defun shr-tag-title (cont)
  (shr-heading cont 'bold 'underline))

817 818 819 820
(defun shr-tag-font (cont)
  (let ((start (point))
        (color (cdr (assq :color cont))))
    (shr-generic cont)
821
    (shr-insert-foreground-overlay color start (point))))
822

823
;;; Table rendering algorithm.
824

825 826 827 828 829 830 831 832
;; Table rendering is the only complicated thing here.  We do this by
;; first counting how many TDs there are in each TR, and registering
;; how wide they think they should be ("width=45%", etc).  Then we
;; render each TD separately (this is done in temporary buffers, so
;; that we can use all the rendering machinery as if we were in the
;; main buffer).  Now we know how much space each TD really takes, so
;; we then render everything again with the new widths, and finally
;; insert all these boxes into the main buffer.
833
(defun shr-tag-table-1 (cont)
834 835
  (setq cont (or (cdr (assq 'tbody cont))
		 cont))
836
  (let* ((shr-inhibit-images t)
837
	 (shr-table-depth (1+ shr-table-depth))
838
	 (shr-kinsoku-shorten t)
839
	 ;; Find all suggested widths.
840
	 (columns (shr-column-specs cont))
841
	 ;; Compute how many characters wide each TD should be.
842
	 (suggested-widths (shr-pro-rate-columns columns))
843 844 845
	 ;; Do a "test rendering" to see how big each TD is (this can
	 ;; be smaller (if there's little text) or bigger (if there's
	 ;; unbreakable text).
846
	 (sketch (shr-make-table cont suggested-widths))
847
	 (sketch-widths (shr-table-widths sketch suggested-widths)))
848
    ;; This probably won't work very well.
849 850 851
    (when (> (+ (loop for width across sketch-widths
		      summing (1+ width))
		shr-indentation 1)
852 853
	     (frame-width))
      (setq truncate-lines t))
854
    ;; Then render the table again with these new "hard" widths.
855
    (shr-insert-table (shr-make-table cont sketch-widths t) sketch-widths))
856 857 858
  ;; Finally, insert all the images after the table.  The Emacs buffer
  ;; model isn't strong enough to allow us to put the images actually
  ;; into the tables.
859 860 861
  (when (zerop shr-table-depth)
    (dolist (elem (shr-find-elements cont 'img))
      (shr-tag-img (cdr elem)))))
862

863 864 865 866 867 868
(defun shr-tag-table (cont)
  (shr-ensure-paragraph)
  (let* ((caption (cdr (assq 'caption cont)))
	 (header (cdr (assq 'thead cont)))
	 (body (or (cdr (assq 'tbody cont)) cont))
	 (footer (cdr (assq 'tfoot cont)))
869
         (bgcolor (cdr (assq :bgcolor cont)))
870 871 872
	 (nheader (if header (shr-max-columns header)))
	 (nbody (if body (shr-max-columns body)))
	 (nfooter (if footer (shr-max-columns footer))))
873
    (shr-insert-background-overlay bgcolor (point))
874
    (shr-tag-table-1
875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905
     (nconc
      (if caption `((tr (td ,@caption))))
      (if header
	  (if footer
	      ;; hader + body + footer
	      (if (= nheader nbody)
		  (if (= nbody nfooter)
		      `((tr (td (table (tbody ,@header ,@body ,@footer)))))
		    (nconc `((tr (td (table (tbody ,@header ,@body)))))
			   (if (= nfooter 1)
			       footer
			     `((tr (td (table (tbody ,@footer))))))))
		(nconc `((tr (td (table (tbody ,@header)))))
		       (if (= nbody nfooter)
			   `((tr (td (table (tbody ,@body ,@footer)))))
			 (nconc `((tr (td (table (tbody ,@body)))))
				(if (= nfooter 1)
				    footer
				  `((tr (td (table (tbody ,@footer))))))))))
	    ;; header + body
	    (if (= nheader nbody)
		`((tr (td (table (tbody ,@header ,@body)))))
	      (if (= nheader 1)
		  `(,@header (tr (td (table (tbody ,@body)))))
		`((tr (td (table (tbody ,@header))))
		  (tr (td (table (tbody ,@body))))))))
	(if footer
	    ;; body + footer
	    (if (= nbody nfooter)
		`((tr (td (table (tbody ,@body ,@footer)))))
	      (nconc `((tr (td (table (tbody ,@body)))))
906
		     (if (= nfooter 1)
907 908 909 910 911
			 footer
		       `((tr (td (table (tbody ,@footer))))))))
	  (if caption
	      `((tr (td (table (tbody ,@body)))))
	    body)))))))
912

913 914 915 916 917 918 919 920
(defun shr-find-elements (cont type)
  (let (result)
    (dolist (elem cont)
      (cond ((eq (car elem) type)
	     (push elem result))
	    ((consp (cdr elem))
	     (setq result (nconc (shr-find-elements (cdr elem) type) result)))))
    (nreverse result)))
921 922 923 924 925 926 927 928 929 930 931

(defun shr-insert-table (table widths)
  (shr-insert-table-ruler widths)
  (dolist (row table)
    (let ((start (point))
	  (height (let ((max 0))
		    (dolist (column row)
		      (setq max (max max (cadr column))))
		    max)))
      (dotimes (i height)
	(shr-indent)
932
	(insert shr-table-vertical-line "\n"))
933 934
      (dolist (column row)
	(goto-char start)
935
	(let ((lines (nth 2 column))
936 937
	      (overlay-lines (nth 3 column))
	      overlay overlay-line)
938
	  (dolist (line lines)
939
	    (setq overlay-line (pop overlay-lines))
940
	    (end-of-line)
941
	    (insert line shr-table-vertical-line)
942 943 944 945 946 947 948
	    (dolist (overlay overlay-line)
	      (let ((o (make-overlay (- (point) (nth 0 overlay) 1)
				     (- (point) (nth 1 overlay) 1)))
		    (properties (nth 2 overlay)))
		(while properties
		  (overlay-put o (pop properties) (pop properties)))))
	    (forward-line 1))
949 950 951 952
	  ;; Add blank lines at padding at the bottom of the TD,
	  ;; possibly.
	  (dotimes (i (- height (length lines)))
	    (end-of-line)
953 954
	    (insert (make-string (string-width (car lines)) ? )
		    shr-table-vertical-line)
955 956 957 958
	    (forward-line 1)))))
    (shr-insert-table-ruler widths)))

(defun shr-insert-table-ruler (widths)
959 960 961
  (when (and (bolp)
	     (> shr-indentation 0))
    (shr-indent))
962
  (insert shr-table-corner)
963
  (dotimes (i (length widths))
964 965
    (insert (make-string (aref widths i) shr-table-horizontal-line)
	    shr-table-corner))
966 967
  (insert "\n"))

968 969 970 971
(defun shr-table-widths (table suggested-widths)
  (let* ((length (length suggested-widths))
	 (widths (make-vector length 0))
	 (natural-widths (make-vector length 0)))
972 973 974 975 976
    (dolist (row table)
      (let ((i 0))
	(dolist (column row)
	  (aset widths i (max (aref widths i)
			      (car column)))
977 978 979
	  (aset natural-widths i (max (aref natural-widths i)
				      (cadr column)))
	  (setq i (1+ i)))))
980 981
    (let ((extra (- (apply '+ (append suggested-widths nil))
		    (apply '+ (append widths nil))))
982 983 984 985 986 987 988 989 990 991 992 993 994
	  (expanded-columns 0))
      (when (> extra 0)
	(dotimes (i length)
	  ;; If the natural width is wider than the rendered width, we
	  ;; want to allow the column to expand.
	  (when (> (aref natural-widths i) (aref widths i))
	    (setq expanded-columns (1+ expanded-columns))))
	(dotimes (i length)
	  (when (> (aref natural-widths i) (aref widths i))
	    (aset widths i (min
			    (1+ (aref natural-widths i))
			    (+ (/ extra expanded-columns)
			       (aref widths i))))))))
995 996 997 998 999 1000
    widths))

(defun shr-make-table (cont widths &optional fill)
  (let ((trs nil))
    (dolist (row cont)
      (when (eq (car row) 'tr)
1001 1002 1003 1004 1005 1006 1007 1008
	(let ((tds nil)
	      (columns (cdr row))
	      (i 0)
	      column)
	  (while (< i (length widths))
	    (setq column (pop columns))
	    (when (or (memq (car column) '(td th))
		      (null column))
1009 1010 1011 1012 1013 1014 1015
	      (push (shr-render-td (cdr column) (aref widths i) fill)
		    tds)
	      (setq i (1+ i))))
	  (push (nreverse tds) trs))))
    (nreverse trs)))

(defun shr-render-td (cont width fill)
1016 1017 1018 1019 1020 1021 1022 1023 1024 1025 1026 1027 1028 1029 1030 1031 1032 1033 1034 1035 1036 1037 1038 1039 1040 1041 1042 1043 1044 1045 1046 1047 1048 1049 1050 1051 1052 1053 1054 1055 1056 1057
  (let ((background (shr-get-background (point))))
    (with-temp-buffer
      (let ((cache (cdr (assoc (cons width cont) shr-content-cache))))
        (if cache
            (insert cache)
          (shr-insert-background-overlay (or (cdr (assq :bgcolor cont))
                                             background)
                                         (point))
          (let ((shr-width width)
                (shr-indentation 0))
            (shr-generic cont))
          (delete-region
           (point)
           (+ (point)
              (skip-chars-backward " \t\n")))
          (push (cons (cons width cont) (buffer-string))
                shr-content-cache)))
      (goto-char (point-min))
      (let ((max 0))
        (while (not (eobp))
          (end-of-line)
          (setq max (max max (current-column)))
          (forward-line 1))
        (when fill
          (goto-char (point-min))
          ;; If the buffer is totally empty, then put a single blank
          ;; line here.
          (if (zerop (buffer-size))
              (insert (make-string width ? ))
            ;; Otherwise, fill the buffer.
            (while (not (eobp))
              (end-of-line)
              (when (> (- width (current-column)) 0)
                (insert (make-string (- width (current-column)) ? )))
              (forward-line 1))))
        (if fill
            (list max
                  (count-lines (point-min) (point-max))
                  (split-string (buffer-string) "\n")
                  (shr-collect-overlays))
          (list max
                (shr-natural-width)))))))
1058 1059 1060 1061 1062 1063 1064 1065 1066 1067 1068 1069 1070

(defun shr-natural-width ()
  (goto-char (point-min))
  (let ((current 0)
	(max 0))
    (while (not (eobp))
      (end-of-line)
      (setq current (+ current (current-column)))
      (unless (get-text-property (point) 'shr-break)
	(setq max (max max current)
	      current 0))
      (forward-line 1))
    max))
1071 1072 1073 1074 1075 1076 1077 1078 1079 1080 1081 1082 1083 1084 1085 1086 1087 1088 1089 1090 1091 1092 1093

(defun shr-collect-overlays ()
  (save-excursion
    (goto-char (point-min))
    (let ((overlays nil))
      (while (not (eobp))
	(push (shr-overlays-in-region (point) (line-end-position))
	      overlays)
	(forward-line 1))
      (nreverse overlays))))

(defun shr-overlays-in-region (start end)
  (let (result)
    (dolist (overlay (overlays-in start end))
      (push (list (if (> start (overlay-start overlay))
		      (- end start)
		    (- end (overlay-start overlay)))
		  (if (< end (overlay-end overlay))
		      0
		    (- end (overlay-end overlay)))
		  (overlay-properties overlay))
	    result))
    (nreverse result)))
1094 1095 1096 1097 1098

(defun shr-pro-rate-columns (columns)
  (let ((total-percentage 0)
	(widths (make-vector (length columns) 0)))
    (dotimes (i (length columns))
1099
      (setq total-percentage (+ total-percentage (aref columns i))))
1100 1101 1102 1103
    (setq total-percentage (/ 1.0 total-percentage))
    (dotimes (i (length columns))
      (aset widths i (max (truncate (* (aref columns i)
				       total-percentage
1104
				       (- shr-width (1+ (length columns)))))
1105 1106 1107 1108 1109 1110 1111 1112 1113 1114 1115 1116 1117 1118 1119 1120
			  10)))
    widths))

;; Return a summary of the number and shape of the TDs in the table.
(defun shr-column-specs (cont)
  (let ((columns (make-vector (shr-max-columns cont) 1)))
    (dolist (row cont)
      (when (eq (car row) 'tr)
	(let ((i 0))
	  (dolist (column (cdr row))
	    (when (memq (car column) '(td th))
	      (let ((width (cdr (assq :width (cdr column)))))
		(when (and width
			   (string-match "\\([0-9]+\\)%" width))
		  (aset columns i
			(/ (string-to-number (match-string 1 width))
1121 1122
			   100.0))))
	      (setq i (1+ i)))))))
1123 1124 1125 1126 1127 1128 1129 1130 1131 1132 1133 1134 1135
    columns))

(defun shr-count (cont elem)
  (let ((i 0))
    (dolist (sub cont)
      (when (eq (car sub) elem)
	(setq i (1+ i))))
    i))

(defun shr-max-columns (cont)
  (let ((max 0))
    (dolist (row cont)
      (when (eq (car row) 'tr)
1136 1137
	(setq max (max max (+ (shr-count (cdr row) 'td)
			      (shr-count (cdr row) 'th))))))
1138 1139
    max))

1140
(provide 'shr)
1141 1142

;;; shr.el ends here