register.el 13.2 KB
Newer Older
1
;;; register.el --- register commands for Emacs
Eric S. Raymond's avatar
Eric S. Raymond committed
2

Glenn Morris's avatar
Glenn Morris committed
3
;; Copyright (C) 1985, 1993, 1994, 2001, 2002, 2003, 2004,
Glenn Morris's avatar
Glenn Morris committed
4
;;   2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
Eric S. Raymond's avatar
Eric S. Raymond committed
5

Eric S. Raymond's avatar
Eric S. Raymond committed
6
;; Maintainer: FSF
Eric S. Raymond's avatar
Eric S. Raymond committed
7
;; Keywords: internal
Eric S. Raymond's avatar
Eric S. Raymond committed
8

Richard M. Stallman's avatar
Richard M. Stallman committed
9 10
;; This file is part of GNU Emacs.

11
;; GNU Emacs is free software: you can redistribute it and/or modify
Richard M. Stallman's avatar
Richard M. Stallman committed
12
;; it under the terms of the GNU General Public License as published by
13 14
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Richard M. Stallman's avatar
Richard M. Stallman committed
15 16 17 18 19 20 21

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
Richard M. Stallman's avatar
Richard M. Stallman committed
23

24 25 26 27 28 29 30
;;; Commentary:

;; This package of functions emulates and somewhat extends the venerable
;; TECO's `register' feature, which permits you to save various useful
;; pieces of buffer state to named variables.  The entry points are
;; documented in the Emacs user's manual.

31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46
;;; Global key bindings

;;;###autoload (define-key ctl-x-r-map "\C-@" 'point-to-register)
;;;###autoload (define-key ctl-x-r-map [?\C-\ ] 'point-to-register)
;;;###autoload (define-key ctl-x-r-map " " 'point-to-register)
;;;###autoload (define-key ctl-x-r-map "j" 'jump-to-register)
;;;###autoload (define-key ctl-x-r-map "s" 'copy-to-register)
;;;###autoload (define-key ctl-x-r-map "x" 'copy-to-register)
;;;###autoload (define-key ctl-x-r-map "i" 'insert-register)
;;;###autoload (define-key ctl-x-r-map "g" 'insert-register)
;;;###autoload (define-key ctl-x-r-map "r" 'copy-rectangle-to-register)
;;;###autoload (define-key ctl-x-r-map "n" 'number-to-register)
;;;###autoload (define-key ctl-x-r-map "+" 'increment-register)
;;;###autoload (define-key ctl-x-r-map "w" 'window-configuration-to-register)
;;;###autoload (define-key ctl-x-r-map "f" 'frame-configuration-to-register)

Eric S. Raymond's avatar
Eric S. Raymond committed
47
;;; Code:
Richard M. Stallman's avatar
Richard M. Stallman committed
48 49 50

