cal-coptic.el 9.71 KB
Newer Older
1
;;; cal-coptic.el --- calendar functions for the Coptic/Ethiopic calendars
Edward M. Reingold's avatar
Edward M. Reingold committed
2

3
;; Copyright (C) 1995, 1997 Free Software Foundation, Inc.
Edward M. Reingold's avatar
Edward M. Reingold committed
4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21

;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
;; Keywords: calendar
;; Human-Keywords: Coptic calendar, Ethiopic calendar, calendar, diary

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
Erik Naggum's avatar
Erik Naggum committed
22 23 24
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.
Edward M. Reingold's avatar
Edward M. Reingold committed
25 26 27 28 29 30

;;; Commentary:

;; This collection of functions implements the features of calendar.el and
;; diary.el that deal with the Coptic and Ethiopic calendars.

31
;; Technical details of all the calendrical calculations can be found in
32 33
;; ``Calendrical Calculations: The Millennium Edition'' by Edward M. Reingold
;; and Nachum Dershowitz, Cambridge University Press (2001).
34

Edward M. Reingold's avatar
Edward M. Reingold committed
35 36 37 38 39 40 41 42 43 44 45
;; Comments, corrections, and improvements should be sent to
;;  Edward M. Reingold               Department of Computer Science
;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
;;                                   Urbana, Illinois 61801

;;; Code:

