frame.el 64.4 KB
Newer Older
1
;;; frame.el --- multi-frame management independent of window systems
Eric S. Raymond's avatar
Eric S. Raymond committed
2

3
;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2002, 2003,
Glenn Morris's avatar
Glenn Morris committed
4
;;   2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
Eric S. Raymond's avatar
Eric S. Raymond committed
5

Eric S. Raymond's avatar
Eric S. Raymond committed
6
;; Maintainer: FSF
Eric S. Raymond's avatar
Eric S. Raymond committed
7
;; Keywords: internal
Eric S. Raymond's avatar
Eric S. Raymond committed
8

Erik Naggum's avatar
Erik Naggum committed
9 10
;; This file is part of GNU Emacs.

11
;; GNU Emacs is free software: you can redistribute it and/or modify
Erik Naggum's avatar
Erik Naggum committed
12
;; it under the terms of the GNU General Public License as published by
13 14
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
Erik Naggum's avatar
Erik Naggum committed
15 16 17 18 19 20 21

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
22
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
Jim Blandy's avatar
Jim Blandy committed
23

24 25
;;; Commentary:

Eric S. Raymond's avatar
Eric S. Raymond committed
26 27
;;; Code:

28 29 30 31
(defvar frame-creation-function-alist
  (list (cons nil
	      (if (fboundp 'tty-create-frame-with-faces)
		  'tty-create-frame-with-faces
32 33
                (lambda (parameters)
                  (error "Can't create multiple frames without a window system")))))
34 35 36 37
  "Alist of window-system dependent functions to call to create a new frame.
The window system startup file should add its frame creation
function to this list, which should take an alist of parameters
as its argument.")
38

39 40
(defvar window-system-default-frame-alist nil
  "Alist of window-system dependent default frame parameters.
41
You can set this in your init file; for example,
42

43 44 45 46
 ;; Disable menubar and toolbar on the console, but enable them under X.
 (setq window-system-default-frame-alist
       '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
         (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
47

48 49
Parameters specified here supersede the values given in
`default-frame-alist'.")
50

51 52 53
;; The initial value given here used to ask for a minibuffer.
;; But that's not necessary, because the default is to have one.
;; By not specifying it here, we let an X resource specify it.
54
(defcustom initial-frame-alist nil
55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73
  "Alist of parameters for the initial X window frame.
You can set this in your init file; for example,

 (setq initial-frame-alist
       '((top . 1) (left . 1) (width . 80) (height . 55)))

Parameters specified here supersede the values given in
`default-frame-alist'.

If the value calls for a frame without a minibuffer, and you have
not created a minibuffer frame on your own, a minibuffer frame is
created according to `minibuffer-frame-alist'.

You can specify geometry-related options for just the initial
frame by setting this variable in your init file; however, they
won't take effect until Emacs reads your init file, which happens
after creating the initial frame.  If you want the initial frame
to have the proper geometry as soon as it appears, you need to
use this three-step process:
74 75 76 77
* Specify X resources to give the geometry you want.
* Set `default-frame-alist' to override these options so that they
  don't affect subsequent frames.
* Set `initial-frame-alist' in a way that matches the X resources,
78 79 80 81 82
  to override what you put in `default-frame-alist'."
  :type '(repeat (cons :format "%v"
		       (symbol :tag "Parameter")
		       (sexp :tag "Value")))
  :group 'frames)
Jim Blandy's avatar
Jim Blandy committed
83

84
(defcustom minibuffer-frame-alist '((width . 80) (height . 2))
85 86 87
  "Alist of parameters for initial minibuffer frame.
You can set this in your init file; for example,

Jim Blandy's avatar
Jim Blandy committed
88
 (setq minibuffer-frame-alist
89 90
       '((top . 1) (left . 1) (width . 80) (height . 2)))

91
Parameters specified here supersede the values given in
92 93 94 95 96
`default-frame-alist', for a minibuffer frame."
  :type '(repeat (cons :format "%v"
		       (symbol :tag "Parameter")
		       (sexp :tag "Value")))
  :group 'frames)
Jim Blandy's avatar
Jim Blandy committed
97

98
(defcustom pop-up-frame-alist nil
99 100 101
  "Alist of parameters for automatically generated new frames.
You can set this in your init file; for example,

Jim Blandy's avatar
Jim Blandy committed
102
  (setq pop-up-frame-alist '((width . 80) (height . 20)))
103 104 105 106 107

If non-nil, the value you specify here is used by the default
`pop-up-frame-function' for the creation of new frames.

Since `pop-up-frame-function' is used by `display-buffer' for
108
making new frames, any value specified here by default affects
109 110 111
the automatic generation of new frames via `display-buffer' and
all functions based on it.  The behavior of `make-frame' is not
affected by this variable."
112 113 114 115
  :type '(repeat (cons :format "%v"
		       (symbol :tag "Parameter")
		       (sexp :tag "Value")))
  :group 'frames)
Jim Blandy's avatar
Jim Blandy committed
116

117 118
(defcustom pop-up-frame-function
  (lambda () (make-frame pop-up-frame-alist))
119 120 121 122
  "Function used by `display-buffer' for creating a new frame.
This function is called with no arguments and should return a new
frame.  The default value calls `make-frame' with the argument
`pop-up-frame-alist'."
123 124
  :type '(choice (const nil) (function :tag "function"))
  :group 'frames)
Jim Blandy's avatar
Jim Blandy committed
125

Richard M. Stallman's avatar
Richard M. Stallman committed
126
(defcustom special-display-frame-alist
127
  '((height . 14) (width . 80) (unsplittable . t))
128
  "Alist of parameters for special frames.
129
Special frames are used for buffers whose names are listed in
130 131
`special-display-buffer-names' and for buffers whose names match
one of the regular expressions in `special-display-regexps'.
132

133
This variable can be set in your init file, like this:
134

135
  (setq special-display-frame-alist '((width . 80) (height . 20)))
136

Richard M. Stallman's avatar
Richard M. Stallman committed
137 138 139 140 141
These supersede the values given in `default-frame-alist'."
  :type '(repeat (cons :format "%v"
			 (symbol :tag "Parameter")
			 (sexp :tag "Value")))
  :group 'frames)
142

143
(defun special-display-popup-frame (buffer &optional args)
144 145 146 147 148 149 150 151 152 153 154 155 156 157 158
  "Display BUFFER and return the window chosen.
If BUFFER is already displayed in a visible or iconified frame,
raise that frame.  Otherwise, display BUFFER in a new frame.

Optional argument ARGS is a list specifying additional
information.

If ARGS is an alist, use it as a list of frame parameters.  If
these parameters contain \(same-window . t), display BUFFER in
the selected window.  If they contain \(same-frame . t), display
BUFFER in a window of the selected frame.

If ARGS is a list whose car is a symbol, use (car ARGS) as a
function to do the work.  Pass it BUFFER as first argument,
and (cdr ARGS) as second."
159 160
  (if (and args (symbolp (car args)))
      (apply (car args) buffer (cdr args))
161
    (let ((window (get-buffer-window buffer 0)))
162 163 164 165 166 167 168 169 170 171 172 173 174 175
      (or
       ;; If we have a window already, make it visible.
       (when window
	 (let ((frame (window-frame window)))
	   (make-frame-visible frame)
	   (raise-frame frame)
	   window))
       ;; Reuse the current window if the user requested it.
       (when (cdr (assq 'same-window args))
	 (condition-case nil
	     (progn (switch-to-buffer buffer) (selected-window))
	   (error nil)))
       ;; Stay on the same frame if requested.
       (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
176 177 178 179
	 (let* ((pop-up-windows t)
		pop-up-frames
		special-display-buffer-names special-display-regexps)
	   (display-buffer buffer)))
180
       ;; If no window yet, make one in a new frame.
181
       (let ((frame
182 183
	      (with-current-buffer buffer
		(make-frame (append args special-display-frame-alist)))))
184 185 186
	 (set-window-buffer (frame-selected-window frame) buffer)
	 (set-window-dedicated-p (frame-selected-window frame) t)
	 (frame-selected-window frame))))))
187

188
(defun handle-delete-frame (event)
189
  "Handle delete-frame events from the X server."
190 191 192 193 194 195 196 197 198 199 200
  (interactive "e")
  (let ((frame (posn-window (event-start event)))
	(i 0)
	(tail (frame-list)))
    (while tail
      (and (frame-visible-p (car tail))
	   (not (eq (car tail) frame))
	  (setq i (1+ i)))
      (setq tail (cdr tail)))
    (if (> i 0)
	(delete-frame frame t)
201 202
      ;; Gildea@x.org says it is ok to ask questions before terminating.
      (save-buffers-kill-emacs))))
Jim Blandy's avatar
Jim Blandy committed
203

Jim Blandy's avatar
Jim Blandy committed
204
;;;; Arrangement of frames at startup
Jim Blandy's avatar
Jim Blandy committed
205

206 207 208 209 210 211 212 213
;; 1) Load the window system startup file from the lisp library and read the
;; high-priority arguments (-q and the like).  The window system startup
;; file should create any frames specified in the window system defaults.
;;
;; 2) If no frames have been opened, we open an initial text frame.
;;
;; 3) Once the init file is done, we apply any newly set parameters
;; in initial-frame-alist to the frame.
Jim Blandy's avatar
Jim Blandy committed
214

Karl Heuer's avatar
Karl Heuer committed
215
;; These are now called explicitly at the proper times,
216 217 218 219
;; since that is easier to understand.
;; Actually using hooks within Emacs is bad for future maintenance. --rms.
;; (add-hook 'before-init-hook 'frame-initialize)
;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
Jim Blandy's avatar
Jim Blandy committed
220

221
;; If we create the initial frame, this is it.
Jim Blandy's avatar
Jim Blandy committed
222
(defvar frame-initial-frame nil)
Jim Blandy's avatar
Jim Blandy committed
223

224 225 226
;; Record the parameters used in frame-initialize to make the initial frame.
(defvar frame-initial-frame-alist)

227 228
(defvar frame-initial-geometry-arguments nil)

229 230 231
;; startup.el calls this function before loading the user's init
;; file - if there is no frame with a minibuffer open now, create
;; one to display messages while loading the init file.
Jim Blandy's avatar
Jim Blandy committed
232
(defun frame-initialize ()
Eli Zaretskii's avatar
Eli Zaretskii committed
233
  "Create an initial frame if necessary."
Jim Blandy's avatar
Jim Blandy committed
234
  ;; Are we actually running under a window system at all?
235 236 237
  (if (and initial-window-system
	   (not noninteractive)
	   (not (eq initial-window-system 'pc)))
238 239 240 241 242 243
      (progn
	;; If there is no frame with a minibuffer besides the terminal
	;; frame, then we need to create the opening frame.  Make sure
	;; it has a minibuffer, but let initial-frame-alist omit the
	;; minibuffer spec.
	(or (delq terminal-frame (minibuffer-frame-list))
244
	    (progn
245
	      (setq frame-initial-frame-alist
246
		    (append initial-frame-alist default-frame-alist nil))
247 248 249 250
	      (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
		  (setq frame-initial-frame-alist
			(cons '(horizontal-scroll-bars . t)
			      frame-initial-frame-alist)))
251 252 253
	      (setq frame-initial-frame-alist
		    (cons (cons 'window-system initial-window-system)
			  frame-initial-frame-alist))
254 255
	      (setq default-minibuffer-frame
		    (setq frame-initial-frame
256
			  (make-frame frame-initial-frame-alist)))
257 258 259 260
	      ;; Delete any specifications for window geometry parameters
	      ;; so that we won't reapply them in frame-notice-user-settings.
	      ;; It would be wrong to reapply them then,
	      ;; because that would override explicit user resizing.
261
	      (setq initial-frame-alist
262
		    (frame-remove-geometry-params initial-frame-alist))))
263 264 265
	;; Copy the environment of the Emacs process into the new frame.
	(set-frame-parameter frame-initial-frame 'environment
			     (frame-parameter terminal-frame 'environment))
Karl Heuer's avatar
Karl Heuer committed
266
	;; At this point, we know that we have a frame open, so we
Jim Blandy's avatar
Jim Blandy committed
267 268
	;; can delete the terminal frame.
	(delete-frame terminal-frame)
269
	(setq terminal-frame nil))))
Karl Heuer's avatar
Karl Heuer committed
270

271 272 273
(defvar frame-notice-user-settings t
  "Non-nil means function `frame-notice-user-settings' wasn't run yet.")

274 275
(declare-function tool-bar-mode "tool-bar" (&optional arg))

276 277 278
;; startup.el calls this function after loading the user's init
;; file.  Now default-frame-alist and initial-frame-alist contain
;; information to which we must react; do what needs to be done.
Jim Blandy's avatar
Jim Blandy committed
279
(defun frame-notice-user-settings ()
280
  "Act on user's init file settings of frame parameters.
281 282 283
React to settings of `initial-frame-alist',
`window-system-default-frame-alist' and `default-frame-alist'
there (in decreasing order of priority)."
284
  ;; Make menu-bar-mode and default-frame-alist consistent.
285 286 287 288 289 290 291
  (when (boundp 'menu-bar-mode)
    (let ((default (assq 'menu-bar-lines default-frame-alist)))
      (if default
	  (setq menu-bar-mode (not (eq (cdr default) 0)))
	(setq default-frame-alist
	      (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
		    default-frame-alist)))))
Sam Steingold's avatar
Sam Steingold committed
292

293 294 295
  ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
  ;; it in batch mode since that would leave a tool-bar-lines
  ;; parameter in default-frame-alist in a dumped Emacs, which is not
296
  ;; what we want.
297
  (when (and (boundp 'tool-bar-mode)
298
 	     (not noninteractive))
299 300
    (let ((default (assq 'tool-bar-lines default-frame-alist)))
      (if default
301 302 303 304 305 306 307 308 309 310 311 312
 	  (setq tool-bar-mode (not (eq (cdr default) 0)))
	;; If Emacs was started on a tty, changing default-frame-alist
	;; would disable the toolbar on X frames created later.  We
	;; want to keep the default of showing a toolbar under X even
	;; in this case.
	;;
	;; If the user explicitly called `tool-bar-mode' in .emacs,
	;; then default-frame-alist is already changed anyway.
	(when initial-window-system
	  (setq default-frame-alist
		(cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
		      default-frame-alist))))))
313

314 315 316 317 318
  ;; Creating and deleting frames may shift the selected frame around,
  ;; and thus the current buffer.  Protect against that.  We don't
  ;; want to use save-excursion here, because that may also try to set
  ;; the buffer of the selected window, which fails when the selected
  ;; window is the minibuffer.
319
  (let ((old-buffer (current-buffer))
Stefan Monnier's avatar
Stefan Monnier committed
320 321 322
	(window-system-frame-alist
         (cdr (assq initial-window-system
                    window-system-default-frame-alist))))
323

324 325
    (when (and frame-notice-user-settings
	       (null frame-initial-frame))
326 327
      ;; This case happens when we don't have a window system, and
      ;; also for MS-DOS frames.
328 329 330 331 332 333
      (let ((parms (frame-parameters frame-initial-frame)))
	;; Don't change the frame names.
	(setq parms (delq (assq 'name parms) parms))
	;; Can't modify the minibuffer parameter, so don't try.
	(setq parms (delq (assq 'minibuffer parms) parms))
	(modify-frame-parameters nil
334
				 (if (null initial-window-system)
335
				     (append initial-frame-alist
336
					     window-system-frame-alist
337 338 339 340 341 342 343
					     default-frame-alist
					     parms
					     nil)
				   ;; initial-frame-alist and
				   ;; default-frame-alist were already
				   ;; applied in pc-win.el.
				   parms))
344
	(if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
345 346 347 348 349 350 351 352 353 354 355
	    (let ((newparms (frame-parameters))
		  (frame (selected-frame)))
	      (tty-handle-reverse-video frame newparms)
	      ;; If we changed the background color, we need to update
	      ;; the background-mode parameter, and maybe some faces,
	      ;; too.
	      (when (assq 'background-color newparms)
		(unless (or (assq 'background-mode initial-frame-alist)
			    (assq 'background-mode default-frame-alist))
		  (frame-set-background-mode frame))
		(face-set-after-frame-default frame))))))
356

357 358
    ;; If the initial frame is still around, apply initial-frame-alist
    ;; and default-frame-alist to it.
359 360 361 362 363
    (when (frame-live-p frame-initial-frame)

      ;; When tool-bar has been switched off, correct the frame size
      ;; by the lines added in x-create-frame for the tool-bar and
      ;; switch `tool-bar-mode' off.
364 365
      (when (display-graphic-p)
	(let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
366
				  (assq 'tool-bar-lines window-system-frame-alist)
367
				  (assq 'tool-bar-lines default-frame-alist))))
368 369 370 371
	  (when (and tool-bar-originally-present
                     (or (null tool-bar-lines)
                         (null (cdr tool-bar-lines))
                         (eq 0 (cdr tool-bar-lines))))
372
	    (let* ((char-height (frame-char-height frame-initial-frame))
373
		   (image-height tool-bar-images-pixel-height)
374 375 376 377 378 379 380 381 382 383 384
		   (margin (cond ((and (consp tool-bar-button-margin)
				       (integerp (cdr tool-bar-button-margin))
				       (> tool-bar-button-margin 0))
				  (cdr tool-bar-button-margin))
				 ((and (integerp tool-bar-button-margin)
				       (> tool-bar-button-margin 0))
				  tool-bar-button-margin)
				 (t 0)))
		   (relief (if (and (integerp tool-bar-button-relief)
				    (> tool-bar-button-relief 0))
			       tool-bar-button-relief 3))
Sam Steingold's avatar
Sam Steingold committed
385
		   (lines (/ (+ image-height
386 387 388 389 390 391
				(* 2 margin)
				(* 2 relief)
				(1- char-height))
			     char-height))
		   (height (frame-parameter frame-initial-frame 'height))
		   (newparms (list (cons 'height (- height lines))))
Sam Steingold's avatar
Sam Steingold committed
392
		   (initial-top (cdr (assq 'top
393 394 395
					   frame-initial-geometry-arguments)))
		   (top (frame-parameter frame-initial-frame 'top)))
	      (when (and (consp initial-top) (eq '- (car initial-top)))
396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411
		(let ((adjusted-top
		       (cond ((and (consp top)
				   (eq '+ (car top)))
			      (list '+
				    (+ (cadr top)
				       (* lines char-height))))
			     ((and (consp top)
				   (eq '- (car top)))
			      (list '-
				    (- (cadr top)
				       (* lines char-height))))
			     (t (+ top (* lines char-height))))))
		  (setq newparms
			(append newparms
				`((top . ,adjusted-top))
				nil))))
412 413
	      (modify-frame-parameters frame-initial-frame newparms)
	      (tool-bar-mode -1)))))
414 415 416 417 418 419 420 421 422 423 424 425

      ;; The initial frame we create above always has a minibuffer.
      ;; If the user wants to remove it, or make it a minibuffer-only
      ;; frame, then we'll have to delete the current frame and make a
      ;; new one; you can't remove or add a root window to/from an
      ;; existing frame.
      ;;
      ;; NOTE: default-frame-alist was nil when we created the
      ;; existing frame.  We need to explicitly include
      ;; default-frame-alist in the parameters of the screen we
      ;; create here, so that its new value, gleaned from the user's
      ;; .emacs file, will be applied to the existing screen.
426
      (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
427
			    (assq 'minibuffer window-system-frame-alist)
428 429 430 431 432 433 434 435 436 437 438 439 440
			    (assq 'minibuffer default-frame-alist)
			    '(minibuffer . t)))
		   t))
	  ;; Create the new frame.
	  (let (parms new)
	    ;; If the frame isn't visible yet, wait till it is.
	    ;; If the user has to position the window,
	    ;; Emacs doesn't know its real position until
	    ;; the frame is seen to be visible.
	    (while (not (cdr (assq 'visibility
				   (frame-parameters frame-initial-frame))))
	      (sleep-for 1))
	    (setq parms (frame-parameters frame-initial-frame))
441

Sam Steingold's avatar
Sam Steingold committed
442
            ;; Get rid of `name' unless it was specified explicitly before.
443 444
	    (or (assq 'name frame-initial-frame-alist)
		(setq parms (delq (assq 'name parms) parms)))
445 446 447
	    ;; An explicit parent-id is a request to XEmbed the frame.
	    (or (assq 'parent-id frame-initial-frame-alist)
                (setq parms (delq (assq 'parent-id parms) parms)))
448 449

	    (setq parms (append initial-frame-alist
450
				window-system-frame-alist
451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485
				default-frame-alist
				parms
				nil))

	    ;; Get rid of `reverse', because that was handled
	    ;; when we first made the frame.
	    (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))

	    (if (assq 'height frame-initial-geometry-arguments)
		(setq parms (assq-delete-all 'height parms)))
	    (if (assq 'width frame-initial-geometry-arguments)
		(setq parms (assq-delete-all 'width parms)))
	    (if (assq 'left frame-initial-geometry-arguments)
		(setq parms (assq-delete-all 'left parms)))
	    (if (assq 'top frame-initial-geometry-arguments)
		(setq parms (assq-delete-all 'top parms)))
	    (setq new
		  (make-frame
		   ;; Use the geometry args that created the existing
		   ;; frame, rather than the parms we get for it.
		   (append frame-initial-geometry-arguments
			   '((user-size . t) (user-position . t))
			   parms)))
	    ;; The initial frame, which we are about to delete, may be
	    ;; the only frame with a minibuffer.  If it is, create a
	    ;; new one.
	    (or (delq frame-initial-frame (minibuffer-frame-list))
		(make-initial-minibuffer-frame nil))

	    ;; If the initial frame is serving as a surrogate
	    ;; minibuffer frame for any frames, we need to wean them
	    ;; onto a new frame.  The default-minibuffer-frame
	    ;; variable must be handled similarly.
	    (let ((users-of-initial
		   (filtered-frame-list
486 487 488 489 490 491
                    (lambda (frame)
                      (and (not (eq frame frame-initial-frame))
                           (eq (window-frame
                                (minibuffer-window frame))
                               frame-initial-frame))))))
              (if (or users-of-initial
492 493 494 495 496 497 498
		      (eq default-minibuffer-frame frame-initial-frame))

		  ;; Choose an appropriate frame.  Prefer frames which
		  ;; are only minibuffers.
		  (let* ((new-surrogate
			  (car
			   (or (filtered-frame-list
499 500 501 502
                                (lambda (frame)
                                  (eq (cdr (assq 'minibuffer
                                                 (frame-parameters frame)))
                                      'only)))
503 504 505 506 507 508 509 510
			       (minibuffer-frame-list))))
			 (new-minibuffer (minibuffer-window new-surrogate)))

		    (if (eq default-minibuffer-frame frame-initial-frame)
			(setq default-minibuffer-frame new-surrogate))

		    ;; Wean the frames using frame-initial-frame as
		    ;; their minibuffer frame.
511 512 513 514 515
		    (dolist (frame users-of-initial)
                      (modify-frame-parameters
                       frame (list (cons 'minibuffer new-minibuffer)))))))

            ;; Redirect events enqueued at this frame to the new frame.
516 517 518 519 520
	    ;; Is this a good idea?
	    (redirect-frame-focus frame-initial-frame new)

	    ;; Finally, get rid of the old frame.
	    (delete-frame frame-initial-frame t))
521 522 523 524 525

	;; Otherwise, we don't need all that rigamarole; just apply
	;; the new parameters.
	(let (newparms allparms tail)
	  (setq allparms (append initial-frame-alist
526
				 window-system-frame-alist
527 528 529 530 531 532 533 534 535 536 537 538
				 default-frame-alist nil))
	  (if (assq 'height frame-initial-geometry-arguments)
	      (setq allparms (assq-delete-all 'height allparms)))
	  (if (assq 'width frame-initial-geometry-arguments)
	      (setq allparms (assq-delete-all 'width allparms)))
	  (if (assq 'left frame-initial-geometry-arguments)
	      (setq allparms (assq-delete-all 'left allparms)))
	  (if (assq 'top frame-initial-geometry-arguments)
	      (setq allparms (assq-delete-all 'top allparms)))
	  (setq tail allparms)
	  ;; Find just the parms that have changed since we first
	  ;; made this frame.  Those are the ones actually set by
Sam Steingold's avatar
Sam Steingold committed
539
          ;; the init file.  For those parms whose values we already knew
540 541
	  ;; (such as those spec'd by command line options)
	  ;; it is undesirable to specify the parm again
Sam Steingold's avatar
Sam Steingold committed
542
          ;; once the user has seen the frame and been able to alter it
543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562
	  ;; manually.
	  (while tail
	    (let (newval oldval)
	      (setq oldval (assq (car (car tail))
				 frame-initial-frame-alist))
	      (setq newval (cdr (assq (car (car tail)) allparms)))
	      (or (and oldval (eq (cdr oldval) newval))
		  (setq newparms
			(cons (cons (car (car tail)) newval) newparms))))
	    (setq tail (cdr tail)))
	  (setq newparms (nreverse newparms))
	  (modify-frame-parameters frame-initial-frame
				   newparms)
	  ;; If we changed the background color,
	  ;; we need to update the background-mode parameter
	  ;; and maybe some faces too.
	  (when (assq 'background-color newparms)
	    (unless (assq 'background-mode newparms)
	      (frame-set-background-mode frame-initial-frame))
	    (face-set-after-frame-default frame-initial-frame)))))
Jim Blandy's avatar
Jim Blandy committed
563

564 565 566 567
    ;; Restore the original buffer.
    (set-buffer old-buffer)

    ;; Make sure the initial frame can be GC'd if it is ever deleted.
568
    ;; Make sure frame-notice-user-settings does nothing if called twice.
569
    (setq frame-notice-user-settings nil)
570
    (setq frame-initial-frame nil)))
Jim Blandy's avatar
Jim Blandy committed
571

572 573 574 575 576 577
(defun make-initial-minibuffer-frame (display)
  (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
    (if display
	(make-frame-on-display display parms)
      (make-frame parms))))

578
;;;; Creation of additional frames, and other frame miscellanea
Jim Blandy's avatar
Jim Blandy committed
579

580
(defun modify-all-frames-parameters (alist)
581
  "Modify all current and future frames' parameters according to ALIST.
582
This changes `default-frame-alist' and possibly `initial-frame-alist'.
583 584
Furthermore, this function removes all parameters in ALIST from
`window-system-default-frame-alist'.
585
See help of `modify-frame-parameters' for more information."
586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601
  (dolist (frame (frame-list))
    (modify-frame-parameters frame alist))

  (dolist (pair alist) ;; conses to add/replace
    ;; initial-frame-alist needs setting only when
    ;; frame-notice-user-settings is true.
    (and frame-notice-user-settings
	 (setq initial-frame-alist
	       (assq-delete-all (car pair) initial-frame-alist)))
    (setq default-frame-alist
	  (assq-delete-all (car pair) default-frame-alist))
    ;; Remove any similar settings from the window-system specific
    ;; parameters---they would override default-frame-alist.
    (dolist (w window-system-default-frame-alist)
      (setcdr w (assq-delete-all (car pair) (cdr w)))))

602 603 604 605
  (and frame-notice-user-settings
       (setq initial-frame-alist (append initial-frame-alist alist)))
  (setq default-frame-alist (append default-frame-alist alist)))

Jim Blandy's avatar
Jim Blandy committed
606
(defun get-other-frame ()
607 608 609
  "Return some frame other than the current frame.
Create one if necessary.  Note that the minibuffer frame, if separate,
is not considered (see `next-frame')."
Jim Blandy's avatar
Jim Blandy committed
610
  (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
611
	       (make-frame)
Jim Blandy's avatar
Jim Blandy committed
612
	     (next-frame (selected-frame)))))
Jim Blandy's avatar
Jim Blandy committed
613 614
    s))

Jim Blandy's avatar
Jim Blandy committed
615 616
(defun next-multiframe-window ()
  "Select the next window, regardless of which frame it is on."
Jim Blandy's avatar
Jim Blandy committed
617 618 619
  (interactive)
  (select-window (next-window (selected-window)
			      (> (minibuffer-depth) 0)
620
			      0))
621
  (select-frame-set-input-focus (selected-frame)))
Jim Blandy's avatar
Jim Blandy committed
622

Jim Blandy's avatar
Jim Blandy committed
623 624
(defun previous-multiframe-window ()
  "Select the previous window, regardless of which frame it is on."
Jim Blandy's avatar
Jim Blandy committed
625 626 627
  (interactive)
  (select-window (previous-window (selected-window)
				  (> (minibuffer-depth) 0)
628
				  0))
629
  (select-frame-set-input-focus (selected-frame)))
Jim Blandy's avatar
Jim Blandy committed
630

631
(declare-function x-initialize-window-system "term/x-win" ())
632
(declare-function ns-initialize-window-system "term/ns-win" ())
633
(defvar x-display-name)                 ; term/x-win
634

635
(defun make-frame-on-display (display &optional parameters)
636 637
  "Make a frame on display DISPLAY.
The optional argument PARAMETERS specifies additional frame parameters."
638
  (interactive "sMake frame on display: ")
639 640 641 642 643 644 645 646 647 648
  (cond ((featurep 'ns)
	 (when (and (boundp 'ns-initialized) (not ns-initialized))
	   (setq x-display-name display)
	   (ns-initialize-window-system))
	 (make-frame `((window-system . ns)
		       (display . ,display) . ,parameters)))
	((eq system-type 'windows-nt)
	 ;; On Windows, ignore DISPLAY.
	 (make-frame parameters))
	(t
649
	 (unless (string-match-p "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
650 651 652 653 654 655
	   (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
	 (when (and (boundp 'x-initialized) (not x-initialized))
	   (setq x-display-name display)
	   (x-initialize-window-system))
	 (make-frame `((window-system . x)
		       (display . ,display) . ,parameters)))))
656

657 658
(declare-function x-close-connection "xfns.c" (terminal))

659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688
(defun close-display-connection (display)
  "Close the connection to a display, deleting all its associated frames.
For DISPLAY, specify either a frame or a display name (a string).
If DISPLAY is nil, that stands for the selected frame's display."
  (interactive
   (list
    (let* ((default (frame-parameter nil 'display))
           (display (completing-read
                     (format "Close display (default %s): " default)
                     (delete-dups
                      (mapcar (lambda (frame)
                                (frame-parameter frame 'display))
                              (frame-list)))
                     nil t nil nil
                     default)))
      (if (zerop (length display)) default display))))
  (let ((frames (delq nil
                      (mapcar (lambda (frame)
                                (if (equal display
                                           (frame-parameter frame 'display))
                                    frame))
                              (frame-list)))))
    (if (and (consp frames)
             (not (y-or-n-p (if (cdr frames)
                                (format "Delete %s frames? " (length frames))
                              (format "Delete %s ? " (car frames))))))
        (error "Abort!")
      (mapc 'delete-frame frames)
      (x-close-connection display))))

689
(defun make-frame-command ()
690 691 692
  "Make a new frame, on the same terminal as the selected frame.
If the terminal is a text-only terminal, this also selects the
new frame."
693
  (interactive)
694
  (if (display-graphic-p)
695 696 697
      (make-frame)
    (select-frame (make-frame))))

698 699 700 701 702 703 704
(defvar before-make-frame-hook nil
  "Functions to run before a frame is created.")

(defvar after-make-frame-functions nil
  "Functions to run after a frame is created.
The functions are run with one arg, the newly created frame.")

705
(defvar after-setting-font-hook nil
706 707
  "Functions to run after a frame's font has been changed.")

708
;; Alias, kept temporarily.
709
(define-obsolete-function-alias 'new-frame 'make-frame "22.1")
Jim Blandy's avatar
Jim Blandy committed
710

711
(defvar frame-inherited-parameters '()
712 713 714
  ;; FIXME: Shouldn't we add `font' here as well?
  "Parameters `make-frame' copies from the `selected-frame' to the new frame.")

715 716 717 718
(defun make-frame (&optional parameters)
  "Return a newly created frame displaying the current buffer.
Optional argument PARAMETERS is an alist of parameters for the new frame.
Each element of PARAMETERS should have the form (NAME . VALUE), for example:
Richard M. Stallman's avatar
Richard M. Stallman committed
719

720
 (name . STRING)	The frame should be named STRING.
Jim Blandy's avatar
Jim Blandy committed
721

722 723
 (width . NUMBER)	The frame should be NUMBER characters in width.
 (height . NUMBER)	The frame should be NUMBER text lines high.
Jim Blandy's avatar
Jim Blandy committed
724

725
You cannot specify either `width' or `height', you must use neither or both.
Jim Blandy's avatar
Jim Blandy committed
726

727 728 729 730
 (minibuffer . t)	The frame should have a minibuffer.
 (minibuffer . nil)	The frame should have no minibuffer.
 (minibuffer . only)	The frame should contain only a minibuffer.
 (minibuffer . WINDOW)	The frame should use WINDOW as its minibuffer window.
Jim Blandy's avatar
Jim Blandy committed
731

732 733 734
 (window-system . nil)	The frame should be displayed on a terminal device.
 (window-system . x)	The frame should be displayed in an X window.

735
 (terminal . ID)          The frame should use the terminal identified by ID.
736

737
Before the frame is created (via `frame-creation-function-alist'), functions on the
738
hook `before-make-frame-hook' are run.  After the frame is created, functions
Luc Teirlinck's avatar
Luc Teirlinck committed
739 740 741 742 743 744 745
on `after-make-frame-functions' are run with one arg, the newly created frame.

This function itself does not make the new frame the selected frame.
The previously selected frame remains selected.  However, the
window system may select the new frame for its own reasons, for
instance if the frame appears under the mouse pointer and your
setup is for focus to follow the pointer."
Jim Blandy's avatar
Jim Blandy committed
746
  (interactive)
747
  (let* ((w (cond
748 749
	     ((assq 'terminal parameters)
	      (let ((type (terminal-live-p (cdr (assq 'terminal parameters)))))
750 751
		(cond
		 ((eq type t) nil)
Stefan Monnier's avatar
Stefan Monnier committed
752 753
		 ((eq type nil) (error "Terminal %s does not exist"
                                       (cdr (assq 'terminal parameters))))
754 755 756 757
		 (t type))))
	     ((assq 'window-system parameters)
	      (cdr (assq 'window-system parameters)))
	     (t window-system)))
758
	 (frame-creation-function (cdr (assq w frame-creation-function-alist)))
759
	 (oldframe (selected-frame))
760 761 762 763
	 frame)
    (unless frame-creation-function
      (error "Don't know how to create a frame on window system %s" w))
    (run-hooks 'before-make-frame-hook)
Stefan Monnier's avatar
Stefan Monnier committed
764 765 766 767
    (setq frame
          (funcall frame-creation-function
                   (append parameters
                           (cdr (assq w window-system-default-frame-alist)))))
768
    (normal-erase-is-backspace-setup-frame frame)
769 770 771 772 773
    ;; Inherit the original frame's parameters.
    (dolist (param frame-inherited-parameters)
      (unless (assq param parameters)   ;Overridden by explicit parameters.
        (let ((val (frame-parameter oldframe param)))
          (when val (set-frame-parameter frame param val)))))
774 775
    (run-hook-with-args 'after-make-frame-functions frame)
    frame))
Jim Blandy's avatar
Jim Blandy committed
776

777 778
(defun filtered-frame-list (predicate)
  "Return a list of all live frames which satisfy PREDICATE."
779 780
  (let* ((frames (frame-list))
	 (list frames))
781
    (while (consp frames)
782 783
      (unless (funcall predicate (car frames))
	(setcar frames nil))
784
      (setq frames (cdr frames)))
785
    (delq nil list)))
786 787 788 789

(defun minibuffer-frame-list ()
  "Return a list of all frames with their own minibuffers."
  (filtered-frame-list
790 791
   (lambda (frame)
     (eq frame (window-frame (minibuffer-window frame))))))
792

793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816
;; Used to be called `terminal-id' in termdev.el.
(defun get-device-terminal (device)
  "Return the terminal corresponding to DEVICE.
DEVICE can be a terminal, a frame, nil (meaning the selected frame's terminal),
the name of an X display device (HOST.SERVER.SCREEN) or a tty device file."
  (cond
   ((or (null device) (framep device))
    (frame-terminal device))
   ((stringp device)
    (let ((f (car (filtered-frame-list
                   (lambda (frame)
                     (or (equal (frame-parameter frame 'display) device)
                         (equal (frame-parameter frame 'tty) device)))))))
      (or f (error "Display %s does not exist" device))
      (frame-terminal f)))
   ((terminal-live-p device) device)
   (t
    (error "Invalid argument %s in `get-device-terminal'" device))))

(defun frames-on-display-list (&optional device)
  "Return a list of all frames on DEVICE.

DEVICE should be a terminal, a frame,
or a name of an X display or tty (a string of the form
817
HOST:SERVER.SCREEN).
818

819
If DEVICE is omitted or nil, it defaults to the selected
820
frame's terminal device."
821
  (let* ((terminal (get-device-terminal device))
822
	 (func #'(lambda (frame)
823
		   (eq (frame-terminal frame) terminal))))
824 825
    (filtered-frame-list func)))

826 827 828 829 830 831
(defun framep-on-display (&optional terminal)
  "Return the type of frames on TERMINAL.
TERMINAL may be a terminal id, a display name or a frame.  If it
is a frame, its type is returned.  If TERMINAL is omitted or nil,
it defaults to the selected frame's terminal device.  All frames
on a given display are of the same type."
832
  (or (terminal-live-p terminal)
833 834
      (framep terminal)
      (framep (car (frames-on-display-list terminal)))))
835

836 837 838
(defun frame-remove-geometry-params (param-list)
  "Return the parameter list PARAM-LIST, but with geometry specs removed.
This deletes all bindings in PARAM-LIST for `top', `left', `width',
839
`height', `user-size' and `user-position' parameters.
840 841 842 843 844 845
Emacs uses this to avoid overriding explicit moves and resizings from
the user during startup."
  (setq param-list (cons nil param-list))
  (let ((tail param-list))
    (while (consp (cdr tail))
      (if (and (consp (car (cdr tail)))
846 847 848 849 850 851
	       (memq (car (car (cdr tail)))
		     '(height width top left user-position user-size)))
	  (progn
	    (setq frame-initial-geometry-arguments
		  (cons (car (cdr tail)) frame-initial-geometry-arguments))
	    (setcdr tail (cdr (cdr tail))))
852
	(setq tail (cdr tail)))))
853 854
  (setq frame-initial-geometry-arguments
	(nreverse frame-initial-geometry-arguments))
855 856
  (cdr param-list))

857 858
(declare-function x-focus-frame "xfns.c" (frame))

859
(defun select-frame-set-input-focus (frame)
860 861 862 863
  "Select FRAME, raise it, and set input focus, if possible.
If `mouse-autoselect-window' is non-nil, also move mouse cursor
to FRAME's selected window.  Otherwise, if `focus-follows-mouse'
is non-nil, move mouse cursor to FRAME."
864 865
  (select-frame frame)
  (raise-frame frame)
866
  ;; Ensure, if possible, that FRAME gets input focus.
867 868
  (when (memq (window-system frame) '(x w32 ns))
    (x-focus-frame frame))
869 870 871 872 873 874 875 876 877 878 879
  ;; Move mouse cursor if necessary.
  (cond
   (mouse-autoselect-window
    (let ((edges (window-inside-edges (frame-selected-window frame))))
      ;; Move mouse cursor into FRAME's selected window to avoid that
      ;; Emacs mouse-autoselects another window.
      (set-mouse-position frame (nth 2 edges) (nth 1 edges))))
   (focus-follows-mouse
    ;; Move mouse cursor into FRAME to avoid that another frame gets
    ;; selected by the window manager.
    (set-mouse-position frame (1- (frame-width frame)) 0))))
880

881
(defun other-frame (arg)
Juanma Barranquero's avatar
Juanma Barranquero committed
882
  "Select the ARGth different visible frame on current display, and raise it.
883 884
All frames are arranged in a cyclic order.
This command selects the frame ARG steps away in that order.
Richard M. Stallman's avatar
Richard M. Stallman committed
885 886 887 888 889 890 891
A negative ARG moves in the opposite order.

To make this command work properly, you must tell Emacs
how the system (or the window manager) generally handles
focus-switching between windows.  If moving the mouse onto a window
selects it (gives it focus), set `focus-follows-mouse' to t.
Otherwise, that variable should be nil."
892 893 894
  (interactive "p")
  (let ((frame (selected-frame)))
    (while (> arg 0)
895 896 897 898
      (setq frame (next-frame frame))
      (while (not (eq (frame-visible-p frame) t))
	(setq frame (next-frame frame)))
      (setq arg (1- arg)))
899
    (while (< arg 0)
900 901 902
      (setq frame (previous-frame frame))
      (while (not (eq (frame-visible-p frame) t))
	(setq frame (previous-frame frame)))
903
      (setq arg (1+ arg)))
904
    (select-frame-set-input-focus frame)))
905

906 907 908 909 910 911 912
(defun iconify-or-deiconify-frame ()
  "Iconify the selected frame, or deiconify if it's currently an icon."
  (interactive)
  (if (eq (cdr (assq 'visibility (frame-parameters))) t)
      (iconify-frame)
    (make-frame-visible)))

913 914
(defun suspend-frame ()
  "Do whatever is right to suspend the current frame.
915 916
Calls `suspend-emacs' if invoked from the controlling tty device,
`suspend-tty' from a secondary tty device, and
917 918 919 920
`iconify-or-deiconify-frame' from an X frame."
  (interactive)
  (let ((type (framep (selected-frame))))
    (cond
921
     ((memq type '(x ns w32)) (iconify-or-deiconify-frame))
922
     ((eq type t)
923
      (if (controlling-tty-p)
924 925
	  (suspend-emacs)
	(suspend-tty)))
926 927
     (t (suspend-emacs)))))

928 929 930 931 932 933 934 935 936 937 938 939 940 941
(defun make-frame-names-alist ()
  (let* ((current-frame (selected-frame))
	 (falist
	  (cons
	   (cons (frame-parameter current-frame 'name) current-frame) nil))
	 (frame (next-frame nil t)))
    (while (not (eq frame current-frame))
      (progn
	(setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
	(setq frame (next-frame frame t))))
    falist))

(defvar frame-name-history nil)
(defun select-frame-by-name (name)
942
  "Select the frame on the current terminal whose name is NAME and raise it.
943 944
If there is no frame by that name, signal an error."
  (interactive
945 946 947 948 949
   (let* ((frame-names-alist (make-frame-names-alist))
	   (default (car (car frame-names-alist)))
	   (input (completing-read
		   (format "Select Frame (default %s): " default)
		   frame-names-alist nil t nil 'frame-name-history)))
950 951 952
     (if (= (length input) 0)
	 (list default)
       (list input))))
953 954
  (let* ((frame-names-alist (make-frame-names-alist))
	 (frame (cdr (assoc name frame-names-alist))))
955 956 957
    (if frame
	(select-frame-set-input-focus frame)
      (error "There is no frame named `%s'" name))))
Jim Blandy's avatar
Jim Blandy committed
958

Jim Blandy's avatar
Jim Blandy committed
959 960 961 962
;;;; Frame configurations

(defun current-frame-configuration ()
  "Return a list describing the positions and states of all frames.
963 964 965 966 967 968 969
Its car is `frame-configuration'.
Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
where
  FRAME is a frame object,
  ALIST is an association list specifying some of FRAME's parameters, and
  WINDOW-CONFIG is a window configuration object for FRAME."
  (cons 'frame-configuration
970 971 972 973
	(mapcar (lambda (frame)
                  (list frame
                        (frame-parameters frame)
                        (current-window-configuration frame)))
974
		(frame-list))))
Jim Blandy's avatar
Jim Blandy committed
975

976
(defun set-frame-configuration (configuration &optional nodelete)
Jim Blandy's avatar
Jim Blandy committed
977 978
  "Restore the frames to the state described by CONFIGURATION.
Each frame listed in CONFIGURATION has its position, size, window
979
configuration, and other parameters set as specified in CONFIGURATION.
980 981
However, this function does not restore deleted frames.

982 983
Ordinarily, this function deletes all existing frames not
listed in CONFIGURATION.  But if optional second argument NODELETE
984
is given and non-nil, the unwanted frames are iconified instead."
985 986 987 988 989
  (or (frame-configuration-p configuration)
      (signal 'wrong-type-argument
	      (list 'frame-configuration-p configuration)))
  (let ((config-alist (cdr configuration))
	frames-to-delete)
990 991 992 993 994 995 996 997 998
    (dolist (frame (frame-list))
      (let ((parameters (assq frame config-alist)))
        (if parameters
            (progn
              (modify-frame-parameters
               frame
               ;; Since we can't set a frame's minibuffer status,
               ;; we might as well omit the parameter altogether.
               (let* ((parms (nth 1 parameters))
Miles Bader's avatar
Miles Bader committed
999 1000 1001 1002 1003 1004 1005 1006 1007
		      (mini (assq 'minibuffer parms))
		      (name (assq 'name parms))
		      (explicit-name (cdr (assq 'explicit-name parms))))
		 (when mini (setq parms (delq mini parms)))
		 ;; Leave name in iff it was set explicitly.
		 ;; This should fix the behavior reported in
		 ;; http://lists.gnu.org/archive/html/emacs-devel/2007-08/msg01632.html
		 (when (and name (not explicit-name))
		   (setq parms (delq name parms)))
1008 1009 1010 1011 1012 1013 1014 1015 1016 1017 1018
                 parms))
              (set-window-configuration (nth 2 parameters)))
          (setq frames-to-delete (cons frame frames-to-delete)))))
    (mapc (if nodelete
              ;; Note: making frames invisible here was tried
              ;; but led to some strange behavior--each time the frame
              ;; was made visible again, the window manager asked afresh
              ;; for where to put it.
              'iconify-frame
            'delete-frame)
          frames-to-delete)))
Jim Blandy's avatar
Jim Blandy committed
1019

Jim Blandy's avatar
Jim Blandy committed
1020 1021
;;;; Convenience functions for accessing and interactively changing
;;;; frame parameters.
Jim Blandy's avatar
Jim Blandy committed
1022

Jim Blandy's avatar
Jim Blandy committed
1023
(defun frame-height (&optional frame)
Jim Blandy's avatar
Jim Blandy committed
1024 1025
  "Return number of lines available for display on FRAME.
If FRAME is omitted, describe the currently selected frame."
Jim Blandy's avatar
Jim Blandy committed
1026
  (cdr (assq 'height (frame-parameters frame))))
Jim Blandy's avatar
Jim Blandy committed
1027 1028 1029 1030

(defun frame-width (&optional frame)
  "Return number of columns available for display on FRAME.
If FRAME is omitted, describe the currently selected frame."
Jim Blandy's avatar
Jim Blandy committed
1031
  (cdr (assq 'width (frame-parameters frame))))
Jim Blandy's avatar
Jim Blandy committed
1032

1033 1034 1035
(declare-function x-list-fonts "xfaces.c"
                  (pattern &optional face frame maximum width))

1036
(define-obsolete-function-alias 'set-default-font 'set-frame-font "23.1")
1037
(defun set-frame-font (font-name &optional keep-size)
1038
  "Set the font of the selected frame to FONT-NAME.
Richard M. Stallman's avatar
Richard M. Stallman committed
1039
When called interactively, prompt for the name of the font to use.
1040 1041 1042
To get the frame's current default font, use `frame-parameters'.

The default behavior is to keep the numbers of lines and columns in
1043
the frame, thus may change its pixel size.  If optional KEEP-SIZE is