mh-print.el 9.01 KB
Newer Older
1 2
;;; mh-print.el --- MH-E printing support

Paul Eggert's avatar
Paul Eggert committed
3
;; Copyright (C) 2003-2020 Free Software Foundation, Inc.
4 5 6 7 8 9 10 11

;; Author: Jeffrey C Honig <jch@honig.net>
;; Maintainer: Bill Wohler <wohler@newt.com>
;; Keywords: mail
;; See: mh-e.el

;; This file is part of GNU Emacs.

12
;; GNU Emacs is free software: you can redistribute it and/or modify
13
;; it under the terms of the GNU General Public License as published by
14 15
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
16 17 18 19 20 21 22

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
23
;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
24 25 26 27 28 29 30

;;; Commentary:

;;; Change Log:

;;; Code:

Bill Wohler's avatar
Bill Wohler committed
31 32 33
(require 'mh-e)
(require 'mh-scan)

34 35 36
(require 'ps-print)

(defvar mh-ps-print-color-option ps-print-color-p
37 38 39 40 41 42 43
  "Specify how buffer's text color is printed.

Valid values are:

   nil         - Do not print colors.
   t           - Print colors.
   black-white - Print colors on black/white printer.
Bill Wohler's avatar
Bill Wohler committed
44
                 See also `ps-black-white-faces'.
45

46 47
Any other value is treated as t. This variable is initialized
from `ps-print-color-p'.")
48 49 50

(defvar mh-ps-print-func 'ps-spool-buffer-with-faces
  "Function to use to spool a buffer.
51

52 53 54 55 56
Sensible choices are the functions `ps-spool-buffer' and
`ps-spool-buffer-with-faces'.")

;;;###mh-autoload
(defun mh-ps-print-msg (range)
57
  "Print RANGE\\<mh-folder-mode-map>.
58

59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74
Check the documentation of `mh-interactive-range' to see how RANGE is
read in interactive use.

This command will print inline text attachments but will not decrypt
messages. However, when a message is displayed in an MH-Show buffer,
then that buffer is used verbatim for printing with the caveat that
only text attachments, if opened inline, are printed. Therefore,
encrypted messages can be printed by showing and decrypting them
first.

MH-E uses the \"ps-print\" package to do the printing, so you can
customize the printing further by going to the `ps-print'
customization group. This command does not use the options
`mh-lpr-command-format' or `mh-print-background-flag'. See also the
commands \\[mh-ps-print-toggle-color] and
\\[mh-ps-print-toggle-faces]."
75 76
  (interactive (list (mh-interactive-range "Print")))
  (mh-ps-print-range range nil))
77

Bill Wohler's avatar
Bill Wohler committed
78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106
(defun mh-ps-print-range (range file)
  "Print RANGE to FILE.

This is the function that actually does the work.
If FILE is nil, then the messages are spooled to the printer."
  (mh-iterate-on-range msg range
    (unwind-protect
        (mh-ps-spool-msg msg))
    (mh-notate msg mh-note-printed mh-cmd-note))
  (ps-despool file))

(defun mh-ps-spool-msg (msg)
  "Spool MSG."
  (let* ((folder mh-current-folder)
         (buffer (mh-in-show-buffer (mh-show-buffer)
                   (if (not (equal (mh-msg-filename msg folder)
                                   buffer-file-name))
                       (get-buffer-create mh-temp-buffer)))))
    (unwind-protect
        (save-excursion
          (if buffer
              (let ((mh-show-buffer buffer))
                (mh-display-msg msg folder)))
          (mh-ps-spool-buffer (if buffer buffer mh-show-buffer)))
      (if buffer
          (kill-buffer buffer)))))

(defun mh-ps-spool-buffer (buffer)
  "Spool BUFFER."
107
  (with-current-buffer buffer
Bill Wohler's avatar
Bill Wohler committed
108 109 110 111 112 113 114 115 116 117 118
    (let ((ps-print-color-p mh-ps-print-color-option)
          (ps-left-header
           (list
            (concat "(" (mh-get-header-field "Subject:") ")")
            (concat "(" (mh-get-header-field "From:") ")")))
          (ps-right-header
           (list
            "/pagenumberstring load"
            (concat "(" (mh-get-header-field "Date:") ")"))))
      (funcall mh-ps-print-func))))

119
;;;###mh-autoload
120
(defun mh-ps-print-msg-file (range file)
121
  "Print RANGE to FILE\\<mh-folder-mode-map>.
122

123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138
Check the documentation of `mh-interactive-range' to see how RANGE is
read in interactive use.

This command will print inline text attachments but will not decrypt
messages. However, when a message is displayed in an MH-Show buffer,
then that buffer is used verbatim for printing with the caveat that
only text attachments, if opened inline, are printed. Therefore,
encrypted messages can be printed by showing and decrypting them
first.

MH-E uses the \"ps-print\" package to do the printing, so you can
customize the printing further by going to the `ps-print'
customization group. This command does not use the options
`mh-lpr-command-format' or `mh-print-background-flag'. See also the
commands \\[mh-ps-print-toggle-color] and
\\[mh-ps-print-toggle-faces]."
139 140
  (interactive (list (mh-interactive-range "Print") (mh-ps-print-preprint 1)))
  (mh-ps-print-range range file))
141

142
(defun mh-ps-print-preprint (arg)
Bill Wohler's avatar
Bill Wohler committed
143
  "Provide a better default file name for `ps-print-preprint'.
144
Pass along the prefix ARG to it."
Bill Wohler's avatar
Bill Wohler committed
145
  (let ((buffer-file-name (format "mh-%s" (substring (buffer-name) 1))))
146
    (ps-print-preprint arg)))
Bill Wohler's avatar
Bill Wohler committed
147

148 149
;;;###mh-autoload
(defun mh-ps-print-toggle-faces ()
150 151
 "Toggle whether printing is done with faces or not.

152 153
When faces are enabled, the printed message will look very
similar to the message in the MH-Show buffer."
154 155 156 157 158 159 160 161 162 163
 (interactive)
 (if (eq mh-ps-print-func 'ps-spool-buffer-with-faces)
     (progn
       (setq mh-ps-print-func 'ps-spool-buffer)
       (message "Printing without faces"))
   (setq mh-ps-print-func 'ps-spool-buffer-with-faces)
   (message "Printing with faces")))

;;;###mh-autoload
(defun mh-ps-print-toggle-color ()
164 165
  "Toggle whether color is used in printing messages.

166 167 168 169 170 171
Colors are emulated on black-and-white printers with shades of
gray. This might produce illegible output, even if your screen
colors only use shades of gray. If this is the case, try using
this command to toggle between color, no color, and a black and
white representation of the colors and see which works best. You
change this setting permanently by customizing the option
172
`ps-print-color-p'."
173 174 175 176
 (interactive)
 (if (eq mh-ps-print-color-option nil)
     (progn
       (setq mh-ps-print-color-option 'black-white)
177
       (message "Colors will be printed as black & white"))
178 179
   (if (eq mh-ps-print-color-option 'black-white)
       (progn
Bill Wohler's avatar
Bill Wohler committed
180 181
         (setq mh-ps-print-color-option t)
         (message "Colors will be printed"))
182
     (setq mh-ps-print-color-option nil)
183
     (message "Colors will not be printed"))))
184

Bill Wohler's avatar
Bill Wohler committed
185
;; Old non-PS based printing
186 187
;;;###mh-autoload
(defun mh-print-msg (range)
188
  "Print RANGE the old fashioned way\\<mh-folder-mode-map>.
189

190 191 192
The message is formatted with \"mhl\" (see option
`mh-mhl-format-file') and printed with the \"lpr\" command (see
option `mh-lpr-command-format').
193

194 195
Check the documentation of `mh-interactive-range' to see how
RANGE is read in interactive use.
196

197
Consider using \\[mh-ps-print-msg] instead."
198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228
  (interactive (list (mh-interactive-range "Print")))
  (message "Printing...")
  (let (msgs)
    ;; Gather message numbers and add them to "printed" sequence.
    (mh-iterate-on-range msg range
      (mh-add-msgs-to-seq msg 'printed t)
      (mh-notate nil mh-note-printed mh-cmd-note)
      (push msg msgs))
    (setq msgs (nreverse msgs))
    ;; Print scan listing if we have more than one message.
    (if (> (length msgs) 1)
        (let* ((msgs-string
                (mapconcat 'identity (mh-list-to-string
                                      (mh-coalesce-msg-list msgs)) " "))
               (lpr-command
                (format mh-lpr-command-format
                        (cond ((listp range)
                               (format "Folder: %s, Messages: %s"
                                       mh-current-folder msgs-string))
                              ((symbolp range)
                               (format "Folder: %s, Sequence: %s"
                                       mh-current-folder range)))))
               (scan-command
                (format "scan %s | %s" msgs-string lpr-command)))
          (if mh-print-background-flag
              (mh-exec-cmd-daemon shell-file-name nil "-c" scan-command)
            (call-process shell-file-name nil nil nil "-c" scan-command))))
    ;; Print the messages
    (dolist (msg msgs)
      (let* ((mhl-command (format "%s %s %s"
                                  (expand-file-name "mhl" mh-lib-progs)
229 230
                                  (if mh-mhl-format-file
                                      (format " -form %s" mh-mhl-format-file)
231 232 233 234 235 236 237 238 239 240 241 242 243 244
                                    "")
                                  (mh-msg-filename msg)))
             (lpr-command
              (format mh-lpr-command-format
                      (format "%s/%s" mh-current-folder msg)))
             (print-command
              (format "%s | %s" mhl-command lpr-command)))
        (if mh-print-background-flag
            (mh-exec-cmd-daemon shell-file-name nil "-c" print-command)
          (call-process shell-file-name nil nil nil "-c" print-command)))))
  (message "Printing...done"))

(provide 'mh-print)

Bill Wohler's avatar
Bill Wohler committed
245 246 247 248
;; Local Variables:
;; indent-tabs-mode: nil
;; sentence-end-double-space: nil
;; End:
249 250

;;; mh-print.el ends here