frame.el 62.8 KB
Newer Older
1
;;; frame.el --- multi-frame management independent of window systems
Eric S. Raymond's avatar
Eric S. Raymond committed
2

3
;; Copyright (C) 1993-1994, 1996-1997, 2000-2011
Glenn Morris's avatar
Glenn Morris committed
4
;;   Free Software Foundation, Inc.
Eric S. Raymond's avatar
Eric S. Raymond committed
5

Eric S. Raymond's avatar
Eric S. Raymond committed
6
;; Maintainer: FSF
Eric S. Raymond's avatar
Eric S. Raymond committed
7
;; Keywords: internal
8
;; Package: emacs
Eric S. Raymond's avatar
Eric S. Raymond committed
9

Erik Naggum's avatar
Erik Naggum committed
10 11
;; This file is part of GNU Emacs.

12
;; GNU Emacs is free software: you can redistribute it and/or modify
Erik Naggum's avatar
Erik Naggum committed
13
;; it under the terms of the GNU General Public License as published by
14 15
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Erik Naggum's avatar
Erik Naggum committed
16 17 18 19 20 21 22

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
23
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
Jim Blandy's avatar
Jim Blandy committed
24

25 26
;;; Commentary:

Eric S. Raymond's avatar
Eric S. Raymond committed
27
;;; Code:
28
(eval-when-compile (require 'cl))
Eric S. Raymond's avatar
Eric S. Raymond committed
29

30 31 32 33
(defvar frame-creation-function-alist
  (list (cons nil
	      (if (fboundp 'tty-create-frame-with-faces)
		  'tty-create-frame-with-faces
34
                (lambda (_parameters)
35
                  (error "Can't create multiple frames without a window system")))))
36 37 38 39
  "Alist of window-system dependent functions to call to create a new frame.
The window system startup file should add its frame creation
function to this list, which should take an alist of parameters
as its argument.")
40

41 42
(defvar window-system-default-frame-alist nil
  "Alist of window-system dependent default frame parameters.
43 44
Parameters specified here supersede the values given in
`default-frame-alist'.")
45

46 47 48
;; The initial value given here used to ask for a minibuffer.
;; But that's not necessary, because the default is to have one.
;; By not specifying it here, we let an X resource specify it.
Chong Yidong's avatar
Chong Yidong committed
49
(defcustom initial-frame-alist nil
50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68
  "Alist of parameters for the initial X window frame.
You can set this in your init file; for example,

 (setq initial-frame-alist
       '((top . 1) (left . 1) (width . 80) (height . 55)))

Parameters specified here supersede the values given in
`default-frame-alist'.

If the value calls for a frame without a minibuffer, and you have
not created a minibuffer frame on your own, a minibuffer frame is
created according to `minibuffer-frame-alist'.

You can specify geometry-related options for just the initial
frame by setting this variable in your init file; however, they
won't take effect until Emacs reads your init file, which happens
after creating the initial frame.  If you want the initial frame
to have the proper geometry as soon as it appears, you need to
use this three-step process:
69 70 71 72
* Specify X resources to give the geometry you want.
* Set `default-frame-alist' to override these options so that they
  don't affect subsequent frames.
* Set `initial-frame-alist' in a way that matches the X resources,
73 74 75 76 77
  to override what you put in `default-frame-alist'."
  :type '(repeat (cons :format "%v"
		       (symbol :tag "Parameter")
		       (sexp :tag "Value")))
  :group 'frames)
Jim Blandy's avatar
Jim Blandy committed
78

79
(defcustom minibuffer-frame-alist '((width . 80) (height . 2))
80 81 82 83 84 85
  "Alist of parameters for the initial minibuffer frame.
This is the minibuffer frame created if `initial-frame-alist'
calls for a frame without a minibuffer.  The parameters specified
here supersede those given in `default-frame-alist', for the
initial minibuffer frame.

86 87
You can set this in your init file; for example,

Jim Blandy's avatar
Jim Blandy committed
88
 (setq minibuffer-frame-alist
89 90
       '((top . 1) (left . 1) (width . 80) (height . 2)))

91 92
It is not necessary to include (minibuffer . only); that is
appended when the minibuffer frame is created."
93 94 95 96
  :type '(repeat (cons :format "%v"
		       (symbol :tag "Parameter")
		       (sexp :tag "Value")))
  :group 'frames)
Jim Blandy's avatar
Jim Blandy committed
97

98
(defun handle-delete-frame (event)
99
  "Handle delete-frame events from the X server."
100 101 102 103 104 105 106 107 108 109 110
  (interactive "e")
  (let ((frame (posn-window (event-start event)))
	(i 0)
	(tail (frame-list)))
    (while tail
      (and (frame-visible-p (car tail))
	   (not (eq (car tail) frame))
	  (setq i (1+ i)))
      (setq tail (cdr tail)))
    (if (> i 0)
	(delete-frame frame t)
111 112
      ;; Gildea@x.org says it is ok to ask questions before terminating.
      (save-buffers-kill-emacs))))
Jim Blandy's avatar
Jim Blandy committed
113

Jim Blandy's avatar
Jim Blandy committed
114
;;;; Arrangement of frames at startup
Jim Blandy's avatar
Jim Blandy committed
115

116 117 118 119 120 121 122 123
;; 1) Load the window system startup file from the lisp library and read the
;; high-priority arguments (-q and the like).  The window system startup
;; file should create any frames specified in the window system defaults.
;;
;; 2) If no frames have been opened, we open an initial text frame.
;;
;; 3) Once the init file is done, we apply any newly set parameters
;; in initial-frame-alist to the frame.
Jim Blandy's avatar
Jim Blandy committed
124

Karl Heuer's avatar
Karl Heuer committed
125
;; These are now called explicitly at the proper times,
126 127 128 129
;; since that is easier to understand.
;; Actually using hooks within Emacs is bad for future maintenance. --rms.
;; (add-hook 'before-init-hook 'frame-initialize)
;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
Jim Blandy's avatar
Jim Blandy committed
130

