Initial revision

lisp/calendar/cal-coptic.el

+;;; cal-coptic.el --- calendar functions for the Coptic/Ethiopic calendars.
+
+;; Copyright (C) 1995 Free Software Foundation, Inc.
+
+;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
+;; Keywords: calendar
+;; Human-Keywords: Coptic calendar, Ethiopic calendar, calendar, diary
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to
+;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
+
+;;; Commentary:
+
+;; This collection of functions implements the features of calendar.el and
+;; diary.el that deal with the Coptic and Ethiopic calendars.
+
+;; Comments, corrections, and improvements should be sent to
+;;  Edward M. Reingold               Department of Computer Science
+;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
+;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
+;;                                   Urbana, Illinois 61801
+
+;;; Code:
+
+(require 'cal-julian)
+
+(defvar coptic-calendar-month-name-array
+  ["Tot" "Babe" "Hatur" "Kihak" "Tube" "Amshir" "Baramhat" "Barmuda"
+   "Bashnas" "Bauna" "Abib" "Misra" "Nisi"])
+
+(defvar coptic-calendar-epoch (calendar-absolute-from-julian '(8 29 284))
+  "Absolute date of start of Coptic calendar = August 29, 284 A.D. (Julian).")
+
+(defconst coptic-name "Coptic")
+
+(defun coptic-calendar-leap-year-p (year)
+  "True if YEAR is a leap year on the Coptic calendar."
+  (zerop (mod (1+ year) 4)))
+
+(defun coptic-calendar-last-day-of-month (month year)
+  "Return last day of MONTH, YEAR on the Coptic calendar.
+The 13th month is not really a month, but the 5 (6 in leap years) day period of
+Nisi (Kebus)  at the end of the year."
+  (if (< month 13)
+      30
+    (if (coptic-calendar-leap-year-p year)
+        6
+      5)))
+
+(defun calendar-absolute-from-coptic (date)
+  "Compute absolute date from Coptic date DATE.
+The absolute date is the number of days elapsed since the (imaginary)
+Gregorian date Sunday, December 31, 1 BC."
+  (let ((month (extract-calendar-month date))
+        (day (extract-calendar-day date))
+        (year (extract-calendar-year date)))
+    (+ (1- coptic-calendar-epoch);; Days before start of calendar
+       (* 365 (1- year))         ;; Days in prior years
+       (/ year 4)                ;; Leap days in prior years
+       (* 30 (1- month))         ;; Days in prior months this year
+       day)))                    ;; Days so far this month
+       
+
+(defun calendar-coptic-from-absolute (date)
+  "Compute the Coptic equivalent for absolute date DATE.
+The result is a list of the form (MONTH DAY YEAR).
+The absolute date is the number of days elapsed since the imaginary
+Gregorian date Sunday, December 31, 1 BC."
+  (if (< date coptic-calendar-epoch)
+      (list 0 0 0);; pre-Coptic date
+    (let* ((approx (/ (- date coptic-calendar-epoch)
+                      366))   ;; Approximation from below.
+           (year              ;; Search forward from the approximation.
+            (+ approx
+               (calendar-sum y approx
+                 (>= date (calendar-absolute-from-coptic (list 1 1 (1+ y))))
+                 1)))
+           (month             ;; Search forward from Tot.
+            (1+ (calendar-sum m 1
+                  (> date
+                     (calendar-absolute-from-coptic
+                      (list m
+                            (coptic-calendar-last-day-of-month m year)
+                            year)))
+                  1)))
+           (day                ;; Calculate the day by subtraction.
+            (- date
+               (1- (calendar-absolute-from-coptic (list month 1 year))))))
+    (list month day year))))
+
+(defun calendar-coptic-date-string (&optional date)
+  "String of Coptic date of Gregorian DATE.
+Returns the empty string if DATE is pre-Coptic calendar.
+Defaults to today's date if DATE is not given."
+  (let* ((coptic-date (calendar-coptic-from-absolute
+                       (calendar-absolute-from-gregorian
+                        (or date (calendar-current-date)))))
+         (y (extract-calendar-year coptic-date))
+         (m (extract-calendar-month coptic-date)))
+    (if (< y 1)
+        ""
+      (let ((monthname (aref coptic-calendar-month-name-array (1- m)))
+            (day (int-to-string (extract-calendar-day coptic-date)))
+            (dayname nil)
+            (month (int-to-string m))
+            (year (int-to-string y)))
+        (mapconcat 'eval calendar-date-display-form "")))))
+
+(defun calendar-print-coptic-date ()
+  "Show the Coptic calendar equivalent of the selected date."
+  (interactive)
+  (let ((f (calendar-coptic-date-string (calendar-cursor-to-date t))))
+    (if (string-equal f "")
+        (message "Date is pre-%s calendar" coptic-name)
+      (message f))))
+
+(defun calendar-goto-coptic-date (date &optional noecho)
+  "Move cursor to Coptic date DATE.
+Echo Coptic date unless NOECHO is t."
+  (interactive (coptic-prompt-for-date))
+  (calendar-goto-date (calendar-gregorian-from-absolute
+                       (calendar-absolute-from-coptic date)))
+  (or noecho (calendar-print-coptic-date)))
+
+(defun coptic-prompt-for-date ()
+  "Ask for a Coptic date."
+  (let* ((today (calendar-current-date))
+         (year (calendar-read
+                (format "%s calendar year (>0): " coptic-name)
+                '(lambda (x) (> x 0))
+                (int-to-string
+                 (extract-calendar-year
+                  (calendar-coptic-from-absolute
+                   (calendar-absolute-from-gregorian today))))))
+         (completion-ignore-case t)
+         (month (cdr (assoc
+                      (capitalize
+                       (completing-read
+                        (format "%s calendar month name: " coptic-name)
+                        (mapcar 'list
+                                (append coptic-calendar-month-name-array nil))
+                        nil t))
+                      (calendar-make-alist coptic-calendar-month-name-array
+                                           1 'capitalize))))
+         (last (coptic-calendar-last-day-of-month month year))
+         (day (calendar-read
+               (format "%s calendar day (1-%d): " coptic-name last)
+               '(lambda (x) (and (< 0 x) (<= x last))))))
+    (list (list month day year))))
+
+(defun diary-coptic-date ()
+  "Coptic calendar equivalent of date diary entry."
+  (let ((f (calendar-coptic-date-string (calendar-cursor-to-date t))))
+    (if (string-equal f "")
+        (format "Date is pre-%s calendar" coptic-name)
+      f)))
+
+(defconst ethiopic-calendar-month-name-array
+  ["Maskarram" "Tekemt" "Hadar" "Tahsas" "Tarr" "Yekatit" "Magawit" "Miaziah"
+   "Genbot" "Sanni" "Hamle" "Nas'hi" "Pagnem"])
+
+(defconst ethiopic-calendar-epoch (calendar-absolute-from-julian '(8 29 7))
+  "Absolute date of start of Ethiopic calendar = August 29, 7 A.D. (Julian).")
+
+(defconst ethiopic-name "Ethiopic")
+
+(defun calendar-absolute-from-ethiopic (date)
+  "Compute absolute date from Ethiopic date DATE.
+The absolute date is the number of days elapsed since the (imaginary)
+Gregorian date Sunday, December 31, 1 BC."
+  (let ((coptic-calendar-epoch ethiopic-calendar-epoch))
+    (calendar-absolute-from-coptic date)))
+
+(defun calendar-ethiopic-from-absolute (date)
+  "Compute the Ethiopic equivalent for absolute date DATE.
+The result is a list of the form (MONTH DAY YEAR).
+The absolute date is the number of days elapsed since the imaginary
+Gregorian date Sunday, December 31, 1 BC."
+  (let ((coptic-calendar-epoch ethiopic-calendar-epoch))
+    (calendar-coptic-from-absolute date)))
+
+(defun calendar-ethiopic-date-string (&optional date)
+  "String of Ethiopic date of Gregorian DATE.
+Returns the empty string if DATE is pre-Ethiopic calendar.
+Defaults to today's date if DATE is not given."
+  (let ((coptic-calendar-epoch ethiopic-calendar-epoch)
+        (coptic-name ethiopic-name)
+        (coptic-calendar-month-name-array ethiopic-calendar-month-name-array))
+    (calendar-coptic-date-string date)))
+
+(defun calendar-print-ethiopic-date ()
+  "Show the Ethiopic calendar equivalent of the selected date."
+  (interactive)
+  (let ((coptic-calendar-epoch ethiopic-calendar-epoch)
+        (coptic-name ethiopic-name)
+        (coptic-calendar-month-name-array ethiopic-calendar-month-name-array))
+    (call-interactively 'calendar-print-coptic-date)))
+
+(defun calendar-goto-ethiopic-date (date &optional noecho)
+  "Move cursor to Ethiopic date DATE.
+Echo Ethiopic date unless NOECHO is t."
+  (interactive
+   (let ((coptic-calendar-epoch ethiopic-calendar-epoch)
+         (coptic-name ethiopic-name)
+         (coptic-calendar-month-name-array ethiopic-calendar-month-name-array))
+     (coptic-prompt-for-date)))
+  (calendar-goto-date (calendar-gregorian-from-absolute
+                       (calendar-absolute-from-ethiopic date)))
+  (or noecho (calendar-print-ethiopic-date)))
+
+(defun diary-ethiopic-date ()
+  "Ethiopic calendar equivalent of date diary entry."
+  (let ((coptic-calendar-epoch ethiopic-calendar-epoch)
+        (coptic-name ethiopic-name)
+        (coptic-calendar-month-name-array ethiopic-calendar-month-name-array))
+    (diary-coptic-date)))
+
+(provide 'cal-coptic)
+
+;;; cal-coptic.el ends here

lisp/calendar/cal-iso.el

+;;; cal-iso.el --- calendar functions for the ISO calendar.
+
+;; Copyright (C) 1995 Free Software Foundation, Inc.
+
+;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
+;; Keywords: calendar
+;; Human-Keywords: ISO calendar, calendar, diary
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to
+;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
+
+;;; Commentary:
+
+;; This collection of functions implements the features of calendar.el and
+;; diary.el that deal with the ISO calendar.
+
+;; Comments, corrections, and improvements should be sent to
+;;  Edward M. Reingold               Department of Computer Science
+;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
+;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
+;;                                   Urbana, Illinois 61801
+
+;;; Code:
+
+(require 'calendar)
+
+(defun calendar-absolute-from-iso (date)
+  "The number of days elapsed between the Gregorian date 12/31/1 BC and DATE.
+The `ISO year' corresponds approximately to the Gregorian year, but
+weeks start on Monday and end on Sunday.  The first week of the ISO year is
+the first such week in which at least 4 days are in a year.  The ISO
+commercial DATE has the form (week day year) in which week is in the range
+1..52 and day is in the range 0..6 (1 = Monday, 2 = Tuesday, ..., 0 =
+Sunday).  The Gregorian date Sunday, December 31, 1 BC is imaginary."
+  (let* ((week (extract-calendar-month date))
+         (day (extract-calendar-day date))
+         (year (extract-calendar-year date)))
+    (+ (calendar-dayname-on-or-before
+        1 (+ 3 (calendar-absolute-from-gregorian (list 1 1 year))))
+       (* 7 (1- week))
+       (if (= day 0) 6 (1- day)))))
+
+(defun calendar-iso-from-absolute (date)
+  "Compute the `ISO commercial date' corresponding to the absolute DATE.
+The ISO year corresponds approximately to the Gregorian year, but weeks
+start on Monday and end on Sunday.  The first week of the ISO year is the
+first such week in which at least 4 days are in a year.  The ISO commercial
+date has the form (week day year) in which week is in the range 1..52 and
+day is in the range 0..6 (1 = Monday, 2 = Tuesday, ..., 0 = Sunday).  The
+absolute date is the number of days elapsed since the (imaginary) Gregorian
+date Sunday, December 31, 1 BC."
+  (let* ((approx (extract-calendar-year
+                  (calendar-gregorian-from-absolute (- date 3))))
+         (year (+ approx
+                  (calendar-sum y approx
+                      (>= date (calendar-absolute-from-iso (list 1 1 (1+ y))))
+                      1))))
+    (list
+     (1+ (/ (- date (calendar-absolute-from-iso (list 1 1 year))) 7))
+     (% date 7)
+     year)))
+
+(defun calendar-iso-date-string (&optional date)
+  "String of ISO date of Gregorian DATE.
+Defaults to today's date if DATE is not given."
+  (let* ((d (calendar-absolute-from-gregorian 
+             (or date (calendar-current-date))))
+         (day (% d 7))
+         (iso-date (calendar-iso-from-absolute d)))
+    (format "Day %s of week %d of %d"
+            (if (zerop day) 7 day)
+            (extract-calendar-month iso-date)
+            (extract-calendar-year iso-date))))
+
+(defun calendar-print-iso-date ()
+  "Show equivalent ISO date for the date under the cursor."
+  (interactive)
+  (message "ISO date: %s"
+           (calendar-iso-date-string (calendar-cursor-to-date t))))
+
+(defun calendar-goto-iso-date (date &optional noecho)
+  "Move cursor to ISO DATE; echo ISO date unless NOECHO is t."
+  (interactive
+   (let* ((today (calendar-current-date))
+          (year (calendar-read
+                 "ISO calendar year (>0): "
+                 '(lambda (x) (> x 0))
+                 (int-to-string (extract-calendar-year today))))
+          (no-weeks (extract-calendar-month
+                     (calendar-iso-from-absolute
+                      (1-
+                       (calendar-dayname-on-or-before
+                        1 (calendar-absolute-from-gregorian
+                           (list 1 4 (1+ year))))))))
+          (week (calendar-read
+                 (format "ISO calendar week (1-%d): " no-weeks)
+                 '(lambda (x) (and (> x 0) (<= x no-weeks)))))
+          (day (calendar-read
+                "ISO day (1-7): "
+                '(lambda (x) (and (<= 1 x) (<= x 7))))))
+     (list (list week day year))))
+  (calendar-goto-date (calendar-gregorian-from-absolute
+                       (calendar-absolute-from-iso date)))
+  (or noecho (calendar-print-iso-date)))
+
+(defun diary-iso-date ()
+  "ISO calendar equivalent of date diary entry."
+  (format "ISO date: %s" (calendar-iso-date-string date)))
+
+(provide 'cal-iso)
+
+;;; cal-iso.el ends here

lisp/calendar/cal-julian.el

+;;; cal-julian.el --- calendar functions for the Julian calendar.
+
+;; Copyright (C) 1995 Free Software Foundation, Inc.
+
+;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
+;; Keywords: calendar
+;; Human-Keywords: Julian calendar, Julian day number, calendar, diary
+
+;; This file is part of GNU Emacs.
+
+;; GNU Emacs is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation; either version 2, or (at your option)
+;; any later version.
+
+;; GNU Emacs is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with GNU Emacs; see the file COPYING.  If not, write to
+;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
+
+;;; Commentary:
+
+;; This collection of functions implements the features of calendar.el and
+;; diary.el that deal with the Julian calendar.
+
+;; Comments, corrections, and improvements should be sent to
+;;  Edward M. Reingold               Department of Computer Science
+;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
+;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
+;;                                   Urbana, Illinois 61801
+
+;;; Code:
+
+(require 'calendar)
+
+(defun calendar-julian-from-absolute (date)
+  "Compute the Julian (month day year) corresponding to the absolute DATE.
+The absolute date is the number of days elapsed since the (imaginary)
+Gregorian date Sunday, December 31, 1 BC."
+  (let* ((approx (/ (+ date 2) 366));; Approximation from below.
+         (year        ;; Search forward from the approximation.
+          (+ approx
+             (calendar-sum y approx
+                (>= date (calendar-absolute-from-julian (list 1 1 (1+ y))))
+                1)))
+         (month       ;; Search forward from January.
+          (1+ (calendar-sum m 1
+                 (> date
+                    (calendar-absolute-from-julian
+                     (list m
+                           (if (and (= m 2) (= (% year 4) 0))
+                               29
+                             (aref [31 28 31 30 31 30 31 31 30 31 30 31]
+                                   (1- m)))
+                           year)))
+                 1)))
+         (day         ;; Calculate the day by subtraction.
+          (- date (1- (calendar-absolute-from-julian (list month 1 year))))))
+    (list month day year)))
+
+(defun calendar-absolute-from-julian (date)
+  "The number of days elapsed between the Gregorian date 12/31/1 BC and DATE.
+The Gregorian date Sunday, December 31, 1 BC is imaginary."
+  (let ((month (extract-calendar-month date))
+        (day (extract-calendar-day date))
+        (year (extract-calendar-year date)))
+    (+ (calendar-day-number date)
+       (if (and (= (% year 100) 0)
+                (/= (% year 400) 0)
+                (> month 2))
+           1 0);; Correct for Julian but not Gregorian leap year.
+       (* 365 (1- year))
+       (/ (1- year) 4)
+       -2)))
+
+(defun calendar-julian-date-string (&optional date)
+  "String of Julian date of Gregorian DATE.
+Defaults to today's date if DATE is not given.
+Driven by the variable `calendar-date-display-form'."
+  (calendar-date-string
+   (calendar-julian-from-absolute
+    (calendar-absolute-from-gregorian
+     (or date (calendar-current-date))))
+   nil t))
+
+(defun calendar-print-julian-date ()
+  "Show the Julian calendar equivalent of the date under the cursor."
+  (interactive)
+  (message "Julian date: %s"
+           (calendar-julian-date-string (calendar-cursor-to-date t))))
+
+(defun calendar-goto-julian-date (date &optional noecho)
+  "Move cursor to Julian DATE; echo Julian date unless NOECHO is t."
+  (interactive
+   (let* ((today (calendar-current-date))
+          (year (calendar-read
+                 "Julian calendar year (>0): "
+                 '(lambda (x) (> x 0))
+                 (int-to-string
+                  (extract-calendar-year
+                   (calendar-julian-from-absolute
+                    (calendar-absolute-from-gregorian
+                     today))))))
+          (month-array calendar-month-name-array)
+          (completion-ignore-case t)
+          (month (cdr (assoc
+                       (capitalize
+                        (completing-read
+                         "Julian calendar month name: "
+                         (mapcar 'list (append month-array nil))
+                         nil t))
+                       (calendar-make-alist month-array 1 'capitalize))))
+          (last 
+           (if (and (zerop (% year 4)) (= month 2))
+               29
+             (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
+          (day (calendar-read
+                (format "Julian calendar day (%d-%d): "
+                        (if (and (= year 1) (= month 1)) 3 1) last)
+                '(lambda (x) 
+                   (and (< (if (and (= year 1) (= month 1)) 2 0) x)
+                        (<= x last))))))
+     (list (list month day year))))
+  (calendar-goto-date (calendar-gregorian-from-absolute
+                       (calendar-absolute-from-julian date)))
+  (or noecho (calendar-print-julian-date)))
+
+(defun holiday-julian (month day string)
+  "Holiday on MONTH, DAY  (Julian) called STRING.
+If MONTH, DAY (Julian) is visible, the value returned is corresponding
+Gregorian date in the form of the list (((month day year) STRING)).  Returns
+nil if it is not visible in the current calendar window."
+  (let ((m1 displayed-month)
+        (y1 displayed-year)
+        (m2 displayed-month)
+        (y2 displayed-year)
+        (year))
+    (increment-calendar-month m1 y1 -1)
+    (increment-calendar-month m2 y2 1)
+    (let* ((start-date (calendar-absolute-from-gregorian
+                        (list m1 1 y1)))
+           (end-date (calendar-absolute-from-gregorian
+                      (list m2 (calendar-last-day-of-month m2 y2) y2)))
+           (julian-start (calendar-julian-from-absolute start-date))
+           (julian-end (calendar-julian-from-absolute end-date))
+           (julian-y1 (extract-calendar-year julian-start))
+           (julian-y2 (extract-calendar-year julian-end)))
+      (setq year (if (< 10 month) julian-y1 julian-y2))
+      (let ((date (calendar-gregorian-from-absolute
+                   (calendar-absolute-from-julian
+                    (list month day year)))))
+        (if (calendar-date-is-visible-p date)
+            (list (list date string)))))))
+
+(defun diary-julian-date ()
+  "Julian calendar equivalent of date diary entry."
+  (format "Julian date: %s" (calendar-julian-date-string date)))
+
+(defun calendar-absolute-from-astro (d)
+  "Absolute date of astronical (Julian) day number D."
+  (- d 1721424.5))
+
+(defun calendar-astro-from-absolute (d)
+  "Astronomical (Julian) day number of absolute date D."
+  (+ d 1721424.5))
+
+(defun calendar-astro-date-string (&optional date)
+  "String of astronomical (Julian) day number after noon UTC of Gregorian DATE.
+Defaults to today's date if DATE is not given."
+  (int-to-string
+   (ceiling
+    (calendar-astro-from-absolute
+     (calendar-absolute-from-gregorian
+      (or date (calendar-current-date)))))))
+
+(defun calendar-print-astro-day-number ()
+  "Show astronomical (Julian) day number after noon UTC on date shown by cursor."
+  (interactive)
+  (message
+   "Astronomical (Julian) day number (after noon UTC): %s"
+   (calendar-astro-date-string (calendar-cursor-to-date t))))
+
+(defun calendar-goto-astro-day-number (daynumber &optional noecho)
+  "Move cursor to astronomical (Julian) DAYNUMBER.
+Echo astronomical (Julian) day number unless NOECHO is t."
+  (interactive (list (calendar-read
+                      "Astronomical (Julian) day number (>1721425): "
+                      '(lambda (x) (> x 1721425)))))
+  (calendar-goto-date
+   (calendar-gregorian-from-absolute
+    (floor
+     (calendar-absolute-from-astro daynumber))))
+  (or noecho (calendar-print-astro-day-number)))
+
+(defun diary-astro-day-number ()
+  "Astronomical (Julian) day number diary entry."
+  (format "Astronomical (Julian) day number %s"
+          (calendar-astro-date-string date)))
+
+(provide 'cal-julian)
+
+;;; cal-julian.el ends here