files.el 204 KB
Newer Older
Eric S. Raymond's avatar
Eric S. Raymond committed
1 2
;;; files.el --- file input and output commands for Emacs

3 4 5
;; Copyright (C) 1985, 1986, 1987, 1992, 1993, 1994, 1995, 1996,
;;   1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
;;   2006 Free Software Foundation, Inc.
Roland McGrath's avatar
Roland McGrath committed
6

Eric S. Raymond's avatar
Eric S. Raymond committed
7 8
;; Maintainer: FSF

Roland McGrath's avatar
Roland McGrath committed
9 10 11 12
;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
Eric S. Raymond's avatar
Eric S. Raymond committed
13
;; the Free Software Foundation; either version 2, or (at your option)
Roland McGrath's avatar
Roland McGrath committed
14 15 16 17 18 19 20 21
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22
;; along with GNU Emacs; see the file COPYING.  If not, write to the
Lute Kamstra's avatar
Lute Kamstra committed
23 24
;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.
Roland McGrath's avatar
Roland McGrath committed
25

26 27 28 29 30 31
;;; Commentary:

;; Defines most of Emacs's file- and directory-handling functions,
;; including basic file visiting, backup generation, link handling,
;; ITS-id version control, load- and write-hook handling, and the like.

Eric S. Raymond's avatar
Eric S. Raymond committed
32 33
;;; Code:

34 35 36
(defvar font-lock-keywords)