(require 'cal-julian)

(defvar coptic-calendar-month-name-array
46 47
  ["Tut" "Babah" "Hatur" "Kiyahk" "Tubah" "Amshir" "Baramhat" "Barmundah"
   "Bashans" "Baunah" "Abib" "Misra" "al-Nasi"])
Edward M. Reingold's avatar
Edward M. Reingold committed
48 49 50 51

(defvar coptic-calendar-epoch (calendar-absolute-from-julian '(8 29 284))
  "Absolute date of start of Coptic calendar = August 29, 284 A.D. (Julian).")

52
(defvar coptic-name "Coptic")
Edward M. Reingold's avatar
Edward M. Reingold committed
53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79

(defun coptic-calendar-leap-year-p (year)
  "True if YEAR is a leap year on the Coptic calendar."
  (zerop (mod (1+ year) 4)))

(defun coptic-calendar-last-day-of-month (month year)
  "Return last day of MONTH, YEAR on the Coptic calendar.
The 13th month is not really a month, but the 5 (6 in leap years) day period of
Nisi (Kebus)  at the end of the year."
  (if (< month 13)
      30
    (if (coptic-calendar-leap-year-p year)
        6
      5)))

(defun calendar-absolute-from-coptic (date)
  "Compute absolute date from Coptic date DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
  (let ((month (extract-calendar-month date))
        (day (extract-calendar-day date))
        (year (extract-calendar-year date)))
    (+ (1- coptic-calendar-epoch);; Days before start of calendar
       (* 365 (1- year))         ;; Days in prior years
       (/ year 4)                ;; Leap days in prior years
       (* 30 (1- month))         ;; Days in prior months this year
       day)))                    ;; Days so far this month
80

Edward M. Reingold's avatar
Edward M. Reingold committed
81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132

(defun calendar-coptic-from-absolute (date)
  "Compute the Coptic equivalent for absolute date DATE.
The result is a list of the form (MONTH DAY YEAR).
The absolute date is the number of days elapsed since the imaginary
Gregorian date Sunday, December 31, 1 BC."
  (if (< date coptic-calendar-epoch)
      (list 0 0 0);; pre-Coptic date
    (let* ((approx (/ (- date coptic-calendar-epoch)
                      366))   ;; Approximation from below.
           (year              ;; Search forward from the approximation.
            (+ approx
               (calendar-sum y approx
                 (>= date (calendar-absolute-from-coptic (list 1 1 (1+ y))))
                 1)))
           (month             ;; Search forward from Tot.
            (1+ (calendar-sum m 1
                  (> date
                     (calendar-absolute-from-coptic
                      (list m
                            (coptic-calendar-last-day-of-month m year)
                            year)))
                  1)))
           (day                ;; Calculate the day by subtraction.
            (- date
               (1- (calendar-absolute-from-coptic (list month 1 year))))))
    (list month day year))))

(defun calendar-coptic-date-string (&optional date)
  "String of Coptic date of Gregorian DATE.
Returns the empty string if DATE is pre-Coptic calendar.
Defaults to today's date if DATE is not given."
  (let* ((coptic-date (calendar-coptic-from-absolute
                       (calendar-absolute-from-gregorian
                        (or date (calendar-current-date)))))
         (y (extract-calendar-year coptic-date))
         (m (extract-calendar-month coptic-date)))
    (if (< y 1)
        ""
      (let ((monthname (aref coptic-calendar-month-name-array (1- m)))
            (day (int-to-string (extract-calendar-day coptic-date)))
            (dayname nil)
            (month (int-to-string m))
            (year (int-to-string y)))
        (mapconcat 'eval calendar-date-display-form "")))))

(defun calendar-print-coptic-date ()
  "Show the Coptic calendar equivalent of the selected date."
  (interactive)
  (let ((f (calendar-coptic-date-string (calendar-cursor-to-date t))))
    (if (string-equal f "")
        (message "Date is pre-%s calendar" coptic-name)
133
      (message "%s date: %s" coptic-name f))))
Edward M. Reingold's avatar
Edward M. Reingold committed
134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153

(defun calendar-goto-coptic-date (date &optional noecho)
  "Move cursor to Coptic date DATE.
Echo Coptic date unless NOECHO is t."
  (interactive (coptic-prompt-for-date))
  (calendar-goto-date (calendar-gregorian-from-absolute
                       (calendar-absolute-from-coptic date)))
  (or noecho (calendar-print-coptic-date)))

(defun coptic-prompt-for-date ()
  "Ask for a Coptic date."
  (let* ((today (calendar-current-date))
         (year (calendar-read
                (format "%s calendar year (>0): " coptic-name)
                '(lambda (x) (> x 0))
                (int-to-string
                 (extract-calendar-year
                  (calendar-coptic-from-absolute
                   (calendar-absolute-from-gregorian today))))))
         (completion-ignore-case t)
154
         (month (cdr (assoc-string
155 156 157 158 159
                      (completing-read
                       (format "%s calendar month name: " coptic-name)
                       (mapcar 'list
                               (append coptic-calendar-month-name-array nil))
                       nil t)
Edward M. Reingold's avatar
Edward M. Reingold committed
160
                      (calendar-make-alist coptic-calendar-month-name-array
161
                                           1) t)))
Edward M. Reingold's avatar
Edward M. Reingold committed
162 163 164 165 166 167 168 169
         (last (coptic-calendar-last-day-of-month month year))
         (day (calendar-read
               (format "%s calendar day (1-%d): " coptic-name last)
               '(lambda (x) (and (< 0 x) (<= x last))))))
    (list (list month day year))))

(defun diary-coptic-date ()
  "Coptic calendar equivalent of date diary entry."
170
  (let ((f (calendar-coptic-date-string date)))
Edward M. Reingold's avatar
Edward M. Reingold committed
171 172
    (if (string-equal f "")
        (format "Date is pre-%s calendar" coptic-name)
173
      (format "%s date: %s" coptic-name f))))
Edward M. Reingold's avatar
Edward M. Reingold committed
174 175

(defconst ethiopic-calendar-month-name-array
176 177
  ["Maskaram" "Teqemt" "Khedar" "Takhsas" "Ter" "Yakatit" "Magabit" "Miyazya"
   "Genbot" "Sane" "Hamle" "Nahas" "Paguem"])
Edward M. Reingold's avatar
Edward M. Reingold committed
178

179 180
(defconst ethiopic-calendar-epoch 2796
  "Absolute date of start of Ethiopic calendar = August 29, 8 C.E. (Julian).")
Edward M. Reingold's avatar
Edward M. Reingold committed
181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236

(defconst ethiopic-name "Ethiopic")

(defun calendar-absolute-from-ethiopic (date)
  "Compute absolute date from Ethiopic date DATE.
The absolute date is the number of days elapsed since the (imaginary)
Gregorian date Sunday, December 31, 1 BC."
  (let ((coptic-calendar-epoch ethiopic-calendar-epoch))
    (calendar-absolute-from-coptic date)))

(defun calendar-ethiopic-from-absolute (date)
  "Compute the Ethiopic equivalent for absolute date DATE.
The result is a list of the form (MONTH DAY YEAR).
The absolute date is the number of days elapsed since the imaginary
Gregorian date Sunday, December 31, 1 BC."
  (let ((coptic-calendar-epoch ethiopic-calendar-epoch))
    (calendar-coptic-from-absolute date)))

(defun calendar-ethiopic-date-string (&optional date)
  "String of Ethiopic date of Gregorian DATE.
Returns the empty string if DATE is pre-Ethiopic calendar.
Defaults to today's date if DATE is not given."
  (let ((coptic-calendar-epoch ethiopic-calendar-epoch)
        (coptic-name ethiopic-name)
        (coptic-calendar-month-name-array ethiopic-calendar-month-name-array))
    (calendar-coptic-date-string date)))

(defun calendar-print-ethiopic-date ()
  "Show the Ethiopic calendar equivalent of the selected date."
  (interactive)
  (let ((coptic-calendar-epoch ethiopic-calendar-epoch)
        (coptic-name ethiopic-name)
        (coptic-calendar-month-name-array ethiopic-calendar-month-name-array))
    (call-interactively 'calendar-print-coptic-date)))

(defun calendar-goto-ethiopic-date (date &optional noecho)
  "Move cursor to Ethiopic date DATE.
Echo Ethiopic date unless NOECHO is t."
  (interactive
   (let ((coptic-calendar-epoch ethiopic-calendar-epoch)
         (coptic-name ethiopic-name)
         (coptic-calendar-month-name-array ethiopic-calendar-month-name-array))
     (coptic-prompt-for-date)))
  (calendar-goto-date (calendar-gregorian-from-absolute
                       (calendar-absolute-from-ethiopic date)))
  (or noecho (calendar-print-ethiopic-date)))

(defun diary-ethiopic-date ()
  "Ethiopic calendar equivalent of date diary entry."
  (let ((coptic-calendar-epoch ethiopic-calendar-epoch)
        (coptic-name ethiopic-name)
        (coptic-calendar-month-name-array ethiopic-calendar-month-name-array))
    (diary-coptic-date)))

(provide 'cal-coptic)

Miles Bader's avatar
Miles Bader committed
237
;;; arch-tag: 72d49161-25df-4072-9312-b182cdca7627
Edward M. Reingold's avatar
Edward M. Reingold committed
238
;;; cal-coptic.el ends here