macroexp.el 20.6 KB
Newer Older
1
;;; macroexp.el --- Additional macro-expansion support -*- lexical-binding: t; coding: utf-8 -*-
2
;;
Paul Eggert's avatar
Paul Eggert committed
3
;; Copyright (C) 2004-2015 Free Software Foundation, Inc.
4 5 6 7 8 9
;;
;; Author: Miles Bader <miles@gnu.org>
;; Keywords: lisp, compiler, macros

;; This file is part of GNU Emacs.

10
;; GNU Emacs is free software: you can redistribute it and/or modify
11
;; it under the terms of the GNU General Public License as published by
12 13
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
14 15 16 17 18 19 20

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
21
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
22 23 24 25 26 27 28 29 30 31 32 33 34

;;; Commentary:
;;
;; This file contains macro-expansions functions that are not defined in
;; the Lisp core, namely `macroexpand-all', which expands all macros in
;; a form, not just a top-level one.

;;; Code:

;; Bound by the top-level `macroexpand-all', and modified to include any
;; macros defined by `defmacro'.
(defvar macroexpand-all-environment nil)

35
(defun macroexp--cons (car cdr original-cons)
36 37 38 39 40 41 42
  "Return (CAR . CDR), using ORIGINAL-CONS if possible."
  (if (and (eq car (car original-cons)) (eq cdr (cdr original-cons)))
      original-cons
    (cons car cdr)))

;; We use this special macro to iteratively process forms and share list
;; structure of the result with the input.  Doing so recursively using
43
;; `macroexp--cons' results in excessively deep recursion for very long
44
;; input forms.
45
(defmacro macroexp--accumulate (var+list &rest body)
46 47 48 49 50
  "Return a list of the results of evaluating BODY for each element of LIST.
Evaluate BODY with VAR bound to each `car' from LIST, in turn.
Return a list of the values of the final form in BODY.
The list structure of the result will share as much with LIST as
possible (for instance, when BODY just returns VAR unchanged, the
51 52 53
result will be eq to LIST).

\(fn (VAR LIST) BODY...)"
54
  (declare (indent 1))
55 56
  (let ((var (car var+list))
	(list (cadr var+list))
57 58 59 60 61 62 63 64
	(shared (make-symbol "shared"))
	(unshared (make-symbol "unshared"))
	(tail (make-symbol "tail"))
	(new-el (make-symbol "new-el")))
    `(let* ((,shared ,list)
	    (,unshared nil)
	    (,tail ,shared)
	    ,var ,new-el)
65
       (while (consp ,tail)
66 67 68 69 70 71 72 73 74 75
	 (setq ,var (car ,tail)
	       ,new-el (progn ,@body))
	 (unless (eq ,var ,new-el)
	   (while (not (eq ,shared ,tail))
	     (push (pop ,shared) ,unshared))
	   (setq ,shared (cdr ,shared))
	   (push ,new-el ,unshared))
	 (setq ,tail (cdr ,tail)))
       (nconc (nreverse ,unshared) ,shared))))

76
(defun macroexp--all-forms (forms &optional skip)
77 78 79
  "Return FORMS with macros expanded.  FORMS is a list of forms.
If SKIP is non-nil, then don't expand that many elements at the start of
FORMS."
80
  (macroexp--accumulate (form forms)
81
    (if (or (null skip) (zerop skip))
82
	(macroexp--expand-all form)
83 84 85
      (setq skip (1- skip))
      form)))

86
(defun macroexp--all-clauses (clauses &optional skip)
87 88 89 90
  "Return CLAUSES with macros expanded.
CLAUSES is a list of lists of forms; any clause that's not a list is ignored.
If SKIP is non-nil, then don't expand that many elements at the start of
each clause."
91
  (macroexp--accumulate (clause clauses)
92
    (if (listp clause)
93
	(macroexp--all-forms clause skip)
94 95
      clause)))

