configure.ac 179 KB
Newer Older
1
dnl  Autoconf script for GNU Emacs
2 3
dnl To rebuild the 'configure' script from this, execute the command
dnl	autoconf
David J. MacKenzie's avatar
David J. MacKenzie committed
4
dnl in the directory containing this script.
5
dnl If you changed any AC_DEFINES, also run autoheader.
6
dnl
Paul Eggert's avatar
Paul Eggert committed
7
dnl Copyright (C) 1994-1996, 1999-2015 Free Software Foundation, Inc.
8
dnl
9
dnl  This file is part of GNU Emacs.
10
dnl
11
dnl  GNU Emacs is free software: you can redistribute it and/or modify
12
dnl  it under the terms of the GNU General Public License as published by
13 14
dnl  the Free Software Foundation, either version 3 of the License, or
dnl  (at your option) any later version.
15
dnl
16 17 18 19
dnl  GNU Emacs is distributed in the hope that it will be useful,
dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl  GNU General Public License for more details.
20
dnl
21
dnl  You should have received a copy of the GNU General Public License
22
dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
23

24
AC_PREREQ(2.65)
Glenn Morris's avatar
Glenn Morris committed
25
dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
26
AC_INIT(GNU Emacs, 25.0.50, bug-gnu-emacs@gnu.org)
27

28 29 30 31 32 33
dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
dnl and then quoted again for a C string.  Separate options with spaces.
dnl Add some environment variables, if they were passed via the environment
dnl rather than on the command-line.
emacs_config_options=
optsep=
34 35
dnl This is the documented way to record the args passed to configure,
dnl rather than $ac_configure_args.
36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64
for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  case $opt in
    -n | --no-create | --no-recursion)
      continue ;;
    CFLAGS | CPPFLAGS | LDFLAGS)
      eval 'test "${'$opt'+set}" = set' || continue
      case " $*" in
	*" $opt="*) continue ;;
      esac
      eval opt=$opt=\$$opt ;;
  esac

  emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  case $opt in
    *[["$emacs_shell_specials"]]*)
      case $opt in
	*\'*)
	  emacs_quote_apostrophes="s/'/'\\\\''/g"
	  opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
      esac
      opt="'$opt'"
      case $opt in
	*[['"\\']]*)
	  emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
	  opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
      esac ;;
  esac
  AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  optsep=' '
65 66
done

67
AC_CONFIG_HEADERS(src/config.h:src/config.in)
68
AC_CONFIG_SRCDIR(src/lisp.h)
69
AC_CONFIG_AUX_DIR(build-aux)
70
dnl automake 1.13 and later understand this, making -I m4 unnecessary.
Glenn Morris's avatar
Glenn Morris committed
71
dnl With older versions this is a no-op.
72
AC_CONFIG_MACRO_DIR(m4)
73 74 75 76

xcsdkdir=
AC_CHECK_PROGS(XCRUN, [xcrun])
if test -n "$XCRUN"; then
77 78
  if test -z "$MAKE"; then
    dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
79
    dnl the usual MAKE variable that 'make' itself uses.
80 81 82 83
    AC_CHECK_PROG([MAKE_PROG], [make], [yes])
    if test -z "$MAKE_PROG"; then
      MAKE="$XCRUN MAKE"
      export MAKE
84
      xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
85 86
    fi
  fi
87 88
fi

89 90 91 92 93 94 95
dnl GNU Make is required, so don't test for its individual features.
am_cv_make_support_nested_variables=yes
AC_DEFUN([AC_PROG_MAKE_SET],
  [SET_MAKE=
   AC_SUBST([SET_MAKE])])

dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
96 97 98 99 100 101 102 103 104
[emacs_check_gnu_make ()
{
  emacs_makeout=`($1 --version) 2>/dev/null` &&
  case $emacs_makeout in
    'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
    'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
       ac_path_MAKE_found=:;;
  esac
}]
105 106 107
AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
  [ac_path_MAKE_found=false
   if test -n "$MAKE"; then
108
     emacs_check_gnu_make "$MAKE"
109 110 111 112 113 114
     ac_cv_path_MAKE=$MAKE
   else
     emacs_tried_make=false
     emacs_tried_gmake=false
     emacs_tried_gnumake=false
     AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
115 116 117 118 119 120 121 122 123 124
       [[emacs_check_gnu_make "$ac_path_MAKE"
	 if $ac_path_MAKE_found; then
	   # Use the fully-qualified program name only if the basename
	   # would not resolve to it.
	   if eval \$emacs_tried_$ac_prog; then
	     ac_cv_path_MAKE=$ac_path_MAKE
	   else
	     ac_cv_path_MAKE=$ac_prog
	   fi
	 fi
125 126
	 eval emacs_tried_$ac_prog=:]])
   fi])
127 128
$ac_path_MAKE_found || {
AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
129 130 131 132
If you have it installed under another name, configure with 'MAKE=...'.
For example, run '$0 MAKE=gnu-make'.]])
}
MAKE=$ac_cv_path_MAKE
133
export MAKE
134