37 38
(defgroup backup nil
  "Backups of edited data files."
39
  :group 'files)
Roland McGrath's avatar
Roland McGrath committed
40

41
(defgroup find-file nil
42 43
  "Finding files."
  :group 'files)
44 45 46


(defcustom delete-auto-save-files t
47 48
  "*Non-nil means delete auto-save file when a buffer is saved or killed.

Dave Love's avatar
Dave Love committed
49
Note that the auto-save file will not be deleted if the buffer is killed
50
when it has unsaved changes."
51 52 53 54
  :type 'boolean
  :group 'auto-save)

(defcustom directory-abbrev-alist
Roland McGrath's avatar
Roland McGrath committed
55 56 57 58 59 60 61
  nil
  "*Alist of abbreviations for file directories.
A list of elements of the form (FROM . TO), each meaning to replace
FROM with TO when it appears in a directory name.  This replacement is
done when setting up the default directory of a newly visited file.
*Every* FROM string should start with `^'.

62 63 64
Do not use `~' in the TO strings.
They should be ordinary absolute directory names.

Roland McGrath's avatar
Roland McGrath committed
65 66
Use this feature when you have directories which you normally refer to
via absolute symbolic links.  Make TO the name of the link, and FROM
67 68 69 70 71 72 73
the name it is linked to."
  :type '(repeat (cons :format "%v"
		       :value ("" . "")
		       (regexp :tag "From")
		       (regexp :tag "To")))
  :group 'abbrev
  :group 'find-file)
Roland McGrath's avatar
Roland McGrath committed
74

75
;; Turn off backup files on VMS since it has version numbers.
76
(defcustom make-backup-files (not (eq system-type 'vax-vms))
77
  "*Non-nil means make a backup of a file the first time it is saved.
Roland McGrath's avatar
Roland McGrath committed
78 79 80 81 82 83 84 85 86 87 88 89 90
This can be done by renaming the file or by copying.

Renaming means that Emacs renames the existing file so that it is a
backup file, then writes the buffer into a new file.  Any other names
that the old file had will now refer to the backup file.  The new file
is owned by you and its group is defaulted.

Copying means that Emacs copies the existing file into the backup
file, then writes the buffer on top of the existing file.  Any other
names that the old file had will now refer to the new (edited) file.
The file's owner and group are unchanged.

The choice of renaming or copying is controlled by the variables
André Spiegel's avatar
André Spiegel committed
91 92 93
`backup-by-copying', `backup-by-copying-when-linked',
`backup-by-copying-when-mismatch' and
`backup-by-copying-when-privileged-mismatch'.  See also `backup-inhibited'."
94 95
  :type 'boolean
  :group 'backup)
Roland McGrath's avatar
Roland McGrath committed
96 97 98 99

;; Do this so that local variables based on the file name
;; are not overridden by the major mode.
(defvar backup-inhibited nil
100 101 102
  "Non-nil means don't make a backup, regardless of the other parameters.
This variable is intended for use by making it local to a buffer.
But it is local only if you make it local.")
Roland McGrath's avatar
Roland McGrath committed
103 104
(put 'backup-inhibited 'permanent-local t)

105
(defcustom backup-by-copying nil
Roland McGrath's avatar
Roland McGrath committed
106
 "*Non-nil means always use copying to create backup files.
107 108 109
See documentation of variable `make-backup-files'."
 :type 'boolean
 :group 'backup)
Roland McGrath's avatar
Roland McGrath committed
110

111
(defcustom backup-by-copying-when-linked nil
Roland McGrath's avatar
Roland McGrath committed
112 113
 "*Non-nil means use copying to create backups for files with multiple names.
This causes the alternate names to refer to the latest version as edited.
114 115 116
This variable is relevant only if `backup-by-copying' is nil."
 :type 'boolean
 :group 'backup)
Roland McGrath's avatar
Roland McGrath committed
117

118
(defcustom backup-by-copying-when-mismatch nil
Roland McGrath's avatar
Roland McGrath committed
119 120 121 122 123
  "*Non-nil means create backups by copying if this preserves owner or group.
Renaming may still be used (subject to control of other variables)
when it would not result in changing the owner or group of the file;
that is, for files which are owned by you and whose group matches
the default for a new file created there by you.
124 125 126
This variable is relevant only if `backup-by-copying' is nil."
  :type 'boolean
  :group 'backup)
Roland McGrath's avatar
Roland McGrath committed
127

André Spiegel's avatar
André Spiegel committed
128 129 130 131 132 133 134 135 136 137 138 139 140
(defcustom backup-by-copying-when-privileged-mismatch 200
  "*Non-nil means create backups by copying to preserve a privileged owner.
Renaming may still be used (subject to control of other variables)
when it would not result in changing the owner of the file or if the owner
has a user id greater than the value of this variable.  This is useful
when low-numbered uid's are used for special system users (such as root)
that must maintain ownership of certain files.
This variable is relevant only if `backup-by-copying' and
`backup-by-copying-when-mismatch' are nil."
  :type '(choice (const nil) integer)
  :group 'backup)

(defvar backup-enable-predicate 'normal-backup-enable-predicate
Roland McGrath's avatar
Roland McGrath committed
141
  "Predicate that looks at a file name and decides whether to make backups.
142
Called with an absolute file name as argument, it returns t to enable backup.")
Roland McGrath's avatar
Roland McGrath committed
143

144
(defcustom buffer-offer-save nil
André Spiegel's avatar
André Spiegel committed
145 146
  "*Non-nil in a buffer means always offer to save buffer on exit.
Do so even if the buffer is not visiting a file.
147 148 149
Automatically local in all buffers."
  :type 'boolean
  :group 'backup)
Roland McGrath's avatar
Roland McGrath committed
150 151
(make-variable-buffer-local 'buffer-offer-save)

152
(defcustom find-file-existing-other-name t
153 154
  "*Non-nil means find a file under alternative names, in existing buffers.
This means if any existing buffer is visiting the file you want
155 156 157
under another name, you get the existing buffer instead of a new buffer."
  :type 'boolean
  :group 'find-file)
158

159
(defcustom find-file-visit-truename nil
160 161
  "*Non-nil means visit a file under its truename.
The truename of a file is found by chasing all links
162 163 164
both at the file level and at the levels of the containing directories."
  :type 'boolean
  :group 'find-file)
165
(put 'find-file-visit-truename 'safe-local-variable 'boolean)
166

167
(defcustom revert-without-query nil
168 169 170
  "*Specify which files should be reverted without query.
The value is a list of regular expressions.
If the file name matches one of these regular expressions,
171
then `revert-buffer' reverts the file without querying
172
if the file has changed on disk and you have not edited the buffer."
173
  :type '(repeat regexp)
174
  :group 'find-file)
175

176 177 178 179 180 181 182 183
(defvar buffer-file-number nil
  "The device number and file number of the file visited in the current buffer.
The value is a list of the form (FILENUM DEVNUM).
This pair of numbers uniquely identifies the file.
If the buffer is visiting a new file, the value is nil.")
(make-variable-buffer-local 'buffer-file-number)
(put 'buffer-file-number 'permanent-local t)

184
(defvar buffer-file-numbers-unique (not (memq system-type '(windows-nt)))
185
  "Non-nil means that `buffer-file-number' uniquely identifies files.")
186

187 188 189 190
(defvar buffer-file-read-only nil
  "Non-nil if visited file was read-only when visited.")
(make-variable-buffer-local 'buffer-file-read-only)

191
(defcustom temporary-file-directory
192 193 194 195 196 197 198
  (file-name-as-directory
   (cond ((memq system-type '(ms-dos windows-nt))
	  (or (getenv "TEMP") (getenv "TMPDIR") (getenv "TMP") "c:/temp"))
	 ((memq system-type '(vax-vms axp-vms))
	  (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "SYS$SCRATCH:"))
	 (t
	  (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "/tmp"))))
199 200 201
  "The directory for writing temporary files."
  :group 'files
  :type 'directory)
202

203
(defcustom small-temporary-file-directory
204 205 206 207
  (if (eq system-type 'ms-dos) (getenv "TMPDIR"))
  "The directory for writing small temporary files.
If non-nil, this directory is used instead of `temporary-file-directory'
by programs that create small temporary files.  This is for systems that
208 209
have fast storage with limited space, such as a RAM disk."
  :group 'files
210
  :type '(choice (const nil) directory))
211 212 213 214

;; The system null device. (Should reference NULL_DEVICE from C.)
(defvar null-device "/dev/null" "The system null device.")

215 216
(defvar file-name-invalid-regexp
  (cond ((and (eq system-type 'ms-dos) (not (msdos-long-file-names)))
217
	 (concat "^\\([^A-Z[-`a-z]\\|..+\\)?:\\|" ; colon except after drive
218
		 "[+, ;=|<>\"?*]\\|\\[\\|\\]\\|"  ; invalid characters
219
		 "[\000-\031]\\|"		  ; control characters
220 221
		 "\\(/\\.\\.?[^/]\\)\\|"	  ; leading dots
		 "\\(/[^/.]+\\.[^/.]*\\.\\)"))	  ; more than a single dot
Juanma Barranquero's avatar
Juanma Barranquero committed
222
	((memq system-type '(ms-dos windows-nt cygwin))
223
	 (concat "^\\([^A-Z[-`a-z]\\|..+\\)?:\\|" ; colon except after drive
224
		 "[|<>\"?*\000-\031]"))		  ; invalid characters
225 226 227
	(t "[\000]"))
  "Regexp recognizing file names which aren't allowed by the filesystem.")

228
(defcustom file-precious-flag nil
Roland McGrath's avatar
Roland McGrath committed
229
  "*Non-nil means protect against I/O errors while saving files.
Karl Heuer's avatar
Karl Heuer committed
230
Some modes set this non-nil in particular buffers.
231 232 233 234 235 236 237

This feature works by writing the new contents into a temporary file
and then renaming the temporary file to replace the original.
In this way, any I/O error in writing leaves the original untouched,
and there is never any instant where the file is nonexistent.

Note that this feature forces backups to be made by copying.
Karl Heuer's avatar
Karl Heuer committed
238
Yet, at the same time, saving a precious file
239 240 241
breaks any hard links between it and other files."
  :type 'boolean
  :group 'backup)
Roland McGrath's avatar
Roland McGrath committed
242

243
(defcustom version-control nil
Roland McGrath's avatar
Roland McGrath committed
244 245 246
  "*Control use of version numbers for backup files.
t means make numeric backup versions unconditionally.
nil means make them for files that have some already.
247
`never' means do not make them."
248 249 250
  :type '(choice (const :tag "Never" never)
		 (const :tag "If existing" nil)
		 (other :tag "Always" t))
251 252
  :group 'backup
  :group 'vc)
253 254
(put 'version-control 'safe-local-variable
     '(lambda (x) (or (booleanp x) (equal x 'never))))
255 256 257 258 259 260 261 262

(defcustom dired-kept-versions 2
  "*When cleaning directory, number of versions to keep."
  :type 'integer
  :group 'backup
  :group 'dired)

(defcustom delete-old-versions nil
263
  "*If t, delete excess backup versions silently.
264 265 266
If nil, ask confirmation.  Any other value prevents any trimming."
  :type '(choice (const :tag "Delete" t)
		 (const :tag "Ask" nil)
267
		 (other :tag "Leave" other))
268 269 270 271 272 273
  :group 'backup)

(defcustom kept-old-versions 2
  "*Number of oldest versions to keep when a new numbered backup is made."
  :type 'integer
  :group 'backup)
274
(put 'kept-old-versions 'safe-local-variable 'integerp)
275 276

(defcustom kept-new-versions 2
Roland McGrath's avatar
Roland McGrath committed
277
  "*Number of newest versions to keep when a new numbered backup is made.
278 279 280
Includes the new backup.  Must be > 0"
  :type 'integer
  :group 'backup)
281
(put 'kept-new-versions 'safe-local-variable 'integerp)
Roland McGrath's avatar
Roland McGrath committed
282

283
(defcustom require-final-newline nil
284 285 286 287 288 289 290 291 292 293 294 295 296
  "*Whether to add a newline automatically at the end of the file.

A value of t means do this only when the file is about to be saved.
A value of `visit' means do this right after the file is visited.
A value of `visit-save' means do it at both of those times.
Any other non-nil value means ask user whether to add a newline, when saving.
nil means don't add newlines.

Certain major modes set this locally to the value obtained
from `mode-require-final-newline'."
  :type '(choice (const :tag "When visiting" visit)
		 (const :tag "When saving" t)
		 (const :tag "When visiting or saving" visit-save)
297
		 (const :tag "Don't add newlines" nil)
298
		 (other :tag "Ask each time" ask))
299
  :group 'editing-basics)
Roland McGrath's avatar
Roland McGrath committed
300

301
(defcustom mode-require-final-newline t
302
  "*Whether to add a newline at end of file, in certain major modes.
303
Those modes set `require-final-newline' to this value when you enable them.
304
They do so because they are often used for files that are supposed
305 306 307 308 309
to end in newlines, and the question is how to arrange that.

A value of t means do this only when the file is about to be saved.
A value of `visit' means do this right after the file is visited.
A value of `visit-save' means do it at both of those times.
310 311
Any other non-nil value means ask user whether to add a newline, when saving.

312 313 314 315
nil means do not add newlines.  That is a risky choice in this variable
since this value is used for modes for files that ought to have final newlines.
So if you set this to nil, you must explicitly check and add
a final newline, whenever you save a file that really needs one."
316 317 318
  :type '(choice (const :tag "When visiting" visit)
		 (const :tag "When saving" t)
		 (const :tag "When visiting or saving" visit-save)
319 320
		 (const :tag "Don't add newlines" nil)
		 (other :tag "Ask each time" ask))
321
  :group 'editing-basics
322
  :version "22.1")
323

324 325 326 327
(defcustom auto-save-default t
  "*Non-nil says by default do auto-saving of every file-visiting buffer."
  :type 'boolean
  :group 'auto-save)
Roland McGrath's avatar
Roland McGrath committed
328

329
(defcustom auto-save-visited-file-name nil
Roland McGrath's avatar
Roland McGrath committed
330
  "*Non-nil says auto-save a buffer in the file it is visiting, when practical.
331 332 333
Normally auto-save files are written under other names."
  :type 'boolean
  :group 'auto-save)
Roland McGrath's avatar
Roland McGrath committed
334

André Spiegel's avatar
André Spiegel committed
335
(defcustom auto-save-file-name-transforms
336
  `(("\\`/[^/]*:\\([^/]*/\\)*\\([^/]*\\)\\'"
337 338
     ;; Don't put "\\2" inside expand-file-name, since it will be
     ;; transformed to "/2" on DOS/Windows.
339
     ,(concat temporary-file-directory "\\2") t))
André Spiegel's avatar
André Spiegel committed
340
  "*Transforms to apply to buffer file name before making auto-save file name.
341
Each transform is a list (REGEXP REPLACEMENT UNIQUIFY):
André Spiegel's avatar
André Spiegel committed
342 343 344
REGEXP is a regular expression to match against the file name.
If it matches, `replace-match' is used to replace the
matching part with REPLACEMENT.
345
If the optional element UNIQUIFY is non-nil, the auto-save file name is
346
constructed by taking the directory part of the replaced file-name,
347 348 349 350
concatenated with the buffer file name with all directory separators
changed to `!' to prevent clashes.  This will not work
correctly if your filesystem truncates the resulting name.

André Spiegel's avatar
André Spiegel committed
351 352 353 354
All the transforms in the list are tried, in the order they are listed.
When one transform applies, its result is final;
no further transforms are tried.

355 356
The default value is set up to put the auto-save file into the
temporary directory (see the variable `temporary-file-directory') for
357 358 359 360
editing a remote file.

On MS-DOS filesystems without long names this variable is always
ignored."
André Spiegel's avatar
André Spiegel committed
361
  :group 'auto-save
362 363
  :type '(repeat (list (string :tag "Regexp") (string :tag "Replacement")
					   (boolean :tag "Uniquify")))
André Spiegel's avatar
André Spiegel committed
364 365
  :version "21.1")

366
(defcustom save-abbrevs t
367 368 369
  "*Non-nil means save word abbrevs too when files are saved.
If `silently', don't ask the user before saving."
  :type '(choice (const t) (const nil) (const silently))
370
  :group 'abbrev)
Roland McGrath's avatar
Roland McGrath committed
371

372
(defcustom find-file-run-dired t
André Spiegel's avatar
André Spiegel committed
373 374
  "*Non-nil means allow `find-file' to visit directories.
To visit the directory, `find-file' runs `find-directory-functions'."
375 376
  :type 'boolean
  :group 'find-file)
Roland McGrath's avatar
Roland McGrath committed
377

André Spiegel's avatar
André Spiegel committed
378 379 380 381 382 383 384
(defcustom find-directory-functions '(cvs-dired-noselect dired-noselect)
  "*List of functions to try in sequence to visit a directory.
Each function is called with the directory name as the sole argument
and should return either a buffer or nil."
  :type '(hook :options (cvs-dired-noselect dired-noselect))
  :group 'find-file)

385 386
;;;It is not useful to make this a local variable.
;;;(put 'find-file-not-found-hooks 'permanent-local t)
Stefan Monnier's avatar
Stefan Monnier committed
387
(defvar find-file-not-found-functions nil
Roland McGrath's avatar
Roland McGrath committed
388 389
  "List of functions to be called for `find-file' on nonexistent file.
These functions are called as soon as the error is detected.
André Spiegel's avatar
André Spiegel committed
390
Variable `buffer-file-name' is already set up.
Roland McGrath's avatar
Roland McGrath committed
391
The functions are called in the order given until one of them returns non-nil.")
392 393
(define-obsolete-variable-alias 'find-file-not-found-hooks
    'find-file-not-found-functions "22.1")
Roland McGrath's avatar
Roland McGrath committed
394

395 396
;;;It is not useful to make this a local variable.
;;;(put 'find-file-hooks 'permanent-local t)
Dave Love's avatar
Dave Love committed
397
(defcustom find-file-hook nil
Roland McGrath's avatar
Roland McGrath committed
398 399
  "List of functions to be called after a buffer is loaded from a file.
The buffer's local variables (if any) will have been processed before the
Dave Love's avatar
Dave Love committed
400 401 402 403
functions are called."
  :group 'find-file
  :type 'hook
  :options '(auto-insert)
404
  :version "22.1")
405
(define-obsolete-variable-alias 'find-file-hooks 'find-file-hook "22.1")
Roland McGrath's avatar
Roland McGrath committed
406

Stefan Monnier's avatar
Stefan Monnier committed
407
(defvar write-file-functions nil
Roland McGrath's avatar
Roland McGrath committed
408 409
  "List of functions to be called before writing out a buffer to a file.
If one of them returns non-nil, the file is considered already written
Jim Blandy's avatar
Jim Blandy committed
410 411
and the rest are not called.
These hooks are considered to pertain to the visited file.
Stefan Monnier's avatar
Stefan Monnier committed
412 413 414 415
So any buffer-local binding of this variable is discarded if you change
the visited file name with \\[set-visited-file-name], but not when you
change the major mode.

416 417 418 419 420
This hook is not run if any of the functions in
`write-contents-functions' returns non-nil.  Both hooks pertain
to how to save a buffer to file, for instance, choosing a suitable
coding system and setting mode bits.  (See Info
node `(elisp)Saving Buffers'.)  To perform various checks or
421
updates before the buffer is saved, use `before-save-hook'.")
Stefan Monnier's avatar
Stefan Monnier committed
422
(put 'write-file-functions 'permanent-local t)
423
(define-obsolete-variable-alias 'write-file-hooks 'write-file-functions "22.1")
Stefan Monnier's avatar
Stefan Monnier committed
424 425

(defvar local-write-file-hooks nil)
426 427
(make-variable-buffer-local 'local-write-file-hooks)
(put 'local-write-file-hooks 'permanent-local t)
428
(make-obsolete-variable 'local-write-file-hooks 'write-file-functions "22.1")
Jim Blandy's avatar
Jim Blandy committed
429

Stefan Monnier's avatar
Stefan Monnier committed
430
(defvar write-contents-functions nil
Jim Blandy's avatar
Jim Blandy committed
431 432
  "List of functions to be called before writing out a buffer to a file.
If one of them returns non-nil, the file is considered already written
433 434
and the rest are not called and neither are the functions in
`write-file-functions'.
435 436 437 438

This variable is meant to be used for hooks that pertain to the
buffer's contents, not to the particular visited file; thus,
`set-visited-file-name' does not clear this variable; but changing the
439 440
major mode does clear it.

441 442 443 444 445
For hooks that _do_ pertain to the particular visited file, use
`write-file-functions'.  Both this variable and
`write-file-functions' relate to how a buffer is saved to file.
To perform various checks or updates before the buffer is saved,
use `before-save-hook'.")
Stefan Monnier's avatar
Stefan Monnier committed
446
(make-variable-buffer-local 'write-contents-functions)
447 448
(define-obsolete-variable-alias 'write-contents-hooks
    'write-contents-functions "22.1")
Roland McGrath's avatar
Roland McGrath committed
449

450
(defcustom enable-local-variables t
451
  "*Control use of local variables in files you visit.
452
The value can be t, nil, :safe, or something else.
453 454

A value of t means file local variables specifications are obeyed
455 456
if all the specified variable values are safe; if any values are
not safe, Emacs queries you, once, whether to set them all.
457 458 459
\(When you say yes to certain values, they are remembered as safe.)

:safe means set the safe variables, and ignore the rest.
460 461
:all means set all variables, whether safe or not.
 (Don't set it permanently to :all.)
462
nil means always ignore the file local variables.
463 464

Any other value means always query you once whether to set them all.
465 466
\(When you say yes to certain values, they are remembered as safe, but
this has no effect when `enable-local-variables' is \"something else\".)
467

468 469
This variable also controls use of major modes specified in
a -*- line.
Roland McGrath's avatar
Roland McGrath committed
470

471 472 473
The command \\[normal-mode], when used interactively,
always obeys file local variable specifications and the -*- line,
and ignores this variable."
474
  :type '(choice (const :tag "Query Unsafe" t)
475
		 (const :tag "Safe Only" :safe)
476
		 (const :tag "Do all" :all)
477
		 (const :tag "Ignore" nil)
478
		 (other :tag "Query" other))
479
  :group 'find-file)
Roland McGrath's avatar
Roland McGrath committed
480

481 482
(defvar local-enable-local-variables t
  "Like `enable-local-variables' but meant for buffer-local bindings.
483
The meaningful values are nil and non-nil.  The default is non-nil.
484
If a major mode sets this to nil, buffer-locally, then any local
485 486 487 488
variables list in the file will be ignored.

This variable does not affect the use of major modes
specified in a -*- line.")
489

490
(defcustom enable-local-eval 'maybe
491
  "Control processing of the \"variable\" `eval' in a file's local variables.
492 493
The value can be t, nil or something else.
A value of t means obey `eval' variables;
494
nil means ignore them; anything else means query."
495 496
  :type '(choice (const :tag "Obey" t)
		 (const :tag "Ignore" nil)
497
		 (other :tag "Query" other))
498
  :group 'find-file)
Roland McGrath's avatar
Roland McGrath committed
499 500 501

;; Avoid losing in versions where CLASH_DETECTION is disabled.
(or (fboundp 'lock-buffer)
502
    (defalias 'lock-buffer 'ignore))
Roland McGrath's avatar
Roland McGrath committed
503
(or (fboundp 'unlock-buffer)
504
    (defalias 'unlock-buffer 'ignore))
505 506
(or (fboundp 'file-locked-p)
    (defalias 'file-locked-p 'ignore))
507

508
(defcustom view-read-only nil
509 510 511 512 513
  "*Non-nil means buffers visiting files read-only do so in view mode.
In fact, this means that all read-only buffers normally have
View mode enabled, including buffers that are read-only because
you visit a file you cannot alter, and buffers you make read-only
using \\[toggle-read-only]."
514 515
  :type 'boolean
  :group 'view)
516

517
(put 'ange-ftp-completion-hook-function 'safe-magic t)
518
(defun ange-ftp-completion-hook-function (op &rest args)
André Spiegel's avatar
André Spiegel committed
519 520 521 522
  "Provides support for ange-ftp host name completion.
Runs the usual ange-ftp hook, but only for completion operations."
  ;; Having this here avoids the need to load ange-ftp when it's not
  ;; really in use.
523 524
  (if (memq op '(file-name-completion file-name-all-completions))
      (apply 'ange-ftp-hook-function op args)
525 526 527 528 529
    (let ((inhibit-file-name-handlers
	   (cons 'ange-ftp-completion-hook-function
		 (and (eq inhibit-file-name-operation op)
		      inhibit-file-name-handlers)))
	  (inhibit-file-name-operation op))
530
      (apply op args))))
531 532

(defun convert-standard-filename (filename)
533
  "Convert a standard file's name to something suitable for the OS.
534 535 536
This means to guarantee valid names and perhaps to canonicalize
certain patterns.

537 538 539 540
FILENAME should be an absolute file name since the conversion rules
sometimes vary depending on the position in the file name.  E.g. c:/foo
is a valid DOS file name, but c:/bar/c:/foo is not.

541 542 543 544 545
This function's standard definition is trivial; it just returns
the argument.  However, on Windows and DOS, replace invalid
characters.  On DOS, make sure to obey the 8.3 limitations.  On
Windows, turn Cygwin names into native names, and also turn
slashes into backslashes if the shell requires it (see
546 547 548
`w32-shell-dos-semantics').

See Info node `(elisp)Standard File Names' for more details."
549
  filename)
550 551 552 553

(defun read-directory-name (prompt &optional dir default-dirname mustmatch initial)
  "Read directory name, prompting with PROMPT and completing in directory DIR.
Value is not expanded---you must call `expand-file-name' yourself.
554 555
Default name to DEFAULT-DIRNAME if user exits with the same
non-empty string that was inserted by this function.
556 557
 (If DEFAULT-DIRNAME is omitted, DIR combined with INITIAL is used,
  or just DIR if INITIAL is nil.)
558 559 560
If the user exits with an empty minibuffer, this function returns
an empty string.  (This can only happen if the user erased the
pre-inserted contents or if `insert-default-directory' is nil.)
561 562 563
Fourth arg MUSTMATCH non-nil means require existing directory's name.
 Non-nil and non-t means also require confirmation after completion.
Fifth arg INITIAL specifies text to start with.
564 565
DIR should be an absolute directory name.  It defaults to
the value of `default-directory'."
566 567
  (unless dir
    (setq dir default-directory))
568
  (read-file-name prompt dir (or default-dirname
569 570 571
				 (if initial (expand-file-name initial dir)
				   dir))
		  mustmatch initial
572 573
		  'file-directory-p))

Roland McGrath's avatar
Roland McGrath committed
574 575 576 577 578 579

(defun pwd ()
  "Show the current default directory."
  (interactive nil)
  (message "Directory %s" default-directory))

580 581
(defvar cd-path nil
  "Value of the CDPATH environment variable, as a list.
582
Not actually set up until the first time you use it.")
583 584

(defun parse-colon-path (cd-path)
585
  "Explode a search path into a list of directory names.
586 587
Directories are separated by occurrences of `path-separator'
\(which is colon in GNU and GNU-like systems)."
André Spiegel's avatar
André Spiegel committed
588
  ;; We could use split-string here.
589
  (and cd-path
590
       (let (cd-list (cd-start 0) cd-colon)
591 592
	 (setq cd-path (concat cd-path path-separator))
	 (while (setq cd-colon (string-match path-separator cd-path cd-start))
593
	   (setq cd-list
594
		 (nconc cd-list
595 596 597
			(list (if (= cd-start cd-colon)
				   nil
				(substitute-in-file-name
598 599
				 (file-name-as-directory
				  (substring cd-path cd-start cd-colon)))))))
600 601 602 603
	   (setq cd-start (+ cd-colon 1)))
	 cd-list)))

(defun cd-absolute (dir)
604
  "Change current directory to given absolute file name DIR."
605 606
  ;; Put the name into directory syntax now,
  ;; because otherwise expand-file-name may give some bad results.
Roland McGrath's avatar
Roland McGrath committed
607 608
  (if (not (eq system-type 'vax-vms))
      (setq dir (file-name-as-directory dir)))
609
  (setq dir (abbreviate-file-name (expand-file-name dir)))
Roland McGrath's avatar
Roland McGrath committed
610
  (if (not (file-directory-p dir))
611 612
      (if (file-exists-p dir)
	  (error "%s is not a directory" dir)
613
	(error "%s: no such directory" dir))
Roland McGrath's avatar
Roland McGrath committed
614 615
    (if (file-executable-p dir)
	(setq default-directory dir)
616
      (error "Cannot cd to %s:  Permission denied" dir))))
Roland McGrath's avatar
Roland McGrath committed
617

618 619
(defun cd (dir)
  "Make DIR become the current buffer's default directory.
620 621
If your environment includes a `CDPATH' variable, try each one of
that list of directories (separated by occurrences of
622 623
`path-separator') when resolving a relative directory name.
The path separator is colon in GNU and GNU-like systems."
624
  (interactive
625
   (list (read-directory-name "Change default directory: "
626 627 628
			 default-directory default-directory
			 (and (member cd-path '(nil ("./")))
			      (null (getenv "CDPATH"))))))
629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644
  (if (file-name-absolute-p dir)
      (cd-absolute (expand-file-name dir))
    (if (null cd-path)
	(let ((trypath (parse-colon-path (getenv "CDPATH"))))
	  (setq cd-path (or trypath (list "./")))))
    (if (not (catch 'found
	       (mapcar
		(function (lambda (x)
			    (let ((f (expand-file-name (concat x dir))))
			      (if (file-directory-p f)
				  (progn
				    (cd-absolute f)
				    (throw 'found t))))))
		cd-path)
	       nil))
	(error "No such directory found via CDPATH environment variable"))))
645

Roland McGrath's avatar
Roland McGrath committed
646 647
(defun load-file (file)
  "Load the Lisp file named FILE."
648 649
  ;; This is a case where .elc makes a lot of sense.
  (interactive (list (let ((completion-ignored-extensions
Dave Love's avatar
Dave Love committed
650
			    (remove ".elc" completion-ignored-extensions)))
651 652
		       (read-file-name "Load file: "))))
  (load (expand-file-name file) nil nil t))
Roland McGrath's avatar
Roland McGrath committed
653

Stefan Monnier's avatar
Stefan Monnier committed
654 655
(defun locate-file (filename path &optional suffixes predicate)
  "Search for FILENAME through PATH.
Eli Zaretskii's avatar
Eli Zaretskii committed
656 657 658 659
If found, return the absolute file name of FILENAME, with its suffixes;
otherwise return nil.
PATH should be a list of directories to look in, like the lists in
`exec-path' or `load-path'.
Stefan Monnier's avatar
Stefan Monnier committed
660 661
If SUFFIXES is non-nil, it should be a list of suffixes to append to
file name when searching.  If SUFFIXES is nil, it is equivalent to '(\"\").
Eli Zaretskii's avatar
Eli Zaretskii committed
662
Use '(\"/\") to disable PATH search, but still try the suffixes in SUFFIXES.
Stefan Monnier's avatar
Stefan Monnier committed
663
If non-nil, PREDICATE is used instead of `file-readable-p'.
Richard M. Stallman's avatar
Richard M. Stallman committed
664 665 666 667 668 669
PREDICATE can also be an integer to pass to the `access' system call,
in which case file-name handlers are ignored.  This usage is deprecated.

For compatibility, PREDICATE can also be one of the symbols
`executable', `readable', `writable', or `exists', or a list of
one or more of those symbols."
Stefan Monnier's avatar
Stefan Monnier committed
670 671 672 673 674 675 676 677 678 679 680
  (if (and predicate (symbolp predicate) (not (functionp predicate)))
      (setq predicate (list predicate)))
  (when (and (consp predicate) (not (functionp predicate)))
    (setq predicate
	  (logior (if (memq 'executable predicate) 1 0)
		  (if (memq 'writable predicate) 2 0)
		  (if (memq 'readable predicate) 4 0))))
  (locate-file-internal filename path suffixes predicate))

(defun locate-file-completion (string path-and-suffixes action)
  "Do completion for file names passed to `locate-file'.
681
PATH-AND-SUFFIXES is a pair of lists, (DIRECTORIES . SUFFIXES)."
682
  (if (file-name-absolute-p string)
Stefan Monnier's avatar
Stefan Monnier committed
683
      (read-file-name-internal string nil action)
684
    (let ((names nil)
Stefan Monnier's avatar
Stefan Monnier committed
685
	  (suffix (concat (regexp-opt (cdr path-and-suffixes) t) "\\'"))
686
	  (string-dir (file-name-directory string)))
Stefan Monnier's avatar
Stefan Monnier committed
687
      (dolist (dir (car path-and-suffixes))
688 689
	(unless dir
	  (setq dir default-directory))
690 691 692 693
	(if string-dir (setq dir (expand-file-name string-dir dir)))
	(when (file-directory-p dir)
	  (dolist (file (file-name-all-completions
			 (file-name-nondirectory string) dir))
694
	    (add-to-list 'names (if string-dir (concat string-dir file) file))
695 696 697
	    (when (string-match suffix file)
	      (setq file (substring file 0 (match-beginning 0)))
	      (push (if string-dir (concat string-dir file) file) names)))))
Stefan Monnier's avatar
Stefan Monnier committed
698 699 700 701
      (cond
       ((eq action t) (all-completions string names))
       ((null action) (try-completion string names))
       (t (test-completion string names))))))
702

703 704 705 706 707 708 709
(defun executable-find (command)
  "Search for COMMAND in `exec-path' and return the absolute file name.
Return nil if COMMAND is not found anywhere in `exec-path'."
  ;; Use 1 rather than file-executable-p to better match the behavior of
  ;; call-process.
  (locate-file command exec-path exec-suffixes 1))

Roland McGrath's avatar
Roland McGrath committed
710 711 712
(defun load-library (library)
  "Load the library named LIBRARY.
This is an interface to the function `load'."
Stefan Monnier's avatar
Stefan Monnier committed
713 714 715
  (interactive
   (list (completing-read "Load library: "
			  'locate-file-completion
716
			  (cons load-path (get-load-suffixes)))))
Roland McGrath's avatar
Roland McGrath committed
717
  (load library))
718

719
(defun file-remote-p (file)
720 721 722 723 724 725 726
  "Test whether FILE specifies a location on a remote system.
Return an identification of the system if the location is indeed
remote.  The identification of the system may comprise a method
to access the system and its hostname, amongst other things.

For example, the filename \"/user@host:/foo\" specifies a location
on the system \"/user@host:\"."
727
  (let ((handler (find-file-name-handler file 'file-remote-p)))
728
    (if handler
729 730
	(funcall handler 'file-remote-p file)
      nil)))
731

André Spiegel's avatar
André Spiegel committed
732
(defun file-local-copy (file)
733 734 735
  "Copy the file FILE into a temporary file on this machine.
Returns the name of the local copy, or nil, if FILE is directly
accessible."
André Spiegel's avatar
André Spiegel committed
736 737
  ;; This formerly had an optional BUFFER argument that wasn't used by
  ;; anything.
738
  (let ((handler (find-file-name-handler file 'file-local-copy)))
739 740 741
    (if handler
	(funcall handler 'file-local-copy file)
      nil)))
742

743
(defun file-truename (filename &optional counter prev-dirs)
744 745 746
  "Return the truename of FILENAME, which should be absolute.
The truename of a file name is found by chasing symbolic links
both at the level of the file and at the level of the directories
747 748
containing it, until no links are left at any level.

Richard M. Stallman's avatar
Richard M. Stallman committed
749
\(fn FILENAME)"  ;; Don't document the optional arguments.
750 751 752
  ;; COUNTER and PREV-DIRS are only used in recursive calls.
  ;; COUNTER can be a cons cell whose car is the count of how many
  ;; more links to chase before getting an error.
753 754
  ;; PREV-DIRS can be a cons cell whose car is an alist
  ;; of truenames we've just recently computed.
755 756 757 758 759 760 761 762 763 764 765
  (cond ((or (string= filename "") (string= filename "~"))
	 (setq filename (expand-file-name filename))
	 (if (string= filename "")
	     (setq filename "/")))
	((and (string= (substring filename 0 1) "~")
	      (string-match "~[^/]*/?" filename))
	 (let ((first-part
		(substring filename 0 (match-end 0)))
	       (rest (substring filename (match-end 0))))
	   (setq filename (concat (expand-file-name first-part) rest)))))

766
  (or counter (setq counter (list 100)))
767 768 769 770 771 772 773 774 775
  (let (done
	;; For speed, remove the ange-ftp completion handler from the list.
	;; We know it's not needed here.
	;; For even more speed, do this only on the outermost call.
	(file-name-handler-alist
	 (if prev-dirs file-name-handler-alist
	   (let ((tem (copy-sequence file-name-handler-alist)))
	     (delq (rassq 'ange-ftp-completion-hook-function tem) tem)))))
    (or prev-dirs (setq prev-dirs (list nil)))
776 777 778 779 780 781 782 783 784 785 786 787 788

    ;; andrewi@harlequin.co.uk - none of the following code (except for
    ;; invoking the file-name handler) currently applies on Windows
    ;; (ie. there are no native symlinks), but there is an issue with
    ;; case differences being ignored by the OS, and short "8.3 DOS"
    ;; name aliases existing for all files.  (The short names are not
    ;; reported by directory-files, but can be used to refer to files.)
    ;; It seems appropriate for file-truename to resolve these issues in
    ;; the most natural way, which on Windows is to call the function
    ;; `w32-long-file-name' - this returns the exact name of a file as
    ;; it is stored on disk (expanding short name aliases with the full
    ;; name in the process).
    (if (eq system-type 'windows-nt)
789
      (let ((handler (find-file-name-handler filename 'file-truename)))
790 791 792 793 794
	;; For file name that has a special handler, call handler.
	;; This is so that ange-ftp can save time by doing a no-op.
	(if handler
	    (setq filename (funcall handler 'file-truename filename))
	  ;; If filename contains a wildcard, newname will be the old name.
795
	  (unless (string-match "[[*?]" filename)
796 797
	    ;; If filename exists, use the long name
	    (setq filename (or (w32-long-file-name filename) filename))))
798 799
	(setq done t)))

800 801 802 803 804 805 806 807 808 809 810 811
    ;; If this file directly leads to a link, process that iteratively
    ;; so that we don't use lots of stack.
    (while (not done)
      (setcar counter (1- (car counter)))
      (if (< (car counter) 0)
	  (error "Apparent cycle of symbolic links for %s" filename))
      (let ((handler (find-file-name-handler filename 'file-truename)))
	;; For file name that has a special handler, call handler.
	;; This is so that ange-ftp can save time by doing a no-op.
	(if handler
	    (setq filename (funcall handler 'file-truename filename)
		  done t)
812
	  (let ((dir (or (file-name-directory filename) default-directory))
813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850
		target dirfile)
	    ;; Get the truename of the directory.
	    (setq dirfile (directory-file-name dir))
	    ;; If these are equal, we have the (or a) root directory.
	    (or (string= dir dirfile)
		;; If this is the same dir we last got the truename for,
		;; save time--don't recalculate.
		(if (assoc dir (car prev-dirs))
		    (setq dir (cdr (assoc dir (car prev-dirs))))
		  (let ((old dir)
			(new (file-name-as-directory (file-truename dirfile counter prev-dirs))))
		    (setcar prev-dirs (cons (cons old new) (car prev-dirs)))
		    (setq dir new))))
	    (if (equal ".." (file-name-nondirectory filename))
		(setq filename
		      (directory-file-name (file-name-directory (directory-file-name dir)))
		      done t)
	      (if (equal "." (file-name-nondirectory filename))
		  (setq filename (directory-file-name dir)
			done t)
		;; Put it back on the file name.
		(setq filename (concat dir (file-name-nondirectory filename)))
		;; Is the file name the name of a link?
		(setq target (file-symlink-p filename))
		(if target
		    ;; Yes => chase that link, then start all over
		    ;; since the link may point to a directory name that uses links.
		    ;; We can't safely use expand-file-name here
		    ;; since target might look like foo/../bar where foo
		    ;; is itself a link.  Instead, we handle . and .. above.
		    (setq filename
			  (if (file-name-absolute-p target)
			      target
			    (concat dir target))
			  done nil)
		  ;; No, we are done!
		  (setq done t))))))))
    filename))
851

852
(defun file-chase-links (filename &optional limit)
853
  "Chase links in FILENAME until a name that is not a link.
854 855 856 857 858
Unlike `file-truename', this does not check whether a parent
directory name is a symbolic link.
If the optional argument LIMIT is a number,
it means chase no more than that many links and then stop."
  (let (tem (newname filename)
859
	    (count 0))
860 861
    (while (and (or (null limit) (< count limit))
		(setq tem (file-symlink-p newname)))
862
      (save-match-data
863
	(if (and (null limit) (= count 100))
864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881
	    (error "Apparent cycle of symbolic links for %s" filename))
	;; In the context of a link, `//' doesn't mean what Emacs thinks.
	(while (string-match "//+" tem)
	  (setq tem (replace-match "/" nil nil tem)))
	;; Handle `..' by hand, since it needs to work in the
	;; target of any directory symlink.
	;; This code is not quite complete; it does not handle
	;; embedded .. in some cases such as ./../foo and foo/bar/../../../lose.
	(while (string-match "\\`\\.\\./" tem)
	  (setq tem (substring tem 3))
	  (setq newname (expand-file-name newname))
	  ;; Chase links in the default dir of the symlink.
	  (setq newname
		(file-chase-links
		 (directory-file-name (file-name-directory newname))))
	  ;; Now find the parent of that dir.
	  (setq newname (file-name-directory newname)))
	(setq newname (expand-file-name tem (file-name-directory newname)))
882
	(setq count (1+ count))))
883
    newname))
884

885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921
(defun make-temp-file (prefix &optional dir-flag suffix)
  "Create a temporary file.
The returned file name (created by appending some random characters at the end
of PREFIX, and expanding against `temporary-file-directory' if necessary),
is guaranteed to point to a newly created empty file.
You can then use `write-region' to write new data into the file.

If DIR-FLAG is non-nil, create a new empty directory instead of a file.

If SUFFIX is non-nil, add that at the end of the file name."
  (let ((umask (default-file-modes))
	file)
    (unwind-protect
	(progn
	  ;; Create temp files with strict access rights.  It's easy to
	  ;; loosen them later, whereas it's impossible to close the
	  ;; time-window of loose permissions otherwise.
	  (set-default-file-modes ?\700)
	  (while (condition-case ()
		     (progn
		       (setq file
			     (make-temp-name
			      (expand-file-name prefix temporary-file-directory)))
		       (if suffix
			   (setq file (concat file suffix)))
		       (if dir-flag
			   (make-directory file)
			 (write-region "" nil file nil 'silent nil 'excl))
		       nil)
		   (file-already-exists t))
	    ;; the file was somehow created by someone else between
	    ;; `make-temp-name' and `write-region', let's try again.
	    nil)
	  file)
      ;; Reset the umask.
      (set-default-file-modes umask))))

922 923 924 925
(defun recode-file-name (file coding new-coding &optional ok-if-already-exists)
  "Change the encoding of FILE's name from CODING to NEW-CODING.
The value is a new name of FILE.
Signals a `file-already-exists' error if a file of the new name
926 927
already exists unless optional fourth argument OK-IF-ALREADY-EXISTS
is non-nil.  A number as fourth arg means request confirmation if
928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947
the new name already exists.  This is what happens in interactive
use with M-x."
  (interactive
   (let ((default-coding (or