96 97 98
(defun macroexp--compiler-macro (handler form)
  (condition-case err
      (apply handler form (cdr form))
99 100
    (error
     (message "Compiler-macro error for %S: %S" (car form) err)
101
           form)))
102

103
(defun macroexp--funcall-if-compiled (_form)
104 105 106 107 108
  "Pseudo function used internally by macroexp to delay warnings.
The purpose is to delay warnings to bytecomp.el, so they can use things
like `byte-compile-log-warning' to get better file-and-line-number data
and also to avoid outputting the warning during normal execution."
  nil)
109
(put 'macroexp--funcall-if-compiled 'byte-compile
110
     (lambda (form)
111
       (funcall (eval (cadr form)))
112 113
       (byte-compile-constant nil)))

114 115 116 117 118 119 120 121 122
(defun macroexp--compiling-p ()
  "Return non-nil if we're macroexpanding for the compiler."
  ;; FIXME: ¡¡Major Ugly Hack!! To determine whether the output of this
  ;; macro-expansion will be processed by the byte-compiler, we check
  ;; circumstantial evidence.
  (member '(declare-function . byte-compile-macroexpand-declare-function)
          macroexpand-all-environment))


123 124 125 126
(defun macroexp--warn-and-return (msg form)
  (let ((when-compiled (lambda () (byte-compile-log-warning msg t))))
    (cond
     ((null msg) form)
127
     ((macroexp--compiling-p)
128 129
      `(progn
         (macroexp--funcall-if-compiled ',when-compiled)
130 131
         ,form))
     (t
132 133 134 135
      (message "%s%s" (if (stringp load-file-name)
                          (concat (file-relative-name load-file-name) ": ")
                        "")
               msg)
136 137 138 139 140 141 142 143 144 145
      form))))

(defun macroexp--obsolete-warning (fun obsolescence-data type)
  (let ((instead (car obsolescence-data))
        (asof (nth 2 obsolescence-data)))
    (format "`%s' is an obsolete %s%s%s" fun type
            (if asof (concat " (as of " asof ")") "")
            (cond ((stringp instead) (concat "; " instead))
                  (instead (format "; use `%s' instead." instead))
                  (t ".")))))
Glenn Morris's avatar
Glenn Morris committed
146