131
;; If we create the initial frame, this is it.
Jim Blandy's avatar
Jim Blandy committed
132
(defvar frame-initial-frame nil)
Jim Blandy's avatar
Jim Blandy committed
133

134 135 136
;; Record the parameters used in frame-initialize to make the initial frame.
(defvar frame-initial-frame-alist)

137 138
(defvar frame-initial-geometry-arguments nil)

139 140 141
;; startup.el calls this function before loading the user's init
;; file - if there is no frame with a minibuffer open now, create
;; one to display messages while loading the init file.
Jim Blandy's avatar
Jim Blandy committed
142
(defun frame-initialize ()
Eli Zaretskii's avatar
Eli Zaretskii committed
143
  "Create an initial frame if necessary."
Jim Blandy's avatar
Jim Blandy committed
144
  ;; Are we actually running under a window system at all?
145 146 147
  (if (and initial-window-system
	   (not noninteractive)
	   (not (eq initial-window-system 'pc)))
148 149 150 151 152 153
      (progn
	;; If there is no frame with a minibuffer besides the terminal
	;; frame, then we need to create the opening frame.  Make sure
	;; it has a minibuffer, but let initial-frame-alist omit the
	;; minibuffer spec.
	(or (delq terminal-frame (minibuffer-frame-list))
154
	    (progn
155
	      (setq frame-initial-frame-alist
156
		    (append initial-frame-alist default-frame-alist nil))
157 158 159 160
	      (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
		  (setq frame-initial-frame-alist
			(cons '(horizontal-scroll-bars . t)
			      frame-initial-frame-alist)))
161 162 163
	      (setq frame-initial-frame-alist
		    (cons (cons 'window-system initial-window-system)
			  frame-initial-frame-alist))
164 165
	      (setq default-minibuffer-frame
		    (setq frame-initial-frame
166
			  (make-frame frame-initial-frame-alist)))
167 168 169 170
	      ;; Delete any specifications for window geometry parameters
	      ;; so that we won't reapply them in frame-notice-user-settings.
	      ;; It would be wrong to reapply them then,
	      ;; because that would override explicit user resizing.
171
	      (setq initial-frame-alist
172
		    (frame-remove-geometry-params initial-frame-alist))))
173 174 175
	;; Copy the environment of the Emacs process into the new frame.
	(set-frame-parameter frame-initial-frame 'environment
			     (frame-parameter terminal-frame 'environment))
Karl Heuer's avatar
Karl Heuer committed
176
	;; At this point, we know that we have a frame open, so we
Jim Blandy's avatar
Jim Blandy committed
177 178
	;; can delete the terminal frame.
	(delete-frame terminal-frame)
179
	(setq terminal-frame nil))))
Karl Heuer's avatar
Karl Heuer committed
180

181 182 183
(defvar frame-notice-user-settings t
  "Non-nil means function `frame-notice-user-settings' wasn't run yet.")

184 185
(declare-function tool-bar-mode "tool-bar" (&optional arg))

186 187 188
;; startup.el calls this function after loading the user's init
;; file.  Now default-frame-alist and initial-frame-alist contain
;; information to which we must react; do what needs to be done.
Jim Blandy's avatar
Jim Blandy committed
189
(defun frame-notice-user-settings ()
190
  "Act on user's init file settings of frame parameters.
191 192 193
React to settings of `initial-frame-alist',
`window-system-default-frame-alist' and `default-frame-alist'
there (in decreasing order of priority)."
194 195 196 197 198
  ;; Creating and deleting frames may shift the selected frame around,
  ;; and thus the current buffer.  Protect against that.  We don't
  ;; want to use save-excursion here, because that may also try to set
  ;; the buffer of the selected window, which fails when the selected
  ;; window is the minibuffer.
199
  (let ((old-buffer (current-buffer))
Stefan Monnier's avatar
Stefan Monnier committed
200 201 202
	(window-system-frame-alist
         (cdr (assq initial-window-system
                    window-system-default-frame-alist))))
203

204 205
    (when (and frame-notice-user-settings
	       (null frame-initial-frame))
206 207
      ;; This case happens when we don't have a window system, and
      ;; also for MS-DOS frames.
208
      (let ((parms (frame-parameters)))
209 210 211 212
	;; Don't change the frame names.
	(setq parms (delq (assq 'name parms) parms))
	;; Can't modify the minibuffer parameter, so don't try.
	(setq parms (delq (assq 'minibuffer parms) parms))
213 214 215 216 217 218 219 220
	(modify-frame-parameters
	 nil
	 (if initial-window-system
	     parms
	   ;; initial-frame-alist and default-frame-alist were already
	   ;; applied in pc-win.el.
	   (append initial-frame-alist window-system-frame-alist
		   default-frame-alist parms nil)))
221
	(if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
222 223 224 225 226 227 228 229 230 231 232
	    (let ((newparms (frame-parameters))
		  (frame (selected-frame)))
	      (tty-handle-reverse-video frame newparms)
	      ;; If we changed the background color, we need to update
	      ;; the background-mode parameter, and maybe some faces,
	      ;; too.
	      (when (assq 'background-color newparms)
		(unless (or (assq 'background-mode initial-frame-alist)
			    (assq 'background-mode default-frame-alist))
		  (frame-set-background-mode frame))
		(face-set-after-frame-default frame))))))
233

234 235
    ;; If the initial frame is still around, apply initial-frame-alist
    ;; and default-frame-alist to it.
236 237 238 239 240
    (when (frame-live-p frame-initial-frame)

      ;; When tool-bar has been switched off, correct the frame size
      ;; by the lines added in x-create-frame for the tool-bar and
      ;; switch `tool-bar-mode' off.
241 242
      (when (display-graphic-p)
	(let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
243
				  (assq 'tool-bar-lines window-system-frame-alist)
244
				  (assq 'tool-bar-lines default-frame-alist))))
245 246 247 248
	  (when (and tool-bar-originally-present
                     (or (null tool-bar-lines)
                         (null (cdr tool-bar-lines))
                         (eq 0 (cdr tool-bar-lines))))
249
	    (let* ((char-height (frame-char-height frame-initial-frame))
250
		   (image-height tool-bar-images-pixel-height)
251 252 253 254 255 256 257 258 259 260 261
		   (margin (cond ((and (consp tool-bar-button-margin)
				       (integerp (cdr tool-bar-button-margin))
				       (> tool-bar-button-margin 0))
				  (cdr tool-bar-button-margin))
				 ((and (integerp tool-bar-button-margin)
				       (> tool-bar-button-margin 0))
				  tool-bar-button-margin)
				 (t 0)))
		   (relief (if (and (integerp tool-bar-button-relief)
				    (> tool-bar-button-relief 0))
			       tool-bar-button-relief 3))
Sam Steingold's avatar
Sam Steingold committed
262
		   (lines (/ (+ image-height
263 264 265 266 267 268
				(* 2 margin)
				(* 2 relief)
				(1- char-height))
			     char-height))
		   (height (frame-parameter frame-initial-frame 'height))
		   (newparms (list (cons 'height (- height lines))))
Sam Steingold's avatar
Sam Steingold committed
269
		   (initial-top (cdr (assq 'top
270 271 272
					   frame-initial-geometry-arguments)))
		   (top (frame-parameter frame-initial-frame 'top)))
	      (when (and (consp initial-top) (eq '- (car initial-top)))
273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288
		(let ((adjusted-top
		       (cond ((and (consp top)
				   (eq '+ (car top)))
			      (list '+
				    (+ (cadr top)
				       (* lines char-height))))
			     ((and (consp top)
				   (eq '- (car top)))
			      (list '-
				    (- (cadr top)
				       (* lines char-height))))
			     (t (+ top (* lines char-height))))))
		  (setq newparms
			(append newparms
				`((top . ,adjusted-top))
				nil))))
289 290
	      (modify-frame-parameters frame-initial-frame newparms)
	      (tool-bar-mode -1)))))
291 292 293 294 295 296 297 298 299 300 301 302

      ;; The initial frame we create above always has a minibuffer.
      ;; If the user wants to remove it, or make it a minibuffer-only
      ;; frame, then we'll have to delete the current frame and make a
      ;; new one; you can't remove or add a root window to/from an
      ;; existing frame.
      ;;
      ;; NOTE: default-frame-alist was nil when we created the
      ;; existing frame.  We need to explicitly include
      ;; default-frame-alist in the parameters of the screen we
      ;; create here, so that its new value, gleaned from the user's
      ;; .emacs file, will be applied to the existing screen.
303
      (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
304
			    (assq 'minibuffer window-system-frame-alist)
305 306 307 308 309 310 311 312 313 314 315 316 317
			    (assq 'minibuffer default-frame-alist)
			    '(minibuffer . t)))
		   t))
	  ;; Create the new frame.
	  (let (parms new)
	    ;; If the frame isn't visible yet, wait till it is.
	    ;; If the user has to position the window,
	    ;; Emacs doesn't know its real position until
	    ;; the frame is seen to be visible.
	    (while (not (cdr (assq 'visibility
				   (frame-parameters frame-initial-frame))))
	      (sleep-for 1))
	    (setq parms (frame-parameters frame-initial-frame))
318

Sam Steingold's avatar
Sam Steingold committed
319
            ;; Get rid of `name' unless it was specified explicitly before.
320 321
	    (or (assq 'name frame-initial-frame-alist)
		(setq parms (delq (assq 'name parms) parms)))
322 323 324
	    ;; An explicit parent-id is a request to XEmbed the frame.
	    (or (assq 'parent-id frame-initial-frame-alist)
                (setq parms (delq (assq 'parent-id parms) parms)))
325 326

	    (setq parms (append initial-frame-alist
327
				window-system-frame-alist
328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362
				default-frame-alist
				parms
				nil))

	    ;; Get rid of `reverse', because that was handled
	    ;; when we first made the frame.
	    (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))

	    (if (assq 'height frame-initial-geometry-arguments)
		(setq parms (assq-delete-all 'height parms)))
	    (if (assq 'width frame-initial-geometry-arguments)
		(setq parms (assq-delete-all 'width parms)))
	    (if (assq 'left frame-initial-geometry-arguments)
		(setq parms (assq-delete-all 'left parms)))
	    (if (assq 'top frame-initial-geometry-arguments)
		(setq parms (assq-delete-all 'top parms)))
	    (setq new
		  (make-frame
		   ;; Use the geometry args that created the existing
		   ;; frame, rather than the parms we get for it.
		   (append frame-initial-geometry-arguments
			   '((user-size . t) (user-position . t))
			   parms)))
	    ;; The initial frame, which we are about to delete, may be
	    ;; the only frame with a minibuffer.  If it is, create a
	    ;; new one.
	    (or (delq frame-initial-frame (minibuffer-frame-list))
		(make-initial-minibuffer-frame nil))

	    ;; If the initial frame is serving as a surrogate
	    ;; minibuffer frame for any frames, we need to wean them
	    ;; onto a new frame.  The default-minibuffer-frame
	    ;; variable must be handled similarly.
	    (let ((users-of-initial
		   (filtered-frame-list
363 364 365 366 367 368
                    (lambda (frame)
                      (and (not (eq frame frame-initial-frame))
                           (eq (window-frame
                                (minibuffer-window frame))
                               frame-initial-frame))))))
              (if (or users-of-initial
369 370 371 372 373 374 375
		      (eq default-minibuffer-frame frame-initial-frame))

		  ;; Choose an appropriate frame.  Prefer frames which
		  ;; are only minibuffers.
		  (let* ((new-surrogate
			  (car
			   (or (filtered-frame-list
376 377 378 379
                                (lambda (frame)
                                  (eq (cdr (assq 'minibuffer
                                                 (frame-parameters frame)))
                                      'only)))
380 381 382 383 384 385 386 387
			       (minibuffer-frame-list))))
			 (new-minibuffer (minibuffer-window new-surrogate)))

		    (if (eq default-minibuffer-frame frame-initial-frame)
			(setq default-minibuffer-frame new-surrogate))

		    ;; Wean the frames using frame-initial-frame as
		    ;; their minibuffer frame.
388 389 390 391 392
		    (dolist (frame users-of-initial)
                      (modify-frame-parameters
                       frame (list (cons 'minibuffer new-minibuffer)))))))

            ;; Redirect events enqueued at this frame to the new frame.
393 394 395 396 397
	    ;; Is this a good idea?
	    (redirect-frame-focus frame-initial-frame new)

	    ;; Finally, get rid of the old frame.
	    (delete-frame frame-initial-frame t))
398 399 400 401 402

	;; Otherwise, we don't need all that rigamarole; just apply
	;; the new parameters.
	(let (newparms allparms tail)
	  (setq allparms (append initial-frame-alist
403
				 window-system-frame-alist
404 405 406 407 408 409 410 411 412 413 414 415
				 default-frame-alist nil))
	  (if (assq 'height frame-initial-geometry-arguments)
	      (setq allparms (assq-delete-all 'height allparms)))
	  (if (assq 'width frame-initial-geometry-arguments)
	      (setq allparms (assq-delete-all 'width allparms)))
	  (if (assq 'left frame-initial-geometry-arguments)
	      (setq allparms (assq-delete-all 'left allparms)))
	  (if (assq 'top frame-initial-geometry-arguments)
	      (setq allparms (assq-delete-all 'top allparms)))
	  (setq tail allparms)
	  ;; Find just the parms that have changed since we first
	  ;; made this frame.  Those are the ones actually set by
Sam Steingold's avatar
Sam Steingold committed
416
          ;; the init file.  For those parms whose values we already knew
417 418
	  ;; (such as those spec'd by command line options)
	  ;; it is undesirable to specify the parm again
Sam Steingold's avatar
Sam Steingold committed
419
          ;; once the user has seen the frame and been able to alter it
420
	  ;; manually.
421 422 423 424
	  (let (newval oldval)
	    (dolist (entry tail)
	      (setq oldval (assq (car entry) frame-initial-frame-alist))
	      (setq newval (cdr (assq (car entry) allparms)))
425 426
	      (or (and oldval (eq (cdr oldval) newval))
		  (setq newparms
427
			(cons (cons (car entry) newval) newparms)))))
428
	  (setq newparms (nreverse newparms))
429 430 431 432 433 434 435 436 437 438 439 440 441 442

	  (let ((new-bg (assq 'background-color newparms)))
	    ;; If the `background-color' parameter is changed, apply
	    ;; it first, then make sure that the `background-mode'
	    ;; parameter and other faces are updated, before applying
	    ;; the other parameters.
	    (when new-bg
	      (modify-frame-parameters frame-initial-frame
				       (list new-bg))
	      (unless (assq 'background-mode newparms)
		(frame-set-background-mode frame-initial-frame))
	      (face-set-after-frame-default frame-initial-frame)
	      (setq newparms (delq new-bg newparms)))
	    (modify-frame-parameters frame-initial-frame newparms)))))
Jim Blandy's avatar
Jim Blandy committed
443

444 445 446 447
    ;; Restore the original buffer.
    (set-buffer old-buffer)

    ;; Make sure the initial frame can be GC'd if it is ever deleted.
448
    ;; Make sure frame-notice-user-settings does nothing if called twice.
449
    (setq frame-notice-user-settings nil)
450
    (setq frame-initial-frame nil)))
Jim Blandy's avatar
Jim Blandy committed
451

452 453 454 455 456 457
(defun make-initial-minibuffer-frame (display)
  (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
    (if display
	(make-frame-on-display display parms)
      (make-frame parms))))

458
;;;; Creation of additional frames, and other frame miscellanea
Jim Blandy's avatar
Jim Blandy committed
459

460
(defun modify-all-frames-parameters (alist)
461
  "Modify all current and future frames' parameters according to ALIST.
462
This changes `default-frame-alist' and possibly `initial-frame-alist'.
463 464
Furthermore, this function removes all parameters in ALIST from
`window-system-default-frame-alist'.
465
See help of `modify-frame-parameters' for more information."
466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481
  (dolist (frame (frame-list))
    (modify-frame-parameters frame alist))

  (dolist (pair alist) ;; conses to add/replace
    ;; initial-frame-alist needs setting only when
    ;; frame-notice-user-settings is true.
    (and frame-notice-user-settings
	 (setq initial-frame-alist
	       (assq-delete-all (car pair) initial-frame-alist)))
    (setq default-frame-alist
	  (assq-delete-all (car pair) default-frame-alist))
    ;; Remove any similar settings from the window-system specific
    ;; parameters---they would override default-frame-alist.
    (dolist (w window-system-default-frame-alist)
      (setcdr w (assq-delete-all (car pair) (cdr w)))))

482 483 484 485
  (and frame-notice-user-settings
       (setq initial-frame-alist (append initial-frame-alist alist)))
  (setq default-frame-alist (append default-frame-alist alist)))

Jim Blandy's avatar
Jim Blandy committed
486
(defun get-other-frame ()
487 488 489
  "Return some frame other than the current frame.
Create one if necessary.  Note that the minibuffer frame, if separate,
is not considered (see `next-frame')."
Jim Blandy's avatar
Jim Blandy committed
490
  (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
491
	       (make-frame)
Jim Blandy's avatar
Jim Blandy committed
492
	     (next-frame (selected-frame)))))
Jim Blandy's avatar
Jim Blandy committed
493 494
    s))

Jim Blandy's avatar
Jim Blandy committed
495 496
(defun next-multiframe-window ()
  "Select the next window, regardless of which frame it is on."
Jim Blandy's avatar
Jim Blandy committed
497 498 499
  (interactive)
  (select-window (next-window (selected-window)
			      (> (minibuffer-depth) 0)
500
			      0))
501
  (select-frame-set-input-focus (selected-frame)))
Jim Blandy's avatar
Jim Blandy committed
502

Jim Blandy's avatar
Jim Blandy committed
503 504
(defun previous-multiframe-window ()
  "Select the previous window, regardless of which frame it is on."
Jim Blandy's avatar
Jim Blandy committed
505 506 507
  (interactive)
  (select-window (previous-window (selected-window)
				  (> (minibuffer-depth) 0)
508
				  0))
509
  (select-frame-set-input-focus (selected-frame)))
Jim Blandy's avatar
Jim Blandy committed
510

511
(declare-function x-initialize-window-system "term/x-win" ())
512
(declare-function ns-initialize-window-system "term/ns-win" ())
513
(defvar x-display-name)                 ; term/x-win
514

515
(defun make-frame-on-display (display &optional parameters)
516 517
  "Make a frame on display DISPLAY.
The optional argument PARAMETERS specifies additional frame parameters."
518
  (interactive "sMake frame on display: ")
519 520 521 522 523 524 525 526 527 528
  (cond ((featurep 'ns)
	 (when (and (boundp 'ns-initialized) (not ns-initialized))
	   (setq x-display-name display)
	   (ns-initialize-window-system))
	 (make-frame `((window-system . ns)
		       (display . ,display) . ,parameters)))
	((eq system-type 'windows-nt)
	 ;; On Windows, ignore DISPLAY.
	 (make-frame parameters))
	(t
529
	 (unless (string-match-p "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
530 531 532 533 534 535
	   (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
	 (when (and (boundp 'x-initialized) (not x-initialized))
	   (setq x-display-name display)
	   (x-initialize-window-system))
	 (make-frame `((window-system . x)
		       (display . ,display) . ,parameters)))))
536

537 538
(declare-function x-close-connection "xfns.c" (terminal))

539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568
(defun close-display-connection (display)
  "Close the connection to a display, deleting all its associated frames.
For DISPLAY, specify either a frame or a display name (a string).
If DISPLAY is nil, that stands for the selected frame's display."
  (interactive
   (list
    (let* ((default (frame-parameter nil 'display))
           (display (completing-read
                     (format "Close display (default %s): " default)
                     (delete-dups
                      (mapcar (lambda (frame)
                                (frame-parameter frame 'display))
                              (frame-list)))
                     nil t nil nil
                     default)))
      (if (zerop (length display)) default display))))
  (let ((frames (delq nil
                      (mapcar (lambda (frame)
                                (if (equal display
                                           (frame-parameter frame 'display))
                                    frame))
                              (frame-list)))))
    (if (and (consp frames)
             (not (y-or-n-p (if (cdr frames)
                                (format "Delete %s frames? " (length frames))
                              (format "Delete %s ? " (car frames))))))
        (error "Abort!")
      (mapc 'delete-frame frames)
      (x-close-connection display))))

569
(defun make-frame-command ()
570 571 572
  "Make a new frame, on the same terminal as the selected frame.
If the terminal is a text-only terminal, this also selects the
new frame."
573
  (interactive)
574
  (if (display-graphic-p)
575 576 577
      (make-frame)
    (select-frame (make-frame))))

578 579 580 581 582 583 584
(defvar before-make-frame-hook nil
  "Functions to run before a frame is created.")

(defvar after-make-frame-functions nil
  "Functions to run after a frame is created.
The functions are run with one arg, the newly created frame.")

585
(defvar after-setting-font-hook nil
586 587
  "Functions to run after a frame's font has been changed.")

588
;; Alias, kept temporarily.
589
(define-obsolete-function-alias 'new-frame 'make-frame "22.1")
Jim Blandy's avatar
Jim Blandy committed
590

591
(defvar frame-inherited-parameters '()
592 593 594
  ;; FIXME: Shouldn't we add `font' here as well?
  "Parameters `make-frame' copies from the `selected-frame' to the new frame.")

595 596
(defun make-frame (&optional parameters)
  "Return a newly created frame displaying the current buffer.
597 598 599
Optional argument PARAMETERS is an alist of frame parameters for
the new frame.  Each element of PARAMETERS should have the
form (NAME . VALUE), for example:
Richard M. Stallman's avatar
Richard M. Stallman committed
600

601
 (name . STRING)	The frame should be named STRING.
Jim Blandy's avatar
Jim Blandy committed
602

603 604
 (width . NUMBER)	The frame should be NUMBER characters in width.
 (height . NUMBER)	The frame should be NUMBER text lines high.
Jim Blandy's avatar
Jim Blandy committed
605

606 607
You cannot specify either `width' or `height', you must specify
neither or both.
Jim Blandy's avatar
Jim Blandy committed
608

609 610 611 612
 (minibuffer . t)	The frame should have a minibuffer.
 (minibuffer . nil)	The frame should have no minibuffer.
 (minibuffer . only)	The frame should contain only a minibuffer.
 (minibuffer . WINDOW)	The frame should use WINDOW as its minibuffer window.
Jim Blandy's avatar
Jim Blandy committed
613

614 615 616
 (window-system . nil)	The frame should be displayed on a terminal device.
 (window-system . x)	The frame should be displayed in an X window.

617
 (terminal . TERMINAL)  The frame should use the terminal object TERMINAL.
618

619 620
In addition, any parameter specified in `default-frame-alist',
but not present in PARAMETERS, is applied.
Luc Teirlinck's avatar
Luc Teirlinck committed
621

622 623 624 625 626 627 628 629
Before creating the frame (via `frame-creation-function-alist'),
this function runs the hook `before-make-frame-hook'.  After
creating the frame, it runs the hook `after-make-frame-functions'
with one arg, the newly created frame.

On graphical displays, this function does not itself make the new
frame the selected frame.  However, the window system may select
the new frame according to its own rules."
Jim Blandy's avatar
Jim Blandy committed
630
  (interactive)
631
  (let* ((w (cond
632 633
	     ((assq 'terminal parameters)
	      (let ((type (terminal-live-p (cdr (assq 'terminal parameters)))))
634 635
		(cond
		 ((eq type t) nil)
Stefan Monnier's avatar
Stefan Monnier committed
636 637
		 ((eq type nil) (error "Terminal %s does not exist"
                                       (cdr (assq 'terminal parameters))))
638 639 640 641
		 (t type))))
	     ((assq 'window-system parameters)
	      (cdr (assq 'window-system parameters)))
	     (t window-system)))
642
	 (frame-creation-function (cdr (assq w frame-creation-function-alist)))
643
	 (oldframe (selected-frame))
644
	 (params parameters)
645 646 647
	 frame)
    (unless frame-creation-function
      (error "Don't know how to create a frame on window system %s" w))
648 649
    ;; Add parameters from `window-system-default-frame-alist'.
    (dolist (p (cdr (assq w window-system-default-frame-alist)))
650
      (unless (assq (car p) params)
651 652 653
	(push p params)))
    ;; Add parameters from `default-frame-alist'.
    (dolist (p default-frame-alist)
654
      (unless (assq (car p) params)
655 656
	(push p params)))
    ;; Now make the frame.
657
    (run-hooks 'before-make-frame-hook)
658
    (setq frame (funcall frame-creation-function params))
659
    (normal-erase-is-backspace-setup-frame frame)
660 661 662 663 664
    ;; Inherit the original frame's parameters.
    (dolist (param frame-inherited-parameters)
      (unless (assq param parameters)   ;Overridden by explicit parameters.
        (let ((val (frame-parameter oldframe param)))
          (when val (set-frame-parameter frame param val)))))
665 666
    (run-hook-with-args 'after-make-frame-functions frame)
    frame))
Jim Blandy's avatar
Jim Blandy committed
667

668 669
(defun filtered-frame-list (predicate)
  "Return a list of all live frames which satisfy PREDICATE."
670 671
  (let* ((frames (frame-list))
	 (list frames))
672
    (while (consp frames)
673 674
      (unless (funcall predicate (car frames))
	(setcar frames nil))
675
      (setq frames (cdr frames)))
676
    (delq nil list)))
677 678 679 680

(defun minibuffer-frame-list ()
  "Return a list of all frames with their own minibuffers."
  (filtered-frame-list
681 682
   (lambda (frame)
     (eq frame (window-frame (minibuffer-window frame))))))
683

684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707
;; Used to be called `terminal-id' in termdev.el.
(defun get-device-terminal (device)
  "Return the terminal corresponding to DEVICE.
DEVICE can be a terminal, a frame, nil (meaning the selected frame's terminal),
the name of an X display device (HOST.SERVER.SCREEN) or a tty device file."
  (cond
   ((or (null device) (framep device))
    (frame-terminal device))
   ((stringp device)
    (let ((f (car (filtered-frame-list
                   (lambda (frame)
                     (or (equal (frame-parameter frame 'display) device)
                         (equal (frame-parameter frame 'tty) device)))))))
      (or f (error "Display %s does not exist" device))
      (frame-terminal f)))
   ((terminal-live-p device) device)
   (t
    (error "Invalid argument %s in `get-device-terminal'" device))))

(defun frames-on-display-list (&optional device)
  "Return a list of all frames on DEVICE.

DEVICE should be a terminal, a frame,
or a name of an X display or tty (a string of the form
708
HOST:SERVER.SCREEN).
709

710
If DEVICE is omitted or nil, it defaults to the selected
711
frame's terminal device."
712
  (let* ((terminal (get-device-terminal device))
713
	 (func #'(lambda (frame)
714
		   (eq (frame-terminal frame) terminal))))
715 716
    (filtered-frame-list func)))

717 718 719 720 721 722
(defun framep-on-display (&optional terminal)
  "Return the type of frames on TERMINAL.
TERMINAL may be a terminal id, a display name or a frame.  If it
is a frame, its type is returned.  If TERMINAL is omitted or nil,
it defaults to the selected frame's terminal device.  All frames
on a given display are of the same type."
723
  (or (terminal-live-p terminal)
724 725
      (framep terminal)
      (framep (car (frames-on-display-list terminal)))))
726

727 728 729
(defun frame-remove-geometry-params (param-list)
  "Return the parameter list PARAM-LIST, but with geometry specs removed.
This deletes all bindings in PARAM-LIST for `top', `left', `width',
730
`height', `user-size' and `user-position' parameters.
731 732 733 734 735 736
Emacs uses this to avoid overriding explicit moves and resizings from
the user during startup."
  (setq param-list (cons nil param-list))
  (let ((tail param-list))
    (while (consp (cdr tail))
      (if (and (consp (car (cdr tail)))
737 738 739 740 741 742
	       (memq (car (car (cdr tail)))
		     '(height width top left user-position user-size)))
	  (progn
	    (setq frame-initial-geometry-arguments
		  (cons (car (cdr tail)) frame-initial-geometry-arguments))
	    (setcdr tail (cdr (cdr tail))))
743
	(setq tail (cdr tail)))))
744 745
  (setq frame-initial-geometry-arguments
	(nreverse frame-initial-geometry-arguments))
746 747
  (cdr param-list))

748 749
(declare-function x-focus-frame "xfns.c" (frame))

750
(defun select-frame-set-input-focus (frame &optional norecord)
751
  "Select FRAME, raise it, and set input focus, if possible.
752
If `mouse-autoselect-window' is non-nil, also move mouse pointer
753
to FRAME's selected window.  Otherwise, if `focus-follows-mouse'
754 755 756 757 758
is non-nil, move mouse cursor to FRAME.

Optional argument NORECORD means to neither change the order of
recently selected windows nor the buffer list."
  (select-frame frame norecord)
759
  (raise-frame frame)
760
  ;; Ensure, if possible, that FRAME gets input focus.
761 762
  (when (memq (window-system frame) '(x w32 ns))
    (x-focus-frame frame))
763 764 765 766 767 768 769 770 771 772 773
  ;; Move mouse cursor if necessary.
  (cond
   (mouse-autoselect-window
    (let ((edges (window-inside-edges (frame-selected-window frame))))
      ;; Move mouse cursor into FRAME's selected window to avoid that
      ;; Emacs mouse-autoselects another window.
      (set-mouse-position frame (nth 2 edges) (nth 1 edges))))
   (focus-follows-mouse
    ;; Move mouse cursor into FRAME to avoid that another frame gets
    ;; selected by the window manager.
    (set-mouse-position frame (1- (frame-width frame)) 0))))
774

775
(defun other-frame (arg)
Juanma Barranquero's avatar
Juanma Barranquero committed
776
  "Select the ARGth different visible frame on current display, and raise it.
777 778
All frames are arranged in a cyclic order.
This command selects the frame ARG steps away in that order.
Richard M. Stallman's avatar
Richard M. Stallman committed
779 780 781 782 783 784 785
A negative ARG moves in the opposite order.

To make this command work properly, you must tell Emacs
how the system (or the window manager) generally handles
focus-switching between windows.  If moving the mouse onto a window
selects it (gives it focus), set `focus-follows-mouse' to t.
Otherwise, that variable should be nil."
786 787 788
  (interactive "p")
  (let ((frame (selected-frame)))
    (while (> arg 0)
789 790 791 792
      (setq frame (next-frame frame))
      (while (not (eq (frame-visible-p frame) t))
	(setq frame (next-frame frame)))
      (setq arg (1- arg)))
793
    (while (< arg 0)
794 795 796
      (setq frame (previous-frame frame))
      (while (not (eq (frame-visible-p frame) t))
	(setq frame (previous-frame frame)))
797
      (setq arg (1+ arg)))
798
    (select-frame-set-input-focus frame)))
799

800 801 802 803 804 805 806
(defun iconify-or-deiconify-frame ()
  "Iconify the selected frame, or deiconify if it's currently an icon."
  (interactive)
  (if (eq (cdr (assq 'visibility (frame-parameters))) t)
      (iconify-frame)
    (make-frame-visible)))

807 808
(defun suspend-frame ()
  "Do whatever is right to suspend the current frame.
809 810
Calls `suspend-emacs' if invoked from the controlling tty device,
`suspend-tty' from a secondary tty device, and
811 812 813 814
`iconify-or-deiconify-frame' from an X frame."
  (interactive)
  (let ((type (framep (selected-frame))))
    (cond
815
     ((memq type '(x ns w32)) (iconify-or-deiconify-frame))
816
     ((eq type t)
817
      (if (controlling-tty-p)
818 819
	  (suspend-emacs)
	(suspend-tty)))
820 821
     (t (suspend-emacs)))))

822
(defun make-frame-names-alist ()
823
  ;; Only consider the frames on the same display.
824 825 826 827
  (let* ((current-frame (selected-frame))
	 (falist
	  (cons
	   (cons (frame-parameter current-frame 'name) current-frame) nil))
828
	 (frame (next-frame nil 0)))
829 830
    (while (not (eq frame current-frame))
      (progn
831 832
	(push (cons (frame-parameter frame 'name) frame) falist)
	(setq frame (next-frame frame 0))))
833 834 835 836
    falist))

(defvar frame-name-history nil)
(defun select-frame-by-name (name)
837
  "Select the frame on the current terminal whose name is NAME and raise it.
838 839
If there is no frame by that name, signal an error."
  (interactive
840 841 842 843 844
   (let* ((frame-names-alist (make-frame-names-alist))
	   (default (car (car frame-names-alist)))
	   (input (completing-read
		   (format "Select Frame (default %s): " default)
		   frame-names-alist nil t nil 'frame-name-history)))
845 846 847
     (if (= (length input) 0)
	 (list default)
       (list input))))
848 849
  (let* ((frame-names-alist (make-frame-names-alist))
	 (frame (cdr (assoc name frame-names-alist))))
850 851 852
    (if frame
	(select-frame-set-input-focus frame)
      (error "There is no frame named `%s'" name))))
853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962


;;;; Background mode.

(defcustom frame-background-mode nil
  "The brightness of the background.
Set this to the symbol `dark' if your background color is dark,
`light' if your background is light, or nil (automatic by default)
if you want Emacs to examine the brightness for you.  Don't set this
variable with `setq'; this won't have the expected effect."
  :group 'faces
  :set #'(lambda (var value)
	   (set-default var value)
	   (mapc 'frame-set-background-mode (frame-list)))
  :initialize 'custom-initialize-changed
  :type '(choice (const dark)
		 (const light)
		 (const :tag "automatic" nil)))

(declare-function x-get-resource "frame.c"
		  (attribute class &optional component subclass))

(defvar inhibit-frame-set-background-mode nil)

(defun frame-set-background-mode (frame &optional keep-face-specs)
  "Set up display-dependent faces on FRAME.
Display-dependent faces are those which have different definitions
according to the `background-mode' and `display-type' frame parameters.

If optional arg KEEP-FACE-SPECS is non-nil, don't recalculate
face specs for the new background mode."
  (unless inhibit-frame-set-background-mode
    (let* ((frame-default-bg-mode (frame-terminal-default-bg-mode frame))
	   (bg-color (frame-parameter frame 'background-color))
	   (tty-type (tty-type frame))
	   (default-bg-mode
	     (if (or (window-system frame)
		     (and tty-type
			  (string-match "^\\(xterm\\|\\rxvt\\|dtterm\\|eterm\\)"
					tty-type)))
		 'light
	       'dark))
	   (non-default-bg-mode (if (eq default-bg-mode 'light) 'dark 'light))
	   (bg-mode
	    (cond (frame-default-bg-mode)
		  ((equal bg-color "unspecified-fg") ; inverted colors
		   non-default-bg-mode)
		  ((not (color-values bg-color frame))
		   default-bg-mode)
		  ((>= (apply '+ (color-values bg-color frame))
		       ;; Just looking at the screen, colors whose
		       ;; values add up to .6 of the white total
		       ;; still look dark to me.
		       (* (apply '+ (color-values "white" frame)) .6))
		   'light)
		  (t 'dark)))
	   (display-type
	    (cond ((null (window-system frame))
		   (if (tty-display-color-p frame) 'color 'mono))
		  ((display-color-p frame)
		   'color)
		  ((x-display-grayscale-p frame)
		   'grayscale)
		  (t 'mono)))
	   (old-bg-mode
	    (frame-parameter frame 'background-mode))
	   (old-display-type
	    (frame-parameter frame 'display-type)))

      (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
	(let ((locally-modified-faces nil)
	      ;; Prevent face-spec-recalc from calling this function
	      ;; again, resulting in a loop (bug#911).
	      (inhibit-frame-set-background-mode t)
	      (params (list (cons 'background-mode bg-mode)
			    (cons 'display-type display-type))))
	  (if keep-face-specs
	      (modify-frame-parameters frame params)
	    ;; If we are recomputing face specs, first collect a list
	    ;; of faces that don't match their face-specs.  These are
	    ;; the faces modified on FRAME, and we avoid changing them
	    ;; below.  Use a negative list to avoid consing (we assume
	    ;; most faces are unmodified).
	    (dolist (face (face-list))
	      (and (not (get face 'face-override-spec))
		   (not (face-spec-match-p face
					   (face-user-default-spec face)
					   (selected-frame)))
		   (push face locally-modified-faces)))
	    ;; Now change to the new frame parameters
	    (modify-frame-parameters frame params)
	    ;; For all unmodified named faces, choose face specs
	    ;; matching the new frame parameters.
	    (dolist (face (face-list))
	      (unless (memq face locally-modified-faces)
		(face-spec-recalc face frame)))))))))

(defun frame-terminal-default-bg-mode (frame)
  "Return the default background mode of FRAME.
This checks the `frame-background-mode' variable, the X resource
named \"backgroundMode\" (if FRAME is an X frame), and finally
the `background-mode' terminal parameter."
  (or frame-background-mode
      (let ((bg-resource
	     (and (window-system frame)
		  (x-get-resource "backgroundMode" "BackgroundMode"))))
	(if bg-resource
	    (intern (downcase bg-resource))))
      (terminal-parameter frame 'background-mode)))

Jim Blandy's avatar
Jim Blandy committed
963

Jim Blandy's avatar
Jim Blandy committed
964 965 966 967
;;;; Frame configurations

(defun current-frame-configuration ()
  "Return a list describing the positions and states of all frames.
968 969 970 971 972 973 974
Its car is `frame-configuration'.
Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
where
  FRAME is a frame object,
  ALIST is an association list specifying some of FRAME's parameters, and
  WINDOW-CONFIG is a window configuration object for FRAME."
  (cons 'frame-configuration
975 976 977 978
	(mapcar (lambda (frame)
                  (list frame
                        (frame-parameters frame)
                        (current-window-configuration frame)))
979
		(frame-list))))
Jim Blandy's avatar
Jim Blandy committed
980

981
(defun set-frame-configuration (configuration &optional nodelete)
Jim Blandy's avatar
Jim Blandy committed
982 983
  "Restore the frames to the state described by CONFIGURATION.
Each frame listed in CONFIGURATION has its position, size, window
984
configuration, and other parameters set as specified in CONFIGURATION.
985 986
However, this function does not restore deleted frames.

987 988
Ordinarily, this function deletes all existing frames not
listed in CONFIGURATION.  But if optional second argument NODELETE
989
is given and non-nil, the unwanted frames are iconified instead."
990 991 992 993 994
  (or (frame-configuration-p configuration)
      (signal 'wrong-type-argument
	      (list 'frame-configuration-p configuration)))
  (let ((config-alist (cdr configuration))
	frames-to-delete)
995 996 997 998 999 1000 1001 1002 1003
    (dolist (frame (frame-list))
      (let ((parameters (assq frame config-alist)))
        (if parameters
            (progn
              (modify-frame-parameters
               frame
               ;; Since we can't set a frame's minibuffer status,
               ;; we might as well omit the parameter altogether.
               (let* ((parms (nth 1 parameters))
Miles Bader's avatar
Miles Bader committed
1004 1005 1006 1007 1008 1009 1010 1011 1012
		      (mini (assq 'minibuffer parms))
		      (name (assq 'name parms))
		      (explicit-name (cdr (assq 'explicit-name parms))))
		 (when mini (setq parms (delq mini parms)))
		 ;; Leave name in iff it was set explicitly.
		 ;; This should fix the behavior reported in
		 ;; http://lists.gnu.org/archive/html/emacs-devel/2007-08/msg01632.html
		 (when (and name (not explicit-name))
		   (setq parms (delq name parms)))
1013 1014 1015 1016 1017 1018 1019 1020 1021 1022 1023
                 parms))
              (set-window-configuration (nth 2 parameters)))
          (setq frames-to-delete (cons frame frames-to-delete)))))
    (mapc (if nodelete
              ;; Note: making frames invisible here was tried
              ;; but led to some strange behavior--each time the frame
              ;; was made visible again, the window manager asked afresh
              ;; for where to put it.
              'iconify-frame
            'delete-frame)
          frames-to-delete)))
Jim Blandy's avatar
Jim Blandy committed
1024

Jim Blandy's avatar
Jim Blandy committed
1025 1026
;;;; Convenience functions for accessing and interactively changing
;;;; frame parameters.
Jim Blandy's avatar
Jim Blandy committed
1027

Jim Blandy's avatar
Jim Blandy committed
1028
(defun frame-height (&optional frame)
Jim Blandy's avatar
Jim Blandy committed
1029
  "Return number of lines available for display on FRAME.
Glenn Morris's avatar
Glenn Morris committed
1030 1031 1032 1033 1034 1035 1036 1037 1038 1039
If FRAME is omitted, describe the currently selected frame.
Exactly what is included in the return value depends on the
window-system and toolkit in use - see `frame-pixel-height' for
more details.  The lines are in units of the default font height.

The result is roughly related to the frame pixel height via
height in pixels = height in lines * `frame-char-height'.
However, this is only approximate, and is complicated e.g. by the
fact that individual window lines and menu bar lines can have
differing font heights."
Jim Blandy's avatar
Jim Blandy committed
1040
  (cdr (assq 'height (frame-parameters frame))))
Jim Blandy's avatar
Jim Blandy committed
1041 1042 1043 1044

(defun frame-width (&optional frame)
  "Return number of columns available for display on FRAME.
If FRAME is omitted, describe the currently selected frame."
Jim Blandy's avatar