Commit 0f443a12 authored by NicolasPetton's avatar NicolasPetton
Browse files

New library thunk.el

thunk.el is extracted from stream.el in ELPA, with additional tests.

* lisp/emacs-lisp/thunk.el: New file.
* test/automated/thunk-tests.el: New file.
* etc/NEWS: Add information about thunk.el
parent 71d6acff
......@@ -582,6 +582,11 @@ prefixed with `seq-' and work on lists, strings and vectors.
The map library provides map-manipulation functions that work on alists,
hash-table and arrays. All functions are prefixed with "map-".
** thunk
*** New thunk library:
Thunk provides functions and macros to control the evaluation of
forms.
** Calendar and diary
+++
......
;;; thunk.el --- Lazy form evaluation -*- lexical-binding: t -*-
;; Copyright (C) 2015 Free Software Foundation, Inc.
;; Author: Nicolas Petton <nicolas@petton.fr>
;; Keywords: sequences
;; Version: 1.0
;; Package: thunk
;; Maintainer: emacs-devel@gnu.org
;; This file is part of GNU Emacs.
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;;
;; Thunk provides functions and macros to control the evaluation of
;; forms. Use `thunk-delay' to delay the evaluation of a form, and
;; `thunk-force' to evaluate it. Evaluation is cached, and only
;; happens once.
;; Tests are located at test/automated/thunk-tests.el
;;; Code:
(defmacro thunk-delay (&rest body)
"Delay the evaluation of BODY."
(declare (debug t))
(let ((forced (make-symbol "forced"))
(val (make-symbol "val")))
`(let (,forced ,val)
(lambda (&optional check)
(if check
,forced
(unless ,forced
(setf ,val (progn ,@body))
(setf ,forced t)))
,val))))
(defun thunk-force (delayed)
"Force the evaluation of DELAYED.
The result is cached and will be returned on subsequent calls
with the same DELAYED argument."
(funcall delayed))
(defun thunk-evaluated-p (delayed)
"Return non-nil if DELAYED has been evaluated."
(funcall delayed t))
(provide 'thunk)
;;; thunk.el ends here
;;; thunk-tests.el --- Tests for thunk.el -*- lexical-binding: t -*-
;; Copyright (C) 2015 Free Software Foundation, Inc.
;; Author: Nicolas Petton <nicolas@petton.fr>
;; Maintainer: emacs-devel@gnu.org
;; This file is part of GNU Emacs.
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;; Tests for thunk.el
;;; Code:
(require 'ert)
(require 'thunk)
(ert-deftest thunk-should-be-lazy ()
(let (x)
(thunk-delay (setq x t))
(should (null x))))
(ert-deftest thunk-can-be-evaluated ()
(let* (x
(thunk (thunk-delay (setq x t))))
(should-not (thunk-evaluated-p thunk))
(should (null x))
(thunk-force thunk)
(should (thunk-evaluated-p thunk))
(should x)))
(ert-deftest thunk-evaluation-is-cached ()
(let* ((x 0)
(thunk (thunk-delay (setq x (1+ x)))))
(thunk-force thunk)
(should (= x 1))
(thunk-force thunk)
(should (= x 1))))
(provide 'thunk-tests)
;;; thunk-tests.el ends here
Markdown is supported
0% or .
You are about to add 0 people to the discussion. Proceed with caution.
Finish editing this message first!
Please register or to comment