147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170
(defun macroexpand-1 (form &optional environment)
  "Perform (at most) one step of macroexpansion."
  (cond
   ((consp form)
    (let* ((head (car form))
           (env-expander (assq head environment)))
      (if env-expander
          (if (cdr env-expander)
              (apply (cdr env-expander) (cdr form))
            form)
        (if (not (and (symbolp head) (fboundp head)))
            form
          (let ((def (autoload-do-load (symbol-function head) head 'macro)))
            (cond
             ;; Follow alias, but only for macros, otherwise we may end up
             ;; skipping an important compiler-macro (e.g. cl--block-wrapper).
             ((and (symbolp def) (macrop def)) (cons def (cdr form)))
             ((not (consp def)) form)
             (t
              (if (eq 'macro (car def))
                  (apply (cdr def) (cdr form))
                form))))))))
   (t form)))

171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190
(defun macroexp-macroexpand (form env)
  "Like `macroexpand' but checking obsolescence."
  (let ((new-form
         (macroexpand form env)))
    (if (and (not (eq form new-form))   ;It was a macro call.
             (car-safe form)
             (symbolp (car form))
             (get (car form) 'byte-obsolete-info)
             (or (not (fboundp 'byte-compile-warning-enabled-p))
                 (byte-compile-warning-enabled-p 'obsolete)))
        (let* ((fun (car form))
               (obsolete (get fun 'byte-obsolete-info)))
          (macroexp--warn-and-return
           (macroexp--obsolete-warning
            fun obsolete
            (if (symbolp (symbol-function fun))
                "alias" "macro"))
           new-form))
      new-form)))

191
(defun macroexp--expand-all (form)
192 193 194
  "Expand all macros in FORM.
This is an internal version of `macroexpand-all'.
Assumes the caller has bound `macroexpand-all-environment'."
195
  (if (eq (car-safe form) 'backquote-list*)
196 197 198 199
      ;; Special-case `backquote-list*', as it is normally a macro that
      ;; generates exceedingly deep expansions from relatively shallow input
      ;; forms.  We just process it `in reverse' -- first we expand all the
      ;; arguments, _then_ we expand the top-level definition.
200
      (macroexpand (macroexp--all-forms form 1)
201 202
		   macroexpand-all-environment)
    ;; Normal form; get its expansion, and then expand arguments.
203
    (setq form (macroexp-macroexpand form macroexpand-all-environment))
204 205
    (pcase form
      (`(cond . ,clauses)
206
       (macroexp--cons 'cond (macroexp--all-clauses clauses) form))
207
      (`(condition-case . ,(or `(,err ,body . ,handlers) dontcare))
208
       (macroexp--cons
209
        'condition-case
210 211 212
        (macroexp--cons err
                    (macroexp--cons (macroexp--expand-all body)
                                (macroexp--all-clauses handlers 1)
213 214 215
                                (cddr form))
                    (cdr form))
        form))
216
      (`(,(or `defvar `defconst) . ,_) (macroexp--all-forms form 2))
217
      (`(function ,(and f `(lambda . ,_)))
218 219
       (macroexp--cons 'function
                   (macroexp--cons (macroexp--all-forms f 2)
220 221 222 223 224
                               nil
                               (cdr form))
                   form))
      (`(,(or `function `quote) . ,_) form)
      (`(,(and fun (or `let `let*)) . ,(or `(,bindings . ,body) dontcare))
225 226 227
       (macroexp--cons fun
                   (macroexp--cons (macroexp--all-clauses bindings 1)
                               (macroexp--all-forms body)
228 229 230 231
                               (cdr form))
                   form))
      (`(,(and fun `(lambda . ,_)) . ,args)
       ;; Embedded lambda in function position.
232 233
       (macroexp--cons (macroexp--all-forms fun 2)
                   (macroexp--all-forms args)
234 235 236 237 238 239 240 241 242
                   form))
      ;; The following few cases are for normal function calls that
      ;; are known to funcall one of their arguments.  The byte
      ;; compiler has traditionally handled these functions specially
      ;; by treating a lambda expression quoted by `quote' as if it
      ;; were quoted by `function'.  We make the same transformation
      ;; here, so that any code that cares about the difference will
      ;; see the same transformation.
      ;; First arg is a function:
243
      (`(,(and fun (or `funcall `apply `mapcar `mapatoms `mapconcat `mapc))
Stefan Monnier's avatar
Stefan Monnier committed
244
         ',(and f `(lambda . ,_)) . ,args)
245
       (macroexp--warn-and-return
246 247
        (format "%s quoted with ' rather than with #'"
                (list 'lambda (nth 1 f) '...))
248
        (macroexp--expand-all `(,fun ,f . ,args))))
249
      ;; Second arg is a function:
Stefan Monnier's avatar
Stefan Monnier committed
250
      (`(,(and fun (or `sort)) ,arg1 ',(and f `(lambda . ,_)) . ,args)
251
       (macroexp--warn-and-return
252 253
        (format "%s quoted with ' rather than with #'"
                (list 'lambda (nth 1 f) '...))
254
        (macroexp--expand-all `(,fun ,arg1 ,f . ,args))))
255
      (`(funcall (,(or 'quote 'function) ,(and f (pred symbolp)) . ,_) . ,args)
256 257 258
       ;; Rewrite (funcall #'foo bar) to (foo bar), in case `foo'
       ;; has a compiler-macro.
       (macroexp--expand-all `(,f . ,args)))
259 260 261 262
      (`(,func . ,_)
       ;; Macro expand compiler macros.  This cannot be delayed to
       ;; byte-optimize-form because the output of the compiler-macro can
       ;; use macros.
263
       (let ((handler (function-get func 'compiler-macro)))
264 265 266 267
         (if (null handler)
             ;; No compiler macro.  We just expand each argument (for
             ;; setq/setq-default this works alright because the variable names
             ;; are symbols).
268
             (macroexp--all-forms form 1)
269 270
           ;; If the handler is not loaded yet, try (auto)loading the
           ;; function itself, which may in turn load the handler.
271
           (unless (functionp handler)
272
             (with-demoted-errors "macroexp--expand-all: %S"
273
               (autoload-do-load (indirect-function func) func)))
274
           (let ((newform (macroexp--compiler-macro handler form)))
275 276
             (if (eq form newform)
                 ;; The compiler macro did not find anything to do.
277
                 (if (equal form (setq newform (macroexp--all-forms form 1)))
278 279 280
                     form
                   ;; Maybe after processing the args, some new opportunities
                   ;; appeared, so let's try the compiler macro again.
281
                   (setq form (macroexp--compiler-macro handler newform))
282
                   (if (eq newform form)
283
                       newform
284 285
                     (macroexp--expand-all newform)))
               (macroexp--expand-all newform))))))
286

287
      (t form))))
288 289 290 291 292 293 294 295

;;;###autoload
(defun macroexpand-all (form &optional environment)
  "Return result of expanding macros at all levels in FORM.
If no macros are expanded, FORM is returned unchanged.
The second optional arg ENVIRONMENT specifies an environment of macro
definitions to shadow the loaded ones for use in file byte-compilation."
  (let ((macroexpand-all-environment environment))
296
    (macroexp--expand-all form)))
297

298 299
;;; Handy functions to use in macros.

300 301 302 303 304 305 306 307 308 309
(defun macroexp-parse-body (body)
  "Parse a function BODY into (DECLARATIONS . EXPS)."
  (let ((decls ()))
    (while (and (cdr body)
                (let ((e (car body)))
                  (or (stringp e)
                      (memq (car-safe e)
                            '(:documentation declare interactive cl-declare)))))
      (push (pop body) decls))
    (cons (nreverse decls) body)))
Leo Liu's avatar
Leo Liu committed
310

311 312 313 314
(defun macroexp-progn (exps)
  "Return an expression equivalent to `(progn ,@EXPS)."
  (if (cdr exps) `(progn ,@exps) (car exps)))

315 316 317 318
(defun macroexp-unprogn (exp)
  "Turn EXP into a list of expressions to execute in sequence."
  (if (eq (car-safe exp) 'progn) (cdr exp) (list exp)))

319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343
(defun macroexp-let* (bindings exp)
  "Return an expression equivalent to `(let* ,bindings ,exp)."
  (cond
   ((null bindings) exp)
   ((eq 'let* (car-safe exp)) `(let* (,@bindings ,@(cadr exp)) ,@(cddr exp)))
   (t `(let* ,bindings ,exp))))

(defun macroexp-if (test then else)
  "Return an expression equivalent to `(if ,test ,then ,else)."
  (cond
   ((eq (car-safe else) 'if)
    (if (equal test (nth 1 else))
        ;; Doing a test a second time: get rid of the redundancy.
        `(if ,test ,then ,@(nthcdr 3 else))
      `(cond (,test ,then)
             (,(nth 1 else) ,(nth 2 else))
             (t ,@(nthcdr 3 else)))))
   ((eq (car-safe else) 'cond)
    `(cond (,test ,then)
           ;; Doing a test a second time: get rid of the redundancy, as above.
           ,@(remove (assoc test else) (cdr else))))
   ;; Invert the test if that lets us reduce the depth of the tree.
   ((memq (car-safe then) '(if cond)) (macroexp-if `(not ,test) else then))
   (t `(if ,test ,then ,else))))

344
(defmacro macroexp-let2 (test var exp &rest exps)
345 346 347 348 349
  "Bind VAR to a copyable expression that returns the value of EXP.
This is like `(let ((v ,EXP)) ,EXPS) except that `v' is a new generated
symbol which EXPS can find in VAR.
TEST should be the name of a predicate on EXP checking whether the `let' can
be skipped; if nil, as is usual, `macroexp-const-p' is used."
350
  (declare (indent 3) (debug (sexp sexp form body)))
351 352 353
  (let ((bodysym (make-symbol "body"))
        (expsym (make-symbol "exp")))
    `(let* ((,expsym ,exp)
354
            (,var (if (funcall #',(or test #'macroexp-const-p) ,expsym)
Stefan Monnier's avatar
Stefan Monnier committed
355
                      ,expsym (make-symbol ,(symbol-name var))))
356 357 358 359 360
            (,bodysym ,(macroexp-progn exps)))
       (if (eq ,var ,expsym) ,bodysym
         (macroexp-let* (list (list ,var ,expsym))
                        ,bodysym)))))

Leo Liu's avatar
Leo Liu committed
361 362 363 364 365 366 367 368 369
(defmacro macroexp-let2* (test bindings &rest body)
  "Bind each binding in BINDINGS as `macroexp-let2' does."
  (declare (indent 2) (debug (sexp (&rest (sexp form)) body)))
  (pcase-exhaustive bindings
    (`nil (macroexp-progn body))
    (`((,var ,exp) . ,tl)
     `(macroexp-let2 ,test ,var ,exp
        (macroexp-let2* ,test ,tl ,@body)))))

370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390
(defun macroexp--maxsize (exp size)
  (cond ((< size 0) size)
        ((symbolp exp) (1- size))
        ((stringp exp) (- size (/ (length exp) 16)))
        ((vectorp exp)
         (dotimes (i (length exp))
           (setq size (macroexp--maxsize (aref exp i) size)))
         (1- size))
        ((consp exp)
         ;; We could try to be more clever with quote&function,
         ;; but it is difficult to do so correctly, and it's not obvious that
         ;; it would be worth the effort.
         (dolist (e exp)
           (setq size (macroexp--maxsize e size)))
         (1- size))
        (t -1)))

(defun macroexp-small-p (exp)
  "Return non-nil if EXP can be considered small."
  (> (macroexp--maxsize exp 10) 0))

391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420
(defsubst macroexp--const-symbol-p (symbol &optional any-value)
  "Non-nil if SYMBOL is constant.
If ANY-VALUE is nil, only return non-nil if the value of the symbol is the
symbol itself."
  (or (memq symbol '(nil t))
      (keywordp symbol)
      (if any-value
	  (or (memq symbol byte-compile-const-variables)
	      ;; FIXME: We should provide a less intrusive way to find out
	      ;; if a variable is "constant".
	      (and (boundp symbol)
		   (condition-case nil
		       (progn (set symbol (symbol-value symbol)) nil)
		     (setting-constant t)))))))

(defun macroexp-const-p (exp)
  "Return non-nil if EXP will always evaluate to the same value."
  (cond ((consp exp) (or (eq (car exp) 'quote)
                         (and (eq (car exp) 'function)
                              (symbolp (cadr exp)))))
        ;; It would sometimes make sense to pass `any-value', but it's not
        ;; always safe since a "constant" variable may not actually always have
        ;; the same value.
        ((symbolp exp) (macroexp--const-symbol-p exp))
        (t t)))

(defun macroexp-copyable-p (exp)
  "Return non-nil if EXP can be copied without extra cost."
  (or (symbolp exp) (macroexp-const-p exp)))

421
(defun macroexp-quote (v)
422
  "Return an expression E such that `(eval E)' is V.
423 424 425 426 427 428 429 430 431 432

E is either V or (quote V) depending on whether V evaluates to
itself or not."
  (if (and (not (consp v))
	   (or (keywordp v)
	       (not (symbolp v))
	       (memq v '(nil t))))
      v
    (list 'quote v)))

433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467
;;; Load-time macro-expansion.

;; Because macro-expansion used to be more lazy, eager macro-expansion
;; tends to bump into previously harmless/unnoticeable cyclic-dependencies.
;; So, we have to delay macro-expansion like we used to when we detect
;; such a cycle, and we also want to help coders resolve those cycles (since
;; they can be non-obvious) by providing a usefully trimmed backtrace
;; (hopefully) highlighting the problem.

(defun macroexp--backtrace ()
  "Return the Elisp backtrace, more recent frames first."
  (let ((bt ())
        (i 0))
    (while
        (let ((frame (backtrace-frame i)))
          (when frame
            (push frame bt)
            (setq i (1+ i)))))
    (nreverse bt)))

(defun macroexp--trim-backtrace-frame (frame)
  (pcase frame
    (`(,_ macroexpand (,head . ,_) . ,_) `(macroexpand (,head )))
    (`(,_ internal-macroexpand-for-load (,head ,second . ,_) . ,_)
     (if (or (symbolp second)
             (and (eq 'quote (car-safe second))
                  (symbolp (cadr second))))
         `(macroexpand-all (,head ,second ))
       '(macroexpand-all )))
    (`(,_ load-with-code-conversion ,name . ,_)
     `(load ,(file-name-nondirectory name)))))

(defvar macroexp--pending-eager-loads nil
  "Stack of files currently undergoing eager macro-expansion.")

468
(defun internal-macroexpand-for-load (form full-p)
469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490
  ;; Called from the eager-macroexpansion in readevalloop.
  (cond
   ;; Don't repeat the same warning for every top-level element.
   ((eq 'skip (car macroexp--pending-eager-loads)) form)
   ;; If we detect a cycle, skip macro-expansion for now, and output a warning
   ;; with a trimmed backtrace.
   ((and load-file-name (member load-file-name macroexp--pending-eager-loads))
    (let* ((bt (delq nil
                     (mapcar #'macroexp--trim-backtrace-frame
                             (macroexp--backtrace))))
           (elem `(load ,(file-name-nondirectory load-file-name)))
           (tail (member elem (cdr (member elem bt)))))
      (if tail (setcdr tail (list ')))
      (if (eq (car-safe (car bt)) 'macroexpand-all) (setq bt (cdr bt)))
      (message "Warning: Eager macro-expansion skipped due to cycle:\n  %s"
               (mapconcat #'prin1-to-string (nreverse bt) " => "))
      (push 'skip macroexp--pending-eager-loads)
      form))
   (t
    (condition-case err
        (let ((macroexp--pending-eager-loads
               (cons load-file-name macroexp--pending-eager-loads)))
491 492 493
          (if full-p
              (macroexpand-all form)
            (macroexpand form)))
494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514
      (error
       ;; Hopefully this shouldn't happen thanks to the cycle detection,
       ;; but in case it does happen, let's catch the error and give the
       ;; code a chance to macro-expand later.
       (message "Eager macro-expansion failure: %S" err)
       form)))))

;; ¡¡¡ Big Ugly Hack !!!
;; src/bootstrap-emacs is mostly used to compile .el files, so it needs
;; macroexp, bytecomp, cconv, and byte-opt to be fast.  Generally this is done
;; by compiling those files first, but this only makes a difference if those
;; files are not preloaded.  But macroexp.el is preloaded so we reload it if
;; the current version is interpreted and there's a compiled version available.
(eval-when-compile
  (add-hook 'emacs-startup-hook
            (lambda ()
              (and (not (byte-code-function-p
                         (symbol-function 'macroexpand-all)))
                   (locate-library "macroexp.elc")
                   (load "macroexp.elc")))))

515 516 517
(provide 'macroexp)

;;; macroexp.el ends here