(defvar register-alist nil
  "Alist of elements (NAME . CONTENTS), one for each Emacs register.
Karl Heuer's avatar
Karl Heuer committed
51
NAME is a character (a number).  CONTENTS is a string, number, marker or list.
52
A list of strings represents a rectangle.
53 54
A list of the form (file . NAME) represents the file named NAME.
A list of the form (file-query NAME POSITION) represents position POSITION
Karl Heuer's avatar
Karl Heuer committed
55 56 57 58 59
 in the file named NAME, but query before visiting it.
A list of the form (WINDOW-CONFIGURATION POSITION)
 represents a saved window configuration plus a saved value of point.
A list of the form (FRAME-CONFIGURATION POSITION)
 represents a saved frame configuration plus a saved value of point.")
Richard M. Stallman's avatar
Richard M. Stallman committed
60

61 62 63
(defun get-register (reg)
  "Return contents of Emacs register named REG, or nil if none."
  (cdr (assq reg register-alist)))
Richard M. Stallman's avatar
Richard M. Stallman committed
64

65 66
(defun set-register (register value)
  "Set contents of Emacs register named REGISTER to VALUE.  Returns VALUE.
67
See the documentation of the variable `register-alist' for possible VALUE."
68
  (let ((aelt (assq register register-alist)))
Richard M. Stallman's avatar
Richard M. Stallman committed
69 70
    (if aelt
	(setcdr aelt value)
Stefan Monnier's avatar
Stefan Monnier committed
71
      (push (cons register value) register-alist))
Richard M. Stallman's avatar
Richard M. Stallman committed
72 73
    value))

74
(defun point-to-register (register &optional arg)
75
  "Store current location of point in register REGISTER.
Jim Blandy's avatar
Jim Blandy committed
76
With prefix argument, store current frame configuration.
77
Use \\[jump-to-register] to go to that location or restore that configuration.
Richard M. Stallman's avatar
Richard M. Stallman committed
78
Argument is a character, naming the register."
79
  (interactive "cPoint to register: \nP")
Stefan Monnier's avatar
Stefan Monnier committed
80 81
  ;; Turn the marker into a file-ref if the buffer is killed.
  (add-hook 'kill-buffer-hook 'register-swap-out nil t)
82
  (set-register register
Karl Heuer's avatar
Karl Heuer committed
83 84
		(if arg (list (current-frame-configuration) (point-marker))
		  (point-marker))))
Richard M. Stallman's avatar
Richard M. Stallman committed
85

86
(defun window-configuration-to-register (register &optional arg)
87 88 89
  "Store the window configuration of the selected frame in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Argument is a character, naming the register."
90
  (interactive "cWindow configuration to register: \nP")
91 92
  ;; current-window-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
93
  (set-register register (list (current-window-configuration) (point-marker))))
94

95
(defun frame-configuration-to-register (register &optional arg)
96 97 98
  "Store the window configuration of all frames in register REGISTER.
Use \\[jump-to-register] to restore the configuration.
Argument is a character, naming the register."
99
  (interactive "cFrame configuration to register: \nP")
100 101
  ;; current-frame-configuration does not include the value
  ;; of point in the current buffer, so record that separately.
Karl Heuer's avatar
Karl Heuer committed
102
  (set-register register (list (current-frame-configuration) (point-marker))))
103

104
(defalias 'register-to-point 'jump-to-register)
105
(defun jump-to-register (register &optional delete)
Richard M. Stallman's avatar
Richard M. Stallman committed
106
  "Move point to location stored in a register.
107 108
If the register contains a file name, find that file.
 \(To put a file name in a register, you must use `set-register'.)
109 110
If the register contains a window configuration (one frame) or a frame
configuration (all frames), restore that frame or all frames accordingly.
111
First argument is a character, naming the register.
112 113
Optional second arg non-nil (interactively, prefix argument) says to
delete any existing frames that the frame configuration doesn't mention.
114
\(Otherwise, these frames are iconified.)"
115
  (interactive "cJump to register: \nP")
116
  (let ((val (get-register register)))
117
    (cond
118 119 120 121 122 123
     ((and (consp val) (frame-configuration-p (car val)))
      (set-frame-configuration (car val) (not delete))
      (goto-char (cadr val)))
     ((and (consp val) (window-configuration-p (car val)))
      (set-window-configuration (car val))
      (goto-char (cadr val)))
124
     ((markerp val)
125 126
      (or (marker-buffer val)
	  (error "That register's buffer no longer exists"))
127 128
      (switch-to-buffer (marker-buffer val))
      (goto-char val))
129 130
     ((and (consp val) (eq (car val) 'file))
      (find-file (cdr val)))
131 132 133 134 135 136
     ((and (consp val) (eq (car val) 'file-query))
      (or (find-buffer-visiting (nth 1 val))
	  (y-or-n-p (format "Visit file %s again? " (nth 1 val)))
	  (error "Register access aborted"))
      (find-file (nth 1 val))
      (goto-char (nth 2 val)))
137 138
     (t
      (error "Register doesn't contain a buffer position or configuration")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
139

140
(defun register-swap-out ()
Stefan Monnier's avatar
Stefan Monnier committed
141
  "Turn markers into file-query references when a buffer is killed."
142
  (and buffer-file-name
Stefan Monnier's avatar
Stefan Monnier committed
143 144 145 146 147 148 149
       (dolist (elem register-alist)
	 (and (markerp (cdr elem))
	      (eq (marker-buffer (cdr elem)) (current-buffer))
	      (setcdr elem
		      (list 'file-query
			    buffer-file-name
			    (marker-position (cdr elem))))))))
150

151
(defun number-to-register (number register)
Karl Heuer's avatar
Karl Heuer committed
152 153
  "Store a number in a register.
Two args, NUMBER and REGISTER (a character, naming the register).
154 155
If NUMBER is nil, a decimal number is read from the buffer starting
at point, and point moves to the end of that number.
Karl Heuer's avatar
Karl Heuer committed
156 157
Interactively, NUMBER is the prefix arg (none means nil)."
  (interactive "P\ncNumber to register: ")
158
  (set-register register
159 160
		(if number
		    (prefix-numeric-value number)
161 162 163
		  (if (looking-at "\\s-*-?[0-9]+")
		      (progn
			(goto-char (match-end 0))
164
			(string-to-number (match-string 0)))
Karl Heuer's avatar
Karl Heuer committed
165 166
		    0))))

167
(defun increment-register (number register)
Karl Heuer's avatar
Karl Heuer committed
168
  "Add NUMBER to the contents of register REGISTER.
169
Interactively, NUMBER is the prefix arg."
Karl Heuer's avatar
Karl Heuer committed
170
  (interactive "p\ncIncrement register: ")
171
  (or (numberp (get-register register))
Karl Heuer's avatar
Karl Heuer committed
172
      (error "Register does not contain a number"))
173
  (set-register register (+ number (get-register register))))
Richard M. Stallman's avatar
Richard M. Stallman committed
174

175
(defun view-register (register)
Richard M. Stallman's avatar
Richard M. Stallman committed
176
  "Display what is contained in register named REGISTER.
177
The Lisp value REGISTER is a character."
Richard M. Stallman's avatar
Richard M. Stallman committed
178
  (interactive "cView register: ")
179
  (let ((val (get-register register)))
Richard M. Stallman's avatar
Richard M. Stallman committed
180
    (if (null val)
181
	(message "Register %s is empty" (single-key-description register))
Richard M. Stallman's avatar
Richard M. Stallman committed
182
      (with-output-to-temp-buffer "*Output*"
183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199
	(describe-register-1 register t)))))

(defun list-registers ()
  "Display a list of nonempty registers saying briefly what they contain."
  (interactive)
  (let ((list (copy-sequence register-alist)))
    (setq list (sort list (lambda (a b) (< (car a) (car b)))))
    (with-output-to-temp-buffer "*Output*"
      (dolist (elt list)
	(when (get-register (car elt))
	  (describe-register-1 (car elt))
	  (terpri))))))

(defun describe-register-1 (register &optional verbose)
  (princ "Register ")
  (princ (single-key-description register))
  (princ " contains ")
200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244
  (let ((val (get-register register)))
    (cond
     ((numberp val)
      (princ val))

     ((markerp val)
      (let ((buf (marker-buffer val)))
	(if (null buf)
	    (princ "a marker in no buffer")
	  (princ "a buffer position:\n    buffer ")
	  (princ (buffer-name buf))
	  (princ ", position ")
	  (princ (marker-position val)))))

     ((and (consp val) (window-configuration-p (car val)))
      (princ "a window configuration."))

     ((and (consp val) (frame-configuration-p (car val)))
      (princ "a frame configuration."))

     ((and (consp val) (eq (car val) 'file))
      (princ "the file ")
      (prin1 (cdr val))
      (princ "."))

     ((and (consp val) (eq (car val) 'file-query))
      (princ "a file-query reference:\n    file ")
      (prin1 (car (cdr val)))
      (princ ",\n    position ")
      (princ (car (cdr (cdr val))))
      (princ "."))

     ((consp val)
      (if verbose
	  (progn
	    (princ "the rectangle:\n")
	    (while val
	      (princ "    ")
	      (princ (car val))
	      (terpri)
	      (setq val (cdr val))))
	(princ "a rectangle starting with ")
	(princ (car val))))

     ((stringp val)
245 246 247 248
      (if (eq yank-excluded-properties t)
	  (set-text-properties 0 (length val) nil val)
	(remove-list-of-text-properties 0 (length val)
					yank-excluded-properties val))
249 250 251 252
      (if verbose
	  (progn
	    (princ "the text:\n")
	    (princ val))
253
	(cond
254 255 256 257 258 259 260 261 262 263 264
	 ;; Extract first N characters starting with first non-whitespace.
	 ((string-match (format "[^ \t\n].\\{,%d\\}"
				;; Deduct 6 for the spaces inserted below.
				(min 20 (max 0 (- (window-width) 6))))
			val)
	  (princ "text starting with\n    ")
	  (princ (match-string 0 val)))
	 ((string-match "^[ \t\n]+$" val)
	  (princ "whitespace"))
	 (t
	  (princ "the empty string")))))
265 266 267
     (t
      (princ "Garbage:\n")
      (if verbose (prin1 val))))))
Richard M. Stallman's avatar
Richard M. Stallman committed
268

269 270
(defun insert-register (register &optional arg)
  "Insert contents of register REGISTER.  (REGISTER is a character.)
Richard M. Stallman's avatar
Richard M. Stallman committed
271 272 273
Normally puts point before and mark after the inserted text.
If optional second arg is non-nil, puts mark before and point after.
Interactively, second arg is non-nil if prefix arg is supplied."
274
  (interactive "*cInsert register: \nP")
Richard M. Stallman's avatar
Richard M. Stallman committed
275
  (push-mark)
276
  (let ((val (get-register register)))
277 278 279 280
    (cond
     ((consp val)
      (insert-rectangle val))
     ((stringp val)
281
      (insert-for-yank val))
Karl Heuer's avatar
Karl Heuer committed
282
     ((numberp val)
283 284 285 286 287
      (princ val (current-buffer)))
     ((and (markerp val) (marker-position val))
      (princ (marker-position val) (current-buffer)))
     (t
      (error "Register does not contain text"))))
Richard M. Stallman's avatar
Richard M. Stallman committed
288 289
  (if (not arg) (exchange-point-and-mark)))

290 291 292
(defun copy-to-register (register start end &optional delete-flag)
  "Copy region into register REGISTER.  With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
293 294
START and END are buffer positions indicating what to copy."
  (interactive "cCopy to register: \nr\nP")
295
  (set-register register (filter-buffer-substring start end))
Richard M. Stallman's avatar
Richard M. Stallman committed
296 297
  (if delete-flag (delete-region start end)))

298 299 300 301
(defun append-to-register (register start end &optional delete-flag)
  "Append region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
302 303
START and END are buffer positions indicating what to append."
  (interactive "cAppend to register: \nr\nP")
304 305 306 307 308 309
  (let ((reg (get-register register))
        (text (filter-buffer-substring start end)))
    (set-register
     register (cond ((not reg) text)
                    ((stringp reg) (concat reg text))
                    (t (error "Register does not contain text")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
310 311
  (if delete-flag (delete-region start end)))

312 313 314 315
(defun prepend-to-register (register start end &optional delete-flag)
  "Prepend region to text in register REGISTER.
With prefix arg, delete as well.
Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
316 317
START and END are buffer positions indicating what to prepend."
  (interactive "cPrepend to register: \nr\nP")
318 319 320 321 322 323
  (let ((reg (get-register register))
        (text (filter-buffer-substring start end)))
    (set-register
     register (cond ((not reg) text)
                    ((stringp reg) (concat text reg))
                    (t (error "Register does not contain text")))))
Richard M. Stallman's avatar
Richard M. Stallman committed
324 325
  (if delete-flag (delete-region start end)))

326 327
(defun copy-rectangle-to-register (register start end &optional delete-flag)
  "Copy rectangular region into register REGISTER.
328 329 330 331
With prefix arg, delete as well.  To insert this register
in the buffer, use \\[insert-register].

Called from a program, takes four args: REGISTER, START, END and DELETE-FLAG.
Richard M. Stallman's avatar
Richard M. Stallman committed
332 333
START and END are buffer positions giving two corners of rectangle."
  (interactive "cCopy rectangle to register: \nr\nP")
334
  (set-register register
Richard M. Stallman's avatar
Richard M. Stallman committed
335 336 337
		(if delete-flag
		    (delete-extract-rectangle start end)
		  (extract-rectangle start end))))
Eric S. Raymond's avatar
Eric S. Raymond committed
338

Masatake YAMATO's avatar
Masatake YAMATO committed
339
(provide 'register)
340
;; arch-tag: ce14dd68-8265-475f-9341-5d4ec5a53035
Eric S. Raymond's avatar
Eric S. Raymond committed
341
;;; register.el ends here