Glenn Morris's avatar
Glenn Morris committed
135 136
dnl Fairly arbitrary, older versions might work too.
AM_INIT_AUTOMAKE(1.11)
David J. MacKenzie's avatar
David J. MacKenzie committed
137

138 139 140
dnl Canonicalize the configuration name.
AC_CANONICAL_HOST

141
case $host in
142 143
 *-mingw*)

144 145 146 147 148 149 150 151 152
  if test -z "$host_alias"; then

      # No --host argument was given to 'configure'; therefore $host
      # was set to a default value based on the build platform.  But
      # this default value may be wrong if we are building from a
      # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
      # Therefore, we'll try to get the right host platform from the
      # compiler's target.

153
      AC_MSG_CHECKING([the compiler's target])
154
      if test -z "$CC"; then
155 156 157 158
	  cc=gcc
      else
	  cc=$CC
      fi
159 160 161
      cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
      case "$cc_target" in
          *-*) host=$cc_target
162 163
	      ;;
          "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
164
Please explicitly provide --host.])
165 166
              ;;
	  *) AC_MSG_WARN([Compiler reported non-standard target.
167
Defaulting to $host.])
168 169
              ;;
      esac
170
      AC_MSG_RESULT([$host])
171 172
  fi

173 174 175 176 177 178 179 180
  . $srcdir/nt/mingw-cfg.site

  case $srcdir in
    /* | ?:*)
      # srcdir is an absolute path.  In this case, force the format
      # "/c/foo/bar", to simplify later conversions to native Windows
      # format ("c:/foo/bar").
      srcdir=`cd "${srcdir}" && pwd -W`
181 182
      # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
      eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
183 184 185 186
      ;;
  esac;;
esac

187 188 189
canonical=$host
configuration=${host_alias-${build_alias-$host}}

190 191 192 193
dnl Support for --program-prefix, --program-suffix and
dnl --program-transform-name options
AC_ARG_PROGRAM

194 195 196 197
dnl It is important that variables on the RHS not be expanded here,
dnl hence the single quotes.  This is per the GNU coding standards, see
dnl (autoconf) Installation Directory Variables
dnl See also epaths.h below.
David J. MacKenzie's avatar
David J. MacKenzie committed
198
lispdir='${datadir}/emacs/${version}/lisp'
199
standardlisppath='${lispdir}'
200
locallisppath='${datadir}/emacs/${version}/site-lisp:'\
201
'${datadir}/emacs/site-lisp'
202
lisppath='${locallisppath}:${standardlisppath}'
David J. MacKenzie's avatar
David J. MacKenzie committed
203
etcdir='${datadir}/emacs/${version}/etc'
204
archlibdir='${libexecdir}/emacs/${version}/${configuration}'
205
etcdocdir='${datadir}/emacs/${version}/etc'
206
gamedir='${localstatedir}/games/emacs'
207

208 209 210
dnl Special option to disable the most of other options.
AC_ARG_WITH(all,
[AS_HELP_STRING([--without-all],
211 212
		[omit almost all features and build
		small executable with minimal dependencies])],
213
  [with_features=$withval],
214
  [with_features=yes])
215

216 217 218 219 220 221 222 223 224 225 226 227
dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
dnl Create a new --with option that defaults to being disabled.
dnl NAME is the base name of the option.  The shell variable with_NAME
dnl   will be set to either the user's value (if the option is
dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
dnl   option is not specified).  Note that the shell variable name is
dnl   constructed as autoconf does, by replacing non-alphanumeric
dnl   characters with "_".
dnl HELP-STRING is the help text for the option.
AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
228
])dnl
229 230

dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
Michael Albinus's avatar
Michael Albinus committed
231
dnl Create a new --with option that defaults to $with_features.
232
dnl NAME is the base name of the option.  The shell variable with_NAME
233 234 235 236 237 238 239
dnl   will be set either to 'no' (for a plain --without-NAME) or to
dnl   'yes' (if the option is not specified).  Note that the shell
dnl   variable name is constructed as autoconf does, by replacing
dnl   non-alphanumeric characters with "_".
dnl HELP-STRING is the help text for the option.
AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
240
   m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
241 242
])dnl

243 244
OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
if test "$with_pop" = yes; then
Dave Love's avatar
Dave Love committed
245
   AC_DEFINE(MAIL_USE_POP)
246
fi
247
AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
248

249
OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
250
if test "$with_kerberos" != no; then
251
   AC_DEFINE(KERBEROS)
252
fi
253 254
AH_TEMPLATE(KERBEROS,
	    [Define to support Kerberos-authenticated POP mail retrieval.])dnl
255

256
OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
257 258
if test "${with_kerberos5}" != no; then
  if test "${with_kerberos}" = no; then
259 260 261
    with_kerberos=yes
    AC_DEFINE(KERBEROS)
  fi
262
  AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
263
fi
264

265
OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
Glenn Morris's avatar
Glenn Morris committed
266 267
dnl FIXME hesiod support may not be present, so it seems like an error
dnl to define, or at least use, this unconditionally.
268
if test "$with_hesiod" != no; then
269
  AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
270
fi
Pavel Janík's avatar
Pavel Janík committed
271

Glenn Morris's avatar
Glenn Morris committed
272 273 274 275 276 277 278 279 280
OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
if test "$with_mail_unlink" != no; then
   AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
fi

AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
    [string giving default POP mail host])],
    AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))

281
AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
Joakim Verona's avatar
Joakim Verona committed
282
  [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
283
default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
284
  [ case "${withval}" in
Joakim Verona's avatar
Joakim Verona committed
285
      yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
286 287
      *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
288 289 290 291 292
      ;;
    esac
    with_sound=$val
  ],
  [with_sound=$with_features])
Pavel Janík's avatar
Pavel Janík committed
293

294
dnl FIXME currently it is not the last.
David J. MacKenzie's avatar
David J. MacKenzie committed
295
dnl This should be the last --with option, because --with-x is
296
dnl added later on when we find the file name of X, and it's best to
David J. MacKenzie's avatar
David J. MacKenzie committed
297
dnl keep them together visually.
298
AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
299
 [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
David J. MacKenzie's avatar
David J. MacKenzie committed
300
[	  case "${withval}" in
Glenn Morris's avatar
Glenn Morris committed
301
	    y | ye | yes )	val=gtk ;;
David J. MacKenzie's avatar
David J. MacKenzie committed
302 303
	    n | no )		val=no  ;;
	    l | lu | luc | luci | lucid )	val=lucid ;;
304
	    a | at | ath | athe | athen | athena )	val=athena ;;
David J. MacKenzie's avatar
David J. MacKenzie committed
305
	    m | mo | mot | moti | motif )	val=motif ;;
Jan Djärv's avatar
Jan Djärv committed
306
	    g | gt | gtk  )	val=gtk ;;
307
	    gtk2  )	val=gtk2 ;;
308
	    gtk3  )	val=gtk3 ;;
David J. MacKenzie's avatar
David J. MacKenzie committed
309
	    * )
310 311 312 313
AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
'athena' and 'lucid' are synonyms.])
David J. MacKenzie's avatar
David J. MacKenzie committed
314 315 316 317
	    ;;
	  esac
	  with_x_toolkit=$val
])
318

Paul Eggert's avatar
Paul Eggert committed
319 320 321 322 323
OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
if test "$with_wide_int" = yes; then
  AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
fi

324 325
dnl _ON results in a '--without' option in the --help output, so
dnl the help text should refer to "don't compile", etc.
Paul Eggert's avatar
Paul Eggert committed
326
with_xpm_set=${with_xpm+set}
327 328 329 330 331 332
OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
Jan D's avatar
Jan D committed
333
OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing])
334
OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
335
OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
336

337
OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
Miles Bader's avatar
Miles Bader committed
338 339 340
OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])

341 342 343
OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
344
OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
345
OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
346 347

OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
348
OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
349
OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
350
OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
Karel Klíc's avatar
Karel Klíc committed
351
OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
Ted Zlatanov's avatar
Ted Zlatanov committed
352
OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
Paul Eggert's avatar
Paul Eggert committed
353
OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
354 355 356 357 358 359 360 361 362

AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 [ case "${withval}" in
    y | ye | yes )	val=yes ;;
    n | no )		val=no  ;;
    g | gf | gfi | gfil | gfile )	val=gfile ;;
    i | in | ino | inot | inoti | inotif | inotify )	val=inotify ;;
    w | w3 | w32 )	val=w32 ;;
363 364 365 366
    * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
this option's value should be 'yes', 'no', 'gfile', 'inotify' or 'w32'.
'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
otherwise for the first of 'gfile' or 'inotify' that is usable.])
367 368 369 370
    ;;
   esac
   with_file_notification=$val
 ],
371
 [with_file_notification=$with_features])
372

373 374 375 376 377
## For the times when you want to build Emacs but don't have
## a suitable makeinfo, and can live without the manuals.
dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])

378
## This might be a 'configure' arg.
379 380
AC_SUBST([ACLOCAL_PATH])

381 382 383
## Makefile.in needs the cache file name.
AC_SUBST(cache_file)

384 385
## This is an option because I do not know if all info/man support
## compressed files, nor how to test if they do so.
Joakim Verona's avatar
Joakim Verona committed
386 387 388
OPTION_DEFAULT_ON([compress-install],
  [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
make GZIP_PROG= install])
389

390
AC_ARG_WITH(gameuser,dnl
391 392 393 394 395
[AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
		[user for shared game score files.
		An argument prefixed by ':' specifies a group instead.])])
gameuser=
gamegroup=
396 397 398
# We don't test if we can actually chown/chgrp here, because configure
# may run without root privileges.  lib-src/Makefile.in will handle
# any errors due to missing user/group gracefully.
399 400
case ${with_gameuser} in
  no) ;;
401
  "" | yes) gamegroup=games ;;
402 403 404
  :*) gamegroup=`echo "${with_gameuser}" | sed -e "s/://"` ;;
  *) gameuser=${with_gameuser} ;;
esac
405

406
AC_ARG_WITH([gnustep-conf],dnl
407
[AS_HELP_STRING([--with-gnustep-conf=FILENAME],
Paul Eggert's avatar
Paul Eggert committed
408 409 410
   [name of GNUstep configuration file to use on systems where the command
    'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
    /etc/GNUstep/GNUstep.conf])])
411 412 413 414 415
test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
  GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
test "X$GNUSTEP_CONFIG_FILE" = "X" && \
     GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf

416
AC_ARG_ENABLE(ns-self-contained,
417 418 419
[AS_HELP_STRING([--disable-ns-self-contained],
                [disable self contained build under NeXTstep])],
   EN_NS_SELF_CONTAINED=$enableval,
420 421
   EN_NS_SELF_CONTAINED=yes)

Jan D's avatar
Jan D committed
422
locallisppathset=no
Lute Kamstra's avatar
Lute Kamstra committed
423
AC_ARG_ENABLE(locallisppath,
424 425 426
[AS_HELP_STRING([--enable-locallisppath=PATH],
                [directories Emacs should search for lisp files specific
		 to this site])],
Lute Kamstra's avatar
Lute Kamstra committed
427 428 429
if test "${enableval}" = "no"; then
  locallisppath=
elif test "${enableval}" != "yes"; then
Jan D's avatar
Jan D committed
430
  locallisppath=${enableval} locallisppathset=yes
Lute Kamstra's avatar
Lute Kamstra committed
431 432
fi)

433
AC_ARG_ENABLE(checking,
434 435 436 437 438
[AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
		[enable expensive run-time checks.  With LIST,
		 enable only specific categories of checks.
		 Categories are: all,yes,no.
		 Flags are: stringbytes, stringoverrun, stringfreelist,
439
		 xmallocoverrun, conslist, glyphs])],
440 441 442 443 444 445 446 447 448 449 450 451
[ac_checking_flags="${enableval}"],[])
IFS="${IFS= 	}"; ac_save_IFS="$IFS"; IFS="$IFS,"
for check in $ac_checking_flags
do
	case $check in
	# these set all the flags to specific states
	yes)		ac_enable_checking=1 ;;
	no)		ac_enable_checking= ;
			ac_gc_check_stringbytes= ;
	                ac_gc_check_string_overrun= ;
	                ac_gc_check_string_free_list= ;
	                ac_xmalloc_overrun= ;
452
	                ac_gc_check_cons_list= ;
453
			ac_glyphs_debug= ;;
454 455 456 457 458
	all)		ac_enable_checking=1 ;
			ac_gc_check_stringbytes=1 ;
	                ac_gc_check_string_overrun=1 ;
	                ac_gc_check_string_free_list=1 ;
	                ac_xmalloc_overrun=1 ;
459
	                ac_gc_check_cons_list=1 ;
460
			ac_glyphs_debug=1 ;;
461
	# these enable particular checks
462 463
	stringbytes)	ac_gc_check_stringbytes=1 ;;
	stringoverrun)	ac_gc_check_string_overrun=1 ;;
464 465 466
	stringfreelist) ac_gc_check_string_free_list=1 ;;
	xmallocoverrun)	ac_xmalloc_overrun=1 ;;
	conslist)	ac_gc_check_cons_list=1 ;;
467
	glyphs)		ac_glyphs_debug=1 ;;
468 469 470 471 472 473 474
	*)	AC_MSG_ERROR(unknown check category $check) ;;
	esac
done
IFS="$ac_save_IFS"

if test x$ac_enable_checking != x ; then
  AC_DEFINE(ENABLE_CHECKING, 1,
475
[Define to 1 if expensive run-time data type and consistency checks are enabled.])
476 477 478 479 480 481 482
fi
if test x$ac_gc_check_stringbytes != x ; then
  AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
[Define this temporarily to hunt a bug.  If defined, the size of
   strings is redundantly recorded in sdata structures so that it can
   be compared to the sizes recorded in Lisp strings.])
fi
483
if test x$ac_gc_check_string_overrun != x ; then
484 485 486 487 488 489 490 491 492 493 494 495 496 497 498
  AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
[Define this to check for short string overrun.])
fi
if test x$ac_gc_check_string_free_list != x ; then
  AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
[Define this to check the string free list.])
fi
if test x$ac_xmalloc_overrun != x ; then
  AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
[Define this to check for malloc buffer overrun.])
fi
if test x$ac_gc_check_cons_list != x ; then
  AC_DEFINE(GC_CHECK_CONS_LIST, 1,
[Define this to check for errors in cons list.])
fi
499
if test x$ac_glyphs_debug != x ; then
500 501 502
  AC_DEFINE(GLYPH_DEBUG, 1,
[Define this to enable glyphs debugging code.])
fi
503

504 505 506 507
AC_ARG_ENABLE(check-lisp-object-type,
[AS_HELP_STRING([--enable-check-lisp-object-type],
                [enable compile time checks for the Lisp_Object data type.
		This is useful for development for catching certain types of bugs.])],
508
if test "${enableval}" != "no"; then
509 510
   AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
   [Define this to enable compile time checks for the Lisp_Object data type.])
511 512 513
fi)


514 515 516 517
dnl The name of this option is unfortunate.  It predates, and has no
dnl relation to, the "sampling-based elisp profiler" added in 24.3.
dnl Actually, it stops it working.
dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
518
AC_ARG_ENABLE(profiling,
519
[AS_HELP_STRING([--enable-profiling],
520 521 522
		[build emacs with low-level, gprof profiling support.
                Mainly useful for debugging Emacs itself.  May not work on
                all platforms.  Stops profiler.el working.])],
523 524 525 526 527 528
[ac_enable_profiling="${enableval}"],[])
if test x$ac_enable_profiling != x ; then
   PROFILING_CFLAGS="-DPROFILING=1 -pg"
else
   PROFILING_CFLAGS=
fi
529
AC_SUBST(PROFILING_CFLAGS)
530

531 532 533
AC_ARG_ENABLE(autodepend,
[AS_HELP_STRING([--enable-autodepend],
		[automatically generate dependencies to .h-files.
534
		 Requires gcc, enabled if found.])],
535 536
[ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])

537 538 539 540 541
AC_ARG_ENABLE(gtk-deprecation-warnings,
[AS_HELP_STRING([--enable-gtk-deprecation-warnings],
		[Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
[ac_enable_gtk_deprecation_warnings="${enableval}"],[])

542
dnl This used to use changequote, but, apart from 'changequote is evil'
Dave Love's avatar
Dave Love committed
543 544 545
dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
dnl the great gob of text.  Thus it's not processed for possible expansion.
dnl Just make sure the brackets remain balanced.
546 547 548 549
dnl
dnl Since Emacs can't find matching pairs of quotes, boundaries are
dnl indicated by comments.
dnl quotation begins
Dave Love's avatar
Dave Love committed
550
[
David J. MacKenzie's avatar
David J. MacKenzie committed
551 552 553

### If you add support for a new configuration, add code to this
### switch statement to recognize your configuration name and select
Glenn Morris's avatar
Glenn Morris committed
554 555
### the appropriate opsys.

David J. MacKenzie's avatar
David J. MacKenzie committed
556 557 558 559 560 561
### As far as handling version numbers on operating systems is
### concerned, make sure things will fail in a fixable way.  If
### /etc/MACHINES doesn't say anything about version numbers, be
### prepared to handle anything reasonably.  If version numbers
### matter, be sure /etc/MACHINES says something about it.

Paul Eggert's avatar
Paul Eggert committed
562
opsys='' unported=no
David J. MacKenzie's avatar
David J. MacKenzie committed
563 564
case "${canonical}" in

565 566
  ## GNU/Linux and similar ports
  *-*-linux* )
567 568 569
    opsys=gnu-linux
  ;;

570
  ## FreeBSD ports
571
  *-*-freebsd* )
572 573 574
    opsys=freebsd
  ;;

575 576 577 578 579
  ## DragonFly ports
  *-*-dragonfly* )
    opsys=dragonfly
  ;;

580 581 582 583 584
  ## FreeBSD kernel + glibc based userland
  *-*-kfreebsd*gnu* )
    opsys=gnu-kfreebsd
  ;;

David J. MacKenzie's avatar
David J. MacKenzie committed
585 586 587 588 589
  ## NetBSD ports
  *-*-netbsd* )
    opsys=netbsd
  ;;

590
  ## OpenBSD ports
591
  *-*-openbsd* | *-*-mirbsd* )
592 593 594
    opsys=openbsd
  ;;

595 596 597
  ## Apple Darwin / Mac OS X
  *-apple-darwin* )
    case "${canonical}" in
598
      *-apple-darwin[0-9].*) unported=yes ;;
599
      i[3456]86-* | x86_64-* )  ;;
600 601 602
      * )            unported=yes ;;
    esac
    opsys=darwin
603 604 605 606 607 608
    ## Use fink packages if available.
    ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
##    if test -d /sw/include && test -d /sw/lib; then
##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
##    fi
609 610
  ;;

611 612 613 614 615
  ## Chromium Native Client
  *-nacl )
    opsys=nacl
  ;;

616 617 618 619 620
  ## Cygwin ports
  *-*-cygwin )
    opsys=cygwin
  ;;

621 622
  ## HP 9000 series 700 and 800, running HP/UX
  hppa*-hp-hpux10.2* )
623
    opsys=hpux10-20
624 625
  ;;
  hppa*-hp-hpux1[1-9]* )
626
    opsys=hpux11
627 628 629
    CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
  ;;

David J. MacKenzie's avatar
David J. MacKenzie committed
630
  ## IBM machines
631
  rs6000-ibm-aix4.[23]* )
Paul Eggert's avatar
Paul Eggert committed
632
    opsys=aix4-2
633
  ;;
634
  powerpc-ibm-aix4.[23]*  )
Paul Eggert's avatar
Paul Eggert committed
635
    opsys=aix4-2
636
  ;;
637
  rs6000-ibm-aix[56]* )
Paul Eggert's avatar
Paul Eggert committed
638
    opsys=aix4-2
Eli Zaretskii's avatar
Eli Zaretskii committed
639
  ;;
Paul Eggert's avatar
Paul Eggert committed
640
  powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
Paul Eggert's avatar
Paul Eggert committed
641
    opsys=aix4-2
642
  ;;
David J. MacKenzie's avatar
David J. MacKenzie committed
643 644 645

  ## Silicon Graphics machines
  ## Iris 4D
Karl Heuer's avatar
Karl Heuer committed
646
  mips-sgi-irix6.5 )
647
    opsys=irix6-5
648
    # Without defining _LANGUAGE_C, things get masked out in the headers
649
    # so that, for instance, grepping for 'free' in stdlib.h fails and
650
    # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
651
    NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
Karl Heuer's avatar
Karl Heuer committed
652
  ;;
David J. MacKenzie's avatar
David J. MacKenzie committed
653 654

  ## Suns
655
  *-sun-solaris* \
Dan Nicolaescu's avatar
Dan Nicolaescu committed
656
    | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
657
    | x86_64-*-solaris2*    | x86_64-*-sunos5*)
David J. MacKenzie's avatar
David J. MacKenzie committed
658
    case "${canonical}" in
Paul Eggert's avatar
Paul Eggert committed
659 660 661
      i[3456]86-*-* )   ;;
      amd64-*-*|x86_64-*-*) ;;
      sparc* )		;;
David J. MacKenzie's avatar
David J. MacKenzie committed
662 663 664
      * )		unported=yes ;;
    esac
    case "${canonical}" in
665 666 667 668
      *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
		opsys=sol2-10
		emacs_check_sunpro_c=yes
		;;
669 670
      *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
      ## Note that Emacs 23.1's NEWS said the following would be dropped.
671 672 673 674
      *-sunos5.6* | *-solaris2.6* )
		opsys=sol2-6
		RANLIB="ar -ts"
		;;
675
      ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
676
      *-sunos5.[7-9]* | *-solaris2.[7-9]* )
677
		opsys=sol2-6
678
		emacs_check_sunpro_c=yes
Dan Nicolaescu's avatar
Dan Nicolaescu committed
679
		;;
David J. MacKenzie's avatar
David J. MacKenzie committed
680
    esac
681 682 683 684 685 686 687 688 689 690 691
    ## Watch out for a compiler that we know will not work.
    case "${canonical}" in
     *-solaris* | *-sunos5* )
		if [ "x$CC" = x/usr/ucb/cc ]; then
		  ## /usr/ucb/cc doesn't work;
		  ## we should find some other compiler that does work.
		  unset CC
		fi
		;;
      *) ;;
    esac
David J. MacKenzie's avatar
David J. MacKenzie committed
692 693
  ;;

694
  ## Intel 386 machines where we don't care about the manufacturer.
695
  i[3456]86-*-* )
David J. MacKenzie's avatar
David J. MacKenzie committed
696
    case "${canonical}" in
697
      *-darwin* )               opsys=darwin ;;
698
      *-mingw* )
699
		opsys=mingw32
700
		# MinGW overrides and adds some system headers in nt/inc.
701
		GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
702
		;;
703 704 705
      *-sysv4.2uw* )		opsys=unixware ;;
      *-sysv5uw* )		opsys=unixware ;;
      *-sysv5OpenUNIX* )	opsys=unixware ;;
David J. MacKenzie's avatar
David J. MacKenzie committed
706 707 708 709
      ## Otherwise, we'll fall through to the generic opsys code at the bottom.
    esac
  ;;

710 711 712
  # MinGW64
  x86_64-*-* )
    case "${canonical}" in
713
      *-mingw* )
714 715 716 717 718 719 720 721
		opsys=mingw32
		# MinGW overrides and adds some system headers in nt/inc.
		GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
		;;
      ## Otherwise, we'll fall through to the generic opsys code at the bottom.
    esac
  ;;

David J. MacKenzie's avatar
David J. MacKenzie committed
722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741
  * )
    unported=yes
  ;;
esac

### If the code above didn't choose an operating system, just choose
### an operating system based on the configuration name.  You really
### only want to use this when you have no idea what the right
### operating system is; if you know what operating systems a machine
### runs, it's cleaner to make it explicit in the case statement
### above.
if test x"${opsys}" = x; then
  case "${canonical}" in
    *-gnu* )				opsys=gnu ;;
    * )
      unported=yes
    ;;
  esac
fi

Dave Love's avatar
Dave Love committed
742
]
743
dnl quotation ends
David J. MacKenzie's avatar
David J. MacKenzie committed
744 745

if test $unported = yes; then
746
  AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
Glenn Morris's avatar
Glenn Morris committed
747
If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
748
Check 'etc/MACHINES' for recognized configuration names.])
David J. MacKenzie's avatar
David J. MacKenzie committed
749 750 751
fi

#### Choose a compiler.
752

Paul Eggert's avatar
Paul Eggert committed
753 754 755
dnl Don't bother to test for C89.
AC_DEFUN([_AC_PROG_CC_C89], [$2])

756
dnl Sets GCC=yes if using gcc.
757
AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
758
if test -n "$XCRUN"; then
759
  AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
760
  test -n "$AR" && export AR
761
fi
762

Paul Eggert's avatar
Paul Eggert committed
763 764 765
dnl Emacs needs C99 or later.
gl_PROG_CC_C99

Paul Eggert's avatar
Paul Eggert committed
766 767
AM_PROG_CC_C_O

768 769 770 771
if test x$GCC = xyes; then
  test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
else
  test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
772
fi
David J. MacKenzie's avatar
David J. MacKenzie committed
773

774 775 776 777 778
dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
dnl alternative to lib/gnulib.mk, so as to avoid generating header files
dnl that clash with MinGW.
AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])

779 780
# Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
AC_DEFUN([gl_CRYPTO_CHECK])
781 782
# Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
# as we don't use them.
783
AC_DEFUN([gl_FCNTL_O_FLAGS])
784 785 786 787 788 789
# Avoid gnulib's test for pthread_sigmask.
funcs=
for func in $ac_func_list; do
  test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
done
ac_func_list=$funcs
Paul Eggert's avatar
Paul Eggert committed
790 791 792 793 794
# Use the system putenv even if it lacks GNU features, as we don't need them,
# and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
AC_CHECK_FUNCS_ONCE([putenv])
AC_DEFUN([gl_FUNC_PUTENV],
  [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
795

796
# Initialize gnulib right after choosing the compiler.
Glenn Morris's avatar
Comment  
Glenn Morris committed
797
dnl Amongst other things, this sets AR and ARFLAGS.
798
gl_EARLY
799

800
if test "$ac_test_CFLAGS" != set; then
Paul Eggert's avatar
Paul Eggert committed
801 802 803
  # It's helpful to have C macros available to GDB, so prefer -g3 to -g
  # if -g3 works and the user does not specify CFLAGS.
  # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
804 805 806 807 808 809 810 811 812 813 814 815 816 817 818
  case $CFLAGS in
    '-g')
      emacs_g3_CFLAGS='-g3';;
    '-g -O2')
      emacs_g3_CFLAGS='-g3 -O2';;
    *)
      emacs_g3_CFLAGS='';;
  esac
  if test -n "$emacs_g3_CFLAGS"; then
    emacs_save_CFLAGS=$CFLAGS
    CFLAGS=$emacs_g3_CFLAGS
    AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
      [emacs_cv_prog_cc_g3],
      [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
	 [emacs_cv_prog_cc_g3=yes],
Paul Eggert's avatar
Paul Eggert committed
819 820
	 [emacs_cv_prog_cc_g3=no])])
    if test $emacs_cv_prog_cc_g3 != yes; then
821 822
      CFLAGS=$emacs_save_CFLAGS
    fi
823 824 825
    if test $opsys = mingw32; then
      CFLAGS="$CFLAGS -gdwarf-2"
    fi
826
  fi
Paul Eggert's avatar
Paul Eggert committed
827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844

  case $CFLAGS in
    *-O*) ;;
    *)
      # No optimization flag was inferred for this non-GCC compiler.
      # Try -O.  This is needed for xlc on AIX; see Bug#14258.
      emacs_save_CFLAGS=$CFLAGS
      test -z "$CFLAGS" || CFLAGS="$CFLAGS "
      CFLAGS=${CFLAGS}-O
      AC_CACHE_CHECK([whether $CC accepts -O],
        [emacs_cv_prog_cc_o],
	[AC_LINK_IFELSE([AC_LANG_PROGRAM()],
	   [emacs_cv_prog_cc_o=yes],
	   [emacs_cv_prog_cc_o=no])])
      if test $emacs_cv_prog_cc_o != yes; then
	CFLAGS=$emacs_save_CFLAGS
      fi ;;
  esac
845 846
fi

847 848
AC_ARG_ENABLE([gcc-warnings],
  [AS_HELP_STRING([--enable-gcc-warnings],
849
                  [turn on lots of GCC warnings/errors. This is intended for
850 851
		   developers, and may generate false alarms when used
		   with older or non-GNU development tools.])],
852 853 854 855 856 857 858 859
  [case $enableval in
     yes|no) ;;
     *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
   esac
   gl_gcc_warnings=$enableval],
  [gl_gcc_warnings=no]
)

860 861 862 863 864
# clang is unduly picky about some things.
AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
  [AC_COMPILE_IFELSE(
     [AC_LANG_PROGRAM([[
	  #ifndef __clang__
Paul Eggert's avatar
Paul Eggert committed
865
	    error "not clang";
866 867 868 869
	  #endif
        ]])],
     [emacs_cv_clang=yes],
     [emacs_cv_clang=no])])
870 871 872 873 874

# When compiling with GCC, prefer -isystem to -I when including system
# include files, to avoid generating useless diagnostics for the files.
if test "$gl_gcc_warnings" != yes; then
  isystem='-I'
875 876 877 878 879 880
  if test "$emacs_cv_clang" = yes
  then
     # Turn off some warnings if supported.
     gl_WARN_ADD([-Wno-switch])
     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
     gl_WARN_ADD([-Wno-pointer-sign])
881
     gl_WARN_ADD([-Wno-string-plus-int])
Paul Eggert's avatar
Paul Eggert committed
882
     gl_WARN_ADD([-Wno-unknown-attributes])
883
  fi
884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902
else
  isystem='-isystem '

  # This, $nw, is the list of warnings we disable.
  nw=

  case $with_x_toolkit in
    lucid | athena | motif)
       # Old toolkits mishandle 'const'.
       nw="$nw -Wwrite-strings"
       ;;
    *)
       gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
       ;;
  esac
  AC_SUBST([WERROR_CFLAGS])

  nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
  nw="$nw -Woverlength-strings"     # Not a problem these days
903
  nw="$nw -Wformat-nonliteral"      # we do this a lot
Paul Eggert's avatar
Paul Eggert committed
904
  nw="$nw -Wvla"                    # Emacs uses <vla.h>.
905
  nw="$nw -Wswitch-default"         # Too many warnings for now
906
  nw="$nw -Winline"                 # OK to ignore 'inline'
907
  nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
908 909
  nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
                                    # signed overflow has undefined behavior
910 911
  nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
  nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
912
  nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
913 914 915 916 917

  # Emacs doesn't care about shadowing; see
  # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
  nw="$nw -Wshadow"

918 919 920
  # Emacs's use of alloca inhibits protecting the stack.
  nw="$nw -Wstack-protector"

921 922 923 924
  # Emacs's use of partly-const functions such as Fgnutls_available_p
  # make this option problematic.
  nw="$nw -Wsuggest-attribute=const"

Paul Eggert's avatar
Paul Eggert committed
925 926
  # Emacs's use of partly-pure functions such as CHECK_TYPE make this
  # option problematic.
927 928
  nw="$nw -Wsuggest-attribute=pure"

Joakim Verona's avatar
Joakim Verona committed
929 930 931 932 933 934 935
  # This part is merely for shortening the command line,
  # since -Wno-FOO needs to be added below regardless.
  nw="$nw -Wmissing-field-initializers"
  nw="$nw -Wswitch"
  nw="$nw -Wtype-limits"
  nw="$nw -Wunused-parameter"

936 937 938 939
  if test $emacs_cv_clang = yes; then
    nw="$nw -Wcast-align"
  fi

940 941 942 943 944
  gl_MANYWARN_ALL_GCC([ws])
  gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
  for w in $ws; do
    gl_WARN_ADD([$w])
  done
Paul Eggert's avatar
Paul Eggert committed
945
  gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
946 947 948 949 950 951
  gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
  gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
  gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
  gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
  gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
  gl_WARN_ADD([-Wno-format-nonliteral])
952

953 954 955 956 957 958 959 960
  # More things that clang is unduly picky about.
  if test $emacs_cv_clang = yes; then
    gl_WARN_ADD([-Wno-format-extra-args])
    gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
    gl_WARN_ADD([-Wno-unused-command-line-argument])
    gl_WARN_ADD([-Wno-unused-value])
  fi

961
  AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
962 963
  AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
  AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
964 965
  [/* Enable compile-time and run-time bounds-checking, and some warnings,
      without upsetting glibc 2.15+. */
966 967
   #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
        && defined __OPTIMIZE__ && __OPTIMIZE__)
968 969 970
   # define _FORTIFY_SOURCE 2
   #endif
  ])
971

972 973 974 975
  # We use a slightly smaller set of warning options for lib/.
  # Remove the following and save the result in GNULIB_WARN_CFLAGS.
  nw=
  nw="$nw -Wunused-macros"
David J. MacKenzie's avatar
David J. MacKenzie committed
976

977 978
  gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
  AC_SUBST([GNULIB_WARN_CFLAGS])
979
fi
980

981 982 983 984 985 986
edit_cflags="
  s,///*,/,g
  s/^/ /
  s/ -I/ $isystem/g
  s/^ //
"
987

988 989 990
AC_ARG_ENABLE(link-time-optimization,
[AS_HELP_STRING([--enable-link-time-optimization],
                [build emacs with link-time optimization.
991 992 993 994 995
		 This requires GCC 4.5.0 or later, or clang.
		 (Note that clang support is experimental - see INSTALL.)
		 It also makes Emacs harder to debug, and when we tried it
		 with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
		 recommended for typical use.])],
996 997 998 999 1000 1001 1002 1003 1004 1005 1006 1007 1008 1009 1010 1011 1012 1013 1014